formal-model/urcu-paulmck/urcu-paulmck.spin

   1 /*
   2  * urcu_mbmin.spin: Promela code to validate urcu.  See commit number
   3  *      3a9e6e9df706b8d39af94d2f027210e2e7d4106e of Mathieu Desnoyer's
   4  *      git archive at git://lttng.org/userspace-rcu.git, but with
   5  *      memory barriers removed.
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published by
   9  * the Free Software Foundation; either version 2 of the License, or
  10  * (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20  *
  21  * Copyright (c) 2009 Paul E. McKenney, IBM Corporation.
  22  */
  23
  24 /* Promela validation variables. */
  25
  26 bit removed = 0;  /* Has RCU removal happened, e.g., list_del_rcu()? */
  27 bit free = 0;     /* Has RCU reclamation happened, e.g., kfree()? */
  28 bit need_mb = 0;  /* =1 says need reader mb, =0 for reader response. */
  29 byte reader_progress[4];
  30                   /* Count of read-side statement executions. */
  31
  32 /* urcu definitions and variables, taken straight from the algorithm. */
  33
  34 #define RCU_GP_CTR_BIT (1 << 7)
  35 #define RCU_GP_CTR_NEST_MASK (RCU_GP_CTR_BIT - 1)
  36
  37 byte urcu_gp_ctr = 1;
  38 byte urcu_active_readers = 0;
  39
  40 /* Model the RCU read-side critical section. */
  41
  42 proctype urcu_reader()
  43 {
  44         bit done = 0;
  45         bit mbok;
  46         byte tmp;
  47         byte tmp_removed;
  48         byte tmp_free;
  49
  50         /* Absorb any early requests for memory barriers. */
  51         do
  52         :: need_mb == 1 ->
  53                 need_mb = 0;
  54         :: 1 -> skip;
  55         :: 1 -> break;
  56         od;
  57
  58         /*
  59          * Each pass through this loop executes one read-side statement
  60          * from the following code fragment:
  61          *
  62          *      rcu_read_lock(); [0a]
  63          *      rcu_read_lock(); [0b]
  64          *      p = rcu_dereference(global_p); [1]
  65          *      x = p->data; [2]
  66          *      rcu_read_unlock(); [3b]
  67          *      rcu_read_unlock(); [3a]
  68          *
  69          * Because we are modeling a weak-memory machine, these statements
  70          * can be seen in any order, the only restriction being that
  71          * rcu_read_unlock() cannot precede the corresponding rcu_read_lock().
  72          * The placement of the inner rcu_read_lock() and rcu_read_unlock()
  73          * is non-deterministic, the above is but one possible placement.
  74          * Intestingly enough, this model validates all possible placements
  75          * of the inner rcu_read_lock() and rcu_read_unlock() statements,
  76          * with the only constraint being that the rcu_read_lock() must
  77          * precede the rcu_read_unlock().
  78          *
  79          * We also respond to memory-barrier requests, but only if our
  80          * execution happens to be ordered.  If the current state is
  81          * misordered, we ignore memory-barrier requests.
  82          */
  83         do
  84         :: 1 ->
  85                 if
  86                 :: reader_progress[0] < 2 -> /* [0a and 0b] */
  87                         tmp = urcu_active_readers;
  88                         if
  89                         :: (tmp & RCU_GP_CTR_NEST_MASK) == 0 ->
  90                                 tmp = urcu_gp_ctr;
  91                                 do
  92                                 :: (reader_progress[1] +
  93                                     reader_progress[2] +
  94                                     reader_progress[3] == 0) && need_mb == 1 ->
  95                                         need_mb = 0;
  96                                 :: 1 -> skip;
  97                                 :: 1 -> break;
  98                                 od;
  99                                 urcu_active_readers = tmp;
 100                          :: else ->
 101                                 urcu_active_readers = tmp + 1;
 102                         fi;
 103                         reader_progress[0] = reader_progress[0] + 1;
 104                 :: reader_progress[1] == 0 -> /* [1] */
 105                         tmp_removed = removed;
 106                         reader_progress[1] = 1;
 107                 :: reader_progress[2] == 0 -> /* [2] */
 108                         tmp_free = free;
 109                         reader_progress[2] = 1;
 110                 :: ((reader_progress[0] > reader_progress[3]) &&
 111                     (reader_progress[3] < 2)) -> /* [3a and 3b] */
 112                         tmp = urcu_active_readers - 1;
 113                         urcu_active_readers = tmp;
 114                         reader_progress[3] = reader_progress[3] + 1;
 115                 :: else -> break;
 116                 fi;
 117
 118                 /* Process memory-barrier requests, if it is safe to do so. */
 119                 atomic {
 120                         mbok = 0;
 121                         tmp = 0;
 122                         do
 123                         :: tmp < 4 && reader_progress[tmp] == 0 ->
 124                                 tmp = tmp + 1;
 125                                 break;
 126                         :: tmp < 4 && reader_progress[tmp] != 0 ->
 127                                 tmp = tmp + 1;
 128                         :: tmp >= 4 &&
 129                            reader_progress[0] == reader_progress[3] ->
 130                                 done = 1;
 131                                 break;
 132                         :: tmp >= 4 &&
 133                            reader_progress[0] != reader_progress[3] ->
 134                                 break;
 135                         od;
 136                         do
 137                         :: tmp < 4 && reader_progress[tmp] == 0 ->
 138                                 tmp = tmp + 1;
 139                         :: tmp < 4 && reader_progress[tmp] != 0 ->
 140                                 break;
 141                         :: tmp >= 4 ->
 142                                 mbok = 1;
 143                                 break;
 144                         od
 145
 146                 }
 147
 148                 if
 149                 :: mbok == 1 ->
 150                         /* We get here if mb processing is safe. */
 151                         do
 152                         :: need_mb == 1 ->
 153                                 need_mb = 0;
 154                         :: 1 -> skip;
 155                         :: 1 -> break;
 156                         od;
 157                 :: else -> skip;
 158                 fi;
 159
 160                 /*
 161                  * Check to see if we have modeled the entire RCU read-side
 162                  * critical section, and leave if so.
 163                  */
 164                 if
 165                 :: done == 1 -> break;
 166                 :: else -> skip;
 167                 fi
 168         od;
 169         assert((tmp_free == 0) || (tmp_removed == 1));
 170
 171         /* Process any late-arriving memory-barrier requests. */
 172         do
 173         :: need_mb == 1 ->
 174                 need_mb = 0;
 175         :: 1 -> skip;
 176         :: 1 -> break;
 177         od;
 178 }
 179
 180 /* Model the RCU update process. */
 181
 182 proctype urcu_updater()
 183 {
 184         byte tmp;
 185
 186         /* prior synchronize_rcu(), second counter flip. */
 187         need_mb = 1; /* mb() A */
 188         do
 189         :: need_mb == 1 -> skip;
 190         :: need_mb == 0 -> break;
 191         od;
 192         urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT;
 193         need_mb = 1; /* mb() B */
 194         do
 195         :: need_mb == 1 -> skip;
 196         :: need_mb == 0 -> break;
 197         od;
 198         do
 199         :: 1 ->
 200                 if
 201                 :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 &&
 202                    (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) !=
 203                    (urcu_gp_ctr & ~RCU_GP_CTR_NEST_MASK) ->
 204                         skip;
 205                 :: else -> break;
 206                 fi
 207         od;
 208         need_mb = 1; /* mb() C absolutely required by analogy with G */
 209         do
 210         :: need_mb == 1 -> skip;
 211         :: need_mb == 0 -> break;
 212         od;
 213
 214         /* Removal statement, e.g., list_del_rcu(). */
 215         removed = 1;
 216
 217         /* current synchronize_rcu(), first counter flip. */
 218         need_mb = 1; /* mb() D suggested */
 219         do
 220         :: need_mb == 1 -> skip;
 221         :: need_mb == 0 -> break;
 222         od;
 223         urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT;
 224         need_mb = 1;  /* mb() E required if D not present */
 225         do
 226         :: need_mb == 1 -> skip;
 227         :: need_mb == 0 -> break;
 228         od;
 229
 230         /* current synchronize_rcu(), first-flip check plus second flip. */
 231         if
 232         :: 1 ->
 233                 do
 234                 :: 1 ->
 235                         if
 236                         :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 &&
 237                            (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) !=
 238                            (urcu_gp_ctr & ~RCU_GP_CTR_NEST_MASK) ->
 239                                 skip;
 240                         :: else -> break;
 241                         fi;
 242                 od;
 243                 urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT;
 244         :: 1 ->
 245                 tmp = urcu_gp_ctr;
 246                 urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT;
 247                 do
 248                 :: 1 ->
 249                         if
 250                         :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 &&
 251                            (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) !=
 252                            (tmp & ~RCU_GP_CTR_NEST_MASK) ->
 253                                 skip;
 254                         :: else -> break;
 255                         fi;
 256                 od;
 257         fi;
 258
 259         /* current synchronize_rcu(), second counter flip check. */
 260         need_mb = 1; /* mb() F not required */
 261         do
 262         :: need_mb == 1 -> skip;
 263         :: need_mb == 0 -> break;
 264         od;
 265         do
 266         :: 1 ->
 267                 if
 268                 :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 &&
 269                    (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) !=
 270                    (urcu_gp_ctr & ~RCU_GP_CTR_NEST_MASK) ->
 271                         skip;
 272                 :: else -> break;
 273                 fi;
 274         od;
 275         need_mb = 1; /* mb() G absolutely required */
 276         do
 277         :: need_mb == 1 -> skip;
 278         :: need_mb == 0 -> break;
 279         od;
 280
 281         /* free-up step, e.g., kfree(). */
 282         free = 1;
 283 }
 284
 285 /*
 286  * Initialize the array, spawn a reader and an updater.  Because readers
 287  * are independent of each other, only one reader is needed.
 288  */
 289
 290 init {
 291         atomic {
 292                 reader_progress[0] = 0;
 293                 reader_progress[1] = 0;
 294                 reader_progress[2] = 0;
 295                 reader_progress[3] = 0;
 296                 run urcu_reader();
 297                 run urcu_updater();
 298         }
 299 }