Add changelog, update version to 0.6.3
[urcu.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4
5 AC_INIT([userspace-rcu], [0.6.3], [mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_CONFIG_SRCDIR([urcu.h])
18 AM_PROG_MKDIR_P
19
20 AC_CONFIG_HEADERS([config.h urcu/config.h])
21
22 # Keep at the end to do not pollute installed header.
23 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
24 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
25 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
26 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
27 cmpxchg instruction.])
28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction is available for use on ARM.])
29
30 # Checks for programs.
31 AC_PROG_CC
32 AC_PROG_MAKE_SET
33 AC_PROG_LIBTOOL
34
35 # Checks for typedefs, structures, and compiler characteristics.
36 AC_C_INLINE
37 AC_TYPE_PID_T
38 AC_TYPE_SIZE_T
39
40 # Checks for library functions.
41 AC_FUNC_MALLOC
42 AC_FUNC_MMAP
43 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
44
45 # Find arch type
46 case $host_cpu in
47 i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
48 i486) ARCHTYPE="x86";;
49 i586) ARCHTYPE="x86";;
50 i686) ARCHTYPE="x86";;
51 x86_64) ARCHTYPE="x86";;
52 powerpc) ARCHTYPE="ppc" ;;
53 ppc64) ARCHTYPE="ppc" ;;
54 powerpc64) ARCHTYPE="ppc" ;;
55 ppc) ARCHTYPE="ppc" ;;
56 s390) ARCHTYPE="s390" ;;
57 s390x) ARCHTYPE="s390" ;;
58 sparc64) ARCHTYPE="sparc64" ;;
59 alpha*) ARCHTYPE="alpha" ;;
60 ia64) ARCHTYPE="gcc" ;;
61 arm*) ARCHTYPE="arm" ;;
62 *) ARCHTYPE="unknown";;
63 esac
64
65 if test "x$ARCHTYPE" = "xarm" ; then
66 AC_MSG_CHECKING([checking for dmb instruction])
67 AC_TRY_COMPILE(
68 [
69 ],
70 [
71 asm volatile("dmb":::"memory");
72 ],
73 [
74 AC_MSG_RESULT([yes])
75 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
76 ]
77 ,
78 [
79 AC_MSG_RESULT([no])
80 ]
81 )
82 fi
83
84 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
85 ARCHSRC=urcu/arch/$ARCHTYPE.h
86 if test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc; then
87 APISRC=tests/api_gcc.h
88 else
89 APISRC=tests/api_$ARCHTYPE.h
90 fi
91 if test "$ARCHTYPE" == "armv7l"; then
92 CFLAGS="-mcpu=cortex-a9 -mtune=cortex-a9 -O"
93 fi
94
95 AC_SUBST(ARCHTYPE)
96 AC_SUBST(SUBARCHTYPE)
97
98 [
99 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
100 #For now, using lock; addl compatibility mode even for i686, because the
101 #Pentium III is seen as a i686, but lacks mfence instruction.
102 #Only using fence for x86_64.
103 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
104 ]
105 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
106 [
107 fi
108 ]
109
110 AC_MSG_CHECKING([sys_futex()])
111 AC_TRY_COMPILE(
112 [
113 #include <sys/syscall.h>
114 ],
115 [
116 #ifndef __NR_futex
117 #error "futexes not available"
118 #endif
119 ],
120 [
121 AC_MSG_RESULT([yes])
122 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
123 compat_futex_test=0
124 ]
125 ,
126 [
127 AC_MSG_RESULT([no])
128 compat_futex_test=1
129 ]
130 )
131
132 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
133
134 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
135
136 [
137 if test "x$SUBARCHTYPE" = xx86compat; then
138 ]
139 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
140 [
141 fi
142 ]
143
144 AC_ARG_ENABLE([smp-support], [ --disable-smp-support Disable SMP support. Warning: only use this
145 on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
146
147 [
148 if test "$def_smp_support" = "no"; then
149 echo "SMP support disabled."
150 else
151 ]
152 AC_DEFINE([CONFIG_RCU_SMP], [1])
153 [
154 echo "SMP support enabled."
155 fi
156 ]
157
158 # From the sched_setaffinity(2)'s man page:
159 # ~~~~
160 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
161 # The library interfaces were introduced in glibc 2.3. Initially, the
162 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
163 # the cpuset size argument was removed, but this argument was
164 # restored in glibc 2.3.4.
165 # ~~~~
166
167 # In addition to that, some vendors ported the system call to 2.4
168 # kernels.
169
170 # Furthermore, when the function first appeared, the MASK argument was
171 # an unsigned long pointer, while later it was made into a cpu_set_t
172 # pointer. Systems that have the cpu_set_t version also should have
173 # the CPU_ZERO, CPU_SET, etc. macros.
174
175 # All this mess means we have to cater for at least 3 different
176 # sched_setaffinity prototypes:
177
178 # ~~~~
179 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
180 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
181 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
182 # ~~~~
183
184 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
185 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
186 dnl sched_setaffinity bits differently.
187 saved_CFLAGS=$CFLAGS
188 CFLAGS="$CFLAGS -D_GNU_SOURCE"
189
190 # First check if the function is available at all.
191 AC_CHECK_FUNCS(
192 [sched_setaffinity],
193 [ # Okay, we have it. Check if also have cpu_set_t. If we don't,
194 # then we have the first version using unsigned long, and no
195 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
196 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
197 # should also be present, but we confirm nonetheless.
198
199 AC_CHECK_TYPES(
200 [cpu_set_t],
201 [ # We do have it. Confirm that we have CPU_ZERO, and it actually works.
202 AC_MSG_CHECKING([whether CPU_ZERO works])
203 AH_TEMPLATE([HAVE_CPU_ZERO],
204 [Define to 1 if we have CPU_ZERO and if it works])
205 AC_COMPILE_IFELSE(
206 [AC_LANG_PROGRAM(
207 [#define _GNU_SOURCE
208 #include <sched.h>],
209 [cpu_set_t foo; CPU_ZERO (&foo);])
210 ],
211 [ # Works!
212 AC_DEFINE(HAVE_CPU_ZERO, 1)
213 AC_MSG_RESULT([yes])
214 ],
215 [AC_MSG_RESULT([no])]
216 )
217
218 # Check how many arguments does sched_setaffinity take.
219 # Should be 3 or 2.
220 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
221 AC_COMPILE_IFELSE(
222 [AC_LANG_PROGRAM(
223 [#include <sched.h>],
224 [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
225 ],
226 [sched_set_affinity_args=3],
227 [sched_set_affinity_args=2])
228 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
229 [Define to sched_setaffinity's number of arguments.])
230 AC_MSG_RESULT([$sched_set_affinity_args])
231 ],
232 [ # No cpu_set_t, always 3 args.
233 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
234 [#include <sched.h>]
235 )
236 ]
237 )
238
239 CFLAGS=$saved_CFLAGS
240
241 AC_CONFIG_LINKS([
242 urcu/arch.h:$ARCHSRC
243 urcu/uatomic.h:$UATOMICSRC
244 tests/api.h:$APISRC
245 ])
246 AC_CONFIG_FILES([
247 Makefile
248 tests/Makefile
249 liburcu-cds.pc
250 liburcu.pc
251 liburcu-bp.pc
252 liburcu-qsbr.pc
253 liburcu-mb.pc
254 liburcu-signal.pc
255 ])
256 AC_OUTPUT
This page took 0.042479 seconds and 5 git commands to generate.