configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.7.2],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3 AC_CONFIG_AUX_DIR([config])
   4 AC_CANONICAL_TARGET
   5 AC_CANONICAL_HOST
   6 AC_CONFIG_MACRO_DIR([config])
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE([enable])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 # Compute minor/major/patchlevel version numbers
  12 AC_PROG_SED
  13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  16 AC_SUBST([MAJOR_VERSION], [$major_version])
  17 AC_SUBST([MINOR_VERSION], [$minor_version])
  18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  22
  23 version_name="Herbe à Détourne"
  24 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  25 version_description_c=$(echo $version_description | sed 's/"/\\"/g')
  26
  27 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  28 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  29
  30 AC_CONFIG_HEADERS([include/config.h])
  31
  32 AC_PROG_GREP
  33 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  34 AC_ARG_ENABLE(libtool-linkdep-fixup,
  35         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  36                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  37         libtool_fixup=$enableval,
  38         libtool_fixup=yes)
  39
  40 AS_IF([test "x$libtool_fixup" = "xyes"],
  41             [
  42             libtool_m4="$srcdir/config/libtool.m4"
  43             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  44             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  45             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  46             AS_IF([test $libtool_flag_pattern_count -ne 0],
  47             [
  48                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  49                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  50                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  51                   ],
  52                   [
  53                   AC_MSG_RESULT([none])
  54                   ])
  55             ])
  56
  57 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  58
  59 AC_CHECK_HEADERS([ \
  60         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  61         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  62         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
  63         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
  64         sys/mount.h sys/param.h sys/time.h
  65 ])
  66
  67 # Basic functions check
  68 AC_CHECK_FUNCS([ \
  69         atexit bzero clock_gettime dup2 fdatasync ftruncate \
  70         gethostbyname gethostname getpagesize localtime_r memchr memset \
  71         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
  72         strncasecmp strndup strpbrk strrchr strstr strtol strtoul \
  73         strtoull \
  74 ])
  75
  76 # Babeltrace viewer check
  77 AC_ARG_WITH([babeltrace-bin],
  78         AS_HELP_STRING([--with-babeltrace-bin],
  79         [Location of the babeltrace viewer executable (including the filename)]),
  80         [BABELTRACE_BIN="$withval"],
  81         [BABELTRACE_BIN=''])
  82 AC_SUBST([BABELTRACE_BIN])
  83
  84 # lttv-gui
  85 AC_ARG_WITH([lttv-gui-bin],
  86         AS_HELP_STRING([--with-lttv-gui-bin],
  87    [Location of the lttv GUI viewer executable (including the filename)]),
  88    [LTTV_GUI_BIN="$withval"],
  89    [LTTV_GUI_BIN=''])
  90 AC_SUBST([LTTV_GUI_BIN])
  91
  92 AC_ARG_WITH([consumerd32-bin],
  93         AS_HELP_STRING([--with-consumerd32-bin],
  94         [Location of the 32-bit consumerd executable (including the filename)]),
  95         [CONSUMERD32_BIN="$withval"],
  96         [CONSUMERD32_BIN=''])
  97 AC_SUBST([CONSUMERD32_BIN])
  98
  99 AC_ARG_WITH([consumerd64-bin],
 100         AS_HELP_STRING([--with-consumerd64-bin],
 101         [Location of the 64-bit consumerd executable (including the filename)]),
 102         [CONSUMERD64_BIN="$withval"],
 103         [CONSUMERD64_BIN=''])
 104 AC_SUBST([CONSUMERD64_BIN])
 105
 106 AC_ARG_WITH([consumerd32-libdir],
 107         AS_HELP_STRING([--with-consumerd32-libdir],
 108         [Directory containing the 32-bit consumerd libraries]),
 109         [CONSUMERD32_LIBDIR="$withval"],
 110         [CONSUMERD32_LIBDIR=''])
 111 AC_SUBST([CONSUMERD32_LIBDIR])
 112
 113 AC_ARG_WITH([consumerd64-libdir],
 114         AS_HELP_STRING([--with-consumerd64-libdir],
 115         [Directory containing the 64-bit consumerd libraries]),
 116         [CONSUMERD64_LIBDIR="$withval"],
 117         [CONSUMERD64_LIBDIR=''])
 118 AC_SUBST([CONSUMERD64_LIBDIR])
 119
 120 AC_ARG_WITH([sessiond-bin],
 121         AS_HELP_STRING([--with-sessiond-bin],
 122         [Location of the sessiond executable (including the filename)]),
 123         [SESSIOND_BIN="$withval"],
 124         [SESSIOND_BIN=''])
 125 AC_SUBST([SESSIOND_BIN])
 126
 127 AC_ARG_WITH([lttng-system-rundir],
 128         AS_HELP_STRING([--with-lttng-system-rundir],
 129         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 130         [LTTNG_SYSTEM_RUNDIR="$withval"],
 131         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 132 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 133
 134 AC_ARG_ENABLE([test-java-agent-jul],
 135         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 136         [test_java_agent_jul=$enableval],
 137         [test_java_agent_jul=no]
 138 )
 139
 140 AC_ARG_ENABLE([test-java-agent-log4j],
 141         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 142         [test_java_agent_log4j=$enableval],
 143         [test_java_agent_log4j=no]
 144 )
 145
 146 AC_ARG_ENABLE([test-java-agent-all],
 147         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 148         [test_java_agent_jul=$enableval
 149          test_java_agent_log4j=$enableval],
 150         [:]
 151 )
 152
 153 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 154 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 155 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 156 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 157 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 158 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 159 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 160 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 161
 162 if test "x$prefix" = "xNONE"; then
 163         prefix=$ac_default_prefix
 164 fi
 165 CONFDIR=`eval echo $sysconfdir`
 166 AC_SUBST(CONFDIR)
 167 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 168
 169 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 170
 171 #
 172 # Check for pthread
 173 AC_CHECK_LIB([pthread], [pthread_create], [],
 174         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 175 )
 176
 177 # Check libpopt
 178 PKG_CHECK_MODULES([POPT], [popt],
 179         [LIBS="$LIBS $POPT_LIBS"],
 180         [
 181                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 182                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 183                 AC_CHECK_LIB([popt],
 184                         [poptGetContext],
 185                         [],
 186                         [
 187                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 188                         ]
 189                 )
 190         ]
 191 )
 192
 193 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 194
 195 # Check for libuuid
 196 PKG_CHECK_MODULES([UUID], [uuid],
 197 [
 198         LIBS="$LIBS $UUID_LIBS"
 199         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 200         have_libuuid=yes
 201 ],
 202 [
 203         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 204         AC_MSG_WARN([Finding libuuid without pkg-config.])
 205         AC_CHECK_LIB([uuid],
 206                 [uuid_generate],
 207                 [
 208                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 209                         have_libuuid=yes
 210                 ],
 211                 [
 212                         # libuuid not found, check for uuid_create in libc.
 213                         AC_CHECK_LIB([c],
 214                                 [uuid_create],
 215                                 [
 216                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 217                                         have_libc_uuid=yes
 218                                 ],
 219                                 [
 220                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 221                                 ]
 222                         )
 223                 ]
 224         )
 225 ])
 226 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 227 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 228
 229 # URCU library version needed or newer
 230 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 231
 232 # Check liburcu needed function calls
 233 AC_CHECK_DECL([cds_list_add], [],
 234         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 235 AC_CHECK_DECL([cds_wfcq_init], [],
 236         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 237 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 238         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 239 AC_CHECK_DECL([futex_async], [],
 240         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 241 AC_CHECK_DECL([rcu_thread_offline], [],
 242         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 243 AC_CHECK_DECL([rcu_thread_online], [],
 244         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 245 AC_CHECK_DECL([caa_likely], [],
 246         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 247
 248 #Function added in urcu 0.7.0
 249 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 250         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 251 )
 252
 253 # Check kmod library
 254 AC_ARG_WITH(kmod-prefix,
 255   AS_HELP_STRING([--with-kmod-prefix=PATH],
 256                 [Specify the installation prefix of the kmod library.
 257                 Headers must be in PATH/include; libraries in PATH/lib.]),
 258                 [
 259                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 260                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 261                 ])
 262
 263 AC_ARG_ENABLE(kmod,
 264         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 265         kmod_support=zz$enableval, kmod_support=yes)
 266
 267 AS_IF([test "x$kmod_support" = "xyes"], [
 268         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 269                 [
 270                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 271                         LIBS="$LIBS -lkmod"
 272                         kmod_found=yes
 273                 ],
 274                 kmod_found=no
 275         )
 276 ])
 277 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 278
 279 AC_ARG_WITH(lttng-ust-prefix,
 280   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 281                  [Specify the installation prefix of the lttng-ust library.
 282                   Headers must be in PATH/include; libraries in PATH/lib.]),
 283                   [
 284                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 285                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 286                   ])
 287
 288 # Check liblttng-ust-ctl library
 289 AC_ARG_ENABLE(lttng-ust,
 290         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 291         lttng_ust_support=$enableval, lttng_ust_support=yes)
 292
 293 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 294         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 295                 [
 296                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 297                         lttng_ust_ctl_found=yes
 298                 ],
 299                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 300                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 301         )
 302 ])
 303 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 304 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 305
 306 # check for dlopen
 307 AC_CHECK_LIB([dl], [dlopen],
 308 [
 309         have_libdl=yes
 310 ],
 311 [
 312         #libdl not found, check for dlopen in libc.
 313         AC_CHECK_LIB([c], [dlopen],
 314         [
 315                 have_libc_dl=yes
 316         ],
 317         [
 318                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 319         ])
 320 ])
 321 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 322 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 323
 324 # Check for fmemopen
 325 AC_CHECK_LIB([c], [fmemopen],
 326 [
 327         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 328 ]
 329 )
 330
 331 # Check for open_memstream
 332 AC_CHECK_LIB([c], [open_memstream],
 333 [
 334         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 335 ]
 336 )
 337
 338 AC_ARG_ENABLE([git-version],
 339               [AC_HELP_STRING([--disable-git-version],
 340                               [Do not use the git version for the build])],
 341               [have_git_version=$enableval], [have_git_version=yes]
 342 )
 343
 344 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 345         [test "x${have_git_version}" = "xyes"])
 346
 347 # For Python
 348 # SWIG version needed or newer:
 349 swig_version=2.0.0
 350
 351 AC_ARG_ENABLE([python-bindings],
 352               [AC_HELP_STRING([--enable-python-bindings],
 353                               [compile Python bindings])],
 354               [enable_python_binding=yes], [enable_python_binding=no])
 355
 356 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 357
 358 if test "x${enable_python_binding:-yes}" = xyes; then
 359   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 360   AM_PATH_PYTHON([3.0])
 361
 362   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 363   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 364   AS_IF([test -z "$PYTHON_INCLUDE"], [
 365     AS_IF([test -z "$PYTHON_CONFIG"], [
 366       AC_PATH_PROGS([PYTHON_CONFIG],
 367                     [python$PYTHON_VERSION-config python-config],
 368                     [no],
 369                     [`dirname $PYTHON`])
 370       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 371     ])
 372     AC_MSG_CHECKING([python include flags])
 373     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 374     AC_MSG_RESULT([$PYTHON_INCLUDE])
 375   ])
 376
 377 else
 378     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 379 [if you want Python bindings.])
 380
 381 fi
 382
 383 # Epoll check. If not present, the build will fallback on poll() API
 384 AX_HAVE_EPOLL(
 385         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 386         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 387 )
 388 AX_CONFIG_FEATURE(
 389         [epoll], [This platform supports epoll(7)],
 390         [HAVE_EPOLL], [This platform supports epoll(7).],
 391         [enable_epoll="yes"], [enable_epoll="no"]
 392 )
 393 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 394
 395 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 396 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 397
 398 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 399         AX_JAVA_OPTIONS
 400         AX_PROG_JAVAC
 401         AX_PROG_JAVA
 402         AX_PROG_JAR
 403
 404         AX_CHECK_CLASSPATH
 405
 406         # Check for Java UST agent common class first
 407         AX_CHECK_CLASS(org.lttng.ust.agent.LTTngAgent)
 408         if test "x$ac_cv_class_org_lttng_ust_agent_LTTngAgent" = "xno"; then
 409                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/liblttng-ust-agent.jar"])
 410         fi
 411
 412         if test "x$test_java_agent_jul" = "xyes"; then
 413                 # Check for JUL agent class
 414                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LTTngJUL)
 415                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LTTngJUL" = "xno"; then
 416                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/liblttng-ust-jul.jar"])
 417                 fi
 418         fi
 419
 420         if test "x$test_java_agent_log4j" = "xyes"; then
 421                 # Check for Log4j agent class
 422                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LTTngLog4j)
 423                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LTTngLog4j" = "xno"; then
 424                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/liblttng-ust-agent.jar"])
 425                 fi
 426
 427                 # Check for Log4j class
 428                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 429                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 430                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 431                 fi
 432         fi
 433 fi
 434
 435 # Python agent test
 436 UST_PYTHON_AGENT="lttngust"
 437
 438 AC_ARG_ENABLE(test-python2-agent,
 439         AS_HELP_STRING([--enable-test-python2-agent],
 440                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 441         ),[:],[test_python2_agent_autodetect=yes]
 442 )
 443
 444 AC_ARG_ENABLE(test-python3-agent,
 445         AS_HELP_STRING([--enable-test-python3-agent],
 446                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 447         ),[:],[test_python3_agent_autodetect=yes]
 448 )
 449
 450 AC_ARG_ENABLE(test-python-agent-all,
 451         AS_HELP_STRING([--enable-test-python-agent-all],
 452                 [enable test for all python{2/3} agent.]
 453         ),
 454 )
 455
 456 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 457        unset test_python2_agent_autodetect
 458        unset test_python3_agent_autodetect
 459 ])
 460
 461 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 462        enable_test_python2_agent=yes
 463        enable_test_python3_agent=yes
 464 ])
 465
 466 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 467        enable_test_python2_agent=no
 468        enable_test_python3_agent=no
 469 ])
 470
 471
 472 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 473         AS_IF([test -z "$PYTHON2"], [
 474                         PYTHON2=python2
 475                 ], [
 476                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 477         ])
 478
 479         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 480         AS_IF([test -z "$PYTHON2_BIN"], [
 481                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 482                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 483                 ])
 484         ], [
 485                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 486                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 487                         PYTHON2_AGENT=$PYTHON2_BIN
 488                         AC_MSG_RESULT([yes])
 489                         RUN_PYTHON_AGENT_TEST=yes
 490                 ], [
 491                         AC_MSG_RESULT([no])
 492                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 493                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 494                         ])
 495                 ])
 496
 497         ])
 498
 499 ])
 500
 501 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 502         AS_IF([test -z "$PYTHON3"], [
 503                 PYTHON3=python3
 504         ], [
 505                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 506         ])
 507
 508         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 509         AS_IF([test -z "$PYTHON3_BIN"], [
 510                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 511                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 512                 ])
 513         ], [
 514                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 515                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 516                         PYTHON3_AGENT=$PYTHON3_BIN
 517                         AC_MSG_RESULT([yes])
 518                         RUN_PYTHON_AGENT_TEST=yes
 519                 ], [
 520                         AC_MSG_RESULT([no])
 521                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 522                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 523                         ])
 524                 ])
 525
 526         ])
 527 ])
 528
 529 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 530 AC_SUBST([PYTHON2_AGENT])
 531 AC_SUBST([PYTHON3_AGENT])
 532
 533 AC_SYS_LARGEFILE
 534
 535 # C compiler tests
 536 AC_PROG_CC
 537 AC_C_INLINE
 538
 539 # Type availability checking
 540 AC_TYPE_INT32_T
 541 AC_TYPE_INT64_T
 542 AC_TYPE_MODE_T
 543 AC_TYPE_OFF_T
 544 AC_TYPE_PID_T
 545 AC_TYPE_SIZE_T
 546 AC_TYPE_SSIZE_T
 547 AC_TYPE_UID_T
 548 AC_TYPE_UINT16_T
 549 AC_TYPE_UINT32_T
 550 AC_TYPE_UINT64_T
 551 AC_TYPE_UINT8_T
 552
 553 LT_INIT
 554 AC_PROG_YACC
 555 AC_PROG_LEX
 556
 557 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 558         if test x"$YACC" != "xbison -y"; then
 559                 AC_MSG_ERROR([[bison not found and is required when building from git.
 560                 Please install bison]])
 561         fi
 562         AC_PATH_PROG([BISON],[bison])
 563         AX_PROG_BISON_VERSION([2.4], [],[
 564                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 565         ])
 566 fi
 567
 568 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 569         if test x"$LEX" != "xflex"; then
 570                 AC_MSG_ERROR([[flex not found and is required when building from git.
 571                 Please install flex]])
 572         fi
 573         AC_PATH_PROG([FLEX],[flex])
 574         AX_PROG_FLEX_VERSION([2.5.35], [],[
 575                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 576         ])
 577 fi
 578
 579 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 580
 581 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 582
 583 lttngincludedir="${includedir}/lttng"
 584
 585 AC_SUBST(lttngincludedir)
 586 AC_SUBST(DEFAULT_INCLUDES)
 587
 588 lttnglibexecdir="${libdir}/lttng/libexec"
 589 AC_SUBST(lttnglibexecdir)
 590
 591 AC_CONFIG_FILES([
 592         Makefile
 593         doc/Makefile
 594         doc/man/Makefile
 595         include/Makefile
 596         extras/Makefile
 597         extras/bindings/Makefile
 598         extras/bindings/swig/Makefile
 599         extras/bindings/swig/python/Makefile
 600         extras/core-handler/Makefile
 601         src/Makefile
 602         src/common/Makefile
 603         src/common/kernel-ctl/Makefile
 604         src/common/kernel-consumer/Makefile
 605         src/common/ust-consumer/Makefile
 606         src/common/hashtable/Makefile
 607         src/common/sessiond-comm/Makefile
 608         src/common/compat/Makefile
 609         src/common/relayd/Makefile
 610         src/common/testpoint/Makefile
 611         src/common/index/Makefile
 612         src/common/health/Makefile
 613         src/common/config/Makefile
 614         src/lib/Makefile
 615         src/lib/lttng-ctl/Makefile
 616         src/lib/lttng-ctl/filter/Makefile
 617         src/lib/lttng-ctl/lttng-ctl.pc
 618         src/bin/Makefile
 619         src/bin/lttng-consumerd/Makefile
 620         src/bin/lttng-sessiond/Makefile
 621         src/bin/lttng-relayd/Makefile
 622         src/bin/lttng/Makefile
 623         src/bin/lttng-crash/Makefile
 624         tests/Makefile
 625         tests/regression/Makefile
 626         tests/regression/kernel/Makefile
 627         tests/regression/tools/Makefile
 628         tests/regression/tools/streaming/Makefile
 629         tests/regression/tools/filtering/Makefile
 630         tests/regression/tools/health/Makefile
 631         tests/regression/tools/tracefile-limits/Makefile
 632         tests/regression/tools/snapshots/Makefile
 633         tests/regression/tools/live/Makefile
 634         tests/regression/tools/exclusion/Makefile
 635         tests/regression/tools/save-load/Makefile
 636         tests/regression/tools/mi/Makefile
 637         tests/regression/tools/wildcard/Makefile
 638         tests/regression/tools/crash/Makefile
 639         tests/regression/ust/Makefile
 640         tests/regression/ust/nprocesses/Makefile
 641         tests/regression/ust/high-throughput/Makefile
 642         tests/regression/ust/low-throughput/Makefile
 643         tests/regression/ust/before-after/Makefile
 644         tests/regression/ust/buffers-pid/Makefile
 645         tests/regression/ust/periodical-metadata-flush/Makefile
 646         tests/regression/ust/multi-session/Makefile
 647         tests/regression/ust/overlap/Makefile
 648         tests/regression/ust/overlap/demo/Makefile
 649         tests/regression/ust/linking/Makefile
 650         tests/regression/ust/daemon/Makefile
 651         tests/regression/ust/exit-fast/Makefile
 652         tests/regression/ust/fork/Makefile
 653         tests/regression/ust/libc-wrapper/Makefile
 654         tests/regression/ust/java-jul/Makefile
 655         tests/regression/ust/java-log4j/Makefile
 656         tests/regression/ust/python-logging/Makefile
 657         tests/regression/ust/getcpu-override/Makefile
 658         tests/regression/ust/clock-override/Makefile
 659         tests/stress/Makefile
 660         tests/unit/Makefile
 661         tests/unit/ini_config/Makefile
 662         tests/utils/Makefile
 663         tests/utils/tap/Makefile
 664         tests/utils/testapp/Makefile
 665         tests/utils/testapp/gen-ust-events/Makefile
 666         tests/utils/testapp/gen-ust-nevents/Makefile
 667         tests/utils/testapp/gen-ust-tracef/Makefile
 668 ])
 669
 670 # Inject variable into python test script
 671 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 672
 673 AC_OUTPUT
 674
 675 #
 676 # Mini-report on what will be built
 677 #
 678 AS_ECHO()
 679
 680 AS_ECHO("Version name: $version_name")
 681 AS_ECHO("$version_description")
 682
 683 AS_ECHO()
 684
 685 # Target architecture we're building for
 686 target_arch=$host_cpu
 687 [
 688 for f in $CFLAGS; do
 689         if test $f = "-m32"; then
 690                         target_arch="32-bit"
 691         elif test $f = "-m64"; then
 692                         target_arch="64-bit"
 693         fi
 694 done
 695 ]
 696 AS_ECHO_N("Target architecture: ")
 697 AS_ECHO($target_arch)
 698
 699 # kmod enabled/disabled
 700 AS_ECHO_N("libkmod support: ")
 701 AS_IF([test "x$kmod_found" = "xyes"],[
 702         AS_ECHO("Enabled")
 703 ],[
 704         AS_ECHO("Disabled")
 705 ])
 706
 707 # LTTng-UST enabled/disabled
 708 AS_ECHO_N("Lttng-UST support: ")
 709 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 710         AS_ECHO("Enabled")
 711 ],[
 712         AS_ECHO("Disabled")
 713 ])
 714
 715 # LTTng UST Java agent JUL tests enabled/disabled
 716 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
 717 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
 718         AS_ECHO("Enabled")
 719 ],[
 720         AS_ECHO("Disabled")
 721 ])
 722
 723 # LTTng UST Java agent Log4j tests enabled/disabled
 724 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
 725 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
 726         AS_ECHO("Enabled")
 727 ],[
 728         AS_ECHO("Disabled")
 729 ])
 730
 731 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
 732 AS_IF([test ! -z "$PYTHON2_AGENT"],[
 733         AS_ECHO("Enabled")
 734 ],[
 735         AS_ECHO("Disabled")
 736 ])
 737
 738 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
 739 AS_IF([test ! -z "$PYTHON3_AGENT"],[
 740         AS_ECHO("Enabled")
 741 ],[
 742         AS_ECHO("Disabled")
 743 ])
 744
 745 #Python binding enabled/disabled
 746 AS_ECHO_N("Python binding: ")
 747 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
 748         AS_ECHO("Enabled")
 749 ],[
 750         AS_ECHO("Disabled")
 751 ])
 752
 753 # Do we build only the consumerd, or everything
 754 AS_IF([test "x$consumerd_only" = "xyes"],[
 755         AS_ECHO("Only the consumerd daemon will be built.")
 756 ],[
 757         AS_ECHO("All binaries will be built.")
 758 ])
 759
 760 # Print the bindir and libdir this `make install' will install into.
 761 AS_ECHO()
 762 AS_ECHO_N("Binaries will be installed in:  ")
 763 AS_ECHO("`eval eval echo $bindir`")
 764 AS_ECHO_N("Libraries will be installed in: ")
 765 AS_ECHO("`eval eval echo $libdir`")
 766
 767 # If we build the sessiond, print the paths it will use
 768 AS_IF([test "x$consumerd_only" = "xno"],[
 769         AS_ECHO()
 770         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 771         AS_IF([test "$SESSIOND_BIN" = ""],[
 772                 AS_ECHO_N("`eval eval echo $bindir`")
 773                 AS_ECHO("/lttng-sessiond")
 774         ],[
 775                 AS_ECHO("$SESSIOND_BIN")
 776         ])
 777
 778         AS_ECHO()
 779         AS_ECHO("The sessiond daemon will look in the following directories: ")
 780         AS_ECHO_N("32-bit consumerd executable at: ")
 781         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 782                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 783                 AS_ECHO("/lttng-consumerd")
 784         ],[
 785                 AS_ECHO("$CONSUMERD32_BIN")
 786         ])
 787
 788         AS_ECHO_N("32-bit consumer libraries in:   ")
 789         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 790                 AS_ECHO("`eval eval echo $libdir`")
 791         ],[
 792                 AS_ECHO("$CONSUMERD32_LIBDIR")
 793         ])
 794
 795         AS_ECHO_N("64-bit consumerd executable at: ")
 796         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 797                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 798                 AS_ECHO("/lttng-consumerd")
 799         ],[
 800                 AS_ECHO("$CONSUMERD64_BIN")
 801         ])
 802
 803         AS_ECHO_N("64-bit consumer libraries in:   ")
 804         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 805                 AS_ECHO("`eval eval echo $libdir`")
 806         ],[
 807                 AS_ECHO("$CONSUMERD64_LIBDIR")
 808         ])
 809 ])
 810
 811 AS_ECHO()
 812