configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.6.1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3 AC_CONFIG_AUX_DIR([config])
   4 AC_CANONICAL_TARGET
   5 AC_CANONICAL_HOST
   6 AC_CONFIG_MACRO_DIR([config])
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE([enable])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 # Compute minor/major/patchlevel version numbers
  12 AC_PROG_SED
  13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  16 AC_SUBST([MAJOR_VERSION], [$major_version])
  17 AC_SUBST([MINOR_VERSION], [$minor_version])
  18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  22
  23 version_name="Gaia"
  24 version_description="From Benelux brewery in Montreal, the Gaia is a witbier with a cloudy light amber ale color. Aroma of coriander with floral hay notes is enchanting. Taste is also dominated by the very floral coriander note and some medium sweet malt notes."
  25
  26 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  27 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  28
  29 AC_CONFIG_HEADERS([include/config.h])
  30
  31 AC_PROG_GREP
  32 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  33 AC_ARG_ENABLE(libtool-linkdep-fixup,
  34         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  35                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  36         libtool_fixup=$enableval,
  37         libtool_fixup=yes)
  38
  39 AS_IF([test "x$libtool_fixup" = "xyes"],
  40             [
  41             libtool_m4="$srcdir/config/libtool.m4"
  42             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  43             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  44             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  45             AS_IF([test $libtool_flag_pattern_count -ne 0],
  46             [
  47                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  48                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  49                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  50                   ],
  51                   [
  52                   AC_MSG_RESULT([none])
  53                   ])
  54             ])
  55
  56 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  57
  58 AC_CHECK_HEADERS([ \
  59         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  60         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  61         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  62 ])
  63
  64 # Babeltrace viewer check
  65 AC_ARG_WITH([babeltrace-bin],
  66         AS_HELP_STRING([--with-babeltrace-bin],
  67         [Location of the babeltrace viewer executable (including the filename)]),
  68         [BABELTRACE_BIN="$withval"],
  69         [BABELTRACE_BIN=''])
  70 AC_SUBST([BABELTRACE_BIN])
  71
  72 # lttv-gui
  73 AC_ARG_WITH([lttv-gui-bin],
  74         AS_HELP_STRING([--with-lttv-gui-bin],
  75    [Location of the lttv GUI viewer executable (including the filename)]),
  76    [LTTV_GUI_BIN="$withval"],
  77    [LTTV_GUI_BIN=''])
  78 AC_SUBST([LTTV_GUI_BIN])
  79
  80 AC_ARG_WITH([consumerd32-bin],
  81         AS_HELP_STRING([--with-consumerd32-bin],
  82         [Location of the 32-bit consumerd executable (including the filename)]),
  83         [CONSUMERD32_BIN="$withval"],
  84         [CONSUMERD32_BIN=''])
  85 AC_SUBST([CONSUMERD32_BIN])
  86
  87 AC_ARG_WITH([consumerd64-bin],
  88         AS_HELP_STRING([--with-consumerd64-bin],
  89         [Location of the 64-bit consumerd executable (including the filename)]),
  90         [CONSUMERD64_BIN="$withval"],
  91         [CONSUMERD64_BIN=''])
  92 AC_SUBST([CONSUMERD64_BIN])
  93
  94 AC_ARG_WITH([consumerd32-libdir],
  95         AS_HELP_STRING([--with-consumerd32-libdir],
  96         [Directory containing the 32-bit consumerd libraries]),
  97         [CONSUMERD32_LIBDIR="$withval"],
  98         [CONSUMERD32_LIBDIR=''])
  99 AC_SUBST([CONSUMERD32_LIBDIR])
 100
 101 AC_ARG_WITH([consumerd64-libdir],
 102         AS_HELP_STRING([--with-consumerd64-libdir],
 103         [Directory containing the 64-bit consumerd libraries]),
 104         [CONSUMERD64_LIBDIR="$withval"],
 105         [CONSUMERD64_LIBDIR=''])
 106 AC_SUBST([CONSUMERD64_LIBDIR])
 107
 108 AC_ARG_WITH([sessiond-bin],
 109         AS_HELP_STRING([--with-sessiond-bin],
 110         [Location of the sessiond executable (including the filename)]),
 111         [SESSIOND_BIN="$withval"],
 112         [SESSIOND_BIN=''])
 113 AC_SUBST([SESSIOND_BIN])
 114
 115 AC_ARG_WITH([lttng-system-rundir],
 116         AS_HELP_STRING([--with-lttng-system-rundir],
 117         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 118         [LTTNG_SYSTEM_RUNDIR="$withval"],
 119         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 120 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 121
 122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 124 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 125 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 126 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 127 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 128 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 129 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 130
 131 if test "x$prefix" = "xNONE"; then
 132         prefix=$ac_default_prefix
 133 fi
 134 CONFDIR=`eval echo $sysconfdir`
 135 AC_SUBST(CONFDIR)
 136 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 137
 138 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 139
 140 #
 141 # Check for pthread
 142 AC_CHECK_LIB([pthread], [pthread_create], [],
 143         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 144 )
 145
 146 # Check libpopt
 147 PKG_CHECK_MODULES([POPT], [popt],
 148         [LIBS="$LIBS $POPT_LIBS"],
 149         [
 150                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 151                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 152                 AC_CHECK_LIB([popt],
 153                         [poptGetContext],
 154                         [],
 155                         [
 156                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 157                         ]
 158                 )
 159         ]
 160 )
 161
 162 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 163
 164 # Check for libuuid
 165 PKG_CHECK_MODULES([UUID], [uuid],
 166 [
 167         LIBS="$LIBS $UUID_LIBS"
 168         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 169         have_libuuid=yes
 170 ],
 171 [
 172         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 173         AC_MSG_WARN([Finding libuuid without pkg-config.])
 174         AC_CHECK_LIB([uuid],
 175                 [uuid_generate],
 176                 [
 177                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 178                         have_libuuid=yes
 179                 ],
 180                 [
 181                         # libuuid not found, check for uuid_create in libc.
 182                         AC_CHECK_LIB([c],
 183                                 [uuid_create],
 184                                 [
 185                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 186                                         have_libc_uuid=yes
 187                                 ],
 188                                 [
 189                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 190                                 ]
 191                         )
 192                 ]
 193         )
 194 ])
 195 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 196 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 197
 198 # URCU library version needed or newer
 199 liburcu_version=">= 0.8.0"
 200
 201 # Check liburcu needed function calls
 202 AC_CHECK_DECL([cds_list_add], [],
 203         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 204 )
 205 AC_CHECK_DECL([cds_wfcq_init], [],
 206         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 207 )
 208 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 209     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 210 )
 211 AC_CHECK_DECL([futex_async], [],
 212         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 213 )
 214 AC_CHECK_DECL([rcu_thread_offline], [],
 215         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 216 )
 217 AC_CHECK_DECL([rcu_thread_online], [],
 218         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 219 )
 220 AC_CHECK_DECL([caa_likely], [],
 221         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 222 )
 223 #Function added in urcu 0.7.0
 224 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 225         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 226 )
 227
 228 # Check kmod library
 229 AC_ARG_WITH(kmod-prefix,
 230   AS_HELP_STRING([--with-kmod-prefix=PATH],
 231                 [Specify the installation prefix of the kmod library.
 232                 Headers must be in PATH/include; libraries in PATH/lib.]),
 233                 [
 234                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 235                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 236                 ])
 237
 238 AC_ARG_ENABLE(kmod,
 239         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 240         kmod_support=zz$enableval, kmod_support=yes)
 241
 242 AS_IF([test "x$kmod_support" = "xyes"], [
 243         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 244                 [
 245                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 246                         LIBS="$LIBS -lkmod"
 247                         kmod_found=yes
 248                 ],
 249                 kmod_found=no
 250         )
 251 ])
 252 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 253
 254 AC_ARG_WITH(lttng-ust-prefix,
 255   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 256                  [Specify the installation prefix of the lttng-ust library.
 257                   Headers must be in PATH/include; libraries in PATH/lib.]),
 258                   [
 259                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 260                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 261                   ])
 262
 263 # Check liblttng-ust-ctl library
 264 AC_ARG_ENABLE(lttng-ust,
 265         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 266         lttng_ust_support=$enableval, lttng_ust_support=yes)
 267
 268 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 269         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 270                 [
 271                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 272                         lttng_ust_ctl_found=yes
 273                 ],
 274                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 275                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 276         )
 277 ])
 278 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 279 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 280
 281 # check for dlopen
 282 AC_CHECK_LIB([dl], [dlopen],
 283 [
 284         have_libdl=yes
 285 ],
 286 [
 287         #libdl not found, check for dlopen in libc.
 288         AC_CHECK_LIB([c], [dlopen],
 289         [
 290                 have_libc_dl=yes
 291         ],
 292         [
 293                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 294         ])
 295 ])
 296 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 297 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 298
 299 # Check for fmemopen
 300 AC_CHECK_LIB([c], [fmemopen],
 301 [
 302         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 303 ]
 304 )
 305
 306 # Check for open_memstream
 307 AC_CHECK_LIB([c], [open_memstream],
 308 [
 309         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 310 ]
 311 )
 312
 313 AC_ARG_ENABLE([git-version],
 314               [AC_HELP_STRING([--disable-git-version],
 315                               [Do not use the git version for the build])],
 316               [have_git_version=$enableval], [have_git_version=yes]
 317 )
 318
 319 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 320         [test "x${have_git_version}" = "xyes"])
 321
 322 # For Python
 323 # SWIG version needed or newer:
 324 swig_version=2.0.0
 325
 326 AC_ARG_ENABLE([python-bindings],
 327               [AC_HELP_STRING([--enable-python-bindings],
 328                               [compile Python bindings])],
 329               [enable_python=yes], [enable_python=no])
 330
 331 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 332
 333 if test "x${enable_python:-yes}" = xyes; then
 334   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 335   AM_PATH_PYTHON
 336
 337   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 338   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 339   AS_IF([test -z "$PYTHON_INCLUDE"], [
 340     AS_IF([test -z "$PYTHON_CONFIG"], [
 341       AC_PATH_PROGS([PYTHON_CONFIG],
 342                     [python$PYTHON_VERSION-config python-config],
 343                     [no],
 344                     [`dirname $PYTHON`])
 345       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 346     ])
 347     AC_MSG_CHECKING([python include flags])
 348     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 349     AC_MSG_RESULT([$PYTHON_INCLUDE])
 350   ])
 351
 352 else
 353     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 354 [if you want Python bindings.])
 355
 356 fi
 357
 358 # Epoll check. If not present, the build will fallback on poll() API
 359 AX_HAVE_EPOLL(
 360         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 361         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 362 )
 363 AX_CONFIG_FEATURE(
 364         [epoll], [This platform supports epoll(7)],
 365         [HAVE_EPOLL], [This platform supports epoll(7).],
 366         [enable_epoll="yes"], [enable_epoll="no"]
 367 )
 368 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 369
 370 # Set compile flags to java include files if given. This is only used to
 371 # compile java agent tests.
 372 AC_ARG_WITH([java-jdk],
 373         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 374         [JAVA_JDK=$withval],
 375         [JAVA_JDK=""]
 376 )
 377 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 378 AC_SUBST([JAVA_JDK])
 379
 380 AS_IF([test $JAVA_JDK],[
 381         AS_IF([test -d $JAVA_JDK],
 382                 [
 383                         AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 384                         SUBDIRS=`find $JAVA_JDK/include -type d`
 385                         CPPFLAGS+=" "
 386                         CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 387                         CPPFLAGS+=" "
 388         ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
 389         )
 390 ])
 391
 392 # Check for the UST agent jar file in the system. Hardcoded path is added here
 393 # since we have *no* idea where this could be installed. Note that this is only
 394 # used for agent testing.
 395 AC_MSG_CHECKING(Java UST agent jar file)
 396 java_agent_jar_path="${prefix}/share/java/liblttng-ust-agent.jar"
 397 if test -f $java_agent_jar_path; then
 398         build_java_agent=yes
 399         AC_MSG_RESULT(found)
 400 else
 401         build_java_agent=no
 402         AC_MSG_RESULT(not found)
 403 fi
 404 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$build_java_agent" = "xyes"])
 405 AC_SUBST([java_agent_jar_path])
 406
 407 # Check for log4j support on the system to know if we can build or not the
 408 # log4j tests.
 409 if test "x$build_java_agent" = "xyes"; then
 410         AC_MSG_CHECKING(Java agent support for log4j)
 411         AX_JAVA_OPTIONS
 412         AX_PROG_JAR
 413         AX_PROG_JAVA
 414         AX_PROG_JAVAC
 415
 416         # By default, use a commonly used classpath on the system to ease things up
 417         # for the Java testing in this directory.
 418         LOG4J_CLASSPATH="$java_agent_jar_path:$CLASSPATH:.:/usr/share/java/*"
 419         JAVAFLAGS="-cp $LOG4J_CLASSPATH"
 420         JAVACFLAGS="$JAVAFLAGS"
 421         AX_CHECK_CLASS(org.apache.log4j.Logger)
 422
 423         if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 424                 build_java_log4j_agent=no
 425         else
 426                 build_java_log4j_agent=yes
 427         fi
 428 fi
 429 AM_CONDITIONAL([BUILD_JAVA_LOG4J_AGENT], [test "x$build_java_log4j_agent" = "xyes"])
 430
 431 AC_SYS_LARGEFILE
 432 AC_PROG_CC
 433 LT_INIT
 434 AC_PROG_YACC
 435 AC_PROG_LEX
 436
 437 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 438         if test x"$YACC" != "xbison -y"; then
 439                 AC_MSG_ERROR([[bison not found and is required when building from git.
 440                 Please install bison]])
 441         fi
 442         AC_PATH_PROG([BISON],[bison])
 443         AX_PROG_BISON_VERSION([2.4], [],[
 444                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 445         ])
 446 fi
 447
 448 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 449         if test x"$LEX" != "xflex"; then
 450                 AC_MSG_ERROR([[flex not found and is required when building from git.
 451                 Please install flex]])
 452         fi
 453         AC_PATH_PROG([FLEX],[flex])
 454         AX_PROG_FLEX_VERSION([2.5.35], [],[
 455                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 456         ])
 457 fi
 458
 459 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 460
 461 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 462
 463 lttngincludedir="${includedir}/lttng"
 464
 465 AC_SUBST(lttngincludedir)
 466 AC_SUBST(DEFAULT_INCLUDES)
 467
 468 lttnglibexecdir="${libdir}/lttng/libexec"
 469 AC_SUBST(lttnglibexecdir)
 470
 471 AC_CONFIG_FILES([
 472         Makefile
 473         doc/Makefile
 474         doc/man/Makefile
 475         include/Makefile
 476         extras/Makefile
 477         extras/bindings/Makefile
 478         extras/bindings/swig/Makefile
 479         extras/bindings/swig/python/Makefile
 480         extras/core-handler/Makefile
 481         src/Makefile
 482         src/common/Makefile
 483         src/common/kernel-ctl/Makefile
 484         src/common/kernel-consumer/Makefile
 485         src/common/ust-consumer/Makefile
 486         src/common/hashtable/Makefile
 487         src/common/sessiond-comm/Makefile
 488         src/common/compat/Makefile
 489         src/common/relayd/Makefile
 490         src/common/testpoint/Makefile
 491         src/common/index/Makefile
 492         src/common/health/Makefile
 493         src/common/config/Makefile
 494         src/lib/Makefile
 495         src/lib/lttng-ctl/Makefile
 496         src/lib/lttng-ctl/filter/Makefile
 497         src/lib/lttng-ctl/lttng-ctl.pc
 498         src/bin/Makefile
 499         src/bin/lttng-consumerd/Makefile
 500         src/bin/lttng-sessiond/Makefile
 501         src/bin/lttng-relayd/Makefile
 502         src/bin/lttng/Makefile
 503         tests/Makefile
 504         tests/regression/Makefile
 505         tests/regression/kernel/Makefile
 506         tests/regression/tools/Makefile
 507         tests/regression/tools/streaming/Makefile
 508         tests/regression/tools/filtering/Makefile
 509         tests/regression/tools/health/Makefile
 510         tests/regression/tools/tracefile-limits/Makefile
 511         tests/regression/tools/snapshots/Makefile
 512         tests/regression/tools/live/Makefile
 513         tests/regression/tools/exclusion/Makefile
 514         tests/regression/tools/save-load/Makefile
 515         tests/regression/tools/mi/Makefile
 516         tests/regression/ust/Makefile
 517         tests/regression/ust/nprocesses/Makefile
 518         tests/regression/ust/high-throughput/Makefile
 519         tests/regression/ust/low-throughput/Makefile
 520         tests/regression/ust/before-after/Makefile
 521         tests/regression/ust/buffers-pid/Makefile
 522         tests/regression/ust/periodical-metadata-flush/Makefile
 523         tests/regression/ust/multi-session/Makefile
 524         tests/regression/ust/overlap/Makefile
 525         tests/regression/ust/overlap/demo/Makefile
 526         tests/regression/ust/linking/Makefile
 527         tests/regression/ust/daemon/Makefile
 528         tests/regression/ust/exit-fast/Makefile
 529         tests/regression/ust/fork/Makefile
 530         tests/regression/ust/libc-wrapper/Makefile
 531         tests/regression/ust/java-jul/Makefile
 532         tests/regression/ust/java-log4j/Makefile
 533         tests/stress/Makefile
 534         tests/unit/Makefile
 535         tests/unit/ini_config/Makefile
 536         tests/utils/Makefile
 537         tests/utils/tap/Makefile
 538         tests/utils/testapp/Makefile
 539         tests/utils/testapp/gen-ust-events/Makefile
 540         tests/utils/testapp/gen-ust-nevents/Makefile
 541         tests/utils/testapp/gen-ust-tracef/Makefile
 542 ])
 543
 544 AC_OUTPUT
 545
 546 #
 547 # Mini-report on what will be built
 548 #
 549 AS_ECHO()
 550
 551 AS_ECHO("Version name: $version_name")
 552 AS_ECHO("$version_description")
 553
 554 AS_ECHO()
 555
 556 # Target architecture we're building for
 557 target_arch=$host_cpu
 558 [
 559 for f in $CFLAGS; do
 560         if test $f = "-m32"; then
 561                         target_arch="32-bit"
 562         elif test $f = "-m64"; then
 563                         target_arch="64-bit"
 564         fi
 565 done
 566 ]
 567 AS_ECHO_N("Target architecture: ")
 568 AS_ECHO($target_arch)
 569
 570 # kmod enabled/disabled
 571 AS_ECHO_N("libkmod support: ")
 572 AS_IF([test "x$kmod_found" = "xyes"],[
 573         AS_ECHO("Enabled")
 574 ],[
 575         AS_ECHO("Disabled")
 576 ])
 577
 578 # LTTng-UST enabled/disabled
 579 AS_ECHO_N("Lttng-UST support: ")
 580 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 581         AS_ECHO("Enabled")
 582 ],[
 583         AS_ECHO("Disabled")
 584 ])
 585
 586 #Python binding enabled/disabled
 587 AS_ECHO_N("Python binding: ")
 588 AS_IF([test "x${enable_python:-yes}" = xyes], [
 589         AS_ECHO("Enabled")
 590 ],[
 591         AS_ECHO("Disabled")
 592 ])
 593
 594 # Do we build only the consumerd, or everything
 595 AS_IF([test "x$consumerd_only" = "xyes"],[
 596         AS_ECHO("Only the consumerd daemon will be built.")
 597 ],[
 598         AS_ECHO("All binaries will be built.")
 599 ])
 600
 601 # Print the bindir and libdir this `make install' will install into.
 602 AS_ECHO()
 603 AS_ECHO_N("Binaries will be installed in:  ")
 604 AS_ECHO("`eval eval echo $bindir`")
 605 AS_ECHO_N("Libraries will be installed in: ")
 606 AS_ECHO("`eval eval echo $libdir`")
 607
 608 # If we build the sessiond, print the paths it will use
 609 AS_IF([test "x$consumerd_only" = "xno"],[
 610         AS_ECHO()
 611         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 612         AS_IF([test "$SESSIOND_BIN" = ""],[
 613                 AS_ECHO_N("`eval eval echo $bindir`")
 614                 AS_ECHO("/lttng-sessiond")
 615         ],[
 616                 AS_ECHO("$SESSIOND_BIN")
 617         ])
 618
 619         AS_ECHO()
 620         AS_ECHO("The sessiond daemon will look in the following directories: ")
 621         AS_ECHO_N("32-bit consumerd executable at: ")
 622         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 623                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 624                 AS_ECHO("/lttng-consumerd")
 625         ],[
 626                 AS_ECHO("$CONSUMERD32_BIN")
 627         ])
 628
 629         AS_ECHO_N("32-bit consumer libraries in:   ")
 630         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 631                 AS_ECHO("`eval eval echo $libdir`")
 632         ],[
 633                 AS_ECHO("$CONSUMERD32_LIBDIR")
 634         ])
 635
 636         AS_ECHO_N("64-bit consumerd executable at: ")
 637         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 638                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 639                 AS_ECHO("/lttng-consumerd")
 640         ],[
 641                 AS_ECHO("$CONSUMERD64_BIN")
 642         ])
 643
 644         AS_ECHO_N("64-bit consumer libraries in:   ")
 645         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 646                 AS_ECHO("`eval eval echo $libdir`")
 647         ],[
 648                 AS_ECHO("$CONSUMERD64_LIBDIR")
 649         ])
 650 ])
 651
 652 AS_ECHO()
 653