configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.2],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28
  29 # Allow overriding storage used for TLS variables.
  30 AC_ARG_ENABLE([compiler-tls],
  31         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  32         [def_compiler_tls=$enableval],
  33         [def_compiler_tls="yes"])
  34
  35 # If not overridden, use ax_tls.m4 to check if TLS is available.
  36 AS_IF([test "x$def_compiler_tls" = "xyes"],
  37         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  38         [:])
  39
  40 AS_IF([test "x$def_tls_detect" = "x"],
  41         [:],
  42         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  43
  44 # Checks for C compiler
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_PROG_CC
  47 AC_PROG_CC_STDC
  48
  49 # Checks for programs.
  50 AC_PROG_AWK
  51 AC_PROG_MAKE_SET
  52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  53 LT_INIT
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_INLINE
  57 AC_TYPE_PID_T
  58 AC_TYPE_SIZE_T
  59 AC_TYPE_SSIZE_T
  60 AC_TYPE_UINT16_T
  61 AC_TYPE_INT32_T
  62 AC_TYPE_UINT32_T
  63 AC_TYPE_UINT64_T
  64 AC_TYPE_UINT8_T
  65
  66 AX_C___ATTRIBUTE__
  67 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  68         [:],
  69         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  70
  71 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  72 LIBS="$PTHREAD_LIBS $LIBS"
  73 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  74 CC="$PTHREAD_CC"
  75
  76 # Checks for library functions.
  77 AC_FUNC_MALLOC
  78 AC_FUNC_MMAP
  79 AC_FUNC_FORK
  80 AC_CHECK_FUNCS([ \
  81         atexit \
  82         getcpuid \
  83         gettid \
  84         gettimeofday \
  85         memeset \
  86         memset \
  87         munmap \
  88         sched_getcpu \
  89         strerror \
  90         strtoul \
  91         sysconf \
  92 ])
  93
  94 # Check for headers
  95 AC_HEADER_STDBOOL
  96 AC_CHECK_HEADERS([ \
  97         limits.h \
  98         stddef.h \
  99         sys/param.h \
 100         sys/time.h \
 101 ])
 102
 103 # Find arch type
 104 AS_CASE([$host_cpu],
 105         [k1om], [ARCHTYPE="x86"],
 106         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 107         [i486], [ARCHTYPE="x86"],
 108         [i586], [ARCHTYPE="x86"],
 109         [i686], [ARCHTYPE="x86"],
 110         [amd64], [ARCHTYPE="x86"],
 111         [x86_64], [ARCHTYPE="x86"],
 112         [powerpc], [ARCHTYPE="ppc"],
 113         [ppc64], [ARCHTYPE="ppc"],
 114         [powerpc64], [ARCHTYPE="ppc"],
 115         [powerpc64le], [ARCHTYPE="ppc"],
 116         [ppc], [ARCHTYPE="ppc"],
 117         [s390], [ARCHTYPE="s390"],
 118         [s390x], [ARCHTYPE="s390"],
 119         [sparc], [ARCHTYPE="sparc64"],
 120         [sparc64], [ARCHTYPE="sparc64"],
 121         [alpha*], [ARCHTYPE="alpha"],
 122         [ia64], [ARCHTYPE="ia64"],
 123         [arm*], [ARCHTYPE="arm"],
 124         [aarch64*], [ARCHTYPE="aarch64"],
 125         [mips*], [ARCHTYPE="mips"],
 126         [tile*], [ARCHTYPE="tile"],
 127         [hppa*], [ARCHTYPE="hppa"],
 128         [ARCHTYPE="unknown"]
 129 )
 130
 131 AS_CASE([$host],[*-*-linux-androideabi],
 132         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 133         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 134 )
 135
 136 AS_CASE([$host],[*-cygwin*],
 137         [AM_CONDITIONAL(USE_CYGWIN, true)],
 138         [AM_CONDITIONAL(USE_CYGWIN, false)]
 139 )
 140
 141 AC_SUBST(ARCHTYPE)
 142 AC_SUBST(SUBARCHTYPE)
 143
 144 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 145 ARCHSRC=urcu/arch/$ARCHTYPE.h
 146
 147 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 148         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 149 ])
 150
 151 AS_IF([test "$host_cpu" = "armv7l"],[
 152         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 153 ])
 154
 155 # ARM-specific checks
 156 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 157         AC_MSG_CHECKING([for dmb instruction])
 158         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 159                                 int main()
 160                                 {
 161                                         asm volatile("dmb":::"memory");
 162                                         return 0;
 163                                 }
 164                 ]])
 165         ],[
 166                 AC_MSG_RESULT([yes])
 167                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 168         ],[
 169                 AC_MSG_RESULT([no])
 170         ])
 171 ])
 172
 173 # Tile-specific checks
 174 AS_IF([echo "$host_cpu" | grep "^tile"],[
 175         AC_MSG_CHECKING([for Tile architecture type])
 176         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 177                                 #ifndef __tilegx__
 178                                 #error
 179                                 #endif
 180                 ]])
 181         ],[
 182                 AC_MSG_RESULT([ok])
 183         ],[
 184                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 185         ])
 186 ])
 187
 188 # x86-specific checks
 189 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 190         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 191         #For now, using lock; addl compatibility mode even for i686, because the
 192         #Pentium III is seen as a i686, but lacks mfence instruction.
 193         #Only using fence for x86_64.
 194         #
 195         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 196         #variant but lacks fence instructions.
 197         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 198                 AC_MSG_RESULT([yes])
 199                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 200         ],[
 201                 AC_MSG_RESULT([no])
 202         ])
 203 ])
 204
 205 # Check if sys_futex() is available
 206 AC_MSG_CHECKING([for sys_futex()])
 207 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 208                 #include <sys/syscall.h>
 209                 #ifndef __NR_futex
 210                 #error "futexes not available"
 211                 #endif
 212         ]])
 213 ],[
 214         AC_MSG_RESULT([yes])
 215         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 216         compat_futex_test=0
 217 ],[
 218         AC_MSG_RESULT([no])
 219         compat_futex_test=1
 220 ])
 221
 222 # Search for clock_gettime
 223 AC_SEARCH_LIBS([clock_gettime], [rt], [],
 224         [AC_MSG_ERROR([Cannot find clock_gettime function.])]
 225 )
 226
 227 # Check for pthread
 228 AC_CHECK_LIB([pthread], [pthread_create],
 229         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 230         [AC_CHECK_LIB([c], [pthread_create],
 231                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 232                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 233         )]
 234 )
 235
 236 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 237 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 238 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 239
 240 # smp-support configure option
 241 AC_ARG_ENABLE([smp-support],
 242         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 243         [def_smp_support=$enableval],
 244         [def_smp_support="yes"])
 245 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 246
 247
 248 # From the sched_setaffinity(2)'s man page:
 249 # ~~~~
 250 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 251 # The library interfaces were introduced in glibc 2.3.  Initially, the
 252 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 253 # the cpuset size argument was removed, but this argument was
 254 # restored in glibc 2.3.4.
 255 # ~~~~
 256
 257 # In addition to that, some vendors ported the system call to 2.4
 258 # kernels.
 259
 260 # Furthermore, when the function first appeared, the MASK argument was
 261 # an unsigned long pointer, while later it was made into a cpu_set_t
 262 # pointer.  Systems that have the cpu_set_t version also should have
 263 # the CPU_ZERO, CPU_SET, etc. macros.
 264
 265 # All this mess means we have to cater for at least 3 different
 266 # sched_setaffinity prototypes:
 267
 268 # ~~~~
 269 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 270 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 271 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 272 # ~~~~
 273
 274 # Since we define _GNU_SOURCE in the sources, must do so too in the
 275 # autoconf tests, as defining _GNU_SOURCE or not exposes
 276 # sched_setaffinity bits differently.
 277 saved_CFLAGS=$CFLAGS
 278 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 279
 280 AC_CHECK_TYPES([cpu_set_t],
 281         [have_cpu_set_t="yes"],
 282         [have_cpu_set_t="no"],
 283         [#include <sched.h>])
 284
 285 # Confirm that we have CPU_ZERO, and it actually works.
 286 AC_MSG_CHECKING([whether CPU_ZERO works])
 287 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 288 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 289                 #define _GNU_SOURCE
 290                 #include <sched.h>
 291                 int main()
 292                 {
 293                         cpu_set_t foo; CPU_ZERO(&foo);
 294                         return 0;
 295                 }
 296         ]])
 297 ],[
 298         AC_DEFINE(HAVE_CPU_ZERO, 1)
 299         AC_MSG_RESULT([yes])
 300 ],[
 301         AC_MSG_RESULT([no])
 302 ])
 303
 304 # Confirm that we have CPU_SET, and it actually works.
 305 AC_MSG_CHECKING([whether CPU_SET works])
 306 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 307 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 308                 #define _GNU_SOURCE
 309                 #include <sched.h>
 310                 int main()
 311                 {
 312                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 313                         return 0;
 314                 }
 315         ]])
 316 ],[
 317         AC_DEFINE(HAVE_CPU_SET, 1)
 318         AC_MSG_RESULT([yes])
 319 ],[
 320         AC_MSG_RESULT([no])
 321 ])
 322
 323 # First check if the function is available at all.
 324 AC_CHECK_FUNCS([sched_setaffinity],[
 325         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 326         # then we have the first version using unsigned long, and no
 327         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 328         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 329         # should also be present, but we confirm nonetheless.
 330
 331         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 332                 # We do have it.
 333                 # Check how many arguments does sched_setaffinity take.
 334                 # Should be 3 or 2.
 335                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 336                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 337                                 #include <sched.h>
 338                                 int main()
 339                                 {
 340                                         cpu_set_t foo;
 341                                         sched_setaffinity(0, sizeof (foo), &foo);
 342                                         return 0;
 343                                 }
 344                         ]])
 345                 ],
 346                 [sched_set_affinity_args=3],
 347                 [sched_set_affinity_args=2])
 348                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 349                         $sched_set_affinity_args,
 350                         [Defined to sched_setaffinity's number of arguments.])
 351                 AC_MSG_RESULT([$sched_set_affinity_args])
 352         ],[
 353                 # No cpu_set_t, always 3 args.
 354                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 355         ])
 356 ])
 357
 358 CFLAGS=$saved_CFLAGS
 359
 360 AC_CONFIG_LINKS([
 361         urcu/arch.h:$ARCHSRC
 362         urcu/uatomic.h:$UATOMICSRC
 363 ])
 364 AC_CONFIG_FILES([
 365         Makefile
 366         doc/Makefile
 367         doc/examples/Makefile
 368         tests/Makefile
 369         tests/common/Makefile
 370         tests/unit/Makefile
 371         tests/benchmark/Makefile
 372         tests/regression/Makefile
 373         tests/regression/regression_tests
 374         tests/utils/Makefile
 375         liburcu.pc
 376         liburcu-bp.pc
 377         liburcu-cds.pc
 378         liburcu-qsbr.pc
 379         liburcu-mb.pc
 380         liburcu-signal.pc
 381 ])
 382 AC_OUTPUT
 383
 384 # Report on selected configure options
 385 AS_IF([test "x$def_smp_support" = "xyes"],[
 386         AS_ECHO("SMP support enabled.")
 387 ],[
 388         AS_ECHO("SMP support disabled.")
 389 ])
 390
 391 AS_IF([test "x$def_tls_detect" = "x"],[
 392         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 393 ],[
 394         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 395 ])