configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [13])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [pre])
   6 m4_define([V_NAME], [[Codename TBD]])
   7 m4_define([V_DESC], [[Description TBD]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 AC_PROG_CC_STDC
  57 AC_PROG_CXX
  58 AX_CXX_COMPILE_STDCXX([11])
  59 RW_PROG_CXX_WORKS
  60 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  61
  62 # Check if the compiler support weak symbols
  63 AX_SYS_WEAK_ALIAS
  64
  65 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  66         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  67 ])
  68
  69 # Checks for programs.
  70 AM_PROG_AR
  71 AC_PROG_SED
  72 AC_PROG_GREP
  73 AC_PROG_LN_S
  74 AC_PROG_MKDIR_P
  75 AC_PROG_MAKE_SET
  76 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  77 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  78
  79 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  80 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  81 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  82 ], [
  83         libtool_fixup=$enableval
  84 ], [
  85         libtool_fixup=yes
  86 ])
  87
  88 AS_IF([test "x$libtool_fixup" = "xyes"], [
  89         libtool_m4="$srcdir/m4/libtool.m4"
  90         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  91         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  92         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  93
  94         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  95         AC_MSG_RESULT([$libtool_flag_pattern_count])
  96         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  97                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  98         ], [
  99                 AC_MSG_RESULT([none])
 100         ])
 101 ])
 102 LT_INIT([disable-static])
 103
 104 AC_MSG_CHECKING([whether shared libraries are enabled])
 105 AS_IF([test "x$enable_shared" = "xyes"], [
 106         AC_MSG_RESULT([yes])
 107 ], [
 108         AC_MSG_RESULT([no])
 109         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 110 ])
 111
 112 # Checks for typedefs, structures, and compiler characteristics.
 113 AC_C_INLINE
 114 AC_TYPE_INT8_T
 115 AC_TYPE_INT16_T
 116 AC_TYPE_INT32_T
 117 AC_TYPE_INT64_T
 118 AC_TYPE_MODE_T
 119 AC_TYPE_OFF_T
 120 AC_TYPE_PID_T
 121 AC_TYPE_SIZE_T
 122 AC_TYPE_SSIZE_T
 123 AC_TYPE_UID_T
 124 AC_TYPE_UINT8_T
 125 AC_TYPE_UINT16_T
 126 AC_TYPE_UINT32_T
 127 AC_TYPE_UINT64_T
 128 AC_CHECK_TYPES([ptrdiff_t])
 129
 130 AX_C___ATTRIBUTE__
 131 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 132         [:],
 133         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 134
 135 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 136
 137 # Checks for library functions.
 138 AC_FUNC_CHOWN
 139 AC_FUNC_FORK
 140 AC_FUNC_MMAP
 141 AC_FUNC_REALLOC
 142 AC_FUNC_STRERROR_R
 143 AC_FUNC_STRNLEN
 144 AC_CHECK_FUNCS([ \
 145         atexit \
 146         clock_gettime \
 147         ftruncate \
 148         getpagesize \
 149         gettimeofday \
 150         localeconv \
 151         memchr \
 152         memmove \
 153         memset \
 154         mkdir \
 155         munmap \
 156         realpath \
 157         sched_getcpu \
 158         socket \
 159         strchr \
 160         strdup \
 161         strerror \
 162         strtol \
 163         sysconf \
 164 ])
 165
 166 # Check for pthread_setname_np and its signature
 167 LTTNG_PTHREAD_SETNAME_NP
 168
 169 # AC_FUNC_MALLOC causes problems when cross-compiling.
 170 #AC_FUNC_MALLOC
 171
 172 # Checks for header files.
 173 AC_HEADER_STDBOOL
 174 AC_CHECK_HEADERS([ \
 175         arpa/inet.h \
 176         fcntl.h \
 177         float.h \
 178         limits.h \
 179         locale.h \
 180         stddef.h \
 181         sys/socket.h \
 182         sys/time.h \
 183         wchar.h \
 184 ])
 185
 186 # Set architecture specific options
 187 AS_CASE([$host_cpu],
 188         [i[[3456]]86], [],
 189         [x86_64], [],
 190         [amd64], [],
 191         [powerpc], [],
 192         [ppc64], [],
 193         [ppc64le], [],
 194         [powerpc64], [],
 195         [powerpc64le], [],
 196         [s390], [NO_UNALIGNED_ACCESS=1],
 197         [s390x], [NO_UNALIGNED_ACCESS=1],
 198         [arm*], [
 199                 NO_UNALIGNED_ACCESS=1
 200                 NO_NUMA=1
 201                 ],
 202         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 203         [mips*], [NO_UNALIGNED_ACCESS=1],
 204         [tile*], [NO_UNALIGNED_ACCESS=1],
 205         [
 206                 UNSUPPORTED_ARCH=1
 207                 NO_UNALIGNED_ACCESS=1
 208         ])
 209
 210 # Configuration options, which will be installed in the config.h
 211 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 212 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 213 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 214
 215 # Checks for libraries.
 216 AC_CHECK_LIB([dl], [dlopen], [
 217         libdl_name=dl
 218         DL_LIBS="-ldl"
 219 ], [
 220         #libdl not found, check for dlopen in libc.
 221         AC_CHECK_LIB([c], [dlopen], [
 222                 libdl_name=c
 223                 DL_LIBS="-lc"
 224         ], [
 225                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 226         ])
 227 ])
 228 AC_SUBST(DL_LIBS)
 229
 230 # Check if libdl has dlmopen support.
 231 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 232 AC_CHECK_LIB([$libdl_name], [dlmopen],
 233         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 234 )
 235
 236 # Check for dlfcn.h
 237 AC_CHECK_HEADER([dlfcn.h])
 238 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 239         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 240                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 241                 #include <dlfcn.h>
 242         ])
 243 ], [
 244         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 245 ])
 246
 247 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 248
 249 # URCU
 250
 251 AC_MSG_CHECKING([DEFINE_URCU_TLS_INIT()])
 252 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 253         #include <urcu/tls-compat.h>
 254         DEFINE_URCU_TLS_INIT(int, a, 1);
 255 ]])], [
 256         AC_MSG_RESULT([yes])
 257 ], [
 258         AC_MSG_RESULT([no])
 259         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.12.0 or better])
 260 ])
 261
 262 # urcu - check if we just find the headers it out of the box.
 263 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 264 This error can also occur when the liburcu package's configure script has not been run.])])
 265
 266 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 267 # Part of Userspace RCU library 0.7.2 or better.
 268 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 269 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 270
 271 AC_MSG_CHECKING([caa_likely()])
 272 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 273         #include <urcu/compiler.h>
 274         void fct(void)
 275         {
 276                 if (caa_likely(1)) {
 277                 }
 278         }
 279 ]])], [
 280         AC_MSG_RESULT([yes])
 281 ], [
 282         AC_MSG_RESULT([no])
 283         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 284 ])
 285
 286 # urcu - check that URCU lib is available to compilation
 287 AC_CHECK_LIB([urcu-bp], [urcu_bp_synchronize_rcu], [], [AC_MSG_ERROR([Cannot find liburcu-bp 0.11 or newer. Use [LDFLAGS]=-Ldir to specify its location.])])
 288
 289 # urcu - check that URCU lib is at least version 0.11
 290 AC_CHECK_LIB([urcu-bp], [urcu_bp_call_rcu], [], [AC_MSG_ERROR([liburcu 0.11 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 291
 292 # numa.h integration
 293 AS_IF([test "x$NO_NUMA" = "x1"],[
 294       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 295 ])
 296
 297 AC_ARG_ENABLE([numa], [
 298 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 299 ], [
 300         enable_numa=$enableval
 301 ], [
 302         enable_numa=yes
 303 ])
 304
 305 AS_IF([test "x$enable_numa" = "xyes"], [
 306         # numa - check that numa lib is available
 307         AC_CHECK_LIB([numa], [numa_available], [],
 308 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 309         have_libnuma=yes
 310 ])
 311 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 312
 313 # optional linux/perf_event.h
 314 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 315
 316 # Perf event counters are supported on all architectures supported by
 317 # perf, using the read system call as fallback.
 318 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 319
 320 AS_IF([test "x$have_perf_event" = "xyes"], [
 321         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 322 ])
 323
 324 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 325         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 326 ])
 327
 328 # Check for JNI header files if requested
 329 AC_ARG_ENABLE([jni-interface], [
 330 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 331 ], [
 332         jni_interface=$enableval
 333 ], [
 334         jni_interface=no
 335 ])
 336
 337 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 338
 339
 340 AC_ARG_ENABLE([java-agent-jul], [
 341 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 342 ], [
 343         java_agent_jul=$enableval
 344 ], [
 345         java_agent_jul=no
 346 ])
 347
 348 AC_ARG_ENABLE([java-agent-log4j], [
 349 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 350 ], [
 351         java_agent_log4j=$enableval
 352 ], [
 353         java_agent_log4j=no
 354 ])
 355
 356 AC_ARG_ENABLE([java-agent-all], [
 357 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 358 ], [
 359         java_agent_jul=$enableval
 360         java_agent_log4j=$enableval
 361 ], [:])
 362
 363 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 364 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 365 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 366
 367 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 368         AX_JAVA_OPTIONS
 369         AX_PROG_JAVAC
 370         AX_PROG_JAVA
 371         AX_PROG_JAR
 372         AC_ARG_VAR([CLASSPATH], [Java class path])
 373
 374         AX_JNI_INCLUDE_DIR
 375         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 376         do
 377                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 378         done
 379
 380         saved_CPPFLAGS="$CPPFLAGS"
 381         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 382         AX_PROG_JAVAH
 383         CPPFLAGS="$saved_CPPFLAGS"
 384 ])
 385
 386 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 387
 388 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 389         AX_CHECK_CLASSPATH
 390         AX_CHECK_CLASS([org.apache.log4j.Logger])
 391         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 392                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 393         ])
 394 ])
 395
 396 # Option to build the python agent
 397 AC_ARG_ENABLE([python-agent], [
 398 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 399 ], [
 400         python_agent=$enableval
 401 ], [:])
 402 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 403 AS_IF([test "x$python_agent" = "xyes"], [
 404         AM_PATH_PYTHON([2.7])
 405 ])
 406
 407 # sdt.h integration
 408 AC_ARG_WITH([sdt], [
 409 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 410 ], [
 411         with_sdt=$withval
 412 ], [
 413         with_sdt="no"
 414 ])
 415
 416 AS_IF([test "x$with_sdt" = "xyes"], [
 417         AC_MSG_CHECKING([STAP_PROBEV()])
 418         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 419                 #define SDT_USE_VARIADIC
 420                 #include <sys/sdt.h>
 421                 void fct(void)
 422                 {
 423                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 424                 }
 425         ]])], [
 426                 AC_MSG_RESULT([yes])
 427                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 428         ], [
 429                 AC_MSG_RESULT([no])
 430                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 431         ])
 432 ])
 433
 434 AC_ARG_WITH([lttng-system-rundir], [
 435 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 436 ], [
 437         lttng_system_rundir="$withval"
 438 ], [
 439         lttng_system_rundir="/var/run/lttng"
 440 ])
 441 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 442                 [LTTng system runtime directory])
 443
 444 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 445 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 446
 447 # Enable building examples
 448 AC_ARG_ENABLE(
 449         examples,
 450         AS_HELP_STRING(
 451                 [--disable-examples],
 452                 [Do not build and install examples]
 453         ),
 454         [enable_examples=$enableval],
 455         [enable_examples=yes]
 456 )
 457
 458 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 459
 460 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 461 # is not distributed in tarballs.
 462 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 463 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 464
 465 # Enable building man pages (user's intention).
 466 AC_ARG_ENABLE(
 467         man-pages,
 468         AS_HELP_STRING(
 469                 [--disable-man-pages],
 470                 [Do not build and install man pages (already built in a distributed tarball)]
 471         ),
 472         [man_pages_opt=$enableval],
 473         [man_pages_opt=yes]
 474 )
 475
 476 # Check for asciidoc and xmlto if we enabled building the man pages.
 477 have_asciidoc_xmlto=no
 478 warn_prebuilt_man_pages=no
 479
 480 AS_IF([test "x$man_pages_opt" = "xyes"], [
 481         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 482         AC_PATH_PROG([XMLTO], [xmlto], [no])
 483
 484         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 485                 AS_IF([test "x$in_git_repo" = "xyes"], [
 486                         # This is an error because we're in the Git repo, which
 487                         # means the man pages are not already generated for us,
 488                         # thus asciidoc/xmlto are required because we were asked
 489                         # to build the man pages.
 490                         AC_MSG_ERROR([
 491 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 492 --disable-man-pages to disable building the man pages, in which case
 493 they will not be installed.
 494                         ])
 495                 ], [
 496                         # Only warn here: since we're in the tarball, the man
 497                         # pages should already be generated at this point, thus
 498                         # asciidoc/xmlto are not strictly required.
 499                         warn_prebuilt_man_pages=yes
 500                 ])
 501         ], [
 502                 have_asciidoc_xmlto=yes
 503         ])
 504 ])
 505
 506 # Export man page build condition: build the man pages if the user
 507 # asked for it, and if the tools are available.
 508 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 509 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 510
 511 # Default values
 512 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 513         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 514         $1="$2"
 515         AC_SUBST([$1])
 516 ])
 517
 518 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 519
 520 AM_CFLAGS="-Wall $PTHREAD_CFLAGS"
 521 AC_SUBST(AM_CFLAGS)
 522 AC_SUBST(JNI_CPPFLAGS)
 523
 524 AC_CONFIG_FILES([
 525         Makefile
 526         doc/Makefile
 527         doc/examples/Makefile
 528         doc/man/Makefile
 529         include/Makefile
 530         include/lttng/ust-version.h
 531         snprintf/Makefile
 532         libringbuffer/Makefile
 533         liblttng-ust-comm/Makefile
 534         liblttng-ust/Makefile
 535         liblttng-ust-ctl/Makefile
 536         liblttng-ust-fork/Makefile
 537         liblttng-ust-dl/Makefile
 538         liblttng-ust-fd/Makefile
 539         liblttng-ust-java/Makefile
 540         liblttng-ust-java-agent/Makefile
 541         liblttng-ust-java-agent/java/Makefile
 542         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 543         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 544         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 545         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 546         liblttng-ust-java-agent/jni/Makefile
 547         liblttng-ust-java-agent/jni/common/Makefile
 548         liblttng-ust-java-agent/jni/jul/Makefile
 549         liblttng-ust-java-agent/jni/log4j/Makefile
 550         liblttng-ust-libc-wrapper/Makefile
 551         liblttng-ust-cyg-profile/Makefile
 552         liblttng-ust-python-agent/Makefile
 553         python-lttngust/Makefile
 554         python-lttngust/setup.py
 555         python-lttngust/lttngust/__init__.py
 556         tools/Makefile
 557         tests/Makefile
 558         tests/ctf-types/Makefile
 559         tests/hello/Makefile
 560         tests/hello-many/Makefile
 561         tests/hello.cxx/Makefile
 562         tests/same_line_tracepoint/Makefile
 563         tests/snprintf/Makefile
 564         tests/ust-elf/Makefile
 565         tests/benchmark/Makefile
 566         tests/utils/Makefile
 567         tests/test-app-ctx/Makefile
 568         tests/gcc-weak-hidden/Makefile
 569         lttng-ust.pc
 570         lttng-ust-ctl.pc
 571 ])
 572
 573 # Create link for python agent for the VPATH guru.
 574 AC_CONFIG_LINKS([
 575         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 576         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 577         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 578         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 579         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 580 ])
 581
 582 AC_CONFIG_FILES([tests/ust-elf/test_ust_elf],[chmod +x tests/ust-elf/test_ust_elf])
 583
 584 AC_OUTPUT
 585
 586
 587 #
 588 # Mini-report on what will be built.
 589 #
 590
 591 PPRINT_INIT
 592 PPRINT_SET_INDENT(1)
 593 PPRINT_SET_TS(38)
 594
 595 AS_ECHO
 596 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 597 AS_ECHO
 598
 599 AS_ECHO("V_DESC")
 600
 601 AS_ECHO
 602 PPRINT_SUBTITLE([System])
 603
 604 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 605
 606 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 607 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 608
 609 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 610        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 611 ])
 612
 613 AS_ECHO
 614 PPRINT_SUBTITLE([Features])
 615 PPRINT_SET_INDENT(1)
 616
 617 test "x$with_sdt" = "xyes" && value=1 || value=0
 618 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 619
 620 test "x$java_agent_jul" = xyes && value=1 || value=0
 621 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 622
 623 test "x$java_agent_log4j" = xyes && value=1 || value=0
 624 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 625
 626 test "x$jni_interface" = xyes && value=1 || value=0
 627 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 628
 629 test "x$python_agent" = xyes && value=1 || value=0
 630 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 631
 632 test "x$have_perf_event" = "xyes" && value=1 || value=0
 633 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 634
 635 test "x$enable_numa" = xyes && value=1 || value=0
 636 PPRINT_PROP_BOOL([NUMA], $value)
 637
 638 AS_ECHO
 639 PPRINT_SET_INDENT(0)
 640
 641 test "x$enable_examples" = xyes && value=1 || value=0
 642 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 643
 644 # man pages build enabled/disabled
 645 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 646
 647 AS_IF([test "x$man_pages_opt" != "xno"], [
 648         AS_IF([test "x$in_git_repo" = "xyes"], [
 649                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 650         ], [
 651                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 652                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 653                 ], [
 654                         PPRINT_PROP_STRING([build_man_pages_msg],
 655                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 656                                 $PPRINT_COLOR_SUBTITLE)
 657                 ])
 658         ])
 659 ], [
 660         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 661 ])
 662
 663 m4_popdef([build_man_pages_msg])
 664
 665 PPRINT_SET_INDENT(1)
 666
 667 report_bindir="`eval eval echo $bindir`"
 668 report_libdir="`eval eval echo $libdir`"
 669
 670 # Print the bindir and libdir this `make install' will install into.
 671 AS_ECHO
 672 PPRINT_SUBTITLE([Install directories])
 673 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 674 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 675
 676 AS_ECHO
 677 PPRINT_SUBTITLE([System directories])
 678
 679 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 680
 681 PPRINT_SET_INDENT(0)
 682
 683 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 684         AS_ECHO
 685         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 686
 687 Note that the man pages are already built in this distribution tarball,
 688 therefore asciidoc and xmlto are only needed if you intend to modify
 689 their sources.
 690
 691 Use --disable-man-pages to completely disable building and installing
 692 the man pages.])
 693 ])