configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.4.4],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 # This is the library version of liblttng-ust.
   9 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
  10 # note: remember to update tracepoint.h dlopen() to match this version
  11 # number. TODO: eventually automate by exporting the major number.
  12
  13 # This is the library version of liblttng-ust-ctl, used internally by
  14 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  15 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
  16
  17 AC_CONFIG_AUX_DIR([config])
  18 AC_CANONICAL_TARGET
  19 AC_CANONICAL_HOST
  20 AC_CONFIG_MACRO_DIR([config])
  21 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  24
  25 # Configuration options, which will be installed in the config.h
  26 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  27 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  28 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  29
  30 # Compute minor/major/patchlevel version numbers
  31 AC_PROG_SED
  32 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  33 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  34 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  35 AC_SUBST([MAJOR_VERSION], [$major_version])
  36 AC_SUBST([MINOR_VERSION], [$minor_version])
  37 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  38 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  39 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  40 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  41
  42 version_name="Époque Opaque"
  43 version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
  44
  45 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  46 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  47
  48 AC_PROG_GREP
  49 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  50 AC_ARG_ENABLE(libtool-linkdep-fixup,
  51         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  52                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  53         libtool_fixup=$enableval,
  54         libtool_fixup=yes)
  55
  56 AS_IF([test "x$libtool_fixup" = "xyes"],
  57             [
  58             libtool_m4="$srcdir/config/libtool.m4"
  59             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  60             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  61             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  62             AS_IF([test $libtool_flag_pattern_count -ne 0],
  63             [
  64                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  65                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  66                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  67                   ],
  68                   [
  69                   AC_MSG_RESULT([none])
  70                   ])
  71             ])
  72
  73 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  74
  75 # Checks for programs.
  76 AC_PROG_CC
  77 AC_PROG_CXX
  78 AC_PROG_MAKE_SET
  79 LT_INIT
  80
  81 # rw_PROG_CXX_WORKS
  82 # Check whether the C++ compiler works.
  83 AC_CACHE_CHECK([whether the C++ compiler works],
  84                 [rw_cv_prog_cxx_works],
  85                 [AC_LANG_PUSH([C++])
  86                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  87                                 [check_cxx_designated_initializers=yes],
  88                                 [rw_cv_prog_cxx_works=no])
  89                 if test "$check_cxx_designated_initializers" = "yes"; then
  90                         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  91                                 struct foo { int a; int b; };
  92                                 void fct(void)
  93                                 {
  94                                         struct foo f = { .a = 0, .b = 1 };
  95                                 }
  96                         ]])],[
  97                                 rw_cv_prog_cxx_works=yes
  98                         ],[
  99                                 rw_cv_prog_cxx_works=no
 100                         ])
 101                 fi
 102                 AC_LANG_POP([C++])])
 103
 104 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
 105
 106 # Check if the compiler support weak symbols
 107 AX_SYS_WEAK_ALIAS
 108
 109 if test "x${ax_cv_sys_weak_alias}" = "xno"; then
 110    AC_MSG_ERROR([Your platform doesn't support weak symbols.])
 111 fi
 112
 113 ## Checks for libraries.
 114 AC_CHECK_LIB([dl], [dlopen],
 115 [
 116         have_libdl=yes
 117 ],
 118 [
 119         #libdl not found, check for dlopen in libc.
 120         AC_CHECK_LIB([c], [dlopen],
 121         [
 122                 have_libc_dl=yes
 123         ],
 124         [
 125                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 126         ])
 127 ])
 128 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 129 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 130
 131 AC_CHECK_LIB([pthread], [pthread_create])
 132
 133 # Check for dlfcn.h
 134 AC_CHECK_HEADER([dlfcn.h])
 135 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
 136         [AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
 137                 [#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 138                 #include <dlfcn.h>])
 139         ],
 140         [ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
 141 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 142
 143 # Checks for header files.
 144 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
 145
 146 # Checks for typedefs, structures, and compiler characteristics.
 147 AC_C_INLINE
 148 #AC_TYPE_INT16_T
 149 #AC_TYPE_INT32_T
 150 #AC_TYPE_INT64_T
 151 #AC_TYPE_INT8_T
 152 #AC_TYPE_PID_T
 153 #AC_TYPE_SIZE_T
 154 #AC_TYPE_SSIZE_T
 155 #AC_TYPE_UINT16_T
 156 #AC_TYPE_UINT32_T
 157 #AC_TYPE_UINT64_T
 158 #AC_TYPE_UINT8_T
 159 #AC_CHECK_TYPES([ptrdiff_t])
 160
 161 # Checks for library functions.
 162 AC_FUNC_MALLOC
 163 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 164
 165 CFLAGS="-Wall $CFLAGS"
 166
 167 # URCU
 168
 169 # urcu - check if we just find the headers it out of the box.
 170 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 171 This error can also occur when the liburcu package's configure script has not been run.])])
 172
 173 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 174 # Part of Userspace RCU library 0.7.2 or better.
 175 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 176 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 177
 178 AC_MSG_CHECKING([caa_likely()])
 179 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 180 #include <urcu/compiler.h>
 181 void fct(void)
 182 {
 183         if (caa_likely(1)) {
 184         }
 185 }
 186 ]])],[
 187         AC_MSG_RESULT([yes])
 188 ],[
 189         AC_MSG_RESULT([no])
 190         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 191
 192 ])
 193
 194 # urcu - check that URCU lib is available to compilation
 195 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 196
 197 # urcu - check that URCU lib is at least version 0.6
 198 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 199
 200 AC_MSG_CHECKING([host system alignment requirements])
 201 case $host_cpu in
 202 changequote(,)dnl
 203         i[3456]86)
 204 changequote([,])dnl
 205           ;;
 206         x86_64) ;;
 207         amd64) ;;
 208         powerpc) ;;
 209         ppc64) ;;
 210         powerpc64) ;;
 211         s390) NO_UNALIGNED_ACCESS=1 ;;
 212         s390x) NO_UNALIGNED_ACCESS=1 ;;
 213         arm*) NO_UNALIGNED_ACCESS=1 ;;
 214         mips*) NO_UNALIGNED_ACCESS=1 ;;
 215         tile*) NO_UNALIGNED_ACCESS=1 ;;
 216         *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
 217 esac
 218 AC_MSG_RESULT([$host_cpu])
 219
 220 if test x$NO_UNALIGNED_ACCESS = x ; then
 221 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 222 fi
 223
 224 # Set compile flags to java include files if given
 225 AC_ARG_WITH([java-jdk],
 226         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 227         [JAVA_JDK=$withval],
 228         [JAVA_JDK=""]
 229 )
 230 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 231 AC_SUBST([JAVA_JDK])
 232
 233 AS_IF([test $JAVA_JDK],[
 234         AS_IF([test -d $JAVA_JDK],[
 235                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 236                 SUBDIRS=`find $JAVA_JDK/include -type d`
 237                 CPPFLAGS+=" "
 238                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 239                 CPPFLAGS+=" "
 240         ],[
 241                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 242         ])
 243 ])
 244
 245 # Check for JNI header files if requested
 246 AC_ARG_WITH([jni-interface],
 247         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 248         [jni_interface=$withval],
 249         [jni_interface=no]
 250 )
 251
 252 AS_IF([test "x$jni_interface" = "xyes"],[
 253         AC_CHECK_HEADERS([jni.h],[],[
 254         AC_MSG_ERROR([missing jni.h
 255 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 256 Use the --with-java-jdk=DIR option to point to your JDK directory, or disable the JNI interface.])
 257         ])
 258 ])
 259 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 260
 261 # sdt.h integration
 262 AC_ARG_WITH([sdt],
 263         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 264         [with_sdt=$withval],
 265         [with_sdt="no"]
 266 )
 267
 268 AS_IF([test "x$with_sdt" = "xyes"],[
 269         AC_MSG_CHECKING([STAP_PROBEV()])
 270         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 271         #define SDT_USE_VARIADIC
 272         #include <sys/sdt.h>
 273         void fct(void)
 274         {
 275                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 276         }
 277         ]])],[
 278                 AC_MSG_RESULT([yes])
 279                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 280         ],[
 281                 AC_MSG_RESULT([no])
 282                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 283         ])
 284 ])
 285
 286 AC_MSG_CHECKING([whether shared libraries are enabled])
 287 AS_IF([test "x$enable_shared" = "xyes"],
 288         [
 289                 AC_MSG_RESULT([yes])
 290         ],
 291         [
 292                 AC_MSG_RESULT([no])
 293                 AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 294         ])
 295
 296 AC_ARG_WITH([lttng-system-rundir],
 297         AS_HELP_STRING([--with-lttng-system-rundir],
 298         [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 299         [lttng_system_rundir="$withval"],
 300         [lttng_system_rundir="/var/run/lttng"])
 301 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 302         [LTTng system runtime directory])
 303
 304 lttnglibjavadir="${libdir}/lttng/java"
 305 AC_SUBST(lttnglibjavadir)
 306
 307 AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
 308 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
 309
 310 AC_CONFIG_FILES([
 311         Makefile
 312         doc/Makefile
 313         doc/examples/Makefile
 314         include/Makefile
 315         include/lttng/ust-version.h
 316         snprintf/Makefile
 317         libringbuffer/Makefile
 318         liblttng-ust-comm/Makefile
 319         liblttng-ust/Makefile
 320         liblttng-ust-ctl/Makefile
 321         liblttng-ust-fork/Makefile
 322         liblttng-ust-dl/Makefile
 323         liblttng-ust-java/Makefile
 324         liblttng-ust-jul/Makefile
 325         liblttng-ust-libc-wrapper/Makefile
 326         liblttng-ust-cyg-profile/Makefile
 327         tools/Makefile
 328         tests/Makefile
 329         tests/hello/Makefile
 330         tests/hello.cxx/Makefile
 331         tests/same_line_tracepoint/Makefile
 332         tests/snprintf/Makefile
 333         tests/benchmark/Makefile
 334         tests/utils/Makefile
 335         tests/java-jul/Makefile
 336         lttng-ust.pc
 337 ])
 338
 339 AC_OUTPUT
 340
 341 AS_ECHO()
 342 AS_ECHO("Version name: $version_name")
 343 AS_ECHO("$version_description")
 344
 345 # Report on the configuration options
 346 AS_ECHO()
 347 AS_ECHO("LTTng-UST will be built with the following options:")
 348
 349 AS_ECHO()
 350 AS_ECHO_N("Java support (JNI): ")
 351 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 352
 353 AS_ECHO_N("sdt.h integration:  ")
 354 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 355
 356 AS_ECHO()
 357 AS_ECHO("Type 'make' to compile.")
 358