configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [10])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [rc1])
   6 m4_define([V_NAME], [[KeKriek]])
   7 m4_define([V_DESC], [[From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 # note: remember to update tracepoint.h dlopen() to match this version
  29 # number. TODO: eventually automate by exporting the major number.
  30
  31 # This is the library version of liblttng-ust-ctl, used internally by
  32 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  33 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  34
  35 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  36 AC_CONFIG_AUX_DIR([config])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  39
  40 AC_CANONICAL_TARGET
  41 AC_CANONICAL_HOST
  42
  43 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  44 AM_MAINTAINER_MODE([enable])
  45
  46 # Enable silent rules if available (Introduced in AM 1.11)
  47 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  48
  49 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  50
  51 # Checks for C compiler
  52 AC_USE_SYSTEM_EXTENSIONS
  53 AC_SYS_LARGEFILE
  54 AC_PROG_CC
  55 AC_PROG_CC_STDC
  56 AC_PROG_CXX
  57 rw_PROG_CXX_WORKS
  58 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  59
  60 # Check if the compiler support weak symbols
  61 AX_SYS_WEAK_ALIAS
  62
  63 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  64         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  65 ])
  66
  67 # Checks for programs.
  68 AC_PROG_SED
  69 AC_PROG_GREP
  70 AC_PROG_LN_S
  71 AC_PROG_MKDIR_P
  72 AC_PROG_MAKE_SET
  73 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  74 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  75
  76 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  77 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  78 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  79 ], [
  80         libtool_fixup=$enableval
  81 ], [
  82         libtool_fixup=yes
  83 ])
  84
  85 AS_IF([test "x$libtool_fixup" = "xyes"], [
  86         libtool_m4="$srcdir/m4/libtool.m4"
  87         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  88         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  89         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  90
  91         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  92         AC_MSG_RESULT([$libtool_flag_pattern_count])
  93         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  94                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  95         ], [
  96                 AC_MSG_RESULT([none])
  97         ])
  98 ])
  99 LT_INIT([disable-static])
 100
 101 AC_MSG_CHECKING([whether shared libraries are enabled])
 102 AS_IF([test "x$enable_shared" = "xyes"], [
 103         AC_MSG_RESULT([yes])
 104 ], [
 105         AC_MSG_RESULT([no])
 106         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 107 ])
 108
 109 # Checks for typedefs, structures, and compiler characteristics.
 110 AC_C_INLINE
 111 AC_TYPE_INT8_T
 112 AC_TYPE_INT16_T
 113 AC_TYPE_INT32_T
 114 AC_TYPE_INT64_T
 115 AC_TYPE_MODE_T
 116 AC_TYPE_OFF_T
 117 AC_TYPE_PID_T
 118 AC_TYPE_SIZE_T
 119 AC_TYPE_SSIZE_T
 120 AC_TYPE_UID_T
 121 AC_TYPE_UINT8_T
 122 AC_TYPE_UINT16_T
 123 AC_TYPE_UINT32_T
 124 AC_TYPE_UINT64_T
 125 AC_CHECK_TYPES([ptrdiff_t])
 126
 127 AX_C___ATTRIBUTE__
 128 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 129         [:],
 130         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 131
 132 # Checks for library functions.
 133 AC_FUNC_CHOWN
 134 AC_FUNC_FORK
 135 AC_FUNC_MMAP
 136 AC_FUNC_REALLOC
 137 AC_FUNC_STRERROR_R
 138 AC_FUNC_STRNLEN
 139 AC_CHECK_FUNCS([ \
 140         atexit \
 141         clock_gettime \
 142         ftruncate \
 143         getpagesize \
 144         gettimeofday \
 145         localeconv \
 146         memchr \
 147         memmove \
 148         memset \
 149         mkdir \
 150         munmap \
 151         realpath \
 152         sched_getcpu \
 153         socket \
 154         strchr \
 155         strdup \
 156         strerror \
 157         strtol \
 158         sysconf \
 159 ])
 160
 161 # AC_FUNC_MALLOC causes problems when cross-compiling.
 162 #AC_FUNC_MALLOC
 163
 164 # Checks for header files.
 165 AC_HEADER_STDBOOL
 166 AC_CHECK_HEADERS([ \
 167         arpa/inet.h \
 168         fcntl.h \
 169         float.h \
 170         limits.h \
 171         locale.h \
 172         stddef.h \
 173         sys/socket.h \
 174         sys/time.h \
 175         wchar.h \
 176 ])
 177
 178 # Set architecture specific options
 179 AS_CASE([$host_cpu],
 180         [i[[3456]]86], [],
 181         [x86_64], [],
 182         [amd64], [],
 183         [powerpc], [],
 184         [ppc64], [],
 185         [ppc64le], [],
 186         [powerpc64], [],
 187         [powerpc64le], [],
 188         [s390], [NO_UNALIGNED_ACCESS=1],
 189         [s390x], [NO_UNALIGNED_ACCESS=1],
 190         [arm*], [
 191                 NO_UNALIGNED_ACCESS=1
 192                 NO_NUMA=1
 193                 ],
 194         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 195         [mips*], [NO_UNALIGNED_ACCESS=1],
 196         [tile*], [NO_UNALIGNED_ACCESS=1],
 197         [
 198                 UNSUPPORTED_ARCH=1
 199                 NO_UNALIGNED_ACCESS=1
 200         ])
 201
 202 # Configuration options, which will be installed in the config.h
 203 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 204 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 205 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 206
 207 # Checks for libraries.
 208 AC_CHECK_LIB([dl], [dlopen], [
 209         have_libdl=yes
 210         libdl_name=dl
 211 ], [
 212         #libdl not found, check for dlopen in libc.
 213         AC_CHECK_LIB([c], [dlopen], [
 214                 have_libc_dl=yes
 215                 libdl_name=c
 216         ], [
 217                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 218         ])
 219 ])
 220
 221 # Check if libdl has dlmopen support.
 222 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 223 AC_CHECK_LIB([$libdl_name], [dlmopen],
 224         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 225 )
 226
 227 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 228 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 229
 230 AC_CHECK_LIB([pthread], [pthread_create])
 231 AC_CHECK_LIB([pthread], [pthread_setname_np],
 232         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 233         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 234                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 235                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 236
 237 # Check for dlfcn.h
 238 AC_CHECK_HEADER([dlfcn.h])
 239 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 240         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 241                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 242                 #include <dlfcn.h>
 243         ])
 244 ], [
 245         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 246 ])
 247
 248 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 249
 250 # URCU
 251
 252 # urcu - check if we just find the headers it out of the box.
 253 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 254 This error can also occur when the liburcu package's configure script has not been run.])])
 255
 256 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 257 # Part of Userspace RCU library 0.7.2 or better.
 258 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 259 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 260
 261 AC_MSG_CHECKING([caa_likely()])
 262 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 263         #include <urcu/compiler.h>
 264         void fct(void)
 265         {
 266                 if (caa_likely(1)) {
 267                 }
 268         }
 269 ]])], [
 270         AC_MSG_RESULT([yes])
 271 ], [
 272         AC_MSG_RESULT([no])
 273         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 274 ])
 275
 276 # urcu - check that URCU lib is available to compilation
 277 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 278
 279 # urcu - check that URCU lib is at least version 0.6
 280 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 281
 282 # numa.h integration
 283 AS_IF([test "x$NO_NUMA" = "x1"],[
 284       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 285 ])
 286
 287 AC_ARG_ENABLE([numa], [
 288 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 289 ], [
 290         enable_numa=$enableval
 291 ], [
 292         enable_numa=yes
 293 ])
 294
 295 AS_IF([test "x$enable_numa" = "xyes"], [
 296         # numa - check that numa lib is available
 297         AC_CHECK_LIB([numa], [numa_available], [],
 298 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 299         have_libnuma=yes
 300 ])
 301 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 302
 303 # optional linux/perf_event.h
 304 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 305
 306 # Perf event counters are supported on all architectures supported by
 307 # perf, using the read system call as fallback.
 308 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 309
 310 AS_IF([test "x$have_perf_event" = "xyes"], [
 311         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 312 ])
 313
 314 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 315         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 316 ])
 317
 318 # Check for JNI header files if requested
 319 AC_ARG_ENABLE([jni-interface], [
 320 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 321 ], [
 322         jni_interface=$enableval
 323 ], [
 324         jni_interface=no
 325 ])
 326
 327 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 328
 329
 330 AC_ARG_ENABLE([java-agent-jul], [
 331 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 332 ], [
 333         java_agent_jul=$enableval
 334 ], [
 335         java_agent_jul=no
 336 ])
 337
 338 AC_ARG_ENABLE([java-agent-log4j], [
 339 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 340 ], [
 341         java_agent_log4j=$enableval
 342 ], [
 343         java_agent_log4j=no
 344 ])
 345
 346 AC_ARG_ENABLE([java-agent-all], [
 347 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 348 ], [
 349         java_agent_jul=$enableval
 350         java_agent_log4j=$enableval
 351 ], [:])
 352
 353 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 354 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 355 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 356
 357 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 358         AX_JAVA_OPTIONS
 359         AX_PROG_JAVAC
 360         AX_PROG_JAVA
 361         AX_PROG_JAR
 362
 363         AX_JNI_INCLUDE_DIR
 364         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 365         do
 366                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 367         done
 368
 369         saved_CPPFLAGS="$CPPFLAGS"
 370         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 371         AX_PROG_JAVAH
 372         CPPFLAGS="$saved_CPPFLAGS"
 373 ])
 374
 375 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 376         AX_CHECK_CLASSPATH
 377         AX_CHECK_CLASS([org.apache.log4j.Logger])
 378         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 379                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 380         ])
 381 ])
 382
 383 # Option to build the python agent
 384 AC_ARG_ENABLE([python-agent], [
 385 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 386 ], [
 387         python_agent=$enableval
 388 ], [:])
 389 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 390 AS_IF([test "x$python_agent" = "xyes"], [
 391         AM_PATH_PYTHON([2.7])
 392 ])
 393
 394 # sdt.h integration
 395 AC_ARG_WITH([sdt], [
 396 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 397 ], [
 398         with_sdt=$withval
 399 ], [
 400         with_sdt="no"
 401 ])
 402
 403 AS_IF([test "x$with_sdt" = "xyes"], [
 404         AC_MSG_CHECKING([STAP_PROBEV()])
 405         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 406                 #define SDT_USE_VARIADIC
 407                 #include <sys/sdt.h>
 408                 void fct(void)
 409                 {
 410                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 411                 }
 412         ]])], [
 413                 AC_MSG_RESULT([yes])
 414                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 415         ], [
 416                 AC_MSG_RESULT([no])
 417                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 418         ])
 419 ])
 420
 421 AC_ARG_WITH([lttng-system-rundir], [
 422 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 423 ], [
 424         lttng_system_rundir="$withval"
 425 ], [
 426         lttng_system_rundir="/var/run/lttng"
 427 ])
 428 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 429                 [LTTng system runtime directory])
 430
 431 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 432 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 433
 434 # Enable building examples
 435 AC_ARG_ENABLE(
 436         examples,
 437         AS_HELP_STRING(
 438                 [--disable-examples],
 439                 [Do not build and install examples]
 440         ),
 441         [enable_examples=$enableval],
 442         [enable_examples=yes]
 443 )
 444
 445 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 446
 447 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 448 # is not distributed in tarballs.
 449 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 450 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 451
 452 # Enable building man pages (user's intention).
 453 AC_ARG_ENABLE(
 454         man-pages,
 455         AS_HELP_STRING(
 456                 [--disable-man-pages],
 457                 [Do not build and install man pages (already built in a distributed tarball)]
 458         ),
 459         [man_pages_opt=$enableval],
 460         [man_pages_opt=yes]
 461 )
 462
 463 # Check for asciidoc and xmlto if we enabled building the man pages.
 464 have_asciidoc_xmlto=no
 465 warn_prebuilt_man_pages=no
 466
 467 AS_IF([test "x$man_pages_opt" = "xyes"], [
 468         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 469         AC_PATH_PROG([XMLTO], [xmlto], [no])
 470
 471         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 472                 AS_IF([test "x$in_git_repo" = "xyes"], [
 473                         # This is an error because we're in the Git repo, which
 474                         # means the man pages are not already generated for us,
 475                         # thus asciidoc/xmlto are required because we were asked
 476                         # to build the man pages.
 477                         AC_MSG_ERROR([
 478 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 479 --disable-man-pages to disable building the man pages, in which case
 480 they will not be installed.
 481                         ])
 482                 ], [
 483                         # Only warn here: since we're in the tarball, the man
 484                         # pages should already be generated at this point, thus
 485                         # asciidoc/xmlto are not strictly required.
 486                         warn_prebuilt_man_pages=yes
 487                 ])
 488         ], [
 489                 have_asciidoc_xmlto=yes
 490         ])
 491 ])
 492
 493 # Export man page build condition: build the man pages if the user
 494 # asked for it, and if the tools are available.
 495 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 496 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 497
 498 # Default values
 499 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 500         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 501         $1="$2"
 502         AC_SUBST([$1])
 503 ])
 504
 505 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 506
 507 AM_CFLAGS="-Wall"
 508 AC_SUBST(AM_CFLAGS)
 509 AC_SUBST(JNI_CPPFLAGS)
 510
 511 AC_CONFIG_FILES([
 512         Makefile
 513         doc/Makefile
 514         doc/examples/Makefile
 515         doc/man/Makefile
 516         include/Makefile
 517         include/lttng/ust-version.h
 518         snprintf/Makefile
 519         libringbuffer/Makefile
 520         liblttng-ust-comm/Makefile
 521         liblttng-ust/Makefile
 522         liblttng-ust-ctl/Makefile
 523         liblttng-ust-fork/Makefile
 524         liblttng-ust-dl/Makefile
 525         liblttng-ust-fd/Makefile
 526         liblttng-ust-java/Makefile
 527         liblttng-ust-java-agent/Makefile
 528         liblttng-ust-java-agent/java/Makefile
 529         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 530         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 531         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 532         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 533         liblttng-ust-java-agent/jni/Makefile
 534         liblttng-ust-java-agent/jni/common/Makefile
 535         liblttng-ust-java-agent/jni/jul/Makefile
 536         liblttng-ust-java-agent/jni/log4j/Makefile
 537         liblttng-ust-libc-wrapper/Makefile
 538         liblttng-ust-cyg-profile/Makefile
 539         liblttng-ust-python-agent/Makefile
 540         python-lttngust/Makefile
 541         python-lttngust/setup.py
 542         python-lttngust/lttngust/__init__.py
 543         tools/Makefile
 544         tests/Makefile
 545         tests/ctf-types/Makefile
 546         tests/hello/Makefile
 547         tests/hello.cxx/Makefile
 548         tests/same_line_tracepoint/Makefile
 549         tests/snprintf/Makefile
 550         tests/ust-elf/Makefile
 551         tests/benchmark/Makefile
 552         tests/utils/Makefile
 553         tests/test-app-ctx/Makefile
 554         tests/gcc-weak-hidden/Makefile
 555         lttng-ust.pc
 556 ])
 557
 558 # Create link for python agent for the VPATH guru.
 559 AC_CONFIG_LINKS([
 560         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 561         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 562         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 563         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 564 ])
 565
 566 AC_OUTPUT
 567
 568
 569 #
 570 # Mini-report on what will be built.
 571 #
 572
 573 PPRINT_INIT
 574 PPRINT_SET_INDENT(1)
 575 PPRINT_SET_TS(38)
 576
 577 AS_ECHO
 578 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 579 AS_ECHO
 580
 581 AS_ECHO("V_DESC")
 582
 583 AS_ECHO
 584 PPRINT_SUBTITLE([System])
 585
 586 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 587
 588 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 589 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 590
 591 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 592        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 593 ])
 594
 595 AS_ECHO
 596 PPRINT_SUBTITLE([Features])
 597 PPRINT_SET_INDENT(1)
 598
 599 test "x$with_sdt" = "xyes" && value=1 || value=0
 600 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 601
 602 test "x$java_agent_jul" = xyes && value=1 || value=0
 603 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 604
 605 test "x$java_agent_log4j" = xyes && value=1 || value=0
 606 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 607
 608 test "x$jni_interface" = xyes && value=1 || value=0
 609 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 610
 611 test "x$python_agent" = xyes && value=1 || value=0
 612 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 613
 614 test "x$enable_numa" = xyes && value=1 || value=0
 615 PPRINT_PROP_BOOL([NUMA], $value)
 616
 617 AS_ECHO
 618 PPRINT_SET_INDENT(0)
 619
 620 test "x$enable_examples" = xyes && value=1 || value=0
 621 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 622
 623 # man pages build enabled/disabled
 624 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 625
 626 AS_IF([test "x$man_pages_opt" != "xno"], [
 627         AS_IF([test "x$in_git_repo" = "xyes"], [
 628                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 629         ], [
 630                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 631                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 632                 ], [
 633                         PPRINT_PROP_STRING([build_man_pages_msg],
 634                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 635                                 $PPRINT_COLOR_SUBTITLE)
 636                 ])
 637         ])
 638 ], [
 639         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 640 ])
 641
 642 m4_popdef([build_man_pages_msg])
 643
 644 PPRINT_SET_INDENT(1)
 645
 646 report_bindir="`eval eval echo $bindir`"
 647 report_libdir="`eval eval echo $libdir`"
 648
 649 # Print the bindir and libdir this `make install' will install into.
 650 AS_ECHO
 651 PPRINT_SUBTITLE([Install directories])
 652 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 653 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 654
 655 AS_ECHO
 656 PPRINT_SUBTITLE([System directories])
 657
 658 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 659
 660 PPRINT_SET_INDENT(0)
 661
 662 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 663         AS_ECHO
 664         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 665
 666 Note that the man pages are already built in this distribution tarball,
 667 therefore asciidoc and xmlto are only needed if you intend to modify
 668 their sources.
 669
 670 Use --disable-man-pages to completely disable building and installing
 671 the man pages.])
 672 ])