configure.ac

   1 # SPDX-License-Identifier: LGPL-2.1-only
   2
   3 dnl Version infos
   4 m4_define([V_MAJOR], [2])
   5 m4_define([V_MINOR], [13])
   6 m4_define([V_PATCH], [0])
   7 m4_define([V_EXTRA], [pre])
   8 m4_define([V_NAME], [[Codename TBD]])
   9 m4_define([V_DESC], [[Description TBD]])
  10
  11 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  12 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  13
  14 AC_PREREQ([2.69])
  15 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  16
  17 dnl Substitute minor/major/patchlevel version numbers
  18 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  19 AC_SUBST([MINOR_VERSION], [V_MINOR])
  20 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  21
  22 # Following the numbering scheme proposed by libtool for the library version
  23 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  24 # This is the library version of liblttng-ust.
  25 m4_define([UST_LIB_V_MAJOR], [1])
  26 m4_define([UST_LIB_V_MINOR], [0])
  27 m4_define([UST_LIB_V_PATCH], [0])
  28
  29 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  30 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  31 # note: remember to update tracepoint.h dlopen() to match this version
  32 # number. TODO: eventually automate by exporting the major number.
  33
  34 # This is the library version of liblttng-ust-ctl, used internally by
  35 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  36 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [5:0:0])
  37
  38 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  39 AC_CONFIG_AUX_DIR([config])
  40 AC_CONFIG_MACRO_DIR([m4])
  41 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  42
  43 AC_CANONICAL_TARGET
  44 AC_CANONICAL_HOST
  45
  46 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 # Enable silent rules by default
  50 AM_SILENT_RULES([yes])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  58 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
  59 AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
  60
  61 # Check if the compiler support weak symbols
  62 AX_SYS_WEAK_ALIAS
  63
  64 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  65         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  66 ])
  67
  68 # Checks for programs.
  69 AM_PROG_AR
  70 AC_PROG_SED
  71 AC_PROG_GREP
  72 AC_PROG_LN_S
  73 AC_PROG_MKDIR_P
  74 AC_PROG_MAKE_SET
  75 AC_CHECK_PROG([CMAKE], [cmake])
  76 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
  77
  78 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  79 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  80 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  81 ], [
  82         libtool_fixup=$enableval
  83 ], [
  84         libtool_fixup=yes
  85 ])
  86
  87 AS_IF([test "x$libtool_fixup" = "xyes"], [
  88         libtool_m4="$srcdir/m4/libtool.m4"
  89         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  90         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  91         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  92
  93         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  94         AC_MSG_RESULT([$libtool_flag_pattern_count])
  95         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  96                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  97         ], [
  98                 AC_MSG_RESULT([none])
  99         ])
 100 ])
 101 LT_INIT([disable-static])
 102
 103 AC_MSG_CHECKING([whether shared libraries are enabled])
 104 AS_IF([test "x$enable_shared" = "xyes"], [
 105         AC_MSG_RESULT([yes])
 106 ], [
 107         AC_MSG_RESULT([no])
 108         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 109 ])
 110
 111 # Checks for typedefs, structures, and compiler characteristics.
 112 AC_C_INLINE
 113 AC_TYPE_INT8_T
 114 AC_TYPE_INT16_T
 115 AC_TYPE_INT32_T
 116 AC_TYPE_INT64_T
 117 AC_TYPE_MODE_T
 118 AC_TYPE_OFF_T
 119 AC_TYPE_PID_T
 120 AC_TYPE_SIZE_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UID_T
 123 AC_TYPE_UINT8_T
 124 AC_TYPE_UINT16_T
 125 AC_TYPE_UINT32_T
 126 AC_TYPE_UINT64_T
 127 AC_CHECK_TYPES([ptrdiff_t])
 128
 129 AX_C___ATTRIBUTE__
 130 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 131         [:],
 132         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 133
 134 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 135
 136 # Checks for library functions.
 137 AC_FUNC_CHOWN
 138 AC_FUNC_FORK
 139 AC_FUNC_MMAP
 140 AC_FUNC_REALLOC
 141 AC_FUNC_STRERROR_R
 142 AC_FUNC_STRNLEN
 143 AC_CHECK_FUNCS([ \
 144         atexit \
 145         clock_gettime \
 146         ftruncate \
 147         getpagesize \
 148         gettimeofday \
 149         localeconv \
 150         memchr \
 151         memmove \
 152         memset \
 153         mkdir \
 154         munmap \
 155         realpath \
 156         sched_getcpu \
 157         socket \
 158         strchr \
 159         strdup \
 160         strerror \
 161         strtol \
 162         strtoul \
 163         sysconf \
 164 ])
 165
 166 # Check for pthread_setname_np and its signature
 167 LTTNG_PTHREAD_SETNAME_NP
 168 LTTNG_PTHREAD_GETNAME_NP
 169
 170 # AC_FUNC_MALLOC causes problems when cross-compiling.
 171 #AC_FUNC_MALLOC
 172
 173 # Checks for header files.
 174 AC_HEADER_STDBOOL
 175 AC_CHECK_HEADERS([ \
 176         arpa/inet.h \
 177         fcntl.h \
 178         float.h \
 179         limits.h \
 180         locale.h \
 181         stddef.h \
 182         sys/socket.h \
 183         sys/time.h \
 184         wchar.h \
 185 ])
 186
 187 # Set architecture specific options
 188 AS_CASE([$host_cpu],
 189         [i[[3456]]86], [],
 190         [x86_64], [],
 191         [amd64], [],
 192         [powerpc], [],
 193         [ppc64], [],
 194         [ppc64le], [],
 195         [powerpc64], [],
 196         [powerpc64le], [],
 197         [s390], [],
 198         [s390x], [],
 199         [arm*], [
 200                 NO_NUMA=1
 201                 ],
 202         [aarch64*], [],
 203         [mips*], [],
 204         [tile*], [],
 205         [
 206                 UNSUPPORTED_ARCH=1
 207         ])
 208
 209 # Set os specific options
 210 AS_CASE([$host_os],
 211         [freebsd*], [NO_NUMA=1]
 212 )
 213
 214 # Configuration options, which will be installed in the config.h
 215 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 216
 217 # Checks for libraries.
 218 AC_CHECK_LIB([dl], [dlopen], [
 219         libdl_name=dl
 220         DL_LIBS="-ldl"
 221 ], [
 222         #libdl not found, check for dlopen in libc.
 223         AC_CHECK_LIB([c], [dlopen], [
 224                 libdl_name=c
 225                 DL_LIBS="-lc"
 226         ], [
 227                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 228         ])
 229 ])
 230 AC_SUBST(DL_LIBS)
 231
 232 # Check if libdl has dlmopen support.
 233 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 234 AC_CHECK_LIB([$libdl_name], [dlmopen],
 235         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 236 )
 237
 238 # Check for dlfcn.h
 239 AC_CHECK_HEADER([dlfcn.h])
 240 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 241         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 242                 #include <dlfcn.h>
 243         ])
 244 ], [
 245         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 246 ])
 247
 248 AM_CONDITIONAL([ENABLE_UST_DL], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 249
 250 # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
 251 PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
 252
 253 # numa.h integration
 254 AS_IF([test "x$NO_NUMA" = "x1"],[
 255       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 256 ])
 257
 258 AC_ARG_ENABLE([numa], [
 259 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 260 ], [
 261         enable_numa=$enableval
 262 ], [
 263         enable_numa=yes
 264 ])
 265
 266 AS_IF([test "x$enable_numa" = "xyes"], [
 267         # numa - check that numa lib is available
 268         AC_CHECK_LIB([numa], [numa_available], [],
 269 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 270         have_libnuma=yes
 271 ])
 272 AM_CONDITIONAL([ENABLE_NUMA], [test "x$have_libnuma" = "xyes"])
 273
 274 # optional linux/perf_event.h
 275 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 276
 277 # Perf event counters are supported on all architectures supported by
 278 # perf, using the read system call as fallback.
 279 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 280
 281 AH_TEMPLATE([HAVE_PERF_EVENT], ["Perf event integration via perf_event.h"])
 282 AS_IF([test "x$have_perf_event" = "xyes"], [
 283         AC_DEFINE([HAVE_PERF_EVENT], [1])
 284 ])
 285
 286 # Check for JNI header files if requested
 287 AC_ARG_ENABLE([jni-interface], [
 288 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 289 ], [
 290         jni_interface=$enableval
 291 ], [
 292         jni_interface=no
 293 ])
 294
 295 AM_CONDITIONAL([ENABLE_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 296
 297
 298 AC_ARG_ENABLE([java-agent-jul], [
 299 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 300 ], [
 301         java_agent_jul=$enableval
 302 ], [
 303         java_agent_jul=no
 304 ])
 305
 306 AC_ARG_ENABLE([java-agent-log4j], [
 307 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 308 ], [
 309         java_agent_log4j=$enableval
 310 ], [
 311         java_agent_log4j=no
 312 ])
 313
 314 AC_ARG_ENABLE([java-agent-all], [
 315 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 316 ], [
 317         java_agent_jul=$enableval
 318         java_agent_log4j=$enableval
 319 ], [:])
 320
 321 AM_CONDITIONAL([ENABLE_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 322 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 323 AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 324
 325 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 326         AX_JAVA_OPTIONS
 327         AX_PROG_JAVAC
 328         AX_PROG_JAVA
 329         AX_PROG_JAR
 330         AC_ARG_VAR([CLASSPATH], [Java class path])
 331
 332         AX_JNI_INCLUDE_DIR
 333         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 334         do
 335                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 336         done
 337
 338         saved_CPPFLAGS="$CPPFLAGS"
 339         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 340         AX_PROG_JAVAH
 341         CPPFLAGS="$saved_CPPFLAGS"
 342 ])
 343
 344 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 345
 346 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 347         AX_CHECK_CLASSPATH
 348         AX_CHECK_CLASS([org.apache.log4j.Logger])
 349         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 350                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 351         ])
 352 ])
 353
 354 # Option to build the python agent
 355 AC_ARG_ENABLE([python-agent], [
 356 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 357 ], [
 358         python_agent=$enableval
 359 ], [:])
 360 AM_CONDITIONAL([ENABLE_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 361 AS_IF([test "x$python_agent" = "xyes"], [
 362         AM_PATH_PYTHON([2.7])
 363 ])
 364
 365 # sdt.h integration
 366 AC_ARG_WITH([sdt], [
 367 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 368 ], [
 369         with_sdt=$withval
 370 ], [
 371         with_sdt="no"
 372 ])
 373
 374 AS_IF([test "x$with_sdt" = "xyes"], [
 375         AC_MSG_CHECKING([STAP_PROBEV()])
 376         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 377                 #define SDT_USE_VARIADIC
 378                 #include <sys/sdt.h>
 379                 void fct(void)
 380                 {
 381                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 382                 }
 383         ]])], [
 384                 AC_MSG_RESULT([yes])
 385                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 386         ], [
 387                 AC_MSG_RESULT([no])
 388                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 389         ])
 390 ])
 391
 392 AC_ARG_WITH([lttng-system-rundir], [
 393 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 394 ], [
 395         lttng_system_rundir="$withval"
 396 ], [
 397         lttng_system_rundir="/var/run/lttng"
 398 ])
 399 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 400                 [LTTng system runtime directory])
 401
 402 AC_CHECK_PROG([ENABLE_GEN_TP_EXAMPLES], [python], ["yes"])
 403 AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$ENABLE_GEN_TP_EXAMPLES" = "xyes"])
 404
 405 # Enable building examples
 406 AC_ARG_ENABLE(
 407         examples,
 408         AS_HELP_STRING(
 409                 [--disable-examples],
 410                 [Do not build and install examples]
 411         ),
 412         [enable_examples=$enableval],
 413         [enable_examples=yes]
 414 )
 415
 416 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 417
 418 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 419 # is not distributed in tarballs.
 420 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 421 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 422
 423 # Enable building man pages (user's intention).
 424 AC_ARG_ENABLE(
 425         man-pages,
 426         AS_HELP_STRING(
 427                 [--disable-man-pages],
 428                 [Do not build and install man pages (already built in a distributed tarball)]
 429         ),
 430         [man_pages_opt=$enableval],
 431         [man_pages_opt=yes]
 432 )
 433
 434 # Check for asciidoc and xmlto if we enabled building the man pages.
 435 have_asciidoc_xmlto=no
 436 warn_prebuilt_man_pages=no
 437
 438 AS_IF([test "x$man_pages_opt" = "xyes"], [
 439         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 440         AC_PATH_PROG([XMLTO], [xmlto], [no])
 441
 442         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 443                 AS_IF([test "x$in_git_repo" = "xyes"], [
 444                         # This is an error because we're in the Git repo, which
 445                         # means the man pages are not already generated for us,
 446                         # thus asciidoc/xmlto are required because we were asked
 447                         # to build the man pages.
 448                         AC_MSG_ERROR([
 449 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 450 --disable-man-pages to disable building the man pages, in which case
 451 they will not be installed.
 452                         ])
 453                 ], [
 454                         # Only warn here: since we're in the tarball, the man
 455                         # pages should already be generated at this point, thus
 456                         # asciidoc/xmlto are not strictly required.
 457                         warn_prebuilt_man_pages=yes
 458                 ])
 459         ], [
 460                 have_asciidoc_xmlto=yes
 461         ])
 462 ])
 463
 464 # Export man page build condition: build the man pages if the user
 465 # asked for it, and if the tools are available.
 466 AM_CONDITIONAL([ENABLE_MAN_PAGES], [test "x$man_pages_opt" != "xno"])
 467 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 468
 469 AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
 470 AC_SUBST(AM_CFLAGS)
 471
 472 AM_CXXFLAGS="$AM_CFLAGS"
 473 AC_SUBST(AM_CXXFLAGS)
 474
 475 # The order in which the include folders are searched is important.
 476 # The top_builddir should always be searched first in the event that a build
 477 # time generated file is included.
 478 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 479 AC_SUBST(AM_CPPFLAGS)
 480
 481 AC_SUBST(JNI_CPPFLAGS)
 482
 483 AC_CONFIG_FILES([
 484         Makefile
 485         doc/Makefile
 486         doc/examples/Makefile
 487         doc/man/Makefile
 488         include/Makefile
 489         include/lttng/ust-version.h
 490         snprintf/Makefile
 491         libcounter/Makefile
 492         libmsgpack/Makefile
 493         libringbuffer/Makefile
 494         liblttng-ust-comm/Makefile
 495         liblttng-ust/Makefile
 496         liblttng-ust-ctl/Makefile
 497         liblttng-ust-fork/Makefile
 498         liblttng-ust-dl/Makefile
 499         liblttng-ust-fd/Makefile
 500         liblttng-ust-java/Makefile
 501         liblttng-ust-java-agent/Makefile
 502         liblttng-ust-java-agent/java/Makefile
 503         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 504         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 505         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 506         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 507         liblttng-ust-java-agent/jni/Makefile
 508         liblttng-ust-java-agent/jni/common/Makefile
 509         liblttng-ust-java-agent/jni/jul/Makefile
 510         liblttng-ust-java-agent/jni/log4j/Makefile
 511         liblttng-ust-libc-wrapper/Makefile
 512         liblttng-ust-cyg-profile/Makefile
 513         liblttng-ust-python-agent/Makefile
 514         python-lttngust/Makefile
 515         python-lttngust/setup.py
 516         python-lttngust/lttngust/__init__.py
 517         tools/Makefile
 518         tests/Makefile
 519         tests/compile/Makefile
 520         tests/compile/ctf-types/Makefile
 521         tests/compile/hello.cxx/Makefile
 522         tests/compile/hello/Makefile
 523         tests/compile/hello-many/Makefile
 524         tests/compile/same_line_tracepoint/Makefile
 525         tests/compile/test-app-ctx/Makefile
 526         tests/benchmark/Makefile
 527         tests/unit/gcc-weak-hidden/Makefile
 528         tests/unit/libmsgpack/Makefile
 529         tests/unit/Makefile
 530         tests/unit/libringbuffer/Makefile
 531         tests/unit/pthread_name/Makefile
 532         tests/unit/snprintf/Makefile
 533         tests/unit/ust-elf/Makefile
 534         tests/utils/Makefile
 535         lttng-ust.pc
 536         lttng-ust-ctl.pc
 537 ])
 538
 539 AC_OUTPUT
 540
 541
 542 #
 543 # Mini-report on what will be built.
 544 #
 545
 546 PPRINT_INIT
 547 PPRINT_SET_INDENT(1)
 548 PPRINT_SET_TS(38)
 549
 550 AS_ECHO
 551 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 552 AS_ECHO
 553
 554 AS_ECHO("V_DESC")
 555
 556 AS_ECHO
 557 PPRINT_SUBTITLE([System])
 558
 559 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 560
 561 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 562        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 563 ])
 564
 565 AS_ECHO
 566 PPRINT_SUBTITLE([Features])
 567 PPRINT_SET_INDENT(1)
 568
 569 test "x$with_sdt" = "xyes" && value=1 || value=0
 570 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 571
 572 test "x$java_agent_jul" = xyes && value=1 || value=0
 573 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 574
 575 test "x$java_agent_log4j" = xyes && value=1 || value=0
 576 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 577
 578 test "x$jni_interface" = xyes && value=1 || value=0
 579 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 580
 581 test "x$python_agent" = xyes && value=1 || value=0
 582 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 583
 584 test "x$have_perf_event" = "xyes" && value=1 || value=0
 585 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 586
 587 test "x$enable_numa" = xyes && value=1 || value=0
 588 PPRINT_PROP_BOOL([NUMA], $value)
 589
 590 AS_ECHO
 591 PPRINT_SET_INDENT(0)
 592
 593 test "x$enable_examples" = xyes && value=1 || value=0
 594 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 595
 596 # man pages build enabled/disabled
 597 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 598
 599 AS_IF([test "x$man_pages_opt" != "xno"], [
 600         AS_IF([test "x$in_git_repo" = "xyes"], [
 601                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 602         ], [
 603                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 604                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 605                 ], [
 606                         PPRINT_PROP_STRING([build_man_pages_msg],
 607                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 608                                 $PPRINT_COLOR_SUBTITLE)
 609                 ])
 610         ])
 611 ], [
 612         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 613 ])
 614
 615 m4_popdef([build_man_pages_msg])
 616
 617 PPRINT_SET_INDENT(1)
 618
 619 report_bindir="`eval eval echo $bindir`"
 620 report_libdir="`eval eval echo $libdir`"
 621
 622 # Print the bindir and libdir this `make install' will install into.
 623 AS_ECHO
 624 PPRINT_SUBTITLE([Install directories])
 625 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 626 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 627
 628 AS_ECHO
 629 PPRINT_SUBTITLE([System directories])
 630
 631 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 632
 633 PPRINT_SET_INDENT(0)
 634
 635 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 636         AS_ECHO
 637         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 638
 639 Note that the man pages are already built in this distribution tarball,
 640 therefore asciidoc and xmlto are only needed if you intend to modify
 641 their sources.
 642
 643 Use --disable-man-pages to completely disable building and installing
 644 the man pages.])
 645 ])