configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.2],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  29
  30 # Allow overriding storage used for TLS variables.
  31 AC_ARG_ENABLE([compiler-tls],
  32         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  33         [def_compiler_tls=$enableval],
  34         [def_compiler_tls="yes"])
  35
  36 # If not overridden, use ax_tls.m4 to check if TLS is available.
  37 AS_IF([test "x$def_compiler_tls" = "xyes"],
  38         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  39         [:])
  40
  41 AS_IF([test "x$def_tls_detect" = "x"],
  42         [:],
  43         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  44
  45 # Checks for C compiler
  46 AC_USE_SYSTEM_EXTENSIONS
  47 AC_PROG_CC
  48 AC_PROG_CC_STDC
  49
  50 # Checks for programs.
  51 AC_PROG_AWK
  52 AC_PROG_MAKE_SET
  53 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  54 AC_CHECK_PROGS(GETCONF, [getconf])
  55 AS_IF([test "x$NPROC" != "x"],
  56         [NPROC_CMD=$NPROC],
  57         [AS_IF([test "x$GETCONF" != "x"],
  58                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  59                 [NPROC_CMD="echo 1"]
  60         )]
  61 )
  62 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  63
  64 LT_INIT
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_INLINE
  68 AC_TYPE_PID_T
  69 AC_TYPE_SIZE_T
  70 AC_TYPE_SSIZE_T
  71 AC_TYPE_UINT16_T
  72 AC_TYPE_INT32_T
  73 AC_TYPE_UINT32_T
  74 AC_TYPE_UINT64_T
  75 AC_TYPE_UINT8_T
  76
  77 AX_C___ATTRIBUTE__
  78 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  79         [:],
  80         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  81
  82 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  83 LIBS="$PTHREAD_LIBS $LIBS"
  84 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  85 CC="$PTHREAD_CC"
  86
  87 # Checks for library functions.
  88 AC_FUNC_MALLOC
  89 AC_FUNC_MMAP
  90 AC_FUNC_FORK
  91 AC_CHECK_FUNCS([ \
  92         atexit \
  93         getcpuid \
  94         gettid \
  95         gettimeofday \
  96         memeset \
  97         memset \
  98         munmap \
  99         sched_getcpu \
 100         strerror \
 101         strtoul \
 102         sysconf \
 103 ])
 104
 105 # Check for headers
 106 AC_HEADER_STDBOOL
 107 AC_CHECK_HEADERS([ \
 108         limits.h \
 109         stddef.h \
 110         sys/param.h \
 111         sys/time.h \
 112 ])
 113
 114 # Find arch type
 115 AS_CASE([$host_cpu],
 116         [k1om], [ARCHTYPE="x86"],
 117         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 118         [i486], [ARCHTYPE="x86"],
 119         [i586], [ARCHTYPE="x86"],
 120         [i686], [ARCHTYPE="x86"],
 121         [amd64], [ARCHTYPE="x86"],
 122         [x86_64], [ARCHTYPE="x86"],
 123         [powerpc], [ARCHTYPE="ppc"],
 124         [ppc64], [ARCHTYPE="ppc"],
 125         [powerpc64], [ARCHTYPE="ppc"],
 126         [powerpc64le], [ARCHTYPE="ppc"],
 127         [ppc], [ARCHTYPE="ppc"],
 128         [s390], [ARCHTYPE="s390"],
 129         [s390x], [ARCHTYPE="s390"],
 130         [sparc], [ARCHTYPE="sparc64"],
 131         [sparc64], [ARCHTYPE="sparc64"],
 132         [alpha*], [ARCHTYPE="alpha"],
 133         [ia64], [ARCHTYPE="ia64"],
 134         [arm*], [ARCHTYPE="arm"],
 135         [aarch64*], [ARCHTYPE="aarch64"],
 136         [mips*], [ARCHTYPE="mips"],
 137         [tile*], [ARCHTYPE="tile"],
 138         [hppa*], [ARCHTYPE="hppa"],
 139         [ARCHTYPE="unknown"]
 140 )
 141
 142 AS_CASE([$host],[*-*-linux-androideabi],
 143         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 144         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 145 )
 146
 147 AS_CASE([$host],[*-cygwin*],
 148         [AM_CONDITIONAL(USE_CYGWIN, true)],
 149         [AM_CONDITIONAL(USE_CYGWIN, false)]
 150 )
 151
 152 AC_SUBST(ARCHTYPE)
 153 AC_SUBST(SUBARCHTYPE)
 154
 155 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 156 ARCHSRC=urcu/arch/$ARCHTYPE.h
 157
 158 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 159         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 160 ])
 161
 162 AS_IF([test "$host_cpu" = "armv7l"],[
 163         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 164 ])
 165
 166 # ARM-specific checks
 167 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 168         AC_MSG_CHECKING([for dmb instruction])
 169         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 170                                 int main()
 171                                 {
 172                                         asm volatile("dmb":::"memory");
 173                                         return 0;
 174                                 }
 175                 ]])
 176         ],[
 177                 AC_MSG_RESULT([yes])
 178                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 179         ],[
 180                 AC_MSG_RESULT([no])
 181         ])
 182 ])
 183
 184 # Tile-specific checks
 185 AS_IF([echo "$host_cpu" | grep "^tile"],[
 186         AC_MSG_CHECKING([for Tile architecture type])
 187         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 188                                 #ifndef __tilegx__
 189                                 #error
 190                                 #endif
 191                 ]])
 192         ],[
 193                 AC_MSG_RESULT([ok])
 194         ],[
 195                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 196         ])
 197 ])
 198
 199 # x86-specific checks
 200 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 201         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 202         #For now, using lock; addl compatibility mode even for i686, because the
 203         #Pentium III is seen as a i686, but lacks mfence instruction.
 204         #Only using fence for x86_64.
 205         #
 206         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 207         #variant but lacks fence instructions.
 208         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 209                 AC_MSG_RESULT([yes])
 210                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 211         ],[
 212                 AC_MSG_RESULT([no])
 213         ])
 214 ])
 215
 216 # Check if sys_futex() is available
 217 AC_MSG_CHECKING([for sys_futex()])
 218 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 219                 #include <sys/syscall.h>
 220                 #ifndef __NR_futex
 221                 #error "futexes not available"
 222                 #endif
 223         ]])
 224 ],[
 225         AC_MSG_RESULT([yes])
 226         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 227         compat_futex_test=0
 228 ],[
 229         AC_MSG_RESULT([no])
 230         compat_futex_test=1
 231 ])
 232
 233 # Search for clock_gettime
 234 AC_SEARCH_LIBS([clock_gettime], [rt], [
 235         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 236 ], [])
 237
 238 # Check for pthread
 239 AC_CHECK_LIB([pthread], [pthread_create],
 240         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 241         [AC_CHECK_LIB([c], [pthread_create],
 242                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 243                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 244         )]
 245 )
 246
 247 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 248 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 249 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 250
 251 # smp-support configure option
 252 AC_ARG_ENABLE([smp-support],
 253         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 254         [def_smp_support=$enableval],
 255         [def_smp_support="yes"])
 256 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 257
 258
 259 # From the sched_setaffinity(2)'s man page:
 260 # ~~~~
 261 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 262 # The library interfaces were introduced in glibc 2.3.  Initially, the
 263 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 264 # the cpuset size argument was removed, but this argument was
 265 # restored in glibc 2.3.4.
 266 # ~~~~
 267
 268 # In addition to that, some vendors ported the system call to 2.4
 269 # kernels.
 270
 271 # Furthermore, when the function first appeared, the MASK argument was
 272 # an unsigned long pointer, while later it was made into a cpu_set_t
 273 # pointer.  Systems that have the cpu_set_t version also should have
 274 # the CPU_ZERO, CPU_SET, etc. macros.
 275
 276 # All this mess means we have to cater for at least 3 different
 277 # sched_setaffinity prototypes:
 278
 279 # ~~~~
 280 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 281 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 282 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 283 # ~~~~
 284
 285 # Since we define _GNU_SOURCE in the sources, must do so too in the
 286 # autoconf tests, as defining _GNU_SOURCE or not exposes
 287 # sched_setaffinity bits differently.
 288 saved_CFLAGS=$CFLAGS
 289 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 290
 291 AC_CHECK_TYPES([cpu_set_t],
 292         [have_cpu_set_t="yes"],
 293         [have_cpu_set_t="no"],
 294         [#include <sched.h>])
 295
 296 # Confirm that we have CPU_ZERO, and it actually works.
 297 AC_MSG_CHECKING([whether CPU_ZERO works])
 298 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 299 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 300                 #define _GNU_SOURCE
 301                 #include <sched.h>
 302                 int main()
 303                 {
 304                         cpu_set_t foo; CPU_ZERO(&foo);
 305                         return 0;
 306                 }
 307         ]])
 308 ],[
 309         AC_DEFINE(HAVE_CPU_ZERO, 1)
 310         AC_MSG_RESULT([yes])
 311 ],[
 312         AC_MSG_RESULT([no])
 313 ])
 314
 315 # Confirm that we have CPU_SET, and it actually works.
 316 AC_MSG_CHECKING([whether CPU_SET works])
 317 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 318 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 319                 #define _GNU_SOURCE
 320                 #include <sched.h>
 321                 int main()
 322                 {
 323                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 324                         return 0;
 325                 }
 326         ]])
 327 ],[
 328         AC_DEFINE(HAVE_CPU_SET, 1)
 329         AC_MSG_RESULT([yes])
 330 ],[
 331         AC_MSG_RESULT([no])
 332 ])
 333
 334 # First check if the function is available at all.
 335 AC_CHECK_FUNCS([sched_setaffinity],[
 336         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 337         # then we have the first version using unsigned long, and no
 338         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 339         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 340         # should also be present, but we confirm nonetheless.
 341
 342         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 343                 # We do have it.
 344                 # Check how many arguments does sched_setaffinity take.
 345                 # Should be 3 or 2.
 346                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 347                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 348                                 #include <sched.h>
 349                                 int main()
 350                                 {
 351                                         cpu_set_t foo;
 352                                         sched_setaffinity(0, sizeof (foo), &foo);
 353                                         return 0;
 354                                 }
 355                         ]])
 356                 ],
 357                 [sched_set_affinity_args=3],
 358                 [sched_set_affinity_args=2])
 359                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 360                         $sched_set_affinity_args,
 361                         [Defined to sched_setaffinity's number of arguments.])
 362                 AC_MSG_RESULT([$sched_set_affinity_args])
 363         ],[
 364                 # No cpu_set_t, always 3 args.
 365                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 366         ])
 367 ])
 368
 369 CFLAGS=$saved_CFLAGS
 370
 371 AC_CONFIG_LINKS([
 372         urcu/arch.h:$ARCHSRC
 373         urcu/uatomic.h:$UATOMICSRC
 374 ])
 375 AC_CONFIG_FILES([
 376         Makefile
 377         doc/Makefile
 378         doc/examples/Makefile
 379         tests/Makefile
 380         tests/common/Makefile
 381         tests/unit/Makefile
 382         tests/benchmark/Makefile
 383         tests/regression/Makefile
 384         tests/regression/regression_tests
 385         tests/utils/Makefile
 386         liburcu.pc
 387         liburcu-bp.pc
 388         liburcu-cds.pc
 389         liburcu-qsbr.pc
 390         liburcu-mb.pc
 391         liburcu-signal.pc
 392 ])
 393 AC_OUTPUT
 394
 395 # Report on selected configure options
 396 AS_IF([test "x$def_smp_support" = "xyes"],[
 397         AS_ECHO("SMP support enabled.")
 398 ],[
 399         AS_ECHO("SMP support disabled.")
 400 ])
 401
 402 AS_IF([test "x$def_tls_detect" = "x"],[
 403         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 404 ],[
 405         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 406 ])