configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.8],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], [$version_name], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], [$version_description], [UST version description])
  41
  42 AC_PROG_GREP
  43 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  44 AC_ARG_ENABLE(libtool-linkdep-fixup,
  45         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  46                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  47         libtool_fixup=$enableval,
  48         libtool_fixup=yes)
  49
  50 AS_IF([test "x$libtool_fixup" = "xyes"],
  51             [
  52             libtool_m4="$srcdir/config/libtool.m4"
  53             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  54             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  55             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  56             AS_IF([test $libtool_flag_pattern_count -ne 0],
  57             [
  58                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  59                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  60                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  61                   ],
  62                   [
  63                   AC_MSG_RESULT([none])
  64                   ])
  65             ])
  66
  67 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
  68
  69 # Checks for programs.
  70 AC_PROG_CC
  71 AC_PROG_CXX
  72 AC_PROG_MAKE_SET
  73 LT_INIT
  74
  75 # rw_PROG_CXX_WORKS
  76 # Check whether the C++ compiler works.
  77 AC_CACHE_CHECK([whether the C++ compiler works],
  78                 [rw_cv_prog_cxx_works],
  79                 [AC_LANG_PUSH([C++])
  80                 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  81                                 [rw_cv_prog_cxx_works=yes],
  82                                 [rw_cv_prog_cxx_works=no])
  83                 AC_LANG_POP([C++])])
  84
  85 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  86
  87 ## Checks for libraries.
  88 AC_CHECK_LIB([dl], [dlopen])
  89 AC_CHECK_LIB([pthread], [pthread_create])
  90
  91 # Check for libuuid
  92 AC_CHECK_LIB([uuid], [uuid_generate], [],
  93         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  94 )
  95
  96 # Checks for header files.
  97 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  98
  99 # Checks for typedefs, structures, and compiler characteristics.
 100 AC_C_INLINE
 101 #AC_TYPE_INT16_T
 102 #AC_TYPE_INT32_T
 103 #AC_TYPE_INT64_T
 104 #AC_TYPE_INT8_T
 105 #AC_TYPE_PID_T
 106 #AC_TYPE_SIZE_T
 107 #AC_TYPE_SSIZE_T
 108 #AC_TYPE_UINT16_T
 109 #AC_TYPE_UINT32_T
 110 #AC_TYPE_UINT64_T
 111 #AC_TYPE_UINT8_T
 112 #AC_CHECK_TYPES([ptrdiff_t])
 113
 114 # Checks for library functions.
 115 AC_FUNC_MALLOC
 116 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 117
 118 CFLAGS="-Wall $CFLAGS"
 119
 120 # URCU
 121
 122 # urcu - check if we just find the headers it out of the box.
 123 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 124 This error can also occur when the liburcu package's configure script has not been run.])])
 125
 126 AC_MSG_CHECKING([caa_likely()])
 127 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 128 #include <urcu/compiler.h>
 129 void fct(void)
 130 {
 131         if (caa_likely(1)) {
 132         }
 133 }
 134 ]])],[
 135         AC_MSG_RESULT([yes])
 136 ],[
 137         AC_MSG_RESULT([no])
 138         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 139
 140 ])
 141
 142 # urcu - check that URCU lib is available to compilation
 143 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 144
 145 # urcu - check that URCU lib is at least version 0.6
 146 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 147
 148
 149 # Check for various supplementary host information (beyond the
 150 # triplet) which might affect the library format choices.  E.g., we
 151 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 152
 153 case "${host}" in
 154 changequote(,)dnl
 155   i[34567]86-*-linux*)
 156 changequote([,])dnl
 157     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 158                     [save_CPPFLAGS="$CPPFLAGS"
 159                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 160                     AC_EGREP_CPP([got it], [
 161 #if __x86_64__
 162 got it
 163 #endif
 164                  ], [ust_cv_i386_is_x86_64=yes],
 165                     [ust_cv_i386_is_x86_64=no])
 166                     CPPFLAGS="$save_CPPFLAGS"])
 167     ;;
 168 esac
 169
 170 AC_MSG_CHECKING([library format for the host system])
 171 case $host_cpu in
 172 changequote(,)dnl
 173         i[3456]86)
 174 changequote([,])dnl
 175           if test "$ust_cv_i386_is_x86_64" = yes ; then
 176              LIBFORMAT="elf64-x86-64"
 177           else
 178              LIBFORMAT="elf32-i386"
 179           fi
 180           ;;
 181         x86_64) LIBFORMAT="elf64-x86-64" ;;
 182         powerpc) LIBFORMAT="elf32-powerpc" ;;
 183         ppc64) LIBFORMAT="elf64-powerpc" ;;
 184         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 185         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 186         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 187         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 188         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 189         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 190         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 191 esac
 192 AC_SUBST(LIBFORMAT)
 193 AC_MSG_RESULT($LIBFORMAT)
 194
 195 if test "x$host_cpu" = "xarm" ; then
 196 AC_MSG_CHECKING([checking for armv5])
 197 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 198 #ifndef __ARM_ARCH_5TEJ__
 199 #error "no arm5 here"
 200 #endif
 201 ]])],[
 202         AC_MSG_RESULT([yes])
 203         NO_UNALIGNED_ACCESS=1
 204
 205 ],[
 206         AC_MSG_RESULT([no])
 207
 208 ])
 209 fi
 210 if test x$NO_UNALIGNED_ACCESS = x ; then
 211 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 212 fi
 213
 214 # Set compile flags to java include files if given
 215 AC_ARG_WITH([java-jdk],
 216         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 217         [JAVA_JDK=$withval],
 218         [JAVA_JDK=""]
 219 )
 220 AS_IF([test $JAVA_JDK],[
 221         AS_IF([test -d $JAVA_JDK],[
 222                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 223                 SUBDIRS=`find $JAVA_JDK/include -type d`
 224                 CPPFLAGS+=" "
 225                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 226                 CPPFLAGS+=" "
 227         ],[
 228                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 229         ])
 230 ])
 231
 232 # sdt.h integration
 233 AC_ARG_WITH([sdt],
 234         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 235         [with_sdt=$withval],
 236         [with_sdt="no"]
 237 )
 238
 239 AS_IF([test "x$with_sdt" = "xyes"],[
 240         AC_MSG_CHECKING([STAP_PROBEV()])
 241         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 242         #define SDT_USE_VARIADIC
 243         #include <sys/sdt.h>
 244         void fct(void)
 245         {
 246                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 247         }
 248         ]])],[
 249                 AC_MSG_RESULT([yes])
 250                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 251         ],[
 252                 AC_MSG_RESULT([no])
 253                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 254         ])
 255 ])
 256
 257 #currently disabled.
 258         #tests/hello2/Makefile
 259         #tests/basic/Makefile
 260         #tests/simple_include/Makefile
 261         #tests/snprintf/Makefile
 262         #tests/test-nevents/Makefile
 263         #tests/test-libustinstr-malloc/Makefile
 264         #tests/dlopen/Makefile
 265         #tests/same_line_marker/Makefile
 266         #tests/trace_event/Makefile
 267         #tests/tracepoint/Makefile
 268         #tests/tracepoint/benchmark/Makefile
 269         #tests/register_test/Makefile
 270         #tests/libustctl_function_#tests/Makefile
 271         #tests/exit-fast/Makefile
 272         #tests/basic_long/Makefile
 273
 274 #       liblttng-ust-java/Makefile
 275
 276 AC_CONFIG_FILES([
 277         Makefile
 278         doc/Makefile
 279         doc/examples/Makefile
 280         include/Makefile
 281         include/lttng/ust-version.h
 282         snprintf/Makefile
 283         libringbuffer/Makefile
 284         liblttng-ust-comm/Makefile
 285         liblttng-ust/Makefile
 286         liblttng-ust-ctl/Makefile
 287         liblttng-ust-fork/Makefile
 288         liblttng-ust-libc-wrapper/Makefile
 289         tools/Makefile
 290         tests/Makefile
 291         tests/hello/Makefile
 292         tests/hello-static-lib/Makefile
 293         tests/hello.cxx/Makefile
 294         tests/demo/Makefile
 295         tests/fork/Makefile
 296         tests/ust-basic-tracing/Makefile
 297         tests/ust-multi-test/Makefile
 298         lttng-ust.pc
 299 ])
 300
 301 AC_OUTPUT
 302
 303 AS_ECHO()
 304 AS_ECHO("Version name: $version_name")
 305 AS_ECHO("$version_description")
 306
 307 # Report on the configuration options
 308 AS_ECHO()
 309 AS_ECHO("LTTng-UST will be built with the following options:")
 310 AS_ECHO("Library format: $LIBFORMAT")
 311
 312 AS_ECHO()
 313 AS_ECHO_N("sdt.h integration:  ")
 314 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 315
 316 AS_ECHO()
 317 AS_ECHO("Type 'make' to compile.")
 318