configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.11.8],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  24 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  25 AC_PROG_CXX
  26 RW_PROG_CXX_WORKS
  27 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  28
  29 # Checks for programs.
  30 AC_PROG_GREP
  31 AC_PROG_MAKE_SET
  32 AC_PROG_SED
  33 AC_PATH_PROG([report_fold], [fold])
  34 LT_INIT
  35
  36 # Check for objcopy, required by the base address statedump and dynamic linker tests
  37 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  38 AS_IF([test "x$OBJCOPY" = "xno"],
  39         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  40 )
  41 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  42
  43 # check for pgrep
  44 AC_PATH_PROG([PGREP], [pgrep], [no])
  45 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  46
  47 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  48 # is not distributed in tarballs
  49 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  50 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  51
  52 # check for bison
  53 AC_PROG_YACC
  54 BISON=$YACC
  55 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  56
  57 AS_IF([test "x$have_bison" != "xyes"], [
  58   AS_IF([test "x$in_git_repo" = "xyes"], [
  59     AC_MSG_FAILURE([
  60 Bison >= 2.4 is required when building from the Git repository. You can
  61 set the YACC variable to override automatic detection.
  62     ])
  63   ], [
  64     AC_MSG_WARN([
  65 Missing Bison >= 2.4. Note that the parser files are already built in
  66 this distribution tarball, so Bison is only needed if you intend to
  67 modify their sources. You can set the YACC variable to override automatic
  68 detection.
  69     ])
  70   ])
  71 ])
  72 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  73
  74 # check for flex
  75 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
  76 # problem since the argument is silently ignored by older versions.
  77 AC_PROG_LEX([noyywrap])
  78 FLEX=$LEX
  79 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  80
  81 AS_IF([test "x$have_flex" != "xyes"], [
  82   AS_IF([test "x$in_git_repo" = "xyes"], [
  83     AC_MSG_FAILURE([
  84 Flex >= 2.5.35 is required when building from the Git repository. You can
  85 set the LEX variable to override automatic detection.
  86     ])
  87   ], [
  88     AC_MSG_WARN([
  89 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  90 this distribution tarball, so Flex is only needed if you intend to
  91 modify their sources. You can set the LEX variable to override automatic
  92 detection.
  93     ])
  94   ])
  95 ])
  96 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  97
  98
  99 # Checks for typedefs, structures, and compiler characteristics.
 100 AC_C_INLINE
 101 AC_TYPE_INT32_T
 102 AC_TYPE_INT64_T
 103 AC_TYPE_MODE_T
 104 AC_TYPE_OFF_T
 105 AC_TYPE_PID_T
 106 AC_TYPE_SIZE_T
 107 AC_TYPE_SSIZE_T
 108 AC_TYPE_UID_T
 109 AC_TYPE_UINT16_T
 110 AC_TYPE_UINT32_T
 111 AC_TYPE_UINT64_T
 112 AC_TYPE_UINT8_T
 113
 114 AX_C___ATTRIBUTE__
 115 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 116         [:],
 117         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 118
 119 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 120
 121 # Check if linker has the -no-pie option.
 122 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 123 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 124
 125 AX_LIB_SOCKET_NSL
 126
 127 LT_NO_UNDEFINED=""
 128 AS_CASE([$host_os],
 129   [cygwin*],
 130     [
 131       LT_NO_UNDEFINED="-no-undefined"
 132     ],
 133   [cygwin*|darwin*|mingw*|solaris*],
 134     [
 135       # On platforms where we only support the relayd, disable the other binaries by default
 136       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 137       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 138       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 139       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 140       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 141       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 142     ]
 143 )
 144
 145 AC_SUBST(LT_NO_UNDEFINED)
 146
 147 # Compute minor/major/patchlevel version numbers
 148 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 149 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 150 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 151
 152 AC_SUBST([MAJOR_VERSION], [$major_version])
 153 AC_SUBST([MINOR_VERSION], [$minor_version])
 154 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 155 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 156 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 157 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 158
 159 version_name="Lafontaine"
 160 version_description="A modern Saison beer from Montréal's Oshlag microbrewery, Lafontaine is a refreshing, zesty, rice beer with hints of fruit and spices."
 161 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 162
 163 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 164 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 165
 166 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 167 AC_ARG_ENABLE(libtool-linkdep-fixup,
 168         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 169                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 170         libtool_fixup=$enableval,
 171         libtool_fixup=yes)
 172
 173 AS_IF([test "x$libtool_fixup" = "xyes"],
 174             [
 175             libtool_m4="$srcdir/m4/libtool.m4"
 176             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 177             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 178             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 179             AS_IF([test $libtool_flag_pattern_count -ne 0],
 180             [
 181                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 182                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 183                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 184                   ],
 185                   [
 186                   AC_MSG_RESULT([none])
 187                   ])
 188             ])
 189
 190 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 191
 192 AC_CHECK_HEADERS([ \
 193         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 194         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 195         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 196         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 197         sys/mount.h sys/param.h sys/time.h elf.h
 198 ])
 199
 200 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 201
 202 # Basic functions check
 203 AC_CHECK_FUNCS([ \
 204         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 205         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 206         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 207         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 208         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 209         sched_getcpu sysconf sync_file_range
 210 ])
 211
 212 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 213 # add -lrt to LIBS
 214 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 215
 216 # Checks for dl.
 217 AC_CHECK_LIB([dl], [dlopen], [
 218         have_libdl=yes
 219         libdl_name=dl
 220         DL_LIBS="-ldl"
 221 ], [
 222         # libdl not found, check for dlopen in libc.
 223         AC_CHECK_LIB([c], [dlopen], [
 224                 have_libc_dl=yes
 225                 libdl_name=c
 226                 DL_LIBS="-lc"
 227         ], [
 228                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 229         ])
 230 ])
 231 AC_SUBST(DL_LIBS)
 232
 233 # Check if libdl has dlmopen support.
 234 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 235 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 236         AC_DEFINE([HAVE_DLMOPEN], [1])
 237         HAVE_DLMOPEN=1
 238 ], [
 239         HAVE_DLMOPEN=0
 240 ])
 241 AC_SUBST(HAVE_DLMOPEN)
 242
 243 # Babeltrace viewer check
 244 AC_ARG_WITH([babeltrace-bin],
 245         AS_HELP_STRING([--with-babeltrace-bin],
 246         [Location of the babeltrace viewer executable (including the filename)]),
 247         [BABELTRACE_BIN="$withval"],
 248         [BABELTRACE_BIN=''])
 249 AC_SUBST([BABELTRACE_BIN])
 250
 251 # lttv-gui
 252 AC_ARG_WITH([lttv-gui-bin],
 253         AS_HELP_STRING([--with-lttv-gui-bin],
 254    [Location of the lttv GUI viewer executable (including the filename)]),
 255    [LTTV_GUI_BIN="$withval"],
 256    [LTTV_GUI_BIN=''])
 257 AC_SUBST([LTTV_GUI_BIN])
 258
 259 AC_ARG_WITH([consumerd32-bin],
 260         AS_HELP_STRING([--with-consumerd32-bin],
 261         [Location of the 32-bit consumerd executable (including the filename)]),
 262         [CONSUMERD32_BIN="$withval"],
 263         [CONSUMERD32_BIN=''])
 264 AC_SUBST([CONSUMERD32_BIN])
 265
 266 AC_ARG_WITH([consumerd64-bin],
 267         AS_HELP_STRING([--with-consumerd64-bin],
 268         [Location of the 64-bit consumerd executable (including the filename)]),
 269         [CONSUMERD64_BIN="$withval"],
 270         [CONSUMERD64_BIN=''])
 271 AC_SUBST([CONSUMERD64_BIN])
 272
 273 AC_ARG_WITH([consumerd32-libdir],
 274         AS_HELP_STRING([--with-consumerd32-libdir],
 275         [Directory containing the 32-bit consumerd libraries]),
 276         [CONSUMERD32_LIBDIR="$withval"],
 277         [CONSUMERD32_LIBDIR=''])
 278 AC_SUBST([CONSUMERD32_LIBDIR])
 279
 280 AC_ARG_WITH([consumerd64-libdir],
 281         AS_HELP_STRING([--with-consumerd64-libdir],
 282         [Directory containing the 64-bit consumerd libraries]),
 283         [CONSUMERD64_LIBDIR="$withval"],
 284         [CONSUMERD64_LIBDIR=''])
 285 AC_SUBST([CONSUMERD64_LIBDIR])
 286
 287 AC_ARG_WITH([sessiond-bin],
 288         AS_HELP_STRING([--with-sessiond-bin],
 289         [Location of the sessiond executable (including the filename)]),
 290         [SESSIOND_BIN="$withval"],
 291         [SESSIOND_BIN=''])
 292 AC_SUBST([SESSIOND_BIN])
 293
 294 AC_ARG_WITH([lttng-system-rundir],
 295         AS_HELP_STRING([--with-lttng-system-rundir],
 296         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 297         [LTTNG_SYSTEM_RUNDIR="$withval"],
 298         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 299 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 300
 301 AC_ARG_ENABLE([test-java-agent-jul],
 302         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 303         [test_java_agent_jul=$enableval],
 304         [test_java_agent_jul=no]
 305 )
 306
 307 AC_ARG_ENABLE([test-java-agent-log4j],
 308         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 309         [test_java_agent_log4j=$enableval],
 310         [test_java_agent_log4j=no]
 311 )
 312
 313 AC_ARG_ENABLE([test-java-agent-all],
 314         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 315         [test_java_agent_jul=$enableval
 316          test_java_agent_log4j=$enableval],
 317         [:]
 318 )
 319
 320 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 321 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 322 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 323 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 324 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 325 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 326 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 327 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 328
 329 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 330         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 331         $1="$2"
 332         AC_SUBST([$1])
 333 ])
 334
 335 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 336         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 337         $1="$2"
 338         AC_SUBST([$1])
 339 ])
 340
 341 # Default values
 342 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 343 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 344 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 345 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 346 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 347 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 348 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 365 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 366 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 367 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 368 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 370 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 385 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 386 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 387 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 388 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 391
 392 # Command short descriptions
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 417 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 418 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 419
 420 if test "x$prefix" = "xNONE"; then
 421         prefix=$ac_default_prefix
 422 fi
 423 CONFDIR=`eval echo $sysconfdir`
 424 AC_SUBST(CONFDIR)
 425 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 426
 427 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 428
 429 # Check libpopt
 430 PKG_CHECK_MODULES([POPT], [popt],
 431   [
 432     dnl PKG_CHECK_MODULES defines POPT_LIBS
 433   ],
 434   [
 435     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 436     AC_MSG_WARN([Finding libpopt without pkg-config.])
 437     AC_CHECK_LIB([popt],
 438       [poptGetContext],
 439       [POPT_LIBS="-lpopt"],
 440       [
 441         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 442       ]
 443     )
 444   ]
 445 )
 446 AC_SUBST(POPT_LIBS)
 447
 448 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 449
 450 # First, check for uuid in system libs
 451 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 452 AC_CHECK_FUNCS([uuid_generate],
 453   [
 454     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 455     UUID_LIBS=""
 456   ],
 457   [
 458     # Then, check if the pkg-config module is available, otherwise explicitly check
 459     # for libuuid, or uuid support in the C-library.
 460     PKG_CHECK_MODULES([UUID], [uuid],
 461       [
 462         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 463         dnl PKG_CHECK_MODULES defines UUID_LIBS
 464       ],
 465       [
 466         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 467         AC_MSG_WARN([Finding libuuid without pkg-config.])
 468         AC_CHECK_LIB([uuid], [uuid_generate],
 469           [
 470             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 471             UUID_LIBS="-luuid"
 472           ],
 473           [
 474             # libuuid not found, check for uuid_create in libc.
 475             AC_CHECK_LIB([c], [uuid_create],
 476               [
 477                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 478                 UUID_LIBS="-lc"
 479               ],
 480               [
 481                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 482               ]
 483             )
 484           ]
 485         )
 486       ]
 487     )
 488   ]
 489 )
 490 AC_SUBST(UUID_LIBS)
 491
 492 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 493
 494 # URCU library version needed or newer
 495 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.11.0 is needed])
 496
 497 # Check liburcu needed function calls
 498 AC_CHECK_DECL([cds_list_add], [],
 499         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 500 AC_CHECK_DECL([cds_wfcq_init], [],
 501         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 502 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 503         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 504 AC_CHECK_DECL([futex_async], [],
 505         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 506 AC_CHECK_DECL([rcu_thread_offline], [],
 507         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 508 AC_CHECK_DECL([rcu_thread_online], [],
 509         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 510 AC_CHECK_DECL([caa_likely], [],
 511         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 512 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 513         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 514
 515 #Function added in urcu 0.7.0
 516 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 517         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 518 )
 519
 520 #Function added in urcu 0.11.0
 521 AC_CHECK_DECL([urcu_memb_barrier], [],
 522         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/urcu-memb.h>]]
 523 )
 524
 525 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 526 # it can be explicitly disabled with --without-kmod
 527 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 528 AC_ARG_WITH([kmod],
 529   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 530   [],
 531   [with_kmod=check]
 532 )
 533
 534 AS_IF([test "x$with_kmod" != "xno"],
 535   [
 536     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 537       [
 538         AC_DEFINE([HAVE_KMOD], [1])
 539         KMOD_LIBS="-lkmod"
 540       ],
 541       [
 542         if test "x$with_kmod" != xcheck; then
 543           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 544         else
 545           with_kmod=no
 546         fi
 547       ]
 548     )
 549   ]
 550 )
 551 AC_SUBST(KMOD_LIBS)
 552
 553 # Check for liblttng-ust-ctl, fail if it's not found,
 554 # it can be explicitly disabled with --without-lttng-ust
 555 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 556 AC_ARG_WITH([lttng-ust],
 557   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 558   [],
 559   [with_lttng_ust=yes]
 560 )
 561
 562 AS_IF([test "x$with_lttng_ust" = "xyes"],
 563   [
 564     AC_CHECK_LIB([lttng-ust-ctl], [lttng_ust_enum_get_from_desc],
 565       [
 566         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 567       ],
 568       [
 569         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.11.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 570       ]
 571     )
 572   ]
 573 )
 574 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 575
 576
 577 # Check for fmemopen
 578 AC_CHECK_LIB([c], [fmemopen],
 579 [
 580         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 581 ]
 582 )
 583
 584 # check for libpfm
 585 AC_CHECK_LIB([pfm], [pfm_initialize],
 586              [
 587               have_libpfm=yes
 588               ])
 589 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 590
 591 # For Python
 592 # SWIG version needed or newer:
 593 swig_version=2.0.0
 594
 595 AC_ARG_ENABLE([python-bindings],
 596               [AS_HELP_STRING([--enable-python-bindings],
 597                               [compile Python bindings])],
 598               [enable_python_binding=$enableval], [enable_python_binding=no])
 599
 600 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 601
 602 if test "x$enable_python_binding" = xyes; then
 603   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 604   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 605   AM_PATH_PYTHON([3.0])
 606
 607   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 608   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 609   AS_IF([test -z "$PYTHON_INCLUDE"], [
 610     AS_IF([test -z "$PYTHON_CONFIG"], [
 611       AC_PATH_PROGS([PYTHON_CONFIG],
 612                     [python$PYTHON_VERSION-config python-config],
 613                     [no],
 614                     [`dirname $PYTHON`])
 615       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 616     ])
 617     AC_MSG_CHECKING([python include flags])
 618     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 619     AC_MSG_RESULT([$PYTHON_INCLUDE])
 620   ])
 621
 622 else
 623     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 624 [if you want Python bindings.])
 625
 626 fi
 627
 628 # Epoll check. If not present, the build will fallback on poll() API
 629 AX_HAVE_EPOLL(
 630         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 631         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 632 )
 633 AX_CONFIG_FEATURE(
 634         [epoll], [This platform supports epoll(7)],
 635         [HAVE_EPOLL], [This platform supports epoll(7).],
 636         [enable_epoll="yes"], [enable_epoll="no"]
 637 )
 638 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 639
 640 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 641         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 642         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 643 )
 644 AX_CONFIG_FEATURE(
 645         [dirfd], [Use directory file descriptors],
 646         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 647         [enable_dirfd="yes"], [enable_dirfd="no"]
 648 )
 649 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 650
 651 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 652 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 653
 654 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 655         AX_JAVA_OPTIONS
 656         AX_PROG_JAVAC
 657         AX_PROG_JAVA
 658         AX_PROG_JAR
 659
 660         AX_CHECK_CLASSPATH
 661
 662         # Check for Java UST agent common class first
 663         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 664         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 665                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 666         fi
 667
 668         if test "x$test_java_agent_jul" = "xyes"; then
 669                 # Check for JUL agent class
 670                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 671                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 672                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 673                 fi
 674         fi
 675
 676         if test "x$test_java_agent_log4j" = "xyes"; then
 677                 # Check for Log4j agent class
 678                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 679                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 680                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 681                 fi
 682
 683                 # Check for Log4j class
 684                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 685                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 686                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 687                 fi
 688         fi
 689 fi
 690
 691 # enable building man pages (user's intention)
 692 AC_ARG_ENABLE(
 693         man-pages,
 694         AS_HELP_STRING(
 695                 [--disable-man-pages],
 696                 [Do not build and install man pages (already built in a distributed tarball)]
 697         ),
 698         [man_pages_opt=$enableval],
 699         [man_pages_opt=yes]
 700 )
 701
 702 # check for asciidoc and xmlto if we enabled building the man pages
 703 have_asciidoc_xmlto=no
 704 warn_prebuilt_man_pages=no
 705
 706 AS_IF([test "x$man_pages_opt" = "xyes"], [
 707         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 708         AC_PATH_PROG([XMLTO], [xmlto], [no])
 709
 710         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 711                 AS_IF([test "x$in_git_repo" = "xyes"], [
 712                         # this is an error because we're in the Git repo, which
 713                         # means the man pages are not already generated for us,
 714                         # thus asciidoc/xmlto are required because we were asked
 715                         # to build the man pages
 716                         AC_MSG_ERROR([
 717 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 718 --disable-man-pages to disable building the man pages, in which case
 719 they will not be installed.
 720                         ])
 721                 ], [
 722                         # only warn here: since we're in the tarball, the man
 723                         # pages should already be generated at this point, thus
 724                         # asciidoc/xmlto are not strictly required
 725                         warn_prebuilt_man_pages=yes
 726                 ])
 727         ], [
 728                 have_asciidoc_xmlto=yes
 729         ])
 730 ])
 731
 732 # export man page build condition: build the man pages if the user
 733 # asked for it, and if the tools are available
 734 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 735 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 736
 737 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 738
 739 # embedded --help message
 740 AC_ARG_ENABLE(
 741         [embedded-help],
 742         AS_HELP_STRING(
 743                 [--enable-embedded-help],
 744                 [Embed the --help messages in the executable files]
 745         ),
 746         [embedded_help=$enableval],
 747         [embedded_help=no]
 748 )
 749 AS_IF([test "x$embedded_help" = "xyes"], [
 750         AS_IF([test "x$man_pages_opt" = "xno"], [
 751                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 752         ])
 753         AC_PATH_PROG([man_prog_path], [man], [no])
 754         AS_IF([test "x$man_prog_path" = "xno"], [
 755                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 756         ])
 757         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 758         AC_SUBST([MANPROG], [$man_prog_path])
 759 ])
 760 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 761
 762 # Python agent test
 763 UST_PYTHON_AGENT="lttngust"
 764
 765 AC_ARG_ENABLE(test-python2-agent,
 766         AS_HELP_STRING([--enable-test-python2-agent],
 767                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 768         ),[:],[test_python2_agent_autodetect=yes]
 769 )
 770
 771 AC_ARG_ENABLE(test-python3-agent,
 772         AS_HELP_STRING([--enable-test-python3-agent],
 773                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 774         ),[:],[test_python3_agent_autodetect=yes]
 775 )
 776
 777 AC_ARG_ENABLE(test-python-agent-all,
 778         AS_HELP_STRING([--enable-test-python-agent-all],
 779                 [enable test for all python{2/3} agent.]
 780         ),
 781 )
 782
 783 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 784        unset test_python2_agent_autodetect
 785        unset test_python3_agent_autodetect
 786 ])
 787
 788 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 789        enable_test_python2_agent=yes
 790        enable_test_python3_agent=yes
 791 ])
 792
 793 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 794        enable_test_python2_agent=no
 795        enable_test_python3_agent=no
 796 ])
 797
 798
 799 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 800         AS_IF([test -z "$PYTHON2"], [
 801                         PYTHON2=python2
 802                 ], [
 803                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 804         ])
 805
 806         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 807         AS_IF([test -z "$PYTHON2_BIN"], [
 808                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 809                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 810                 ])
 811         ], [
 812                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 813                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 814                         PYTHON2_AGENT=$PYTHON2_BIN
 815                         AC_MSG_RESULT([yes])
 816                         RUN_PYTHON_AGENT_TEST=yes
 817                 ], [
 818                         AC_MSG_RESULT([no])
 819                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 820                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 821                         ])
 822                 ])
 823
 824         ])
 825
 826 ])
 827
 828 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 829         AS_IF([test -z "$PYTHON3"], [
 830                 PYTHON3=python3
 831         ], [
 832                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 833         ])
 834
 835         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 836         AS_IF([test -z "$PYTHON3_BIN"], [
 837                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 838                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 839                 ])
 840         ], [
 841                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 842                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 843                         PYTHON3_AGENT=$PYTHON3_BIN
 844                         AC_MSG_RESULT([yes])
 845                         RUN_PYTHON_AGENT_TEST=yes
 846                 ], [
 847                         AC_MSG_RESULT([no])
 848                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 849                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 850                         ])
 851                 ])
 852
 853         ])
 854 ])
 855 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 856 AC_SUBST([PYTHON2_AGENT])
 857 AC_SUBST([PYTHON3_AGENT])
 858
 859 AC_ARG_ENABLE([test-sdt-uprobe],
 860   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 861   [test_sdt_uprobe="$enableval"],
 862   [test_sdt_uprobe=autodetect]
 863 )
 864
 865 AS_IF([test "$test_sdt_uprobe" != "no"], [
 866   LTTNG_CHECK_SDT_WORKS
 867   AC_PATH_PROG([DTRACE], [dtrace])
 868 ])
 869
 870 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 871   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 872     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 873   ])
 874   AS_IF([test "x$DTRACE" = "x"], [
 875     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 876   ])
 877 ])
 878
 879 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 880   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 881     AS_IF([test "x$DTRACE" != "x"], [
 882       test_sdt_uprobe=yes
 883     ])
 884   ])
 885 ])
 886
 887 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 888
 889 # Arguments for binaries build exclusion
 890 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 891 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 892               [Disable the build of lttng-consumerd binaries]))
 893 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 894 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 895               [Disable the build of lttng-relayd binaries]))
 896 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 897               [Disable the build of lttng-sessiond binaries]))
 898 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 899               [Disable the build of the extra components]))
 900
 901
 902 # Always build libconfig since it a dependency of libcommon
 903 build_lib_config=yes
 904
 905 build_lib_compat=no
 906 build_lib_consumer=no
 907 build_lib_hashtable=no
 908 build_lib_health=no
 909 build_lib_index=no
 910 build_lib_kernel_consumer=no
 911 build_lib_kernel_ctl=no
 912 build_lib_lttng_ctl=no
 913 build_lib_relayd=no
 914 build_lib_sessiond_comm=no
 915 build_lib_testpoint=no
 916 build_lib_ust_consumer=no
 917
 918 # There is an overlap for enabled dependencies, but this makes everything
 919 # simpler. libcommon and libconfig are always compiled so they are not repeated
 920 # here.
 921
 922 # Enable binary dependencies.
 923 AS_IF([test x$enable_bin_lttng != xno],
 924       [
 925        build_lib_lttng_ctl=yes
 926       ]
 927 )
 928
 929 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 930       [
 931        build_lib_consumer=yes
 932        build_lib_sessiond_comm=yes
 933        build_lib_index=yes
 934        build_lib_health=yes
 935        build_lib_testpoint=yes
 936       ]
 937 )
 938
 939 AS_IF([test x$enable_bin_lttng_crash != xno],
 940       # Do nothing since libconfig and libcommon are built by default.
 941       []
 942 )
 943
 944 AS_IF([test x$enable_bin_lttng_relayd != xno],
 945       [
 946        build_lib_lttng_ctl=yes
 947        build_lib_sessiond_comm=yes
 948        build_lib_hashtable=yes
 949        build_lib_compat=yes
 950        build_lib_index=yes
 951        build_lib_health=yes
 952        build_lib_testpoint=yes
 953       ]
 954 )
 955 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 956       [
 957        build_lib_lttng_ctl=yes
 958        build_lib_sessiond_comm=yes
 959        build_lib_kernel_ctl=yes
 960        build_lib_hashtable=yes
 961        build_lib_compat=yes
 962        build_lib_relayd=yes
 963        build_lib_testpoint=yes
 964        build_lib_health=yes
 965       ]
 966 )
 967
 968 # Libraries dependencies enabling
 969 AS_IF([test x$build_lib_lttng_ctl = xyes],
 970       [
 971        build_lib_sessiond_comm=yes
 972        build_lib_hashtable=yes
 973       ]
 974 )
 975
 976 AS_IF([test x$build_lib_consumer = xyes],
 977       [
 978        build_lib_sessiond_comm=yes
 979        build_lib_kernel_consumer=yes
 980        build_lib_hashtable=yes
 981        build_lib_compat=yes
 982        build_lib_relayd=yes
 983        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 984       ]
 985 )
 986
 987 AS_IF([test x$build_lib_kernel_consumer = xyes],
 988       [
 989        build_lib_kernel_ctl=yes
 990        build_lib_relayd=yes
 991       ]
 992 )
 993
 994 AS_IF([test x$build_lib_relayd = xyes],
 995       [
 996        build_lib_sessiond_comm=yes
 997       ]
 998 )
 999
