configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [13])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [pre])
   6 m4_define([V_NAME], [[Codename TBD]])
   7 m4_define([V_DESC], [[Description TBD]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ([2.69])
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 # Checks for C compiler
  51 AC_USE_SYSTEM_EXTENSIONS
  52 AC_SYS_LARGEFILE
  53 AC_PROG_CC
  54 AC_PROG_CC_STDC
  55 AC_PROG_CXX
  56 AX_CXX_COMPILE_STDCXX([11])
  57 RW_PROG_CXX_WORKS
  58 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  59
  60 # Check if the compiler support weak symbols
  61 AX_SYS_WEAK_ALIAS
  62
  63 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  64         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  65 ])
  66
  67 # Checks for programs.
  68 AM_PROG_AR
  69 AC_PROG_SED
  70 AC_PROG_GREP
  71 AC_PROG_LN_S
  72 AC_PROG_MKDIR_P
  73 AC_PROG_MAKE_SET
  74 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  75 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  76
  77 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  78 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  79 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  80 ], [
  81         libtool_fixup=$enableval
  82 ], [
  83         libtool_fixup=yes
  84 ])
  85
  86 AS_IF([test "x$libtool_fixup" = "xyes"], [
  87         libtool_m4="$srcdir/m4/libtool.m4"
  88         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  89         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  90         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  91
  92         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  93         AC_MSG_RESULT([$libtool_flag_pattern_count])
  94         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  95                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  96         ], [
  97                 AC_MSG_RESULT([none])
  98         ])
  99 ])
 100 LT_INIT([disable-static])
 101
 102 AC_MSG_CHECKING([whether shared libraries are enabled])
 103 AS_IF([test "x$enable_shared" = "xyes"], [
 104         AC_MSG_RESULT([yes])
 105 ], [
 106         AC_MSG_RESULT([no])
 107         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 108 ])
 109
 110 # Checks for typedefs, structures, and compiler characteristics.
 111 AC_C_INLINE
 112 AC_TYPE_INT8_T
 113 AC_TYPE_INT16_T
 114 AC_TYPE_INT32_T
 115 AC_TYPE_INT64_T
 116 AC_TYPE_MODE_T
 117 AC_TYPE_OFF_T
 118 AC_TYPE_PID_T
 119 AC_TYPE_SIZE_T
 120 AC_TYPE_SSIZE_T
 121 AC_TYPE_UID_T
 122 AC_TYPE_UINT8_T
 123 AC_TYPE_UINT16_T
 124 AC_TYPE_UINT32_T
 125 AC_TYPE_UINT64_T
 126 AC_CHECK_TYPES([ptrdiff_t])
 127
 128 AX_C___ATTRIBUTE__
 129 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 130         [:],
 131         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 132
 133 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 134
 135 # Checks for library functions.
 136 AC_FUNC_CHOWN
 137 AC_FUNC_FORK
 138 AC_FUNC_MMAP
 139 AC_FUNC_REALLOC
 140 AC_FUNC_STRERROR_R
 141 AC_FUNC_STRNLEN
 142 AC_CHECK_FUNCS([ \
 143         atexit \
 144         clock_gettime \
 145         ftruncate \
 146         getpagesize \
 147         gettimeofday \
 148         localeconv \
 149         memchr \
 150         memmove \
 151         memset \
 152         mkdir \
 153         munmap \
 154         realpath \
 155         sched_getcpu \
 156         socket \
 157         strchr \
 158         strdup \
 159         strerror \
 160         strtol \
 161         strtoul \
 162         sysconf \
 163 ])
 164
 165 # Check for pthread_setname_np and its signature
 166 LTTNG_PTHREAD_SETNAME_NP
 167
 168 # AC_FUNC_MALLOC causes problems when cross-compiling.
 169 #AC_FUNC_MALLOC
 170
 171 # Checks for header files.
 172 AC_HEADER_STDBOOL
 173 AC_CHECK_HEADERS([ \
 174         arpa/inet.h \
 175         fcntl.h \
 176         float.h \
 177         limits.h \
 178         locale.h \
 179         stddef.h \
 180         sys/socket.h \
 181         sys/time.h \
 182         wchar.h \
 183 ])
 184
 185 # Set architecture specific options
 186 AS_CASE([$host_cpu],
 187         [i[[3456]]86], [],
 188         [x86_64], [],
 189         [amd64], [],
 190         [powerpc], [],
 191         [ppc64], [],
 192         [ppc64le], [],
 193         [powerpc64], [],
 194         [powerpc64le], [],
 195         [s390], [NO_UNALIGNED_ACCESS=1],
 196         [s390x], [NO_UNALIGNED_ACCESS=1],
 197         [arm*], [
 198                 NO_UNALIGNED_ACCESS=1
 199                 NO_NUMA=1
 200                 ],
 201         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 202         [mips*], [NO_UNALIGNED_ACCESS=1],
 203         [tile*], [NO_UNALIGNED_ACCESS=1],
 204         [
 205                 UNSUPPORTED_ARCH=1
 206                 NO_UNALIGNED_ACCESS=1
 207         ])
 208
 209 # Set os specific options
 210 AS_CASE([$host_os],
 211         [freebsd*], [NO_NUMA=1]
 212 )
 213
 214 # Configuration options, which will be installed in the config.h
 215 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 216 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 217 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 218
 219 # Checks for libraries.
 220 AC_CHECK_LIB([dl], [dlopen], [
 221         libdl_name=dl
 222         DL_LIBS="-ldl"
 223 ], [
 224         #libdl not found, check for dlopen in libc.
 225         AC_CHECK_LIB([c], [dlopen], [
 226                 libdl_name=c
 227                 DL_LIBS="-lc"
 228         ], [
 229                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 230         ])
 231 ])
 232 AC_SUBST(DL_LIBS)
 233
 234 # Check if libdl has dlmopen support.
 235 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 236 AC_CHECK_LIB([$libdl_name], [dlmopen],
 237         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 238 )
 239
 240 # Check for dlfcn.h
 241 AC_CHECK_HEADER([dlfcn.h])
 242 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 243         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 244                 #include <dlfcn.h>
 245         ])
 246 ], [
 247         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 248 ])
 249
 250 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 251
 252 # URCU
 253
 254 AC_MSG_CHECKING([DEFINE_URCU_TLS_INIT()])
 255 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 256         #include <urcu/tls-compat.h>
 257         DEFINE_URCU_TLS_INIT(int, a, 1);
 258 ]])], [
 259         AC_MSG_RESULT([yes])
 260 ], [
 261         AC_MSG_RESULT([no])
 262         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.12.0 or better])
 263 ])
 264
 265 # urcu - check if we just find the headers it out of the box.
 266 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 267 This error can also occur when the liburcu package's configure script has not been run.])])
 268
 269 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 270 # Part of Userspace RCU library 0.7.2 or better.
 271 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 272 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 273
 274 AC_MSG_CHECKING([caa_likely()])
 275 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 276         #include <urcu/compiler.h>
 277         void fct(void)
 278         {
 279                 if (caa_likely(1)) {
 280                 }
 281         }
 282 ]])], [
 283         AC_MSG_RESULT([yes])
 284 ], [
 285         AC_MSG_RESULT([no])
 286         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 287 ])
 288
 289 # urcu - check that URCU lib is available to compilation
 290 AC_CHECK_LIB([urcu-bp], [urcu_bp_synchronize_rcu], [], [AC_MSG_ERROR([Cannot find liburcu-bp 0.11 or newer. Use [LDFLAGS]=-Ldir to specify its location.])])
 291
 292 # urcu - check that URCU lib is at least version 0.11
 293 AC_CHECK_LIB([urcu-bp], [urcu_bp_call_rcu], [], [AC_MSG_ERROR([liburcu 0.11 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 294
 295 # numa.h integration
 296 AS_IF([test "x$NO_NUMA" = "x1"],[
 297       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 298 ])
 299
 300 AC_ARG_ENABLE([numa], [
 301 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 302 ], [
 303         enable_numa=$enableval
 304 ], [
 305         enable_numa=yes
 306 ])
 307
 308 AS_IF([test "x$enable_numa" = "xyes"], [
 309         # numa - check that numa lib is available
 310         AC_CHECK_LIB([numa], [numa_available], [],
 311 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 312         have_libnuma=yes
 313 ])
 314 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 315
 316 # optional linux/perf_event.h
 317 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 318
 319 # Perf event counters are supported on all architectures supported by
 320 # perf, using the read system call as fallback.
 321 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 322
 323 AS_IF([test "x$have_perf_event" = "xyes"], [
 324         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 325 ])
 326
 327 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 328         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 329 ])
 330
 331 # Check for JNI header files if requested
 332 AC_ARG_ENABLE([jni-interface], [
 333 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 334 ], [
 335         jni_interface=$enableval
 336 ], [
 337         jni_interface=no
 338 ])
 339
 340 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 341
 342
 343 AC_ARG_ENABLE([java-agent-jul], [
 344 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 345 ], [
 346         java_agent_jul=$enableval
 347 ], [
 348         java_agent_jul=no
 349 ])
 350
 351 AC_ARG_ENABLE([java-agent-log4j], [
 352 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 353 ], [
 354         java_agent_log4j=$enableval
 355 ], [
 356         java_agent_log4j=no
 357 ])
 358
 359 AC_ARG_ENABLE([java-agent-all], [
 360 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 361 ], [
 362         java_agent_jul=$enableval
 363         java_agent_log4j=$enableval
 364 ], [:])
 365
 366 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 367 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 368 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 369
 370 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 371         AX_JAVA_OPTIONS
 372         AX_PROG_JAVAC
 373         AX_PROG_JAVA
 374         AX_PROG_JAR
 375         AC_ARG_VAR([CLASSPATH], [Java class path])
 376
 377         AX_JNI_INCLUDE_DIR
 378         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 379         do
 380                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 381         done
 382
 383         saved_CPPFLAGS="$CPPFLAGS"
 384         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 385         AX_PROG_JAVAH
 386         CPPFLAGS="$saved_CPPFLAGS"
 387 ])
 388
 389 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 390
 391 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 392         AX_CHECK_CLASSPATH
 393         AX_CHECK_CLASS([org.apache.log4j.Logger])
 394         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 395                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 396         ])
 397 ])
 398
 399 # Option to build the python agent
 400 AC_ARG_ENABLE([python-agent], [
 401 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 402 ], [
 403         python_agent=$enableval
 404 ], [:])
 405 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 406 AS_IF([test "x$python_agent" = "xyes"], [
 407         AM_PATH_PYTHON([2.7])
 408 ])
 409
 410 # sdt.h integration
 411 AC_ARG_WITH([sdt], [
 412 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 413 ], [
 414         with_sdt=$withval
 415 ], [
 416         with_sdt="no"
 417 ])
 418
 419 AS_IF([test "x$with_sdt" = "xyes"], [
 420         AC_MSG_CHECKING([STAP_PROBEV()])
 421         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 422                 #define SDT_USE_VARIADIC
 423                 #include <sys/sdt.h>
 424                 void fct(void)
 425                 {
 426                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 427                 }
 428         ]])], [
 429                 AC_MSG_RESULT([yes])
 430                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 431         ], [
 432                 AC_MSG_RESULT([no])
 433                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 434         ])
 435 ])
 436
 437 AC_ARG_WITH([lttng-system-rundir], [
 438 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 439 ], [
 440         lttng_system_rundir="$withval"
 441 ], [
 442         lttng_system_rundir="/var/run/lttng"
 443 ])
 444 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 445                 [LTTng system runtime directory])
 446
 447 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 448 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 449
 450 # Enable building examples
 451 AC_ARG_ENABLE(
 452         examples,
 453         AS_HELP_STRING(
 454                 [--disable-examples],
 455                 [Do not build and install examples]
 456         ),
 457         [enable_examples=$enableval],
 458         [enable_examples=yes]
 459 )
 460
 461 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 462
 463 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 464 # is not distributed in tarballs.
 465 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 466 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 467
 468 # Enable building man pages (user's intention).
 469 AC_ARG_ENABLE(
 470         man-pages,
 471         AS_HELP_STRING(
 472                 [--disable-man-pages],
 473                 [Do not build and install man pages (already built in a distributed tarball)]
 474         ),
 475         [man_pages_opt=$enableval],
 476         [man_pages_opt=yes]
 477 )
 478
 479 # Check for asciidoc and xmlto if we enabled building the man pages.
 480 have_asciidoc_xmlto=no
 481 warn_prebuilt_man_pages=no
 482
 483 AS_IF([test "x$man_pages_opt" = "xyes"], [
 484         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 485         AC_PATH_PROG([XMLTO], [xmlto], [no])
 486
 487         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 488                 AS_IF([test "x$in_git_repo" = "xyes"], [
 489                         # This is an error because we're in the Git repo, which
 490                         # means the man pages are not already generated for us,
 491                         # thus asciidoc/xmlto are required because we were asked
 492                         # to build the man pages.
 493                         AC_MSG_ERROR([
 494 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 495 --disable-man-pages to disable building the man pages, in which case
 496 they will not be installed.
 497                         ])
 498                 ], [
 499                         # Only warn here: since we're in the tarball, the man
 500                         # pages should already be generated at this point, thus
 501                         # asciidoc/xmlto are not strictly required.
 502                         warn_prebuilt_man_pages=yes
 503                 ])
 504         ], [
 505                 have_asciidoc_xmlto=yes
 506         ])
 507 ])
 508
 509 # Export man page build condition: build the man pages if the user
 510 # asked for it, and if the tools are available.
 511 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 512 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 513
 514 # Default values
 515 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 516         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 517         $1="$2"
 518         AC_SUBST([$1])
 519 ])
 520
 521 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 522
 523 AM_CFLAGS="-Wall $PTHREAD_CFLAGS"
 524 AC_SUBST(AM_CFLAGS)
 525
 526 # The order in which the include folders are searched is important.
 527 # The top_builddir should always be searched first in the event that a build
 528 # time generated file is included.
 529 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 530 AC_SUBST(AM_CPPFLAGS)
 531
 532 AC_SUBST(JNI_CPPFLAGS)
 533
 534 AC_CONFIG_FILES([
 535         Makefile
 536         doc/Makefile
 537         doc/examples/Makefile
 538         doc/man/Makefile
 539         include/Makefile
 540         include/lttng/ust-version.h
 541         snprintf/Makefile
 542         libringbuffer/Makefile
 543         liblttng-ust-comm/Makefile
 544         liblttng-ust/Makefile
 545         liblttng-ust-ctl/Makefile
 546         liblttng-ust-fork/Makefile
 547         liblttng-ust-dl/Makefile
 548         liblttng-ust-fd/Makefile
 549         liblttng-ust-java/Makefile
 550         liblttng-ust-java-agent/Makefile
 551         liblttng-ust-java-agent/java/Makefile
 552         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 553         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 554         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 555         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 556         liblttng-ust-java-agent/jni/Makefile
 557         liblttng-ust-java-agent/jni/common/Makefile
 558         liblttng-ust-java-agent/jni/jul/Makefile
 559         liblttng-ust-java-agent/jni/log4j/Makefile
 560         liblttng-ust-libc-wrapper/Makefile
 561         liblttng-ust-cyg-profile/Makefile
 562         liblttng-ust-python-agent/Makefile
 563         python-lttngust/Makefile
 564         python-lttngust/setup.py
 565         python-lttngust/lttngust/__init__.py
 566         tools/Makefile
 567         tests/Makefile
 568         tests/compile/Makefile
 569         tests/compile/ctf-types/Makefile
 570         tests/compile/hello.cxx/Makefile
 571         tests/compile/hello/Makefile
 572         tests/compile/hello-many/Makefile
 573         tests/compile/same_line_tracepoint/Makefile
 574         tests/compile/test-app-ctx/Makefile
 575         tests/benchmark/Makefile
 576         tests/unit/gcc-weak-hidden/Makefile
 577         tests/unit/Makefile
 578         tests/unit/pthread_name/Makefile
 579         tests/unit/snprintf/Makefile
 580         tests/unit/ust-elf/Makefile
 581         tests/utils/Makefile
 582         lttng-ust.pc
 583         lttng-ust-ctl.pc
 584 ])
 585
 586 # Create link for python agent for the VPATH guru.
 587 AC_CONFIG_LINKS([
 588         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 589         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 590         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 591         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 592         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 593 ])
 594
 595 AC_CONFIG_FILES([tests/unit/ust-elf/test_ust_elf],[chmod +x tests/unit/ust-elf/test_ust_elf])
 596
 597 AC_OUTPUT
 598
 599
 600 #
 601 # Mini-report on what will be built.
 602 #
 603
 604 PPRINT_INIT
 605 PPRINT_SET_INDENT(1)
 606 PPRINT_SET_TS(38)
 607
 608 AS_ECHO
 609 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 610 AS_ECHO
 611
 612 AS_ECHO("V_DESC")
 613
 614 AS_ECHO
 615 PPRINT_SUBTITLE([System])
 616
 617 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 618
 619 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 620 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 621
 622 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 623        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 624 ])
 625
 626 AS_ECHO
 627 PPRINT_SUBTITLE([Features])
 628 PPRINT_SET_INDENT(1)
 629
 630 test "x$with_sdt" = "xyes" && value=1 || value=0
 631 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 632
 633 test "x$java_agent_jul" = xyes && value=1 || value=0
 634 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 635
 636 test "x$java_agent_log4j" = xyes && value=1 || value=0
 637 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 638
 639 test "x$jni_interface" = xyes && value=1 || value=0
 640 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 641
 642 test "x$python_agent" = xyes && value=1 || value=0
 643 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 644
 645 test "x$have_perf_event" = "xyes" && value=1 || value=0
 646 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 647
 648 test "x$enable_numa" = xyes && value=1 || value=0
 649 PPRINT_PROP_BOOL([NUMA], $value)
 650
 651 AS_ECHO
 652 PPRINT_SET_INDENT(0)
 653
 654 test "x$enable_examples" = xyes && value=1 || value=0
 655 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 656
 657 # man pages build enabled/disabled
 658 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 659
 660 AS_IF([test "x$man_pages_opt" != "xno"], [
 661         AS_IF([test "x$in_git_repo" = "xyes"], [
 662                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 663         ], [
 664                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 665                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 666                 ], [
 667                         PPRINT_PROP_STRING([build_man_pages_msg],
 668                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 669                                 $PPRINT_COLOR_SUBTITLE)
 670                 ])
 671         ])
 672 ], [
 673         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 674 ])
 675
 676 m4_popdef([build_man_pages_msg])
 677
 678 PPRINT_SET_INDENT(1)
 679
 680 report_bindir="`eval eval echo $bindir`"
 681 report_libdir="`eval eval echo $libdir`"
 682
 683 # Print the bindir and libdir this `make install' will install into.
 684 AS_ECHO
 685 PPRINT_SUBTITLE([Install directories])
 686 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 687 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 688
 689 AS_ECHO
 690 PPRINT_SUBTITLE([System directories])
 691
 692 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 693
 694 PPRINT_SET_INDENT(0)
 695
 696 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 697         AS_ECHO
 698         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 699
 700 Note that the man pages are already built in this distribution tarball,
 701 therefore asciidoc and xmlto are only needed if you intend to modify
 702 their sources.
 703
 704 Use --disable-man-pages to completely disable building and installing
 705 the man pages.])
 706 ])