configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [11])
   4 m4_define([V_PATCH], [5])
   5 dnl m4_define([V_EXTRA], [])
   6 m4_define([V_NAME], [[Lafontaine]])
   7 m4_define([V_DESC], [[A modern Saison beer from Montréal's Oshlag microbrewery, Lafontaine is a refreshing, zesty, rice beer with hints of fruit and spices.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_SUBST([LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  58 AC_PROG_CXX
  59 rw_PROG_CXX_WORKS
  60 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  61
  62 # Check if the compiler support weak symbols
  63 AX_SYS_WEAK_ALIAS
  64
  65 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  66         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  67 ])
  68
  69 # Checks for programs.
  70 AC_PROG_SED
  71 AC_PROG_GREP
  72 AC_PROG_LN_S
  73 AC_PROG_MKDIR_P
  74 AC_PROG_MAKE_SET
  75 AC_CHECK_PROG([CMAKE], [cmake])
  76 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
  77
  78 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  79 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  80 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  81 ], [
  82         libtool_fixup=$enableval
  83 ], [
  84         libtool_fixup=yes
  85 ])
  86
  87 AS_IF([test "x$libtool_fixup" = "xyes"], [
  88         libtool_m4="$srcdir/m4/libtool.m4"
  89         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  90         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  91         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  92
  93         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  94         AC_MSG_RESULT([$libtool_flag_pattern_count])
  95         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  96                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  97         ], [
  98                 AC_MSG_RESULT([none])
  99         ])
 100 ])
 101 LT_INIT([disable-static])
 102
 103 AC_MSG_CHECKING([whether shared libraries are enabled])
 104 AS_IF([test "x$enable_shared" = "xyes"], [
 105         AC_MSG_RESULT([yes])
 106 ], [
 107         AC_MSG_RESULT([no])
 108         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 109 ])
 110
 111 # Checks for typedefs, structures, and compiler characteristics.
 112 AC_C_INLINE
 113 AC_TYPE_INT8_T
 114 AC_TYPE_INT16_T
 115 AC_TYPE_INT32_T
 116 AC_TYPE_INT64_T
 117 AC_TYPE_MODE_T
 118 AC_TYPE_OFF_T
 119 AC_TYPE_PID_T
 120 AC_TYPE_SIZE_T
 121 AC_TYPE_SSIZE_T
 122 AC_TYPE_UID_T
 123 AC_TYPE_UINT8_T
 124 AC_TYPE_UINT16_T
 125 AC_TYPE_UINT32_T
 126 AC_TYPE_UINT64_T
 127 AC_CHECK_TYPES([ptrdiff_t])
 128
 129 AX_C___ATTRIBUTE__
 130 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 131         [:],
 132         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 133
 134 # Checks for library functions.
 135 AC_FUNC_CHOWN
 136 AC_FUNC_FORK
 137 AC_FUNC_MMAP
 138 AC_FUNC_REALLOC
 139 AC_FUNC_STRERROR_R
 140 AC_FUNC_STRNLEN
 141 AC_CHECK_FUNCS([ \
 142         atexit \
 143         clock_gettime \
 144         ftruncate \
 145         getpagesize \
 146         gettimeofday \
 147         localeconv \
 148         memchr \
 149         memmove \
 150         memset \
 151         mkdir \
 152         munmap \
 153         realpath \
 154         sched_getcpu \
 155         socket \
 156         strchr \
 157         strdup \
 158         strerror \
 159         strtol \
 160         sysconf \
 161 ])
 162
 163 # AC_FUNC_MALLOC causes problems when cross-compiling.
 164 #AC_FUNC_MALLOC
 165
 166 # Checks for header files.
 167 AC_HEADER_STDBOOL
 168 AC_CHECK_HEADERS([ \
 169         arpa/inet.h \
 170         fcntl.h \
 171         float.h \
 172         limits.h \
 173         locale.h \
 174         stddef.h \
 175         sys/socket.h \
 176         sys/time.h \
 177         wchar.h \
 178 ])
 179
 180 # Set architecture specific options
 181 AS_CASE([$host_cpu],
 182         [i[[3456]]86], [],
 183         [x86_64], [],
 184         [amd64], [],
 185         [powerpc], [],
 186         [ppc64], [],
 187         [ppc64le], [],
 188         [powerpc64], [],
 189         [powerpc64le], [],
 190         [s390], [NO_UNALIGNED_ACCESS=1],
 191         [s390x], [NO_UNALIGNED_ACCESS=1],
 192         [arm*], [
 193                 NO_UNALIGNED_ACCESS=1
 194                 NO_NUMA=1
 195                 ],
 196         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 197         [mips*], [NO_UNALIGNED_ACCESS=1],
 198         [tile*], [NO_UNALIGNED_ACCESS=1],
 199         [
 200                 UNSUPPORTED_ARCH=1
 201                 NO_UNALIGNED_ACCESS=1
 202         ])
 203
 204 # Configuration options, which will be installed in the config.h
 205 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 206 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 207 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 208
 209 # Checks for libraries.
 210 AC_CHECK_LIB([dl], [dlopen], [
 211         have_libdl=yes
 212         libdl_name=dl
 213 ], [
 214         #libdl not found, check for dlopen in libc.
 215         AC_CHECK_LIB([c], [dlopen], [
 216                 have_libc_dl=yes
 217                 libdl_name=c
 218         ], [
 219                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 220         ])
 221 ])
 222
 223 # Check if libdl has dlmopen support.
 224 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 225 AC_CHECK_LIB([$libdl_name], [dlmopen],
 226         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 227 )
 228
 229 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 230 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 231
 232 AC_CHECK_LIB([pthread], [pthread_create])
 233 AC_CHECK_LIB([pthread], [pthread_setname_np],
 234         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 235         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 236                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 237                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 238
 239 # Check for dlfcn.h
 240 AC_CHECK_HEADER([dlfcn.h])
 241 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 242         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 243                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 244                 #include <dlfcn.h>
 245         ])
 246 ], [
 247         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 248 ])
 249
 250 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 251
 252 # URCU
 253
 254 # urcu - check if we just find the headers it out of the box.
 255 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 256 This error can also occur when the liburcu package's configure script has not been run.])])
 257
 258 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 259 # Part of Userspace RCU library 0.7.2 or better.
 260 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 261 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 262
 263 AC_MSG_CHECKING([caa_likely()])
 264 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 265         #include <urcu/compiler.h>
 266         void fct(void)
 267         {
 268                 if (caa_likely(1)) {
 269                 }
 270         }
 271 ]])], [
 272         AC_MSG_RESULT([yes])
 273 ], [
 274         AC_MSG_RESULT([no])
 275         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 276 ])
 277
 278 # urcu - check that URCU lib is available to compilation
 279 # Check for 'synchronize_rcu_bp' and then failback to 'urcu_bp_synchronize_rcu' as the former was
 280 # removed from the ABI in liburcu 0.13.
 281 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [
 282         AC_CHECK_LIB([urcu-bp], [urcu_bp_synchronize_rcu], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 283 ])
 284
 285
 286 # numa.h integration
 287 AS_IF([test "x$NO_NUMA" = "x1"],[
 288       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 289 ])
 290
 291 AC_ARG_ENABLE([numa], [
 292 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 293 ], [
 294         enable_numa=$enableval
 295 ], [
 296         enable_numa=yes
 297 ])
 298
 299 AS_IF([test "x$enable_numa" = "xyes"], [
 300         # numa - check that numa lib is available
 301         AC_CHECK_LIB([numa], [numa_available], [],
 302 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 303         have_libnuma=yes
 304 ])
 305 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 306
 307 # optional linux/perf_event.h
 308 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 309
 310 # Perf event counters are supported on all architectures supported by
 311 # perf, using the read system call as fallback.
 312 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 313
 314 AS_IF([test "x$have_perf_event" = "xyes"], [
 315         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 316 ])
 317
 318 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 319         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 320 ])
 321
 322 # Check for JNI header files if requested
 323 AC_ARG_ENABLE([jni-interface], [
 324 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 325 ], [
 326         jni_interface=$enableval
 327 ], [
 328         jni_interface=no
 329 ])
 330
 331 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 332
 333
 334 AC_ARG_ENABLE([java-agent-jul], [
 335 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 336 ], [
 337         java_agent_jul=$enableval
 338 ], [
 339         java_agent_jul=no
 340 ])
 341
 342 AC_ARG_ENABLE([java-agent-log4j], [
 343 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 344 ], [
 345         java_agent_log4j=$enableval
 346 ], [
 347         java_agent_log4j=no
 348 ])
 349
 350 AC_ARG_ENABLE([java-agent-all], [
 351 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 352 ], [
 353         java_agent_jul=$enableval
 354         java_agent_log4j=$enableval
 355 ], [:])
 356
 357 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 358 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 359 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 360
 361 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 362         AX_JAVA_OPTIONS
 363         AX_PROG_JAVAC
 364         AX_PROG_JAVA
 365         AX_PROG_JAR
 366         AC_ARG_VAR([CLASSPATH], [Java class path])
 367
 368         AX_JNI_INCLUDE_DIR
 369         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 370         do
 371                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 372         done
 373
 374         saved_CPPFLAGS="$CPPFLAGS"
 375         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 376         AX_PROG_JAVAH
 377         CPPFLAGS="$saved_CPPFLAGS"
 378 ])
 379
 380 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 381
 382 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 383         AX_CHECK_CLASSPATH
 384         AX_CHECK_CLASS([org.apache.log4j.Logger])
 385         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 386                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 387         ])
 388 ])
 389
 390 # Option to build the python agent
 391 AC_ARG_ENABLE([python-agent], [
 392 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 393 ], [
 394         python_agent=$enableval
 395 ], [:])
 396 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 397 AS_IF([test "x$python_agent" = "xyes"], [
 398         AM_PATH_PYTHON([2.7])
 399 ])
 400
 401 # sdt.h integration
 402 AC_ARG_WITH([sdt], [
 403 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 404 ], [
 405         with_sdt=$withval
 406 ], [
 407         with_sdt="no"
 408 ])
 409
 410 AS_IF([test "x$with_sdt" = "xyes"], [
 411         AC_MSG_CHECKING([STAP_PROBEV()])
 412         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 413                 #define SDT_USE_VARIADIC
 414                 #include <sys/sdt.h>
 415                 void fct(void)
 416                 {
 417                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 418                 }
 419         ]])], [
 420                 AC_MSG_RESULT([yes])
 421                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 422         ], [
 423                 AC_MSG_RESULT([no])
 424                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 425         ])
 426 ])
 427
 428 AC_ARG_WITH([lttng-system-rundir], [
 429 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 430 ], [
 431         lttng_system_rundir="$withval"
 432 ], [
 433         lttng_system_rundir="/var/run/lttng"
 434 ])
 435 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 436                 [LTTng system runtime directory])
 437
 438 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 439 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 440
 441 # Enable building examples
 442 AC_ARG_ENABLE(
 443         examples,
 444         AS_HELP_STRING(
 445                 [--disable-examples],
 446                 [Do not build and install examples]
 447         ),
 448         [enable_examples=$enableval],
 449         [enable_examples=yes]
 450 )
 451
 452 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 453
 454 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 455 # is not distributed in tarballs.
 456 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 457 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 458
 459 # Enable building man pages (user's intention).
 460 AC_ARG_ENABLE(
 461         man-pages,
 462         AS_HELP_STRING(
 463                 [--disable-man-pages],
 464                 [Do not build and install man pages (already built in a distributed tarball)]
 465         ),
 466         [man_pages_opt=$enableval],
 467         [man_pages_opt=yes]
 468 )
 469
 470 # Check for asciidoc and xmlto if we enabled building the man pages.
 471 have_asciidoc_xmlto=no
 472 warn_prebuilt_man_pages=no
 473
 474 AS_IF([test "x$man_pages_opt" = "xyes"], [
 475         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 476         AC_PATH_PROG([XMLTO], [xmlto], [no])
 477
 478         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 479                 AS_IF([test "x$in_git_repo" = "xyes"], [
 480                         # This is an error because we're in the Git repo, which
 481                         # means the man pages are not already generated for us,
 482                         # thus asciidoc/xmlto are required because we were asked
 483                         # to build the man pages.
 484                         AC_MSG_ERROR([
 485 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 486 --disable-man-pages to disable building the man pages, in which case
 487 they will not be installed.
 488                         ])
 489                 ], [
 490                         # Only warn here: since we're in the tarball, the man
 491                         # pages should already be generated at this point, thus
 492                         # asciidoc/xmlto are not strictly required.
 493                         warn_prebuilt_man_pages=yes
 494                 ])
 495         ], [
 496                 have_asciidoc_xmlto=yes
 497         ])
 498 ])
 499
 500 # Export man page build condition: build the man pages if the user
 501 # asked for it, and if the tools are available.
 502 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 503 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 504
 505 # Default values
 506 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 507         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 508         $1="$2"
 509         AC_SUBST([$1])
 510 ])
 511
 512 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 513
 514 AM_CFLAGS="-Wall"
 515 AC_SUBST(AM_CFLAGS)
 516 AC_SUBST(JNI_CPPFLAGS)
 517
 518 AC_CONFIG_FILES([
 519         Makefile
 520         doc/Makefile
 521         doc/examples/Makefile
 522         doc/man/Makefile
 523         include/Makefile
 524         include/lttng/ust-version.h
 525         snprintf/Makefile
 526         libringbuffer/Makefile
 527         liblttng-ust-comm/Makefile
 528         liblttng-ust/Makefile
 529         liblttng-ust-ctl/Makefile
 530         liblttng-ust-fork/Makefile
 531         liblttng-ust-dl/Makefile
 532         liblttng-ust-fd/Makefile
 533         liblttng-ust-java/Makefile
 534         liblttng-ust-java-agent/Makefile
 535         liblttng-ust-java-agent/java/Makefile
 536         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 537         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 538         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 539         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 540         liblttng-ust-java-agent/jni/Makefile
 541         liblttng-ust-java-agent/jni/common/Makefile
 542         liblttng-ust-java-agent/jni/jul/Makefile
 543         liblttng-ust-java-agent/jni/log4j/Makefile
 544         liblttng-ust-libc-wrapper/Makefile
 545         liblttng-ust-cyg-profile/Makefile
 546         liblttng-ust-python-agent/Makefile
 547         python-lttngust/Makefile
 548         python-lttngust/setup.py
 549         python-lttngust/lttngust/__init__.py
 550         tools/Makefile
 551         tests/Makefile
 552         tests/ctf-types/Makefile
 553         tests/hello/Makefile
 554         tests/hello.cxx/Makefile
 555         tests/same_line_tracepoint/Makefile
 556         tests/snprintf/Makefile
 557         tests/ust-elf/Makefile
 558         tests/benchmark/Makefile
 559         tests/utils/Makefile
 560         tests/test-app-ctx/Makefile
 561         tests/gcc-weak-hidden/Makefile
 562         tests/libringbuffer/Makefile
 563         lttng-ust.pc
 564 ])
 565
 566 # Create link for python agent for the VPATH guru.
 567 AC_CONFIG_LINKS([
 568         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 569         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 570         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 571         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 572         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 573 ])
 574
 575 AC_OUTPUT
 576
 577
 578 #
 579 # Mini-report on what will be built.
 580 #
 581
 582 PPRINT_INIT
 583 PPRINT_SET_INDENT(1)
 584 PPRINT_SET_TS(38)
 585
 586 AS_ECHO
 587 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 588 AS_ECHO
 589
 590 AS_ECHO("V_DESC")
 591
 592 AS_ECHO
 593 PPRINT_SUBTITLE([System])
 594
 595 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 596
 597 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 598 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 599
 600 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 601        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 602 ])
 603
 604 AS_ECHO
 605 PPRINT_SUBTITLE([Features])
 606 PPRINT_SET_INDENT(1)
 607
 608 test "x$with_sdt" = "xyes" && value=1 || value=0
 609 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 610
 611 test "x$java_agent_jul" = xyes && value=1 || value=0
 612 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 613
 614 test "x$java_agent_log4j" = xyes && value=1 || value=0
 615 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 616
 617 test "x$jni_interface" = xyes && value=1 || value=0
 618 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 619
 620 test "x$python_agent" = xyes && value=1 || value=0
 621 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 622
 623 test "x$enable_numa" = xyes && value=1 || value=0
 624 PPRINT_PROP_BOOL([NUMA], $value)
 625
 626 AS_ECHO
 627 PPRINT_SET_INDENT(0)
 628
 629 test "x$enable_examples" = xyes && value=1 || value=0
 630 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 631
 632 # man pages build enabled/disabled
 633 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 634
 635 AS_IF([test "x$man_pages_opt" != "xno"], [
 636         AS_IF([test "x$in_git_repo" = "xyes"], [
 637                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 638         ], [
 639                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 640                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 641                 ], [
 642                         PPRINT_PROP_STRING([build_man_pages_msg],
 643                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 644                                 $PPRINT_COLOR_SUBTITLE)
 645                 ])
 646         ])
 647 ], [
 648         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 649 ])
 650
 651 m4_popdef([build_man_pages_msg])
 652
 653 PPRINT_SET_INDENT(1)
 654
 655 report_bindir="`eval eval echo $bindir`"
 656 report_libdir="`eval eval echo $libdir`"
 657
 658 # Print the bindir and libdir this `make install' will install into.
 659 AS_ECHO
 660 PPRINT_SUBTITLE([Install directories])
 661 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 662 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 663
 664 AS_ECHO
 665 PPRINT_SUBTITLE([System directories])
 666
 667 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 668
 669 PPRINT_SET_INDENT(0)
 670
 671 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 672         AS_ECHO
 673         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 674
 675 Note that the man pages are already built in this distribution tarball,
 676 therefore asciidoc and xmlto are only needed if you intend to modify
 677 their sources.
 678
 679 Use --disable-man-pages to completely disable building and installing
 680 the man pages.])
 681 ])