configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.7.1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3 AC_CONFIG_AUX_DIR([config])
   4 AC_CANONICAL_TARGET
   5 AC_CANONICAL_HOST
   6 AC_CONFIG_MACRO_DIR([config])
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE([enable])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 # Compute minor/major/patchlevel version numbers
  12 AC_PROG_SED
  13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  16 AC_SUBST([MAJOR_VERSION], [$major_version])
  17 AC_SUBST([MINOR_VERSION], [$minor_version])
  18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  22
  23 version_name="Herbe à Détourne"
  24 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  25 version_description_c=$(echo $version_description | sed 's/"/\\"/g')
  26
  27 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  28 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  29
  30 AC_CONFIG_HEADERS([include/config.h])
  31
  32 AC_PROG_GREP
  33 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  34 AC_ARG_ENABLE(libtool-linkdep-fixup,
  35         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  36                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  37         libtool_fixup=$enableval,
  38         libtool_fixup=yes)
  39
  40 AS_IF([test "x$libtool_fixup" = "xyes"],
  41             [
  42             libtool_m4="$srcdir/config/libtool.m4"
  43             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  44             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  45             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  46             AS_IF([test $libtool_flag_pattern_count -ne 0],
  47             [
  48                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  49                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  50                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  51                   ],
  52                   [
  53                   AC_MSG_RESULT([none])
  54                   ])
  55             ])
  56
  57 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  58
  59 AC_CHECK_HEADERS([ \
  60         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  61         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  62         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
  63         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
  64         sys/mount.h sys/param.h sys/time.h
  65 ])
  66
  67 # Basic functions check
  68 AC_CHECK_FUNCS([ \
  69         atexit bzero clock_gettime dup2 fdatasync ftruncate \
  70         gethostbyname gethostname getpagesize localtime_r memchr memset \
  71         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
  72         strncasecmp strndup strpbrk strrchr strstr strtol strtoul \
  73         strtoull \
  74 ])
  75
  76 # Babeltrace viewer check
  77 AC_ARG_WITH([babeltrace-bin],
  78         AS_HELP_STRING([--with-babeltrace-bin],
  79         [Location of the babeltrace viewer executable (including the filename)]),
  80         [BABELTRACE_BIN="$withval"],
  81         [BABELTRACE_BIN=''])
  82 AC_SUBST([BABELTRACE_BIN])
  83
  84 # lttv-gui
  85 AC_ARG_WITH([lttv-gui-bin],
  86         AS_HELP_STRING([--with-lttv-gui-bin],
  87    [Location of the lttv GUI viewer executable (including the filename)]),
  88    [LTTV_GUI_BIN="$withval"],
  89    [LTTV_GUI_BIN=''])
  90 AC_SUBST([LTTV_GUI_BIN])
  91
  92 AC_ARG_WITH([consumerd32-bin],
  93         AS_HELP_STRING([--with-consumerd32-bin],
  94         [Location of the 32-bit consumerd executable (including the filename)]),
  95         [CONSUMERD32_BIN="$withval"],
  96         [CONSUMERD32_BIN=''])
  97 AC_SUBST([CONSUMERD32_BIN])
  98
  99 AC_ARG_WITH([consumerd64-bin],
 100         AS_HELP_STRING([--with-consumerd64-bin],
 101         [Location of the 64-bit consumerd executable (including the filename)]),
 102         [CONSUMERD64_BIN="$withval"],
 103         [CONSUMERD64_BIN=''])
 104 AC_SUBST([CONSUMERD64_BIN])
 105
 106 AC_ARG_WITH([consumerd32-libdir],
 107         AS_HELP_STRING([--with-consumerd32-libdir],
 108         [Directory containing the 32-bit consumerd libraries]),
 109         [CONSUMERD32_LIBDIR="$withval"],
 110         [CONSUMERD32_LIBDIR=''])
 111 AC_SUBST([CONSUMERD32_LIBDIR])
 112
 113 AC_ARG_WITH([consumerd64-libdir],
 114         AS_HELP_STRING([--with-consumerd64-libdir],
 115         [Directory containing the 64-bit consumerd libraries]),
 116         [CONSUMERD64_LIBDIR="$withval"],
 117         [CONSUMERD64_LIBDIR=''])
 118 AC_SUBST([CONSUMERD64_LIBDIR])
 119
 120 AC_ARG_WITH([sessiond-bin],
 121         AS_HELP_STRING([--with-sessiond-bin],
 122         [Location of the sessiond executable (including the filename)]),
 123         [SESSIOND_BIN="$withval"],
 124         [SESSIOND_BIN=''])
 125 AC_SUBST([SESSIOND_BIN])
 126
 127 AC_ARG_WITH([lttng-system-rundir],
 128         AS_HELP_STRING([--with-lttng-system-rundir],
 129         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 130         [LTTNG_SYSTEM_RUNDIR="$withval"],
 131         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 132 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 133
 134 AC_ARG_ENABLE([test-java-agent-jul],
 135         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 136         [test_java_agent_jul=$enableval],
 137         [test_java_agent_jul=no]
 138 )
 139
 140 AC_ARG_ENABLE([test-java-agent-log4j],
 141         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 142         [test_java_agent_log4j=$enableval],
 143         [test_java_agent_log4j=no]
 144 )
 145
 146 AC_ARG_ENABLE([test-java-agent-all],
 147         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 148         [test_java_agent_jul=$enableval
 149          test_java_agent_log4j=$enableval],
 150         [:]
 151 )
 152
 153 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 154 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 155 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 156 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 157 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 158 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 159 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 160 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 161
 162 if test "x$prefix" = "xNONE"; then
 163         prefix=$ac_default_prefix
 164 fi
 165 CONFDIR=`eval echo $sysconfdir`
 166 AC_SUBST(CONFDIR)
 167 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 168
 169 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 170
 171 #
 172 # Check for pthread
 173 AC_CHECK_LIB([pthread], [pthread_create], [],
 174         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 175 )
 176
 177 # Check libpopt
 178 PKG_CHECK_MODULES([POPT], [popt],
 179         [LIBS="$LIBS $POPT_LIBS"],
 180         [
 181                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 182                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 183                 AC_CHECK_LIB([popt],
 184                         [poptGetContext],
 185                         [],
 186                         [
 187                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 188                         ]
 189                 )
 190         ]
 191 )
 192
 193 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 194
 195 # Check for libuuid
 196 PKG_CHECK_MODULES([UUID], [uuid],
 197 [
 198         LIBS="$LIBS $UUID_LIBS"
 199         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 200         have_libuuid=yes
 201 ],
 202 [
 203         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 204         AC_MSG_WARN([Finding libuuid without pkg-config.])
 205         AC_CHECK_LIB([uuid],
 206                 [uuid_generate],
 207                 [
 208                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 209                         have_libuuid=yes
 210                 ],
 211                 [
 212                         # libuuid not found, check for uuid_create in libc.
 213                         AC_CHECK_LIB([c],
 214                                 [uuid_create],
 215                                 [
 216                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 217                                         have_libc_uuid=yes
 218                                 ],
 219                                 [
 220                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 221                                 ]
 222                         )
 223                 ]
 224         )
 225 ])
 226 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 227 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 228
 229 # URCU library version needed or newer
 230 liburcu_version=">= 0.8.0"
 231
 232 # Check liburcu needed function calls
 233 AC_CHECK_DECL([cds_list_add], [],
 234         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 235 )
 236 AC_CHECK_DECL([cds_wfcq_init], [],
 237         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 238 )
 239 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 240     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 241 )
 242 AC_CHECK_DECL([futex_async], [],
 243         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 244 )
 245 AC_CHECK_DECL([rcu_thread_offline], [],
 246         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 247 )
 248 AC_CHECK_DECL([rcu_thread_online], [],
 249         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 250 )
 251 AC_CHECK_DECL([caa_likely], [],
 252         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 253 )
 254 #Function added in urcu 0.7.0
 255 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 256         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 257 )
 258
 259 # Check kmod library
 260 AC_ARG_WITH(kmod-prefix,
 261   AS_HELP_STRING([--with-kmod-prefix=PATH],
 262                 [Specify the installation prefix of the kmod library.
 263                 Headers must be in PATH/include; libraries in PATH/lib.]),
 264                 [
 265                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 266                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 267                 ])
 268
 269 AC_ARG_ENABLE(kmod,
 270         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 271         kmod_support=zz$enableval, kmod_support=yes)
 272
 273 AS_IF([test "x$kmod_support" = "xyes"], [
 274         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 275                 [
 276                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 277                         LIBS="$LIBS -lkmod"
 278                         kmod_found=yes
 279                 ],
 280                 kmod_found=no
 281         )
 282 ])
 283 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 284
 285 AC_ARG_WITH(lttng-ust-prefix,
 286   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 287                  [Specify the installation prefix of the lttng-ust library.
 288                   Headers must be in PATH/include; libraries in PATH/lib.]),
 289                   [
 290                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 291                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 292                   ])
 293
 294 # Check liblttng-ust-ctl library
 295 AC_ARG_ENABLE(lttng-ust,
 296         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 297         lttng_ust_support=$enableval, lttng_ust_support=yes)
 298
 299 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 300         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 301                 [
 302                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 303                         lttng_ust_ctl_found=yes
 304                 ],
 305                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 306                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 307         )
 308 ])
 309 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 310 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 311
 312 # check for dlopen
 313 AC_CHECK_LIB([dl], [dlopen],
 314 [
 315         have_libdl=yes
 316 ],
 317 [
 318         #libdl not found, check for dlopen in libc.
 319         AC_CHECK_LIB([c], [dlopen],
 320         [
 321                 have_libc_dl=yes
 322         ],
 323         [
 324                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 325         ])
 326 ])
 327 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 328 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 329
 330 # Check for fmemopen
 331 AC_CHECK_LIB([c], [fmemopen],
 332 [
 333         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 334 ]
 335 )
 336
 337 # Check for open_memstream
 338 AC_CHECK_LIB([c], [open_memstream],
 339 [
 340         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 341 ]
 342 )
 343
 344 AC_ARG_ENABLE([git-version],
 345               [AC_HELP_STRING([--disable-git-version],
 346                               [Do not use the git version for the build])],
 347               [have_git_version=$enableval], [have_git_version=yes]
 348 )
 349
 350 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 351         [test "x${have_git_version}" = "xyes"])
 352
 353 # For Python
 354 # SWIG version needed or newer:
 355 swig_version=2.0.0
 356
 357 AC_ARG_ENABLE([python-bindings],
 358               [AC_HELP_STRING([--enable-python-bindings],
 359                               [compile Python bindings])],
 360               [enable_python_binding=yes], [enable_python_binding=no])
 361
 362 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 363
 364 if test "x${enable_python_binding:-yes}" = xyes; then
 365   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 366   AM_PATH_PYTHON([3.0])
 367
 368   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 369   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 370   AS_IF([test -z "$PYTHON_INCLUDE"], [
 371     AS_IF([test -z "$PYTHON_CONFIG"], [
 372       AC_PATH_PROGS([PYTHON_CONFIG],
 373                     [python$PYTHON_VERSION-config python-config],
 374                     [no],
 375                     [`dirname $PYTHON`])
 376       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 377     ])
 378     AC_MSG_CHECKING([python include flags])
 379     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 380     AC_MSG_RESULT([$PYTHON_INCLUDE])
 381   ])
 382
 383 else
 384     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 385 [if you want Python bindings.])
 386
 387 fi
 388
 389 # Epoll check. If not present, the build will fallback on poll() API
 390 AX_HAVE_EPOLL(
 391         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 392         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 393 )
 394 AX_CONFIG_FEATURE(
 395         [epoll], [This platform supports epoll(7)],
 396         [HAVE_EPOLL], [This platform supports epoll(7).],
 397         [enable_epoll="yes"], [enable_epoll="no"]
 398 )
 399 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 400
 401 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 402 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 403
 404 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 405         AX_JAVA_OPTIONS
 406         AX_PROG_JAVAC
 407         AX_PROG_JAVA
 408         AX_PROG_JAR
 409
 410         AX_CHECK_CLASSPATH
 411
 412         # Check for Java UST agent common class first
 413         AX_CHECK_CLASS(org.lttng.ust.agent.LTTngAgent)
 414         if test "x$ac_cv_class_org_lttng_ust_agent_LTTngAgent" = "xno"; then
 415                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/liblttng-ust-agent.jar"])
 416         fi
 417
 418         if test "x$test_java_agent_jul" = "xyes"; then
 419                 # Check for JUL agent class
 420                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LTTngJUL)
 421                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LTTngJUL" = "xno"; then
 422                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/liblttng-ust-jul.jar"])
 423                 fi
 424         fi
 425
 426         if test "x$test_java_agent_log4j" = "xyes"; then
 427                 # Check for Log4j agent class
 428                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LTTngLog4j)
 429                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LTTngLog4j" = "xno"; then
 430                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/liblttng-ust-agent.jar"])
 431                 fi
 432
 433                 # Check for Log4j class
 434                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 435                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 436                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 437                 fi
 438         fi
 439 fi
 440
 441 # Python agent test
 442 UST_PYTHON_AGENT="lttngust"
 443
 444 AC_ARG_ENABLE(test-python2-agent,
 445         AS_HELP_STRING([--enable-test-python2-agent],
 446                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 447         ),[:],[test_python2_agent_autodetect=yes]
 448 )
 449
 450 AC_ARG_ENABLE(test-python3-agent,
 451         AS_HELP_STRING([--enable-test-python3-agent],
 452                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 453         ),[:],[test_python3_agent_autodetect=yes]
 454 )
 455
 456 AC_ARG_ENABLE(test-python-agent-all,
 457         AS_HELP_STRING([--enable-test-python-agent-all],
 458                 [enable test for all python{2/3} agent.]
 459         ),
 460 )
 461
 462 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 463        unset test_python2_agent_autodetect
 464        unset test_python3_agent_autodetect
 465 ])
 466
 467 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 468        enable_test_python2_agent=yes
 469        enable_test_python3_agent=yes
 470 ])
 471
 472 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 473        enable_test_python2_agent=no
 474        enable_test_python3_agent=no
 475 ])
 476
 477
 478 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 479         AS_IF([test -z "$PYTHON2"], [
 480                         PYTHON2=python2
 481                 ], [
 482                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 483         ])
 484
 485         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 486         AS_IF([test -z "$PYTHON2_BIN"], [
 487                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 488                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 489                 ])
 490         ], [
 491                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 492                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 493                         PYTHON2_AGENT=$PYTHON2_BIN
 494                         AC_MSG_RESULT([yes])
 495                         RUN_PYTHON_AGENT_TEST=yes
 496                 ], [
 497                         AC_MSG_RESULT([no])
 498                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 499                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 500                         ])
 501                 ])
 502
 503         ])
 504
 505 ])
 506
 507 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 508         AS_IF([test -z "$PYTHON3"], [
 509                 PYTHON3=python3
 510         ], [
 511                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 512         ])
 513
 514         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 515         AS_IF([test -z "$PYTHON3_BIN"], [
 516                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 517                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 518                 ])
 519         ], [
 520                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 521                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 522                         PYTHON3_AGENT=$PYTHON3_BIN
 523                         AC_MSG_RESULT([yes])
 524                         RUN_PYTHON_AGENT_TEST=yes
 525                 ], [
 526                         AC_MSG_RESULT([no])
 527                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 528                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 529                         ])
 530                 ])
 531
 532         ])
 533 ])
 534
 535 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 536 AC_SUBST([PYTHON2_AGENT])
 537 AC_SUBST([PYTHON3_AGENT])
 538
 539 AC_SYS_LARGEFILE
 540
 541 # C compiler tests
 542 AC_PROG_CC
 543 AC_C_INLINE
 544
 545 # Type availability checking
 546 AC_TYPE_INT32_T
 547 AC_TYPE_INT64_T
 548 AC_TYPE_MODE_T
 549 AC_TYPE_OFF_T
 550 AC_TYPE_PID_T
 551 AC_TYPE_SIZE_T
 552 AC_TYPE_SSIZE_T
 553 AC_TYPE_UID_T
 554 AC_TYPE_UINT16_T
 555 AC_TYPE_UINT32_T
 556 AC_TYPE_UINT64_T
 557 AC_TYPE_UINT8_T
 558
 559 LT_INIT
 560 AC_PROG_YACC
 561 AC_PROG_LEX
 562
 563 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 564         if test x"$YACC" != "xbison -y"; then
 565                 AC_MSG_ERROR([[bison not found and is required when building from git.
 566                 Please install bison]])
 567         fi
 568         AC_PATH_PROG([BISON],[bison])
 569         AX_PROG_BISON_VERSION([2.4], [],[
 570                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 571         ])
 572 fi
 573
 574 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 575         if test x"$LEX" != "xflex"; then
 576                 AC_MSG_ERROR([[flex not found and is required when building from git.
 577                 Please install flex]])
 578         fi
 579         AC_PATH_PROG([FLEX],[flex])
 580         AX_PROG_FLEX_VERSION([2.5.35], [],[
 581                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 582         ])
 583 fi
 584
 585 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 586
 587 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 588
 589 lttngincludedir="${includedir}/lttng"
 590
 591 AC_SUBST(lttngincludedir)
 592 AC_SUBST(DEFAULT_INCLUDES)
 593
 594 lttnglibexecdir="${libdir}/lttng/libexec"
 595 AC_SUBST(lttnglibexecdir)
 596
 597 AC_CONFIG_FILES([
 598         Makefile
 599         doc/Makefile
 600         doc/man/Makefile
 601         include/Makefile
 602         extras/Makefile
 603         extras/bindings/Makefile
 604         extras/bindings/swig/Makefile
 605         extras/bindings/swig/python/Makefile
 606         extras/core-handler/Makefile
 607         src/Makefile
 608         src/common/Makefile
 609         src/common/kernel-ctl/Makefile
 610         src/common/kernel-consumer/Makefile
 611         src/common/ust-consumer/Makefile
 612         src/common/hashtable/Makefile
 613         src/common/sessiond-comm/Makefile
 614         src/common/compat/Makefile
 615         src/common/relayd/Makefile
 616         src/common/testpoint/Makefile
 617         src/common/index/Makefile
 618         src/common/health/Makefile
 619         src/common/config/Makefile
 620         src/lib/Makefile
 621         src/lib/lttng-ctl/Makefile
 622         src/lib/lttng-ctl/filter/Makefile
 623         src/lib/lttng-ctl/lttng-ctl.pc
 624         src/bin/Makefile
 625         src/bin/lttng-consumerd/Makefile
 626         src/bin/lttng-sessiond/Makefile
 627         src/bin/lttng-relayd/Makefile
 628         src/bin/lttng/Makefile
 629         src/bin/lttng-crash/Makefile
 630         tests/Makefile
 631         tests/regression/Makefile
 632         tests/regression/kernel/Makefile
 633         tests/regression/tools/Makefile
 634         tests/regression/tools/streaming/Makefile
 635         tests/regression/tools/filtering/Makefile
 636         tests/regression/tools/health/Makefile
 637         tests/regression/tools/tracefile-limits/Makefile
 638         tests/regression/tools/snapshots/Makefile
 639         tests/regression/tools/live/Makefile
 640         tests/regression/tools/exclusion/Makefile
 641         tests/regression/tools/save-load/Makefile
 642         tests/regression/tools/mi/Makefile
 643         tests/regression/tools/wildcard/Makefile
 644         tests/regression/tools/crash/Makefile
 645         tests/regression/ust/Makefile
 646         tests/regression/ust/nprocesses/Makefile
 647         tests/regression/ust/high-throughput/Makefile
 648         tests/regression/ust/low-throughput/Makefile
 649         tests/regression/ust/before-after/Makefile
 650         tests/regression/ust/buffers-pid/Makefile
 651         tests/regression/ust/periodical-metadata-flush/Makefile
 652         tests/regression/ust/multi-session/Makefile
 653         tests/regression/ust/overlap/Makefile
 654         tests/regression/ust/overlap/demo/Makefile
 655         tests/regression/ust/linking/Makefile
 656         tests/regression/ust/daemon/Makefile
 657         tests/regression/ust/exit-fast/Makefile
 658         tests/regression/ust/fork/Makefile
 659         tests/regression/ust/libc-wrapper/Makefile
 660         tests/regression/ust/java-jul/Makefile
 661         tests/regression/ust/java-log4j/Makefile
 662         tests/regression/ust/python-logging/Makefile
 663         tests/regression/ust/getcpu-override/Makefile
 664         tests/regression/ust/clock-override/Makefile
 665         tests/stress/Makefile
 666         tests/unit/Makefile
 667         tests/unit/ini_config/Makefile
 668         tests/utils/Makefile
 669         tests/utils/tap/Makefile
 670         tests/utils/testapp/Makefile
 671         tests/utils/testapp/gen-ust-events/Makefile
 672         tests/utils/testapp/gen-ust-nevents/Makefile
 673         tests/utils/testapp/gen-ust-tracef/Makefile
 674 ])
 675
 676 # Inject variable into python test script
 677 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 678
 679 AC_OUTPUT
 680
 681 #
 682 # Mini-report on what will be built
 683 #
 684 AS_ECHO()
 685
 686 AS_ECHO("Version name: $version_name")
 687 AS_ECHO("$version_description")
 688
 689 AS_ECHO()
 690
 691 # Target architecture we're building for
 692 target_arch=$host_cpu
 693 [
 694 for f in $CFLAGS; do
 695         if test $f = "-m32"; then
 696                         target_arch="32-bit"
 697         elif test $f = "-m64"; then
 698                         target_arch="64-bit"
 699         fi
 700 done
 701 ]
 702 AS_ECHO_N("Target architecture: ")
 703 AS_ECHO($target_arch)
 704
 705 # kmod enabled/disabled
 706 AS_ECHO_N("libkmod support: ")
 707 AS_IF([test "x$kmod_found" = "xyes"],[
 708         AS_ECHO("Enabled")
 709 ],[
 710         AS_ECHO("Disabled")
 711 ])
 712
 713 # LTTng-UST enabled/disabled
 714 AS_ECHO_N("Lttng-UST support: ")
 715 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 716         AS_ECHO("Enabled")
 717 ],[
 718         AS_ECHO("Disabled")
 719 ])
 720
 721 # LTTng UST Java agent JUL tests enabled/disabled
 722 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
 723 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
 724         AS_ECHO("Enabled")
 725 ],[
 726         AS_ECHO("Disabled")
 727 ])
 728
 729 # LTTng UST Java agent Log4j tests enabled/disabled
 730 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
 731 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
 732         AS_ECHO("Enabled")
 733 ],[
 734         AS_ECHO("Disabled")
 735 ])
 736
 737 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
 738 AS_IF([test ! -z "$PYTHON2_AGENT"],[
 739         AS_ECHO("Enabled")
 740 ],[
 741         AS_ECHO("Disabled")
 742 ])
 743
 744 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
 745 AS_IF([test ! -z "$PYTHON3_AGENT"],[
 746         AS_ECHO("Enabled")
 747 ],[
 748         AS_ECHO("Disabled")
 749 ])
 750
 751 #Python binding enabled/disabled
 752 AS_ECHO_N("Python binding: ")
 753 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
 754         AS_ECHO("Enabled")
 755 ],[
 756         AS_ECHO("Disabled")
 757 ])
 758
 759 # Do we build only the consumerd, or everything
 760 AS_IF([test "x$consumerd_only" = "xyes"],[
 761         AS_ECHO("Only the consumerd daemon will be built.")
 762 ],[
 763         AS_ECHO("All binaries will be built.")
 764 ])
 765
 766 # Print the bindir and libdir this `make install' will install into.
 767 AS_ECHO()
 768 AS_ECHO_N("Binaries will be installed in:  ")
 769 AS_ECHO("`eval eval echo $bindir`")
 770 AS_ECHO_N("Libraries will be installed in: ")
 771 AS_ECHO("`eval eval echo $libdir`")
 772
 773 # If we build the sessiond, print the paths it will use
 774 AS_IF([test "x$consumerd_only" = "xno"],[
 775         AS_ECHO()
 776         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 777         AS_IF([test "$SESSIOND_BIN" = ""],[
 778                 AS_ECHO_N("`eval eval echo $bindir`")
 779                 AS_ECHO("/lttng-sessiond")
 780         ],[
 781                 AS_ECHO("$SESSIOND_BIN")
 782         ])
 783
 784         AS_ECHO()
 785         AS_ECHO("The sessiond daemon will look in the following directories: ")
 786         AS_ECHO_N("32-bit consumerd executable at: ")
 787         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 788                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 789                 AS_ECHO("/lttng-consumerd")
 790         ],[
 791                 AS_ECHO("$CONSUMERD32_BIN")
 792         ])
 793
 794         AS_ECHO_N("32-bit consumer libraries in:   ")
 795         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 796                 AS_ECHO("`eval eval echo $libdir`")
 797         ],[
 798                 AS_ECHO("$CONSUMERD32_LIBDIR")
 799         ])
 800
 801         AS_ECHO_N("64-bit consumerd executable at: ")
 802         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 803                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 804                 AS_ECHO("/lttng-consumerd")
 805         ],[
 806                 AS_ECHO("$CONSUMERD64_BIN")
 807         ])
 808
 809         AS_ECHO_N("64-bit consumer libraries in:   ")
 810         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 811                 AS_ECHO("`eval eval echo $libdir`")
 812         ],[
 813                 AS_ECHO("$CONSUMERD64_LIBDIR")
 814         ])
 815 ])
 816
 817 AS_ECHO()
 818