1000 # Find arch type
1001 AS_CASE([$host_cpu],
1002         [k1om], [ARCHTYPE="x86"],
1003         [i386], [ARCHTYPE="x86"],
1004         [i486], [ARCHTYPE="x86"],
1005         [i586], [ARCHTYPE="x86"],
1006         [i686], [ARCHTYPE="x86"],
1007         [amd64], [ARCHTYPE="x86"],
1008         [x86_64], [ARCHTYPE="x86"],
1009         [powerpc], [ARCHTYPE="ppc"],
1010         [ppc64], [ARCHTYPE="ppc"],
1011         [powerpc64], [ARCHTYPE="ppc"],
1012         [powerpc64le], [ARCHTYPE="ppc"],
1013         [ppc], [ARCHTYPE="ppc"],
1014         [s390], [ARCHTYPE="s390"],
1015         [s390x], [ARCHTYPE="s390"],
1016         [sparc], [ARCHTYPE="sparc64"],
1017         [sparc64], [ARCHTYPE="sparc64"],
1018         [alpha*], [ARCHTYPE="alpha"],
1019         [ia64], [ARCHTYPE="ia64"],
1020         [arm*], [ARCHTYPE="arm"],
1021         [aarch64*], [ARCHTYPE="aarch64"],
1022         [mips*], [ARCHTYPE="mips"],
1023         [nios2*], [ARCHTYPE="nios2"],
1024         [tile*], [ARCHTYPE="tile"],
1025         [hppa*], [ARCHTYPE="hppa"],
1026         [m68k], [ARCHTYPE="m68k"],
1027         [riscv*], [ARCHTYPE="riscv"],
1028         [ARCHTYPE="unknown"]
1029 )
1030
1031 AC_SUBST(ARCHTYPE)
1032
1033 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1034 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1035 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1036         # Userspace callstack capture is only supported by the Linux kernel on x86.
1037         AC_MSG_RESULT([yes])
1038         have_modules_userspace_callstack_context=yes
1039         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1040 ], [
1041         AC_MSG_RESULT([no])
1042         have_modules_userspace_callstack_context=no
1043 ])
1044 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1045
1046 # Export binaries build conditions.
1047 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1048 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1049 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1050 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1051 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1052
1053 # Export the tests and extras build conditions.
1054 AS_IF([\
1055 test "x$enable_bin_lttng" != "xno" && \
1056 test "x$enable_bin_lttng_consumerd" != "xno" && \
1057 test "x$enable_bin_lttng_crash" != "xno" && \
1058 test "x$enable_bin_lttng_relayd" != "xno" && \
1059 test "x$enable_bin_lttng_sessiond" != "xno"],
1060 [build_tests=yes],
1061 [build_tests=no]
1062 )
1063
1064 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1065 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1066
1067 # Export libraries build conditions.
1068 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1069 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1070 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1071 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1072 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1073 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1074 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1075 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1076 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1077 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1078 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1079 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1080 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1081
1082 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1083 AC_SUBST(AM_CFLAGS)
1084
1085 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1086 AC_SUBST(AM_CPPFLAGS)
1087
1088 lttngincludedir="${includedir}/lttng"
1089 AC_SUBST(lttngincludedir)
1090
1091 lttngactionincludedir="${includedir}/lttng/action"
1092 AC_SUBST(lttngactionincludedir)
1093
1094 lttngconditionincludedir="${includedir}/lttng/condition"
1095 AC_SUBST(lttngconditionincludedir)
1096
1097 lttngnotificationincludedir="${includedir}/lttng/notification"
1098 AC_SUBST(lttngnotificationincludedir)
1099
1100 lttngtriggerincludedir="${includedir}/lttng/trigger"
1101 AC_SUBST(lttngtriggerincludedir)
1102
1103 lttnglibexecdir="${libdir}/lttng/libexec"
1104 AC_SUBST(lttnglibexecdir)
1105
1106 AC_CONFIG_FILES([
1107         Makefile
1108         doc/Makefile
1109         doc/man/Makefile
1110         doc/man/asciidoc-attrs.conf
1111         include/Makefile
1112         extras/Makefile
1113         extras/bindings/Makefile
1114         extras/bindings/swig/Makefile
1115         extras/bindings/swig/python/Makefile
1116         extras/core-handler/Makefile
1117         src/Makefile
1118         src/common/Makefile
1119         src/common/kernel-ctl/Makefile
1120         src/common/kernel-consumer/Makefile
1121         src/common/consumer/Makefile
1122         src/common/ust-consumer/Makefile
1123         src/common/hashtable/Makefile
1124         src/common/sessiond-comm/Makefile
1125         src/common/compat/Makefile
1126         src/common/relayd/Makefile
1127         src/common/testpoint/Makefile
1128         src/common/index/Makefile
1129         src/common/health/Makefile
1130         src/common/config/Makefile
1131         src/common/string-utils/Makefile
1132         src/lib/Makefile
1133         src/lib/lttng-ctl/Makefile
1134         src/lib/lttng-ctl/filter/Makefile
1135         src/lib/lttng-ctl/lttng-ctl.pc
1136         src/bin/Makefile
1137         src/bin/lttng-consumerd/Makefile
1138         src/bin/lttng-sessiond/Makefile
1139         src/bin/lttng-relayd/Makefile
1140         src/bin/lttng/Makefile
1141         src/bin/lttng-crash/Makefile
1142         tests/Makefile
1143         tests/destructive/Makefile
1144         tests/regression/Makefile
1145         tests/regression/kernel/Makefile
1146         tests/regression/tools/Makefile
1147         tests/regression/tools/streaming/Makefile
1148         tests/regression/tools/filtering/Makefile
1149         tests/regression/tools/health/Makefile
1150         tests/regression/tools/tracefile-limits/Makefile
1151         tests/regression/tools/snapshots/Makefile
1152         tests/regression/tools/live/Makefile
1153         tests/regression/tools/exclusion/Makefile
1154         tests/regression/tools/save-load/Makefile
1155         tests/regression/tools/save-load/configuration/Makefile
1156         tests/regression/tools/mi/Makefile
1157         tests/regression/tools/wildcard/Makefile
1158         tests/regression/tools/crash/Makefile
1159         tests/regression/tools/regen-metadata/Makefile
1160         tests/regression/tools/regen-statedump/Makefile
1161         tests/regression/tools/notification/Makefile
1162         tests/regression/tools/rotation/Makefile
1163         tests/regression/tools/base-path/Makefile
1164         tests/regression/tools/metadata/Makefile
1165         tests/regression/ust/Makefile
1166         tests/regression/ust/nprocesses/Makefile
1167         tests/regression/ust/high-throughput/Makefile
1168         tests/regression/ust/low-throughput/Makefile
1169         tests/regression/ust/before-after/Makefile
1170         tests/regression/ust/buffers-pid/Makefile
1171         tests/regression/ust/periodical-metadata-flush/Makefile
1172         tests/regression/ust/multi-session/Makefile
1173         tests/regression/ust/multi-lib/Makefile
1174         tests/regression/ust/overlap/Makefile
1175         tests/regression/ust/overlap/demo/Makefile
1176         tests/regression/ust/linking/Makefile
1177         tests/regression/ust/daemon/Makefile
1178         tests/regression/ust/exit-fast/Makefile
1179         tests/regression/ust/fork/Makefile
1180         tests/regression/ust/libc-wrapper/Makefile
1181         tests/regression/ust/baddr-statedump/Makefile
1182         tests/regression/ust/ust-dl/Makefile
1183         tests/regression/ust/java-jul/Makefile
1184         tests/regression/ust/java-log4j/Makefile
1185         tests/regression/ust/python-logging/Makefile
1186         tests/regression/ust/getcpu-override/Makefile
1187         tests/regression/ust/clock-override/Makefile
1188         tests/regression/ust/type-declarations/Makefile
1189         tests/regression/ust/rotation-destroy-flush/Makefile
1190         tests/regression/ust/blocking/Makefile
1191         tests/stress/Makefile
1192         tests/unit/Makefile
1193         tests/unit/ini_config/Makefile
1194         tests/perf/Makefile
1195         tests/utils/Makefile
1196         tests/utils/tap/Makefile
1197         tests/utils/testapp/Makefile
1198         tests/utils/testapp/gen-ust-events/Makefile
1199         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1200         tests/utils/testapp/gen-ust-nevents/Makefile
1201         tests/utils/testapp/gen-ust-nevents-str/Makefile
1202         tests/utils/testapp/gen-syscall-events/Makefile
1203         tests/utils/testapp/gen-ust-tracef/Makefile
1204         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1205         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1206         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1207 ])
1208
1209 # Inject variable into python test script.
1210 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1211 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1212 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1213 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1214
1215 AC_OUTPUT
1216
1217 #
1218 # Mini-report on what will be built.
1219 #
1220
1221 PPRINT_INIT
1222 PPRINT_SET_INDENT(1)
1223 PPRINT_SET_TS(38)
1224
1225 AS_ECHO
1226 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1227 AS_ECHO
1228
1229 AS_IF([test -n "$report_fold"], [
1230         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1231 ], [
1232         AS_ECHO("$version_description")
1233 ])
1234
1235 AS_ECHO
1236 PPRINT_SUBTITLE([Features])
1237
1238 # Target architecture we're building for.
1239 target_arch=$host_cpu
1240 [
1241 for f in $CFLAGS; do
1242         if test $f = "-m32"; then
1243                         target_arch="32-bit"
1244         elif test $f = "-m64"; then
1245                         target_arch="64-bit"
1246         fi
1247 done
1248 ]
1249 PPRINT_PROP_STRING([Target architecture], $target_arch)
1250
1251 # kmod enabled/disabled
1252 test "x$with_kmod" != "xno" && value=1 || value=0
1253 PPRINT_PROP_BOOL([libkmod support], $value)
1254
1255 # LTTng-UST enabled/disabled
1256 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1257 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1258
1259 AS_ECHO
1260 PPRINT_SUBTITLE([Binaries])
1261
1262 # List binaries to be built
1263 test x$enable_bin_lttng != xno && value=1 || value=0
1264 PPRINT_PROP_BOOL([lttng], $value)
1265
1266 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1267 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1268
1269 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1270 PPRINT_PROP_BOOL([lttng-crash], $value)
1271
1272 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1273 PPRINT_PROP_BOOL([lttng-relayd], $value)
1274
1275 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1276 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1277
1278 # Extras
1279 test x$enable_extras != xno && value=1 || value=0
1280 AS_ECHO
1281 PPRINT_SET_INDENT(0)
1282 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1283 PPRINT_SET_INDENT(1)
1284
1285 AS_ECHO
1286 PPRINT_SUBTITLE([Tests])
1287
1288 # Print clear message that tests won't be built
1289 AS_IF([test "x$build_tests" = "xno"],[
1290         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1291 ])
1292
1293 # LTTng UST Java agent JUL tests enabled/disabled
1294 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1295 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1296
1297 # LTTng UST Java agent Log4j tests enabled/disabled
1298 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1299 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1300
1301 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1302 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1303
1304 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1305 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1306
1307 # LTTng UST Java agent Log4j tests enabled/disabled
1308 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1309 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1310
1311 #Python binding enabled/disabled
1312 test "x$enable_python_binding" = xyes && value=1 || value=0
1313 AS_ECHO
1314 PPRINT_SET_INDENT(0)
1315 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1316
1317 # man pages build enabled/disabled
1318 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1319
1320 AS_IF([test "x$man_pages_opt" != "xno"], [
1321         AS_IF([test "x$in_git_repo" = "xyes"], [
1322                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1323         ], [
1324                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1325                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1326                 ], [
1327                         PPRINT_PROP_STRING([build_man_pages_msg],
1328                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1329                                 $PPRINT_COLOR_SUBTITLE)
1330                 ])
1331         ])
1332 ], [
1333         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1334 ])
1335
1336 m4_popdef([build_man_pages_msg])
1337
1338 test "x$embedded_help" = xyes && value=1 || value=0
1339 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1340
1341 PPRINT_SET_INDENT(1)
1342
1343 report_bindir="`eval eval echo $bindir`"
1344 report_libdir="`eval eval echo $libdir`"
1345
1346 # Print the bindir and libdir this `make install' will install into.
1347 AS_ECHO
1348 PPRINT_SUBTITLE([Install directories])
1349 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1350 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1351
1352 AS_ECHO
1353 PPRINT_SUBTITLE([Search directories])
1354
1355 # If we build the sessiond, print the paths it will use
1356 AS_IF([test "$SESSIOND_BIN" = ""],[
1357         path="$report_bindir/lttng-sessiond"
1358 ],[
1359         path="$SESSIOND_BIN"
1360 ])
1361 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1362
1363 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1364         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1365 ],[
1366         path="$CONSUMERD32_BIN"
1367 ])
1368 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1369
1370 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1371         path="`eval eval echo $libdir`"
1372 ],[
1373         path="$CONSUMERD32_LIBDIR"
1374 ])
1375 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1376
1377 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1378         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1379 ],[
1380         path="$CONSUMERD64_BIN"
1381 ])
1382 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1383
1384 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1385         path="`eval eval echo $libdir`"
1386 ],[
1387         path="$CONSUMERD64_LIBDIR"
1388 ])
1389 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1390 PPRINT_SET_INDENT(0)
1391
1392 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1393         AS_ECHO
1394         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1395
1396 Note that the man pages are already built in this distribution tarball,
1397 therefore asciidoc and xmlto are only needed if you intend to modify
1398 their sources.
1399
1400 Also note that the installed man pages will contain the project's
1401 default command-line option and environment variable values.
1402
1403 Use --disable-man-pages to completely disable building and installing
1404 the man pages.])
1405 ])