configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7
   8 # Project version information
   9 m4_define([ust_version_major], [2])
  10 m4_define([ust_version_minor], [14])
  11 m4_define([ust_version_patch], [0])
  12 m4_define([ust_version_dev_stage], [-pre])
  13 m4_define([ust_version], ust_version_major[.]ust_version_minor[.]ust_version_patch[]ust_version_dev_stage)
  14 m4_define([ust_version_name], [[O-Beer]])
  15 m4_define([ust_version_description], [[An alcoholic drink made from yeast-fermented malt flavored with hops.]])
  16
  17 # Library version information of "liblttng-ust"
  18 # Following the numbering scheme proposed by libtool for the library version
  19 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  20 m4_define([ust_lib_version_current], [1])
  21 m4_define([ust_lib_version_revision], [0])
  22 m4_define([ust_lib_version_age], [0])
  23 m4_define([ust_lib_version], ust_lib_version_current[:]ust_lib_version_revision[:]ust_lib_version_age)
  24
  25 # Library version information of "liblttng-ust-ctl"
  26 # Following the numbering scheme proposed by libtool for the library version
  27 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  28 m4_define([ust_ctl_lib_version_current], [5])
  29 m4_define([ust_ctl_lib_version_revision], [0])
  30 m4_define([ust_ctl_lib_version_age], [0])
  31 m4_define([ust_ctl_lib_version], ust_ctl_lib_version_current[:]ust_ctl_lib_version_revision[:]ust_ctl_lib_version_age)
  32
  33
  34 ##                     ##
  35 ## Autoconf base setup ##
  36 ##                     ##
  37
  38 AC_PREREQ([2.69])
  39 AC_INIT([lttng-ust],[ust_version],[mathieu dot desnoyers at efficios dot com],[],[https://lttng.org])
  40
  41 AC_CONFIG_HEADERS([src/common/config.h include/lttng/ust-config.h include/lttng/ust-version.h])
  42 AC_CONFIG_AUX_DIR([config])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 AC_CANONICAL_TARGET
  46 AC_CANONICAL_HOST
  47
  48
  49 ##                     ##
  50 ## Automake base setup ##
  51 ##                     ##
  52
  53 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  54 AM_MAINTAINER_MODE([enable])
  55
  56 # Enable silent rules by default
  57 AM_SILENT_RULES([yes])
  58
  59
  60 ##                               ##
  61 ## OS and Arch specific defaults ##
  62 ##                               ##
  63
  64 # Set os specific options
  65 AS_CASE([$host_os],
  66   [freebsd*], [AE_FEATURE_DISABLE([numa])]
  67 )
  68
  69 # Set architecture specific options
  70 AS_CASE([$host_cpu],
  71   [i[[3456]]86], [],
  72   [x86_64], [],
  73   [amd64], [],
  74   [powerpc], [],
  75   [ppc64], [],
  76   [ppc64le], [],
  77   [powerpc64], [],
  78   [powerpc64le], [],
  79   [s390], [],
  80   [s390x], [],
  81   [arm*], [AE_FEATURE_DISABLE([numa])],
  82   [aarch64*], [],
  83   [mips*], [],
  84   [tile*], [],
  85   [
  86     unsupported_arch="yes"
  87   ])
  88
  89
  90 ##                   ##
  91 ## C compiler checks ##
  92 ##                   ##
  93
  94 # Choose the C compiler
  95 AC_PROG_CC
  96 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  97 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  98
  99 # Make sure the C compiler supports C99
 100 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
 101
 102 # Enable available system extensions and LFS support
 103 AC_USE_SYSTEM_EXTENSIONS
 104 AC_SYS_LARGEFILE
 105
 106 # Make sure the C compiler supports __attribute__
 107 AX_C___ATTRIBUTE__
 108 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
 109   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 110
 111 # Make sure we have pthread support
 112 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
 113
 114 # Make sure the C compiler supports weak symbols
 115 AX_SYS_WEAK_ALIAS
 116 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
 117   [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
 118
 119 # Checks for typedefs, structures, and compiler characteristics.
 120 AC_C_INLINE
 121 AC_C_TYPEOF
 122 AC_TYPE_INT16_T
 123 AC_TYPE_INT32_T
 124 AC_TYPE_INT64_T
 125 AC_TYPE_INT8_T
 126 AC_TYPE_MODE_T
 127 AC_TYPE_OFF_T
 128 AC_TYPE_PID_T
 129 AC_TYPE_SIZE_T
 130 AC_TYPE_SSIZE_T
 131 AC_TYPE_UID_T
 132 AC_TYPE_UINT16_T
 133 AC_TYPE_UINT32_T
 134 AC_TYPE_UINT64_T
 135 AC_TYPE_UINT8_T
 136 AC_CHECK_TYPES([ptrdiff_t])
 137
 138 # Detect warning flags supported by the C compiler and append them to
 139 # WARN_CFLAGS.
 140 m4_define([WARN_FLAGS_LIST], [ dnl
 141   -Wall dnl
 142   -Wextra dnl
 143   -Wmissing-prototypes dnl
 144   -Wmissing-declarations dnl
 145   -Wnull-dereference dnl
 146   -Wundef dnl
 147   -Wshadow dnl
 148   -Wjump-misses-init dnl
 149   -Wsuggest-attribute=format dnl
 150   -Wtautological-constant-out-of-range-compare dnl
 151   -Wnested-externs dnl
 152   -Wwrite-strings dnl
 153   -Wformat=2 dnl
 154   -Wstrict-aliasing dnl
 155   -Wmissing-noreturn dnl
 156   -Winit-self dnl
 157   -Wduplicated-cond dnl
 158   -Wduplicated-branches dnl
 159   -Wlogical-op dnl
 160   dnl These would require reworking the tracepoint macros
 161   dnl-Wredundant-decls dnl
 162   -Wno-sign-compare dnl
 163   -Wno-missing-field-initializers dnl
 164   -Wno-null-dereference dnl
 165   -Wno-gnu dnl Disable warnings for GNU extensions on Clang
 166 ])
 167
 168 # Pass -Werror as an extra flag during the test: this is needed to make the
 169 # -Wunknown-warning-option diagnostic fatal with clang.
 170 AC_LANG_PUSH([C])
 171 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 172 AC_LANG_POP([C])
 173
 174 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
 175 # written in such a way that it triggers warnings with the following warning
 176 # flags.  So they would always end up disabled if we put them there, because
 177 # the test program would not build.
 178 #
 179 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
 180 # Clang >= 3.3 (required by the project) and are only valid for C code.
 181 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
 182
 183 # Disable 'strict aliasing' if the compiler supports it.
 184 AC_LANG_PUSH([C])
 185 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
 186 AC_LANG_POP([C])
 187
 188
 189 ##                     ##
 190 ## C++ compiler checks ##
 191 ##                     ##
 192
 193 # Find an optional C++11 compiler without GNU extensions (-std=c++11)
 194 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 195
 196 AS_IF([test "$HAVE_CXX11" = "1"], [
 197   # Pass -Werror as an extra flag during the test: this is needed to make the
 198   # -Wunknown-warning-option diagnostic fatal with clang.
 199   AC_LANG_PUSH([C++])
 200   AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST -Wno-undef -Wno-duplicated-branches], [WARN_CXXFLAGS], [-Werror])
 201   AC_LANG_POP([C++])
 202 ])
 203
 204
 205 ##               ##
 206 ## Header checks ##
 207 ##               ##
 208
 209 AC_HEADER_STDBOOL
 210 AC_CHECK_HEADERS([ \
 211   arpa/inet.h \
 212   dlfcn.h \
 213   fcntl.h \
 214   float.h \
 215   limits.h \
 216   linux/perf_event.h \
 217   locale.h \
 218   stddef.h \
 219   sys/socket.h \
 220   sys/time.h \
 221   wchar.h \
 222 ])
 223
 224 # Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
 225 AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
 226   AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
 227 ])
 228
 229
 230 ##                 ##
 231 ## Programs checks ##
 232 ##                 ##
 233
 234 AM_PROG_AR
 235 AC_PROG_SED
 236 AC_PROG_GREP
 237 AC_PROG_LN_S
 238 AC_PROG_MKDIR_P
 239 AC_PROG_MAKE_SET
 240 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 241 AC_CHECK_PROGS([CMAKE], [cmake])
 242 AC_CHECK_PROGS([FOLD], [fold])
 243 AC_CHECK_PROGS([XMLTO], [xmlto])
 244
 245 AM_PATH_PYTHON([2.7], [], [PYTHON=""])
 246
 247 # Initialize and configure libtool
 248 LT_INIT([disable-static])
 249
 250
 251 ##                ##
 252 ## Library checks ##
 253 ##                ##
 254
 255 AC_FUNC_CHOWN
 256 AC_FUNC_FORK
 257 AC_FUNC_MMAP
 258 AC_FUNC_STRERROR_R
 259 AC_FUNC_STRNLEN
 260 AC_CHECK_FUNCS([ \
 261   atexit \
 262   clock_gettime \
 263   ftruncate \
 264   getpagesize \
 265   gettid \
 266   gettimeofday \
 267   localeconv \
 268   memchr \
 269   memmove \
 270   memset \
 271   mkdir \
 272   munmap \
 273   realpath \
 274   sched_getcpu \
 275   socket \
 276   strchr \
 277   strdup \
 278   strerror \
 279   strtol \
 280   strtoul \
 281   sysconf \
 282 ])
 283
 284 # AC_FUNC_MALLOC causes problems when cross-compiling.
 285 #AC_FUNC_MALLOC
 286 #AC_FUNC_REALLOC
 287
 288 # Check for pthread_setname_np and its signature
 289 LTTNG_PTHREAD_SETNAME_NP
 290 LTTNG_PTHREAD_GETNAME_NP
 291
 292 # Check dor dlopen() in -ldl or -lc
 293 AC_CHECK_LIB([dl], [dlopen], [
 294   libdl_name=dl
 295   DL_LIBS="-ldl"
 296 ], [
 297   # dlopen not found in libdl, check in libc
 298   AC_CHECK_LIB([c], [dlopen], [
 299     libdl_name=c
 300     DL_LIBS="-lc"
 301   ], [
 302     AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 303   ])
 304 ])
 305 AC_SUBST(DL_LIBS)
 306
 307 # Check if libdl has dlmopen()
 308 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 309   AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
 310 ])
 311
 312 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 313 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 314
 315
 316 ##                 ##
 317 ## User variables  ##
 318 ##                 ##
 319
 320 # Additional variables captured during ./configure
 321
 322 AC_ARG_VAR([CLASSPATH], [Java class path])
 323 AC_ARG_VAR([JAVACFLAGS], [Java compiler flags])
 324 AC_ARG_VAR([JAVAC], [Java compiler])
 325 AC_ARG_VAR([JAVAFLAGS], [Java VM flags])
 326 AC_ARG_VAR([JAVA], [Java VM])
 327 AC_ARG_VAR([JAVAPREFIX], [prefix where Java runtime is installed])
 328
 329
 330 ##                              ##
 331 ## Optional features selection ##
 332 ##                              ##
 333
 334 # numa integration
 335 # Enabled by default, except on some platforms
 336 AE_FEATURE_DEFAULT_ENABLE
 337 AE_FEATURE([numa],[disable NUMA support])
 338
 339 # Java JNI interface library
 340 # Disabled by default
 341 AE_FEATURE_DEFAULT_DISABLE
 342 AE_FEATURE([jni-interface], [build JNI interface between C and Java])
 343
 344 # Build the Java Logging API agent
 345 # Disabled by default
 346 AE_FEATURE_DEFAULT_DISABLE
 347 AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
 348
 349 # Build the Java Log4j 1.x agent
 350 # Disabled by default
 351 AE_FEATURE_DEFAULT_DISABLE
 352 AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j 1.x support (deprecated)])
 353
 354 # Build the Java Log4j 2.x agent
 355 # Disabled by default
 356 AE_FEATURE_DEFAULT_DISABLE
 357 AE_FEATURE([java-agent-log4j2],[build the LTTng UST Java agent with Log4j 2.x support])
 358
 359 # Build both Java agents
 360 # Disabled by default
 361 AE_FEATURE_DEFAULT_DISABLE
 362 AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
 363
 364 # Build the Python agent
 365 # Disabled by default
 366 AE_FEATURE_DEFAULT_DISABLE
 367 AE_FEATURE([python-agent],[build the LTTng UST Python agent])
 368
 369 # Build the examples
 370 # Disabled by default
 371 AE_FEATURE_DEFAULT_ENABLE
 372 AE_FEATURE([examples],[Do not build and install examples])
 373
 374 # Man pages
 375 # Enabled by default
 376 AE_FEATURE_DEFAULT_ENABLE
 377 AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
 378
 379 # Systemtap sdt.h integration
 380 # Disabled by default
 381 AC_ARG_WITH([sdt],
 382   [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
 383 )
 384
 385 # Override the default runtime directory
 386 AC_ARG_WITH([lttng-system-rundir], [
 387 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 388 ], [
 389   lttng_system_rundir="$withval"
 390 ], [
 391   lttng_system_rundir="/var/run/lttng"
 392 ])
 393
 394
 395 ##                                          ##
 396 ## Check for conflicting features selection ##
 397 ##                                          ##
 398
 399 AE_IF_FEATURE_DISABLED([shared], [
 400   AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
 401 ])
 402
 403 AE_IF_FEATURE_ENABLED([java-agent-all], [
 404   AE_FEATURE_ENABLE([java-agent-jul])
 405   AE_FEATURE_ENABLE([java-agent-log4j])
 406   AE_FEATURE_ENABLE([java-agent-log4j2])
 407 ])
 408
 409
 410 ##                                          ##
 411 ## Check for optional features dependencies ##
 412 ##                                          ##
 413
 414 # The numa integration requires libnuma
 415 AE_IF_FEATURE_ENABLED([numa], [
 416   AC_CHECK_LIB([numa], [numa_available], [
 417     AC_DEFINE([HAVE_LIBNUMA], [1], [Define to 1 if libnuma is available.])
 418   ], [
 419     AC_MSG_ERROR([dnl
 420 libnuma is not available. Please either install it (e.g. libnuma-dev) or use
 421 [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
 422 argument to disable NUMA support.
 423     ])
 424   ])
 425 ])
 426
 427 # The JNI interface and Java Agents require a working Java JDK
 428 AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || \
 429     AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2])], [
 430   AX_PROG_JAVAC
 431   AX_PROG_JAVA
 432   AX_PROG_JAR
 433
 434   # Get the CPPFLAGS required to build jni libraries
 435   AX_JNI_INCLUDE_DIR
 436   for jni_include_dir in $JNI_INCLUDE_DIRS; do
 437     JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
 438   done
 439
 440   # Check for javah and jni.h
 441   saved_CPPFLAGS="$CPPFLAGS"
 442   CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 443   AX_PROG_JAVAH
 444   CPPFLAGS="$saved_CPPFLAGS"
 445 ])
 446
 447 # The log4j 1.x agent requires the log4j jar in the classpath
 448 AE_IF_FEATURE_ENABLED([java-agent-log4j], [
 449   AX_CHECK_CLASS([org.apache.log4j.Logger])
 450   AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 451     AC_MSG_ERROR([dnl
 452 The UST Java agent support for log4j was requested but the Log4j classes were
 453 not found. Please specify the location of the Log4j jar via the Java CLASSPATH
 454 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
 455
 456 Current CLASSPATH: "$CLASSPATH"
 457     ])
 458   ])
 459 ])
 460
 461 # The log4j 2.x agent requires the log4j core and api jars in the classpath
 462 AE_IF_FEATURE_ENABLED([java-agent-log4j2], [
 463   AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 464   AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 465   AS_IF([test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"], [
 466     AC_MSG_ERROR([dnl
 467 The UST Java agent support for log4j was requested but the Log4j classes were
 468 not found. Please specify the location of the Log4j API and core 2.x jars via the Java CLASSPATH
 469 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"
 470
 471 Current CLASSPATH: "$CLASSPATH"
 472     ])
 473   ])
 474 ])
 475
 476 # The python agent requires a python interpreter
 477 AE_IF_FEATURE_ENABLED([python-agent], [
 478   AS_IF([test "x$PYTHON" = "x"], [
 479     AC_MSG_ERROR([dnl
 480 Cannot find a suitable python interpreter. You can override it with the PYTHON
 481 environment variable.
 482     ])
 483   ])
 484
 485   AX_COMPARE_VERSION(["$PYTHON_VERSION"], [ge], ["3.12"], [
 486     AC_MSG_CHECKING([for python setuptools])
 487     AS_IF(["$PYTHON" -c "import setuptools" 2>/dev/null], [
 488       AC_MSG_RESULT([yes])
 489     ], [
 490       AC_MSG_RESULT([no])
 491       AC_MSG_ERROR([Python >= 3.12 removed 'distutils', the 'setuptools' module needs to be installed for the selected interpreter.])
 492     ])
 493   ])
 494 ])
 495
 496 # Check for asciidoc and xmlto if we enabled building the man pages.
 497 AE_IF_FEATURE_ENABLED([man-pages], [
 498   AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 499     AE_IF_IN_GIT_REPO([
 500       # This is an error because we're in the Git repo, which
 501       # means the man pages are not already generated for us,
 502       # thus asciidoc/xmlto are required because we were asked
 503       # to build the man pages.
 504       AC_MSG_ERROR([dnl
 505 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 506 --disable-man-pages to disable building the man pages, in which case
 507 they will not be installed.
 508       ])
 509     ], [
 510       # Only warn here: since we're in the tarball, the man
 511       # pages should already be generated at this point, thus
 512       # asciidoc/xmlto are not strictly required.
 513       warn_prebuilt_man_pages=yes
 514     ])
 515   ], [
 516     have_asciidoc_xmlto=yes
 517   ])
 518 ])
 519
 520 AS_IF([test "x$with_sdt" = "xyes"], [
 521   AC_MSG_CHECKING([STAP_PROBEV()])
 522   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 523     #define SDT_USE_VARIADIC
 524     #include <sys/sdt.h>
 525     void fct(void)
 526     {
 527       STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 528     }
 529   ]])], [
 530     AC_MSG_RESULT([yes])
 531     AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
 532   ], [
 533     AC_MSG_RESULT([no])
 534     AC_MSG_ERROR([dnl
 535 The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
 536 Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
 537 a non-standard path to sys/sdt.h
 538     ])
 539   ])
 540 ])
 541
 542
 543 ##                                                                    ##
 544 ## Set defines for optional features conditionnals in the source code ##
 545 ##                                                                    ##
 546
 547 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
 548
 549 # Defined in include/lttng/ust-version.h
 550 AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
 551 AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
 552 AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
 553 AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
 554 AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
 555 AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
 556
 557
 558 ##                                                                          ##
 559 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 560 ##                                                                          ##
 561
 562 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
 563 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
 564 AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 565 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
 566 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
 567 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J2], AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 568 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J_COMMON], AE_IS_FEATURE_ENABLED([java-agent-log4j]) || AE_IS_FEATURE_ENABLED([java-agent-log4j2]))
 569 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
 570 AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
 571 AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
 572 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
 573 AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
 574 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 575 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
 576 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
 577 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 578 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
 579
 580
 581 ##                                             ##
 582 ## Substitute variables for use in Makefile.am ##
 583 ##                                             ##
 584
 585 # Library versions for libtool
 586 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
 587 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
 588
 589 # Major soname for python-lttngust
 590 AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
 591
 592 AM_CFLAGS="$OPT_CFLAGS $WARN_CFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 593 AC_SUBST(AM_CFLAGS)
 594
 595 AM_CXXFLAGS="$WARN_CXXFLAGS $URCU_CFLAGS $PTHREAD_CFLAGS"
 596 AC_SUBST(AM_CXXFLAGS)
 597
 598 # The order in which the include folders are searched is important.
 599 # The top_builddir should always be searched first in the event that a build
 600 # time generated file is included.
 601 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include common/config.h"
 602 AC_SUBST(AM_CPPFLAGS)
 603
 604 AC_SUBST(JNI_CPPFLAGS)
 605
 606
 607 ##                                     ##
 608 ## Output files generated by configure ##
 609 ##                                     ##
 610
 611 # List of files to be generated from '.in' templates by AC_OUTPUT
 612 AC_CONFIG_FILES([
 613   Makefile
 614   doc/examples/Makefile
 615   doc/Makefile
 616   doc/man/Makefile
 617   extras/Makefile
 618   include/Makefile
 619   src/common/Makefile
 620   src/lib/lttng-ust-common/Makefile
 621   src/lib/lttng-ust-ctl/Makefile
 622   src/lib/lttng-ust-cyg-profile/Makefile
 623   src/lib/lttng-ust-dl/Makefile
 624   src/lib/lttng-ust-fd/Makefile
 625   src/lib/lttng-ust-fork/Makefile
 626   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 627   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 628   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 629   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 630   src/lib/lttng-ust-java-agent/java/lttng-ust-agent-log4j2/Makefile
 631   src/lib/lttng-ust-java-agent/java/Makefile
 632   src/lib/lttng-ust-java-agent/jni/common/Makefile
 633   src/lib/lttng-ust-java-agent/jni/jul/Makefile
 634   src/lib/lttng-ust-java-agent/jni/log4j/Makefile
 635   src/lib/lttng-ust-java-agent/jni/Makefile
 636   src/lib/lttng-ust-java-agent/Makefile
 637   src/lib/lttng-ust-java/Makefile
 638   src/lib/lttng-ust-libc-wrapper/Makefile
 639   src/lib/lttng-ust-pthread-wrapper/Makefile
 640   src/lib/lttng-ust-tracepoint/Makefile
 641   src/lib/lttng-ust/Makefile
 642   src/lib/lttng-ust-python-agent/Makefile
 643   src/lib/Makefile
 644   src/lib/lttng-ust-ctl.pc
 645   src/lib/lttng-ust.pc
 646   src/Makefile
 647   src/python-lttngust/lttngust/version.py
 648   src/python-lttngust/Makefile
 649   src/python-lttngust/setup.py
 650   tests/benchmark/Makefile
 651   tests/compile/api0/ctf-types/Makefile
 652   tests/compile/api0/hello.cxx/Makefile
 653   tests/compile/api0/hello/Makefile
 654   tests/compile/api0/hello-many/Makefile
 655   tests/compile/api0/Makefile
 656   tests/compile/api0/same_line_tracepoint/Makefile
 657   tests/compile/api1/ust-fields/Makefile
 658   tests/compile/api1/hello.cxx/Makefile
 659   tests/compile/api1/hello/Makefile
 660   tests/compile/api1/hello-many/Makefile
 661   tests/compile/api1/Makefile
 662   tests/compile/api1/same_line_tracepoint/Makefile
 663   tests/compile/api1/test-app-ctx/Makefile
 664   tests/compile/Makefile
 665   tests/Makefile
 666   tests/regression/abi0-conflict/Makefile
 667   tests/regression/Makefile
 668   tests/unit/gcc-weak-hidden/Makefile
 669   tests/unit/libcommon/Makefile
 670   tests/unit/libmsgpack/Makefile
 671   tests/unit/libringbuffer/Makefile
 672   tests/unit/Makefile
 673   tests/unit/pthread_name/Makefile
 674   tests/unit/snprintf/Makefile
 675   tests/unit/ust-elf/Makefile
 676   tests/unit/ust-error/Makefile
 677   tests/unit/ust-utils/Makefile
 678   tests/utils/Makefile
 679   tools/Makefile
 680 ])
 681
 682 AC_OUTPUT
 683
 684
 685 ##                                    ##
 686 ## Mini-report on what will be built. ##
 687 ##                                    ##
 688
 689 PPRINT_INIT
 690 PPRINT_SET_INDENT(1)
 691 PPRINT_SET_TS(38)
 692
 693 AS_ECHO
 694 AS_IF([test -n "ust_version_name"], [
 695   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"ust_version_name\"$PPRINT_COLOR_RST")
 696 ], [
 697   AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION")
 698 ])
 699
 700 AS_ECHO
 701
 702 AS_IF([test -n "ust_version_description"], [
 703   AS_IF([test -n "$FOLD"], [
 704     AS_ECHO(["ust_version_description"]) | $FOLD -s
 705   ], [
 706     AS_ECHO(["ust_version_description"])
 707   ])
 708   AS_ECHO
 709 ])
 710
 711 PPRINT_SUBTITLE([System])
 712
 713 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 714
 715 AS_IF([test "x$unsupported_arch" = "xyes"],[
 716        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 717 ])
 718
 719 AS_ECHO
 720 PPRINT_SUBTITLE([Features])
 721 PPRINT_SET_INDENT(1)
 722
 723 test "x$with_sdt" = "xyes" && value=1 || value=0
 724 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 725
 726 AE_IS_FEATURE_ENABLED([java-agent-jul]) && value=1 || value=0
 727 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 728
 729 AE_IS_FEATURE_ENABLED([java-agent-log4j]) && value=1 || value=0
 730 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 1.x support (deprecated))], $value, [use --enable-java-agent-log4j])
 731
 732 AE_IS_FEATURE_ENABLED([java-agent-log4j2]) && value=1 || value=0
 733 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 2.x support)], $value, [use --enable-java-agent-log4j2])
 734
 735 AE_IS_FEATURE_ENABLED([jni-interface]) && value=1 || value=0
 736 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 737
 738 AE_IS_FEATURE_ENABLED([python-agent]) && value=1 || value=0
 739 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 740
 741 test "x$ac_cv_header_linux_perf_event_h" = "xyes" && value=1 || value=0
 742 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 743
 744 AE_IS_FEATURE_ENABLED([numa]) && value=1 || value=0
 745 PPRINT_PROP_BOOL([NUMA], $value)
 746
 747 AS_ECHO
 748 PPRINT_SET_INDENT(0)
 749
 750 AE_IS_FEATURE_ENABLED([examples]) && value=1 || value=0
 751 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 752
 753 # man pages build enabled/disabled
 754 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 755
 756 AE_IF_FEATURE_ENABLED([man-pages], [
 757   AE_IF_IN_GIT_REPO([
 758     PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 759   ], [
 760     AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 761       PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 762     ], [
 763       PPRINT_PROP_STRING([build_man_pages_msg],
 764         [${PPRINT_COLOR_BLDGRN}yes (already built)],
 765         $PPRINT_COLOR_SUBTITLE)
 766     ])
 767   ])
 768 ], [
 769   PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 770 ])
 771
 772 m4_popdef([build_man_pages_msg])
 773
 774 PPRINT_SET_INDENT(1)
 775
 776 report_bindir="`eval eval echo $bindir`"
 777 report_libdir="`eval eval echo $libdir`"
 778
 779 # Print the bindir and libdir this `make install' will install into.
 780 AS_ECHO
 781 PPRINT_SUBTITLE([Install directories])
 782 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 783 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 784
 785 AS_ECHO
 786 PPRINT_SUBTITLE([System directories])
 787
 788 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 789
 790 PPRINT_SET_INDENT(0)
 791
 792 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 793   AS_ECHO
 794   PPRINT_WARN([dnl
 795 Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 796
 797 Note that the man pages are already built in this distribution tarball,
 798 therefore asciidoc and xmlto are only needed if you intend to modify
 799 their sources.
 800
 801 Use --disable-man-pages to completely disable building and installing
 802 the man pages.])
 803 ])
 804
 805 # vim: shiftwidth=2 softtabstop=2 expandtab