configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.8.8],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 # Compute minor/major/patchlevel version numbers
  69 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  70 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  71 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  72
  73 AC_SUBST([MAJOR_VERSION], [$major_version])
  74 AC_SUBST([MINOR_VERSION], [$minor_version])
  75 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  76 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  77 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  78 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  79
  80 version_name="Isseki Nicho"
  81 version_description='The result of a collaboration between "Dieu du Ciel!" and Nagano-based "Shiga Kogen", Isseki Nicho is a strong Imperial Dark Saison offering a rich roasted malt flavor combined with a complex fruity finish typical of Saison yeasts.'
  82 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  83
  84 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  85 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  86
  87 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  88 AC_ARG_ENABLE(libtool-linkdep-fixup,
  89         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  90                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  91         libtool_fixup=$enableval,
  92         libtool_fixup=yes)
  93
  94 AS_IF([test "x$libtool_fixup" = "xyes"],
  95             [
  96             libtool_m4="$srcdir/m4/libtool.m4"
  97             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  98             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  99             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 100             AS_IF([test $libtool_flag_pattern_count -ne 0],
 101             [
 102                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 103                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 104                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 105                   ],
 106                   [
 107                   AC_MSG_RESULT([none])
 108                   ])
 109             ])
 110
 111 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 112
 113 AC_CHECK_HEADERS([ \
 114         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 115         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 116         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 117         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 118         sys/mount.h sys/param.h sys/time.h
 119 ])
 120
 121 # Basic functions check
 122 AC_CHECK_FUNCS([ \
 123         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 124         gethostbyname gethostname getpagesize localtime_r memchr memset \
 125         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 126         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 127         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 128 ])
 129
 130 # Babeltrace viewer check
 131 AC_ARG_WITH([babeltrace-bin],
 132         AS_HELP_STRING([--with-babeltrace-bin],
 133         [Location of the babeltrace viewer executable (including the filename)]),
 134         [BABELTRACE_BIN="$withval"],
 135         [BABELTRACE_BIN=''])
 136 AC_SUBST([BABELTRACE_BIN])
 137
 138 # lttv-gui
 139 AC_ARG_WITH([lttv-gui-bin],
 140         AS_HELP_STRING([--with-lttv-gui-bin],
 141    [Location of the lttv GUI viewer executable (including the filename)]),
 142    [LTTV_GUI_BIN="$withval"],
 143    [LTTV_GUI_BIN=''])
 144 AC_SUBST([LTTV_GUI_BIN])
 145
 146 AC_ARG_WITH([consumerd32-bin],
 147         AS_HELP_STRING([--with-consumerd32-bin],
 148         [Location of the 32-bit consumerd executable (including the filename)]),
 149         [CONSUMERD32_BIN="$withval"],
 150         [CONSUMERD32_BIN=''])
 151 AC_SUBST([CONSUMERD32_BIN])
 152
 153 AC_ARG_WITH([consumerd64-bin],
 154         AS_HELP_STRING([--with-consumerd64-bin],
 155         [Location of the 64-bit consumerd executable (including the filename)]),
 156         [CONSUMERD64_BIN="$withval"],
 157         [CONSUMERD64_BIN=''])
 158 AC_SUBST([CONSUMERD64_BIN])
 159
 160 AC_ARG_WITH([consumerd32-libdir],
 161         AS_HELP_STRING([--with-consumerd32-libdir],
 162         [Directory containing the 32-bit consumerd libraries]),
 163         [CONSUMERD32_LIBDIR="$withval"],
 164         [CONSUMERD32_LIBDIR=''])
 165 AC_SUBST([CONSUMERD32_LIBDIR])
 166
 167 AC_ARG_WITH([consumerd64-libdir],
 168         AS_HELP_STRING([--with-consumerd64-libdir],
 169         [Directory containing the 64-bit consumerd libraries]),
 170         [CONSUMERD64_LIBDIR="$withval"],
 171         [CONSUMERD64_LIBDIR=''])
 172 AC_SUBST([CONSUMERD64_LIBDIR])
 173
 174 AC_ARG_WITH([sessiond-bin],
 175         AS_HELP_STRING([--with-sessiond-bin],
 176         [Location of the sessiond executable (including the filename)]),
 177         [SESSIOND_BIN="$withval"],
 178         [SESSIOND_BIN=''])
 179 AC_SUBST([SESSIOND_BIN])
 180
 181 AC_ARG_WITH([lttng-system-rundir],
 182         AS_HELP_STRING([--with-lttng-system-rundir],
 183         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 184         [LTTNG_SYSTEM_RUNDIR="$withval"],
 185         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 186 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 187
 188 AC_ARG_ENABLE([test-java-agent-jul],
 189         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 190         [test_java_agent_jul=$enableval],
 191         [test_java_agent_jul=no]
 192 )
 193
 194 AC_ARG_ENABLE([test-java-agent-log4j],
 195         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 196         [test_java_agent_log4j=$enableval],
 197         [test_java_agent_log4j=no]
 198 )
 199
 200 AC_ARG_ENABLE([test-java-agent-all],
 201         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 202         [test_java_agent_jul=$enableval
 203          test_java_agent_log4j=$enableval],
 204         [:]
 205 )
 206
 207 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 208 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 209 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 210 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 211 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 212 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 213 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 214 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 215
 216 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 217         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 218         $1="$2"
 219         AC_SUBST([$1])
 220 ])
 221
 222 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 223         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 224         $1="$2"
 225         AC_SUBST([$1])
 226 ])
 227
 228 # Default values
 229 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096])
 230 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 231 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 232 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 233 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 234 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 235 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 236 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 237 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 238 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 239 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 240 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 241 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 242 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144])
 243 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 244 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 245 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 246 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 247 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 248 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 263 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 264 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 265 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 266 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 267
 268 # Command short descriptions
 269 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 270 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CALIBRATE], [Quantify LTTng overhead])
 271 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 272 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 273 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 274 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 275 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 276 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 277 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 278 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 279 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 280 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_METADATA], [Manage an LTTng tracing session's metadata generation])
 281 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 282 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 283 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 284 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 285 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 286 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 291
 292 if test "x$prefix" = "xNONE"; then
 293         prefix=$ac_default_prefix
 294 fi
 295 CONFDIR=`eval echo $sysconfdir`
 296 AC_SUBST(CONFDIR)
 297 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 298
 299 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 300
 301 #
 302 # Check for pthread
 303 AC_CHECK_LIB([pthread], [pthread_create], [],
 304         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 305 )
 306
 307 # Check libpopt
 308 PKG_CHECK_MODULES([POPT], [popt],
 309         [LIBS="$LIBS $POPT_LIBS"],
 310         [
 311                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 312                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 313                 AC_CHECK_LIB([popt],
 314                         [poptGetContext],
 315                         [],
 316                         [
 317                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 318                         ]
 319                 )
 320         ]
 321 )
 322
 323 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 324
 325 # Check for libuuid
 326 PKG_CHECK_MODULES([UUID], [uuid],
 327 [
 328         LIBS="$LIBS $UUID_LIBS"
 329         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 330         have_libuuid=yes
 331 ],
 332 [
 333         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 334         AC_MSG_WARN([Finding libuuid without pkg-config.])
 335         AC_CHECK_LIB([uuid],
 336                 [uuid_generate],
 337                 [
 338                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 339                         have_libuuid=yes
 340                 ],
 341                 [
 342                         # libuuid not found, check for uuid_create in libc.
 343                         AC_CHECK_LIB([c],
 344                                 [uuid_create],
 345                                 [
 346                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 347                                         have_libc_uuid=yes
 348                                 ],
 349                                 [
 350                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 351                                 ]
 352                         )
 353                 ]
 354         )
 355 ])
 356 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 357 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 358
 359 # URCU library version needed or newer
 360 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 361
 362 # Check liburcu needed function calls
 363 AC_CHECK_DECL([cds_list_add], [],
 364         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 365 AC_CHECK_DECL([cds_wfcq_init], [],
 366         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 367 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 368         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 369 AC_CHECK_DECL([futex_async], [],
 370         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 371 AC_CHECK_DECL([rcu_thread_offline], [],
 372         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 373 AC_CHECK_DECL([rcu_thread_online], [],
 374         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 375 AC_CHECK_DECL([caa_likely], [],
 376         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 377 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 378         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 379
 380 #Function added in urcu 0.7.0
 381 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 382         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 383 )
 384
 385 # Check kmod library
 386 AC_ARG_WITH(kmod-prefix,
 387   AS_HELP_STRING([--with-kmod-prefix=PATH],
 388                 [Specify the installation prefix of the kmod library.
 389                 Headers must be in PATH/include; libraries in PATH/lib.]),
 390                 [
 391                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 392                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 393                 ])
 394
 395 AC_ARG_ENABLE(kmod,
 396         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 397         kmod_support=$enableval, kmod_support=yes)
 398
 399 AS_IF([test "x$kmod_support" = "xyes"], [
 400         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 401                 [
 402                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 403                         LIBS="$LIBS -lkmod"
 404                         kmod_found=yes
 405                 ],
 406                 kmod_found=no
 407         )
 408 ])
 409 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 410
 411 AC_ARG_WITH(lttng-ust-prefix,
 412   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 413                  [Specify the installation prefix of the lttng-ust library.
 414                   Headers must be in PATH/include; libraries in PATH/lib.]),
 415                   [
 416                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 417                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 418                   ])
 419
 420 # Check liblttng-ust-ctl library
 421 AC_ARG_WITH(lttng-ust,
 422         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 423         lttng_ust_support=$withval, lttng_ust_support=yes)
 424
 425 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 426         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 427                 [
 428                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 429                         lttng_ust_ctl_found=yes
 430                 ],
 431                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 432                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 433         )
 434 ])
 435 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 436 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 437
 438 # check for dlopen
 439 AC_CHECK_LIB([dl], [dlopen],
 440 [
 441         have_libdl=yes
 442 ],
 443 [
 444         #libdl not found, check for dlopen in libc.
 445         AC_CHECK_LIB([c], [dlopen],
 446         [
 447                 have_libc_dl=yes
 448         ],
 449         [
 450                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 451         ])
 452 ])
 453 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 454 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 455
 456 # Check for fmemopen
 457 AC_CHECK_LIB([c], [fmemopen],
 458 [
 459         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 460 ]
 461 )
 462
 463 # Check for open_memstream
 464 AC_CHECK_LIB([c], [open_memstream],
 465 [
 466         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 467 ]
 468 )
 469
 470 AC_ARG_ENABLE([git-version],
 471               [AC_HELP_STRING([--disable-git-version],
 472                               [Do not use the git version for the build])],
 473               [have_git_version=$enableval], [have_git_version=yes]
 474 )
 475
 476 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 477         [test "x${have_git_version}" = "xyes"])
 478
 479 # For Python
 480 # SWIG version needed or newer:
 481 swig_version=2.0.0
 482
 483 AC_ARG_ENABLE([python-bindings],
 484               [AC_HELP_STRING([--enable-python-bindings],
 485                               [compile Python bindings])],
 486               [enable_python_binding=$enableval], [enable_python_binding=no])
 487
 488 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 489
 490 if test "x$enable_python_binding" = xyes; then
 491   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 492   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 493   AM_PATH_PYTHON([3.0])
 494
 495   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 496   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 497   AS_IF([test -z "$PYTHON_INCLUDE"], [
 498     AS_IF([test -z "$PYTHON_CONFIG"], [
 499       AC_PATH_PROGS([PYTHON_CONFIG],
 500                     [python$PYTHON_VERSION-config python-config],
 501                     [no],
 502                     [`dirname $PYTHON`])
 503       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 504     ])
 505     AC_MSG_CHECKING([python include flags])
 506     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 507     AC_MSG_RESULT([$PYTHON_INCLUDE])
 508   ])
 509
 510 else
 511     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 512 [if you want Python bindings.])
 513
 514 fi
 515
 516 # Epoll check. If not present, the build will fallback on poll() API
 517 AX_HAVE_EPOLL(
 518         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 519         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 520 )
 521 AX_CONFIG_FEATURE(
 522         [epoll], [This platform supports epoll(7)],
 523         [HAVE_EPOLL], [This platform supports epoll(7).],
 524         [enable_epoll="yes"], [enable_epoll="no"]
 525 )
 526 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 527
 528 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 529 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 530
 531 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 532         AX_JAVA_OPTIONS
 533         AX_PROG_JAVAC
 534         AX_PROG_JAVA
 535         AX_PROG_JAR
 536
 537         AX_CHECK_CLASSPATH
 538
 539         # Check for Java UST agent common class first
 540         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 541         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 542                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 543         fi
 544
 545         if test "x$test_java_agent_jul" = "xyes"; then
 546                 # Check for JUL agent class
 547                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 548                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 549                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 550                 fi
 551         fi
 552
 553         if test "x$test_java_agent_log4j" = "xyes"; then
 554                 # Check for Log4j agent class
 555                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 556                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 557                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 558                 fi
 559
 560                 # Check for Log4j class
 561                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 562                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 563                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 564                 fi
 565         fi
 566 fi
 567
 568 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 569 # is not distributed in tarballs
 570 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 571 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 572
 573 # enable building man pages (user's intention)
 574 AC_ARG_ENABLE(
 575         man-pages,
 576         AS_HELP_STRING(
 577                 [--disable-man-pages],
 578                 [Do not build and install man pages (already built in a distributed tarball)]
 579         ),
 580         [man_pages_opt=$enableval],
 581         [man_pages_opt=yes]
 582 )
 583
 584 # check for asciidoc and xmlto if we enabled building the man pages
 585 have_asciidoc_xmlto=no
 586 warn_prebuilt_man_pages=no
 587
 588 AS_IF([test "x$man_pages_opt" = "xyes"], [
 589         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 590         AC_PATH_PROG([XMLTO], [xmlto], [no])
 591
 592         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 593                 AS_IF([test "x$in_git_repo" = "xyes"], [
 594                         # this is an error because we're in the Git repo, which
 595                         # means the man pages are not already generated for us,
 596                         # thus asciidoc/xmlto are required because we were asked
 597                         # to build the man pages
 598                         AC_MSG_ERROR([
 599 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 600 --disable-man-pages to disable building the man pages, in which case
 601 they will not be installed.
 602                         ])
 603                 ], [
 604                         # only warn here: since we're in the tarball, the man
 605                         # pages should already be generated at this point, thus
 606                         # asciidoc/xmlto are not strictly required
 607                         warn_prebuilt_man_pages=yes
 608                 ])
 609         ], [
 610                 have_asciidoc_xmlto=yes
 611         ])
 612 ])
 613
 614 # export man page build condition: build the man pages if the user
 615 # asked for it, and if the tools are available
 616 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 617 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 618
 619 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 620
 621 # Python agent test
 622 UST_PYTHON_AGENT="lttngust"
 623
 624 AC_ARG_ENABLE(test-python2-agent,
 625         AS_HELP_STRING([--enable-test-python2-agent],
 626                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 627         ),[:],[test_python2_agent_autodetect=yes]
 628 )
 629
 630 AC_ARG_ENABLE(test-python3-agent,
 631         AS_HELP_STRING([--enable-test-python3-agent],
 632                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 633         ),[:],[test_python3_agent_autodetect=yes]
 634 )
 635
 636 AC_ARG_ENABLE(test-python-agent-all,
 637         AS_HELP_STRING([--enable-test-python-agent-all],
 638                 [enable test for all python{2/3} agent.]
 639         ),
 640 )
 641
 642 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 643        unset test_python2_agent_autodetect
 644        unset test_python3_agent_autodetect
 645 ])
 646
 647 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 648        enable_test_python2_agent=yes
 649        enable_test_python3_agent=yes
 650 ])
 651
 652 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 653        enable_test_python2_agent=no
 654        enable_test_python3_agent=no
 655 ])
 656
 657
 658 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 659         AS_IF([test -z "$PYTHON2"], [
 660                         PYTHON2=python2
 661                 ], [
 662                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 663         ])
 664
 665         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 666         AS_IF([test -z "$PYTHON2_BIN"], [
 667                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 668                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 669                 ])
 670         ], [
 671                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 672                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 673                         PYTHON2_AGENT=$PYTHON2_BIN
 674                         AC_MSG_RESULT([yes])
 675                         RUN_PYTHON_AGENT_TEST=yes
 676                 ], [
 677                         AC_MSG_RESULT([no])
 678                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 679                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 680                         ])
 681                 ])
 682
 683         ])
 684
 685 ])
 686
 687 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 688         AS_IF([test -z "$PYTHON3"], [
 689                 PYTHON3=python3
 690         ], [
 691                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 692         ])
 693
 694         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 695         AS_IF([test -z "$PYTHON3_BIN"], [
 696                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 697                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 698                 ])
 699         ], [
 700                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 701                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 702                         PYTHON3_AGENT=$PYTHON3_BIN
 703                         AC_MSG_RESULT([yes])
 704                         RUN_PYTHON_AGENT_TEST=yes
 705                 ], [
 706                         AC_MSG_RESULT([no])
 707                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 708                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 709                         ])
 710                 ])
 711
 712         ])
 713 ])
 714 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 715 AC_SUBST([PYTHON2_AGENT])
 716 AC_SUBST([PYTHON3_AGENT])
 717
 718 # Arguments for binaries build exclusion
 719 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 720 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 721               [Disable the build of lttng-consumerd binaries]))
 722 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 723 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 724               [Disable the build of lttng-relayd binaries]))
 725 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 726               [Disable the build of lttng-sessiond binaries]))
 727 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 728               [Disable the build of the extra components]))
 729
 730
 731 # Always build libconfig since it a dependency of libcommon
 732 build_lib_config=yes
 733
 734 build_lib_compat=no
 735 build_lib_consumer=no
 736 build_lib_hashtable=no
 737 build_lib_health=no
 738 build_lib_index=no
 739 build_lib_kernel_consumer=no
 740 build_lib_kernel_ctl=no
 741 build_lib_lttng_ctl=no
 742 build_lib_relayd=no
 743 build_lib_sessiond_comm=no
 744 build_lib_testpoint=no
 745 build_lib_ust_consumer=no
 746
 747 # There is an overlap for enabled dependencies, but this makes everything
 748 # simpler. libcommon and libconfig are always compiled so they are not repeated
 749 # here.
 750
 751 # Enable binary dependencies.
 752 AS_IF([test x$enable_bin_lttng != xno],
 753       [
 754        build_lib_lttng_ctl=yes
 755       ]
 756 )
 757
 758 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 759       [
 760        build_lib_consumer=yes
 761        build_lib_sessiond_comm=yes
 762        build_lib_index=yes
 763        build_lib_health=yes
 764        build_lib_testpoint=yes
 765       ]
 766 )
 767
 768 AS_IF([test x$enable_bin_lttng_crash != xno],
 769       # Do nothing since libconfig and libcommon are built by default.
 770       []
 771 )
 772
 773 AS_IF([test x$enable_bin_lttng_relayd != xno],
 774       [
 775        build_lib_lttng_ctl=yes
 776        build_lib_sessiond_comm=yes
 777        build_lib_hashtable=yes
 778        build_lib_compat=yes
 779        build_lib_index=yes
 780        build_lib_health=yes
 781        build_lib_testpoint=yes
 782       ]
 783 )
 784 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 785       [
 786        build_lib_lttng_ctl=yes
 787        build_lib_sessiond_comm=yes
 788        build_lib_kernel_ctl=yes
 789        build_lib_hashtable=yes
 790        build_lib_compat=yes
 791        build_lib_relayd=yes
 792        build_lib_testpoint=yes
 793        build_lib_health=yes
 794        build_lib_health=yes
 795       ]
 796 )
 797
 798 # Libraries dependencies enabling
 799 AS_IF([test x$build_lib_lttng_ctl = xyes],
 800       [
 801        build_lib_sessiond_comm=yes
 802        build_lib_hashtable=yes
 803       ]
 804 )
 805
 806 AS_IF([test x$build_lib_consumer = xyes],
 807       [
 808        build_lib_sessiond_comm=yes
 809        build_lib_kernel_consumer=yes
 810        build_lib_hashtable=yes
 811        build_lib_compat=yes
 812        build_lib_relayd=yes
 813        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 814       ]
 815 )
 816
 817 AS_IF([test x$build_lib_kernel_consumer = xyes],
 818       [
 819        build_lib_kernel_ctl=yes
 820        build_lib_relayd=yes
 821       ]
 822 )
 823
 824 AS_IF([test x$build_lib_relayd = xyes],
 825       [
 826        build_lib_sessiond_comm=yes
 827       ]
 828 )
 829
 830
 831 # Export binaries build conditions.
 832 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 833 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 834 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 835 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 836 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 837
 838 # Export the tests and extras build conditions.
 839 AS_IF([\
 840 test "x$enable_bin_lttng" != "xno" && \
 841 test "x$enable_bin_lttng_consumerd" != "xno" && \
 842 test "x$enable_bin_lttng_crash" != "xno" && \
 843 test "x$enable_bin_lttng_relayd" != "xno" && \
 844 test "x$enable_bin_lttng_sessiond" != "xno"],
 845 [build_tests=yes],
 846 [build_tests=no]
 847 )
 848
 849 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 850 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 851
 852 # Export libraries build conditions.
 853 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 854 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 855 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 856 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 857 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 858 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 859 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 860 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 861 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 862 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 863 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 864 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 865 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 866
 867 # check for pgrep
 868 AC_PATH_PROG([PGREP], [pgrep], [no])
 869 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 870
 871 # check for bison
 872 have_bison=yes
 873
 874 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 875 AC_PATH_PROG([BISON], [bison])
 876 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 877
 878 AS_IF([test "x$have_bison" = "xno"], [
 879         AS_IF([test "x$in_git_repo" = "xyes"], [
 880                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 881         ], [
 882                 AC_MSG_WARN([
 883 Missing Bison >= 2.4. Note that the parser files are already built in
 884 this distribution tarball, so Bison is only needed if you intend to
 885 modify their sources.
 886                 ])
 887         ])
 888 ])
 889
 890 # export bison condition
 891 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 892
 893 # check for flex
 894 have_flex=yes
 895
 896 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 897 AC_PATH_PROG([FLEX], [flex])
 898 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 899
 900 AS_IF([test "x$have_flex" = "xno"], [
 901         AS_IF([test "x$in_git_repo" = "xyes"], [
 902                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 903         ], [
 904                 AC_MSG_WARN([
 905 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 906 this distribution tarball, so Flex is only needed if you intend to
 907 modify their sources.
 908                 ])
 909         ])
 910 ])
 911
 912 # export flex condition
 913 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 914
 915 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 916
 917 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 918
 919 lttngincludedir="${includedir}/lttng"
 920
 921 AC_SUBST(lttngincludedir)
 922 AC_SUBST(DEFAULT_INCLUDES)
 923
 924 lttnglibexecdir="${libdir}/lttng/libexec"
 925 AC_SUBST(lttnglibexecdir)
 926
 927 AC_CONFIG_FILES([
 928         Makefile
 929         doc/Makefile
 930         doc/man/Makefile
 931         doc/man/asciidoc-attrs.conf
 932         include/Makefile
 933         extras/Makefile
 934         extras/bindings/Makefile
 935         extras/bindings/swig/Makefile
 936         extras/bindings/swig/python/Makefile
 937         extras/core-handler/Makefile
 938         src/Makefile
 939         src/common/Makefile
 940         src/common/kernel-ctl/Makefile
 941         src/common/kernel-consumer/Makefile
 942         src/common/consumer/Makefile
 943         src/common/ust-consumer/Makefile
 944         src/common/hashtable/Makefile
 945         src/common/sessiond-comm/Makefile
 946         src/common/compat/Makefile
 947         src/common/relayd/Makefile
 948         src/common/testpoint/Makefile
 949         src/common/index/Makefile
 950         src/common/health/Makefile
 951         src/common/config/Makefile
 952         src/lib/Makefile
 953         src/lib/lttng-ctl/Makefile
 954         src/lib/lttng-ctl/filter/Makefile
 955         src/lib/lttng-ctl/lttng-ctl.pc
 956         src/bin/Makefile
 957         src/bin/lttng-consumerd/Makefile
 958         src/bin/lttng-sessiond/Makefile
 959         src/bin/lttng-relayd/Makefile
 960         src/bin/lttng/Makefile
 961         src/bin/lttng-crash/Makefile
 962         tests/Makefile
 963         tests/destructive/Makefile
 964         tests/regression/Makefile
 965         tests/regression/kernel/Makefile
 966         tests/regression/tools/Makefile
 967         tests/regression/tools/streaming/Makefile
 968         tests/regression/tools/filtering/Makefile
 969         tests/regression/tools/health/Makefile
 970         tests/regression/tools/tracefile-limits/Makefile
 971         tests/regression/tools/snapshots/Makefile
 972         tests/regression/tools/live/Makefile
 973         tests/regression/tools/exclusion/Makefile
 974         tests/regression/tools/save-load/Makefile
 975         tests/regression/tools/mi/Makefile
 976         tests/regression/tools/wildcard/Makefile
 977         tests/regression/tools/crash/Makefile
 978         tests/regression/tools/metadata-regen/Makefile
 979         tests/regression/ust/Makefile
 980         tests/regression/ust/nprocesses/Makefile
 981         tests/regression/ust/high-throughput/Makefile
 982         tests/regression/ust/low-throughput/Makefile
 983         tests/regression/ust/before-after/Makefile
 984         tests/regression/ust/buffers-pid/Makefile
 985         tests/regression/ust/periodical-metadata-flush/Makefile
 986         tests/regression/ust/multi-session/Makefile
 987         tests/regression/ust/overlap/Makefile
 988         tests/regression/ust/overlap/demo/Makefile
 989         tests/regression/ust/linking/Makefile
 990         tests/regression/ust/daemon/Makefile
 991         tests/regression/ust/exit-fast/Makefile
 992         tests/regression/ust/fork/Makefile
 993         tests/regression/ust/libc-wrapper/Makefile
 994         tests/regression/ust/baddr-statedump/Makefile
 995         tests/regression/ust/ust-dl/Makefile
 996         tests/regression/ust/java-jul/Makefile
 997         tests/regression/ust/java-log4j/Makefile
 998         tests/regression/ust/python-logging/Makefile
 999         tests/regression/ust/getcpu-override/Makefile
1000         tests/regression/ust/clock-override/Makefile
1001         tests/regression/ust/type-declarations/Makefile
1002         tests/regression/ust/rotation-destroy-flush/Makefile
1003         tests/stress/Makefile
1004         tests/unit/Makefile
1005         tests/unit/ini_config/Makefile
1006         tests/utils/Makefile
1007         tests/utils/tap/Makefile
1008         tests/utils/testapp/Makefile
1009         tests/utils/testapp/gen-ust-events/Makefile
1010         tests/utils/testapp/gen-ust-nevents/Makefile
1011         tests/utils/testapp/gen-ust-tracef/Makefile
1012 ])
1013
1014 # Inject variable into python test script.
1015 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1016
1017 AC_OUTPUT
1018
1019 #
1020 # Mini-report on what will be built.
1021 #
1022
1023 PPRINT_INIT
1024 PPRINT_SET_INDENT(1)
1025 PPRINT_SET_TS(38)
1026
1027 AS_ECHO
1028 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1029 AS_ECHO
1030
1031 AS_IF([test -n "$report_fold"], [
1032         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1033 ], [
1034         AS_ECHO("$version_description")
1035 ])
1036
1037 AS_ECHO
1038 PPRINT_SUBTITLE([Features])
1039
1040 # Target architecture we're building for.
1041 target_arch=$host_cpu
1042 [
1043 for f in $CFLAGS; do
1044         if test $f = "-m32"; then
1045                         target_arch="32-bit"
1046         elif test $f = "-m64"; then
1047                         target_arch="64-bit"
1048         fi
1049 done
1050 ]
1051 PPRINT_PROP_STRING([Target architecture], $target_arch)
1052
1053 # kmod enabled/disabled
1054 test "x$kmod_found" = "xyes" && value=1 || value=0
1055 PPRINT_PROP_BOOL([libkmod support], $value)
1056
1057 # LTTng-UST enabled/disabled
1058 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1059 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1060
1061 AS_ECHO
1062 PPRINT_SUBTITLE([Binaries])
1063
1064 # List binaries to be built
1065 test x$enable_bin_lttng != xno && value=1 || value=0
1066 PPRINT_PROP_BOOL([lttng], $value)
1067
1068 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1069 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1070
1071 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1072 PPRINT_PROP_BOOL([lttng-crash], $value)
1073
1074 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1075 PPRINT_PROP_BOOL([lttng-relayd], $value)
1076
1077 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1078 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1079
1080 # Extras
1081 test x$enable_extras != xno && value=1 || value=0
1082 AS_ECHO
1083 PPRINT_SET_INDENT(0)
1084 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1085 PPRINT_SET_INDENT(1)
1086
1087 AS_ECHO
1088 PPRINT_SUBTITLE([Tests])
1089
1090 # Print clear message that tests won't be built
1091 AS_IF([test "x$build_tests" = "xno"],[
1092         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1093 ])
1094
1095 # LTTng UST Java agent JUL tests enabled/disabled
1096 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1097 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1098
1099 # LTTng UST Java agent Log4j tests enabled/disabled
1100 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1101 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1102
1103 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1104 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1105
1106 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1107 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1108
1109 #Python binding enabled/disabled
1110 test "x$enable_python_binding" = xyes && value=1 || value=0
1111 AS_ECHO
1112 PPRINT_SET_INDENT(0)
1113 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1114
1115 # man pages build enabled/disabled
1116 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1117
1118 AS_IF([test "x$man_pages_opt" != "xno"], [
1119         AS_IF([test "x$in_git_repo" = "xyes"], [
1120                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1121         ], [
1122                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1123                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1124                 ], [
1125                         PPRINT_PROP_STRING([build_man_pages_msg],
1126                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1127                                 $PPRINT_COLOR_SUBTITLE)
1128                 ])
1129         ])
1130 ], [
1131         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1132 ])
1133
1134 m4_popdef([build_man_pages_msg])
1135
1136 PPRINT_SET_INDENT(1)
1137
1138 report_bindir="`eval eval echo $bindir`"
1139 report_libdir="`eval eval echo $libdir`"
1140
1141 # Print the bindir and libdir this `make install' will install into.
1142 AS_ECHO
1143 PPRINT_SUBTITLE([Install directories])
1144 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1145 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1146
1147 AS_ECHO
1148 PPRINT_SUBTITLE([Search directories])
1149
1150 # If we build the sessiond, print the paths it will use
1151 AS_IF([test "$SESSIOND_BIN" = ""],[
1152         path="$report_bindir/lttng-sessiond"
1153 ],[
1154         path="$SESSIOND_BIN"
1155 ])
1156 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1157
1158 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1159         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1160 ],[
1161         path="$CONSUMERD32_BIN"
1162 ])
1163 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1164
1165 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1166         path="`eval eval echo $libdir`"
1167 ],[
1168         path="$CONSUMERD32_LIBDIR"
1169 ])
1170 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1171
1172 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1173         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1174 ],[
1175         path="$CONSUMERD64_BIN"
1176 ])
1177 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1178
1179 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1180         path="`eval eval echo $libdir`"
1181 ],[
1182         path="$CONSUMERD64_LIBDIR"
1183 ])
1184 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1185 PPRINT_SET_INDENT(0)
1186
1187 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1188         AS_ECHO
1189         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1190
1191 Note that the man pages are already built in this distribution tarball,
1192 therefore asciidoc and xmlto are only needed if you intend to modify
1193 their sources.
1194
1195 Also note that the installed man pages will contain the project's
1196 default command-line option and environment variable values.
1197
1198 Use --disable-man-pages to completely disable building and installing
1199 the man pages.])
1200 ])