configure.ac

   1 # SPDX-License-Identifier: LGPL-2.1-only
   2
   3 dnl Version infos
   4 m4_define([V_MAJOR], [2])
   5 m4_define([V_MINOR], [13])
   6 m4_define([V_PATCH], [0])
   7 m4_define([V_EXTRA], [pre])
   8 m4_define([V_NAME], [[Codename TBD]])
   9 m4_define([V_DESC], [[Description TBD]])
  10
  11 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  12 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  13
  14 AC_PREREQ([2.69])
  15 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  16
  17 dnl Substitute minor/major/patchlevel version numbers
  18 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  19 AC_SUBST([MINOR_VERSION], [V_MINOR])
  20 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  21
  22 # Following the numbering scheme proposed by libtool for the library version
  23 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  24 # This is the library version of liblttng-ust.
  25 m4_define([UST_LIB_V_MAJOR], [1])
  26 m4_define([UST_LIB_V_MINOR], [0])
  27 m4_define([UST_LIB_V_PATCH], [0])
  28
  29 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  30 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  31 # note: remember to update tracepoint.h dlopen() to match this version
  32 # number. TODO: eventually automate by exporting the major number.
  33
  34 # This is the library version of liblttng-ust-ctl, used internally by
  35 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  36 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [5:0:0])
  37
  38 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  39 AC_CONFIG_AUX_DIR([config])
  40 AC_CONFIG_MACRO_DIR([m4])
  41 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  42
  43 AC_CANONICAL_TARGET
  44 AC_CANONICAL_HOST
  45
  46 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 # Enable silent rules by default
  50 AM_SILENT_RULES([yes])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  58 AC_PROG_CXX
  59 AX_CXX_COMPILE_STDCXX([11])
  60 RW_PROG_CXX_WORKS
  61 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  62
  63 # Check if the compiler support weak symbols
  64 AX_SYS_WEAK_ALIAS
  65
  66 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  67         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  68 ])
  69
  70 # Checks for programs.
  71 AM_PROG_AR
  72 AC_PROG_SED
  73 AC_PROG_GREP
  74 AC_PROG_LN_S
  75 AC_PROG_MKDIR_P
  76 AC_PROG_MAKE_SET
  77 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  78 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  79
  80 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  81 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  82 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  83 ], [
  84         libtool_fixup=$enableval
  85 ], [
  86         libtool_fixup=yes
  87 ])
  88
  89 AS_IF([test "x$libtool_fixup" = "xyes"], [
  90         libtool_m4="$srcdir/m4/libtool.m4"
  91         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  92         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  93         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  94
  95         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  96         AC_MSG_RESULT([$libtool_flag_pattern_count])
  97         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  98                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  99         ], [
 100                 AC_MSG_RESULT([none])
 101         ])
 102 ])
 103 LT_INIT([disable-static])
 104
 105 AC_MSG_CHECKING([whether shared libraries are enabled])
 106 AS_IF([test "x$enable_shared" = "xyes"], [
 107         AC_MSG_RESULT([yes])
 108 ], [
 109         AC_MSG_RESULT([no])
 110         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 111 ])
 112
 113 # Checks for typedefs, structures, and compiler characteristics.
 114 AC_C_INLINE
 115 AC_TYPE_INT8_T
 116 AC_TYPE_INT16_T
 117 AC_TYPE_INT32_T
 118 AC_TYPE_INT64_T
 119 AC_TYPE_MODE_T
 120 AC_TYPE_OFF_T
 121 AC_TYPE_PID_T
 122 AC_TYPE_SIZE_T
 123 AC_TYPE_SSIZE_T
 124 AC_TYPE_UID_T
 125 AC_TYPE_UINT8_T
 126 AC_TYPE_UINT16_T
 127 AC_TYPE_UINT32_T
 128 AC_TYPE_UINT64_T
 129 AC_CHECK_TYPES([ptrdiff_t])
 130
 131 AX_C___ATTRIBUTE__
 132 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 133         [:],
 134         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 135
 136 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 137
 138 # Checks for library functions.
 139 AC_FUNC_CHOWN
 140 AC_FUNC_FORK
 141 AC_FUNC_MMAP
 142 AC_FUNC_REALLOC
 143 AC_FUNC_STRERROR_R
 144 AC_FUNC_STRNLEN
 145 AC_CHECK_FUNCS([ \
 146         atexit \
 147         clock_gettime \
 148         ftruncate \
 149         getpagesize \
 150         gettimeofday \
 151         localeconv \
 152         memchr \
 153         memmove \
 154         memset \
 155         mkdir \
 156         munmap \
 157         realpath \
 158         sched_getcpu \
 159         socket \
 160         strchr \
 161         strdup \
 162         strerror \
 163         strtol \
 164         strtoul \
 165         sysconf \
 166 ])
 167
 168 # Check for pthread_setname_np and its signature
 169 LTTNG_PTHREAD_SETNAME_NP
 170 LTTNG_PTHREAD_GETNAME_NP
 171
 172 # AC_FUNC_MALLOC causes problems when cross-compiling.
 173 #AC_FUNC_MALLOC
 174
 175 # Checks for header files.
 176 AC_HEADER_STDBOOL
 177 AC_CHECK_HEADERS([ \
 178         arpa/inet.h \
 179         fcntl.h \
 180         float.h \
 181         limits.h \
 182         locale.h \
 183         stddef.h \
 184         sys/socket.h \
 185         sys/time.h \
 186         wchar.h \
 187 ])
 188
 189 # Set architecture specific options
 190 AS_CASE([$host_cpu],
 191         [i[[3456]]86], [],
 192         [x86_64], [],
 193         [amd64], [],
 194         [powerpc], [],
 195         [ppc64], [],
 196         [ppc64le], [],
 197         [powerpc64], [],
 198         [powerpc64le], [],
 199         [s390], [NO_UNALIGNED_ACCESS=1],
 200         [s390x], [NO_UNALIGNED_ACCESS=1],
 201         [arm*], [
 202                 NO_UNALIGNED_ACCESS=1
 203                 NO_NUMA=1
 204                 ],
 205         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 206         [mips*], [NO_UNALIGNED_ACCESS=1],
 207         [tile*], [NO_UNALIGNED_ACCESS=1],
 208         [
 209                 UNSUPPORTED_ARCH=1
 210                 NO_UNALIGNED_ACCESS=1
 211         ])
 212
 213 # Set os specific options
 214 AS_CASE([$host_os],
 215         [freebsd*], [NO_NUMA=1]
 216 )
 217
 218 # Configuration options, which will be installed in the config.h
 219 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 220 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 221
 222 # Checks for libraries.
 223 AC_CHECK_LIB([dl], [dlopen], [
 224         libdl_name=dl
 225         DL_LIBS="-ldl"
 226 ], [
 227         #libdl not found, check for dlopen in libc.
 228         AC_CHECK_LIB([c], [dlopen], [
 229                 libdl_name=c
 230                 DL_LIBS="-lc"
 231         ], [
 232                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 233         ])
 234 ])
 235 AC_SUBST(DL_LIBS)
 236
 237 # Check if libdl has dlmopen support.
 238 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 239 AC_CHECK_LIB([$libdl_name], [dlmopen],
 240         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 241 )
 242
 243 # Check for dlfcn.h
 244 AC_CHECK_HEADER([dlfcn.h])
 245 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 246         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 247                 #include <dlfcn.h>
 248         ])
 249 ], [
 250         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 251 ])
 252
 253 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 254
 255 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 256 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 257
 258 # numa.h integration
 259 AS_IF([test "x$NO_NUMA" = "x1"],[
 260       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 261 ])
 262
 263 AC_ARG_ENABLE([numa], [
 264 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 265 ], [
 266         enable_numa=$enableval
 267 ], [
 268         enable_numa=yes
 269 ])
 270
 271 AS_IF([test "x$enable_numa" = "xyes"], [
 272         # numa - check that numa lib is available
 273         AC_CHECK_LIB([numa], [numa_available], [],
 274 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 275         have_libnuma=yes
 276 ])
 277 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 278
 279 # optional linux/perf_event.h
 280 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 281
 282 # Perf event counters are supported on all architectures supported by
 283 # perf, using the read system call as fallback.
 284 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 285
 286 AH_TEMPLATE([HAVE_PERF_EVENT], ["Perf event integration via perf_event.h"])
 287 AS_IF([test "x$have_perf_event" = "xyes"], [
 288         AC_DEFINE([HAVE_PERF_EVENT], [1])
 289 ])
 290
 291 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 292         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 293 ])
 294
 295 # Check for JNI header files if requested
 296 AC_ARG_ENABLE([jni-interface], [
 297 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 298 ], [
 299         jni_interface=$enableval
 300 ], [
 301         jni_interface=no
 302 ])
 303
 304 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 305
 306
 307 AC_ARG_ENABLE([java-agent-jul], [
 308 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 309 ], [
 310         java_agent_jul=$enableval
 311 ], [
 312         java_agent_jul=no
 313 ])
 314
 315 AC_ARG_ENABLE([java-agent-log4j], [
 316 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 317 ], [
 318         java_agent_log4j=$enableval
 319 ], [
 320         java_agent_log4j=no
 321 ])
 322
 323 AC_ARG_ENABLE([java-agent-all], [
 324 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 325 ], [
 326         java_agent_jul=$enableval
 327         java_agent_log4j=$enableval
 328 ], [:])
 329
 330 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 331 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 332 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 333
 334 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 335         AX_JAVA_OPTIONS
 336         AX_PROG_JAVAC
 337         AX_PROG_JAVA
 338         AX_PROG_JAR
 339         AC_ARG_VAR([CLASSPATH], [Java class path])
 340
 341         AX_JNI_INCLUDE_DIR
 342         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 343         do
 344                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 345         done
 346
 347         saved_CPPFLAGS="$CPPFLAGS"
 348         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 349         AX_PROG_JAVAH
 350         CPPFLAGS="$saved_CPPFLAGS"
 351 ])
 352
 353 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 354
 355 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 356         AX_CHECK_CLASSPATH
 357         AX_CHECK_CLASS([org.apache.log4j.Logger])
 358         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 359                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 360         ])
 361 ])
 362
 363 # Option to build the python agent
 364 AC_ARG_ENABLE([python-agent], [
 365 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 366 ], [
 367         python_agent=$enableval
 368 ], [:])
 369 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 370 AS_IF([test "x$python_agent" = "xyes"], [
 371         AM_PATH_PYTHON([2.7])
 372 ])
 373
 374 # sdt.h integration
 375 AC_ARG_WITH([sdt], [
 376 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 377 ], [
 378         with_sdt=$withval
 379 ], [
 380         with_sdt="no"
 381 ])
 382
 383 AS_IF([test "x$with_sdt" = "xyes"], [
 384         AC_MSG_CHECKING([STAP_PROBEV()])
 385         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 386                 #define SDT_USE_VARIADIC
 387                 #include <sys/sdt.h>
 388                 void fct(void)
 389                 {
 390                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 391                 }
 392         ]])], [
 393                 AC_MSG_RESULT([yes])
 394                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 395         ], [
 396                 AC_MSG_RESULT([no])
 397                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 398         ])
 399 ])
 400
 401 AC_ARG_WITH([lttng-system-rundir], [
 402 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 403 ], [
 404         lttng_system_rundir="$withval"
 405 ], [
 406         lttng_system_rundir="/var/run/lttng"
 407 ])
 408 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 409                 [LTTng system runtime directory])
 410
 411 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 412 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 413
 414 # Enable building examples
 415 AC_ARG_ENABLE(
 416         examples,
 417         AS_HELP_STRING(
 418                 [--disable-examples],
 419                 [Do not build and install examples]
 420         ),
 421         [enable_examples=$enableval],
 422         [enable_examples=yes]
 423 )
 424
 425 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 426
 427 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 428 # is not distributed in tarballs.
 429 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 430 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 431
 432 # Enable building man pages (user's intention).
 433 AC_ARG_ENABLE(
 434         man-pages,
 435         AS_HELP_STRING(
 436                 [--disable-man-pages],
 437                 [Do not build and install man pages (already built in a distributed tarball)]
 438         ),
 439         [man_pages_opt=$enableval],
 440         [man_pages_opt=yes]
 441 )
 442
 443 # Check for asciidoc and xmlto if we enabled building the man pages.
 444 have_asciidoc_xmlto=no
 445 warn_prebuilt_man_pages=no
 446
 447 AS_IF([test "x$man_pages_opt" = "xyes"], [
 448         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 449         AC_PATH_PROG([XMLTO], [xmlto], [no])
 450
 451         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 452                 AS_IF([test "x$in_git_repo" = "xyes"], [
 453                         # This is an error because we're in the Git repo, which
 454                         # means the man pages are not already generated for us,
 455                         # thus asciidoc/xmlto are required because we were asked
 456                         # to build the man pages.
 457                         AC_MSG_ERROR([
 458 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 459 --disable-man-pages to disable building the man pages, in which case
 460 they will not be installed.
 461                         ])
 462                 ], [
 463                         # Only warn here: since we're in the tarball, the man
 464                         # pages should already be generated at this point, thus
 465                         # asciidoc/xmlto are not strictly required.
 466                         warn_prebuilt_man_pages=yes
 467                 ])
 468         ], [
 469                 have_asciidoc_xmlto=yes
 470         ])
 471 ])
 472
 473 # Export man page build condition: build the man pages if the user
 474 # asked for it, and if the tools are available.
 475 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 476 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 477
 478 # Default values
 479 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 480         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 481         $1="$2"
 482         AC_SUBST([$1])
 483 ])
 484
 485 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 486
 487 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 488 AC_SUBST(AM_CFLAGS)
 489
 490 AM_CXXFLAGS="$AM_CFLAGS"
 491 AC_SUBST(AM_CXXFLAGS)
 492
 493 # The order in which the include folders are searched is important.
 494 # The top_builddir should always be searched first in the event that a build
 495 # time generated file is included.
 496 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 497 AC_SUBST(AM_CPPFLAGS)
 498
 499 AC_SUBST(JNI_CPPFLAGS)
 500
 501 AC_CONFIG_FILES([
 502         Makefile
 503         doc/Makefile
 504         doc/examples/Makefile
 505         doc/man/Makefile
 506         include/Makefile
 507         include/lttng/ust-version.h
 508         snprintf/Makefile
 509         libcounter/Makefile
 510         libmsgpack/Makefile
 511         libringbuffer/Makefile
 512         liblttng-ust-comm/Makefile
 513         liblttng-ust/Makefile
 514         liblttng-ust-ctl/Makefile
 515         liblttng-ust-fork/Makefile
 516         liblttng-ust-dl/Makefile
 517         liblttng-ust-fd/Makefile
 518         liblttng-ust-java/Makefile
 519         liblttng-ust-java-agent/Makefile
 520         liblttng-ust-java-agent/java/Makefile
 521         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 522         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 523         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 524         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 525         liblttng-ust-java-agent/jni/Makefile
 526         liblttng-ust-java-agent/jni/common/Makefile
 527         liblttng-ust-java-agent/jni/jul/Makefile
 528         liblttng-ust-java-agent/jni/log4j/Makefile
 529         liblttng-ust-libc-wrapper/Makefile
 530         liblttng-ust-cyg-profile/Makefile
 531         liblttng-ust-python-agent/Makefile
 532         python-lttngust/Makefile
 533         python-lttngust/setup.py
 534         python-lttngust/lttngust/__init__.py
 535         tools/Makefile
 536         tests/Makefile
 537         tests/compile/Makefile
 538         tests/compile/ctf-types/Makefile
 539         tests/compile/hello.cxx/Makefile
 540         tests/compile/hello/Makefile
 541         tests/compile/hello-many/Makefile
 542         tests/compile/same_line_tracepoint/Makefile
 543         tests/compile/test-app-ctx/Makefile
 544         tests/benchmark/Makefile
 545         tests/unit/gcc-weak-hidden/Makefile
 546         tests/unit/libmsgpack/Makefile
 547         tests/unit/Makefile
 548         tests/unit/libringbuffer/Makefile
 549         tests/unit/pthread_name/Makefile
 550         tests/unit/snprintf/Makefile
 551         tests/unit/ust-elf/Makefile
 552         tests/utils/Makefile
 553         lttng-ust.pc
 554         lttng-ust-ctl.pc
 555 ])
 556
 557 # Create link for python agent for the VPATH guru.
 558 AC_CONFIG_LINKS([
 559         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 560         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 561         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 562         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 563         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 564 ])
 565
 566 AC_CONFIG_FILES([tests/unit/ust-elf/test_ust_elf],[chmod +x tests/unit/ust-elf/test_ust_elf])
 567
 568 AC_OUTPUT
 569
 570
 571 #
 572 # Mini-report on what will be built.
 573 #
 574
 575 PPRINT_INIT
 576 PPRINT_SET_INDENT(1)
 577 PPRINT_SET_TS(38)
 578
 579 AS_ECHO
 580 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 581 AS_ECHO
 582
 583 AS_ECHO("V_DESC")
 584
 585 AS_ECHO
 586 PPRINT_SUBTITLE([System])
 587
 588 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 589
 590 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 591 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 592
 593 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 594        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 595 ])
 596
 597 AS_ECHO
 598 PPRINT_SUBTITLE([Features])
 599 PPRINT_SET_INDENT(1)
 600
 601 test "x$with_sdt" = "xyes" && value=1 || value=0
 602 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 603
 604 test "x$java_agent_jul" = xyes && value=1 || value=0
 605 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 606
 607 test "x$java_agent_log4j" = xyes && value=1 || value=0
 608 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 609
 610 test "x$jni_interface" = xyes && value=1 || value=0
 611 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 612
 613 test "x$python_agent" = xyes && value=1 || value=0
 614 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 615
 616 test "x$have_perf_event" = "xyes" && value=1 || value=0
 617 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 618
 619 test "x$enable_numa" = xyes && value=1 || value=0
 620 PPRINT_PROP_BOOL([NUMA], $value)
 621
 622 AS_ECHO
 623 PPRINT_SET_INDENT(0)
 624
 625 test "x$enable_examples" = xyes && value=1 || value=0
 626 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 627
 628 # man pages build enabled/disabled
 629 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 630
 631 AS_IF([test "x$man_pages_opt" != "xno"], [
 632         AS_IF([test "x$in_git_repo" = "xyes"], [
 633                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 634         ], [
 635                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 636                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 637                 ], [
 638                         PPRINT_PROP_STRING([build_man_pages_msg],
 639                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 640                                 $PPRINT_COLOR_SUBTITLE)
 641                 ])
 642         ])
 643 ], [
 644         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 645 ])
 646
 647 m4_popdef([build_man_pages_msg])
 648
 649 PPRINT_SET_INDENT(1)
 650
 651 report_bindir="`eval eval echo $bindir`"
 652 report_libdir="`eval eval echo $libdir`"
 653
 654 # Print the bindir and libdir this `make install' will install into.
 655 AS_ECHO
 656 PPRINT_SUBTITLE([Install directories])
 657 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 658 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 659
 660 AS_ECHO
 661 PPRINT_SUBTITLE([System directories])
 662
 663 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 664
 665 PPRINT_SET_INDENT(0)
 666
 667 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 668         AS_ECHO
 669         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 670
 671 Note that the man pages are already built in this distribution tarball,
 672 therefore asciidoc and xmlto are only needed if you intend to modify
 673 their sources.
 674
 675 Use --disable-man-pages to completely disable building and installing
 676 the man pages.])
 677 ])