configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.10],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_MAKE_SET
  28 AC_PROG_SED
  29 AC_PATH_PROG([report_fold], [fold])
  30 LT_INIT
  31
  32 # Check for objcopy, required by the base address statedump and dynamic linker tests
  33 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  34 AS_IF([test "x$OBJCOPY" = "xno"],
  35         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  36 )
  37 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  38
  39 # check for pgrep
  40 AC_PATH_PROG([PGREP], [pgrep], [no])
  41 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  42
  43 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  44 # is not distributed in tarballs
  45 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  46 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  47
  48 # check for bison
  49 AC_PROG_YACC
  50 BISON=$YACC
  51 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  52
  53 AS_IF([test "x$have_bison" != "xyes"], [
  54   AS_IF([test "x$in_git_repo" = "xyes"], [
  55     AC_MSG_FAILURE([
  56 Bison >= 2.4 is required when building from the Git repository. You can
  57 set the YACC variable to override automatic detection.
  58     ])
  59   ], [
  60     AC_MSG_WARN([
  61 Missing Bison >= 2.4. Note that the parser files are already built in
  62 this distribution tarball, so Bison is only needed if you intend to
  63 modify their sources. You can set the YACC variable to override automatic
  64 detection.
  65     ])
  66   ])
  67 ])
  68 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  69
  70 # check for flex
  71 AC_PROG_LEX
  72 FLEX=$LEX
  73 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  74
  75 AS_IF([test "x$have_flex" != "xyes"], [
  76   AS_IF([test "x$in_git_repo" = "xyes"], [
  77     AC_MSG_FAILURE([
  78 Flex >= 2.5.35 is required when building from the Git repository. You can
  79 set the LEX variable to override automatic detection.
  80     ])
  81   ], [
  82     AC_MSG_WARN([
  83 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  84 this distribution tarball, so Flex is only needed if you intend to
  85 modify their sources. You can set the LEX variable to override automatic
  86 detection.
  87     ])
  88   ])
  89 ])
  90 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  91
  92
  93 # Checks for typedefs, structures, and compiler characteristics.
  94 AC_C_INLINE
  95 AC_TYPE_INT32_T
  96 AC_TYPE_INT64_T
  97 AC_TYPE_MODE_T
  98 AC_TYPE_OFF_T
  99 AC_TYPE_PID_T
 100 AC_TYPE_SIZE_T
 101 AC_TYPE_SSIZE_T
 102 AC_TYPE_UID_T
 103 AC_TYPE_UINT16_T
 104 AC_TYPE_UINT32_T
 105 AC_TYPE_UINT64_T
 106 AC_TYPE_UINT8_T
 107
 108 AX_C___ATTRIBUTE__
 109 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 110         [:],
 111         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 112
 113 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 114
 115 AX_LIB_SOCKET_NSL
 116
 117 LT_NO_UNDEFINED=""
 118 AS_CASE([$host_os],
 119   [cygwin*],
 120     [
 121       LT_NO_UNDEFINED="-no-undefined"
 122     ],
 123   [cygwin*|darwin*|mingw*|solaris*],
 124     [
 125       # On platforms where we only support the relayd, disable the other binaries by default
 126       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 127       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 128       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 129       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 130       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 131       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 132     ]
 133 )
 134
 135 AC_SUBST(LT_NO_UNDEFINED)
 136
 137 # Compute minor/major/patchlevel version numbers
 138 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 139 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 140 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 141
 142 AC_SUBST([MAJOR_VERSION], [$major_version])
 143 AC_SUBST([MINOR_VERSION], [$minor_version])
 144 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 145 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 146 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 147 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 148
 149 version_name="KeKriek"
 150 version_description='From Brasserie Dunham, a sour mashed golden wheat ale fermented with local sour cherries from Tougas orchards. Fresh sweet cherry notes with some tartness, lively carbonation with a dry finish.'
 151 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 152
 153 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 154 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 155
 156 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 157 AC_ARG_ENABLE(libtool-linkdep-fixup,
 158         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 159                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 160         libtool_fixup=$enableval,
 161         libtool_fixup=yes)
 162
 163 AS_IF([test "x$libtool_fixup" = "xyes"],
 164             [
 165             libtool_m4="$srcdir/m4/libtool.m4"
 166             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 167             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 168             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 169             AS_IF([test $libtool_flag_pattern_count -ne 0],
 170             [
 171                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 172                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 173                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 174                   ],
 175                   [
 176                   AC_MSG_RESULT([none])
 177                   ])
 178             ])
 179
 180 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 181
 182 AC_CHECK_HEADERS([ \
 183         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 184         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 185         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 186         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 187         sys/mount.h sys/param.h sys/time.h
 188 ])
 189
 190 # Basic functions check
 191 AC_CHECK_FUNCS([ \
 192         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 193         gethostbyname gethostname getpagesize localtime_r memchr memset \
 194         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 195         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 196         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 197         sched_getcpu sysconf sync_file_range
 198 ])
 199
 200 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 201 # add -lrt to LIBS
 202 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 203
 204 # Checks for dl.
 205 AC_CHECK_LIB([dl], [dlopen], [
 206         have_libdl=yes
 207         libdl_name=dl
 208         DL_LIBS="-ldl"
 209 ], [
 210         # libdl not found, check for dlopen in libc.
 211         AC_CHECK_LIB([c], [dlopen], [
 212                 have_libc_dl=yes
 213                 libdl_name=c
 214                 DL_LIBS="-lc"
 215         ], [
 216                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 217         ])
 218 ])
 219 AC_SUBST(DL_LIBS)
 220
 221 # Check if libdl has dlmopen support.
 222 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 223 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 224         AC_DEFINE([HAVE_DLMOPEN], [1])
 225         HAVE_DLMOPEN=1
 226 ], [
 227         HAVE_DLMOPEN=0
 228 ])
 229 AC_SUBST(HAVE_DLMOPEN)
 230
 231 # Babeltrace viewer check
 232 AC_ARG_WITH([babeltrace-bin],
 233         AS_HELP_STRING([--with-babeltrace-bin],
 234         [Location of the babeltrace viewer executable (including the filename)]),
 235         [BABELTRACE_BIN="$withval"],
 236         [BABELTRACE_BIN=''])
 237 AC_SUBST([BABELTRACE_BIN])
 238
 239 # lttv-gui
 240 AC_ARG_WITH([lttv-gui-bin],
 241         AS_HELP_STRING([--with-lttv-gui-bin],
 242    [Location of the lttv GUI viewer executable (including the filename)]),
 243    [LTTV_GUI_BIN="$withval"],
 244    [LTTV_GUI_BIN=''])
 245 AC_SUBST([LTTV_GUI_BIN])
 246
 247 AC_ARG_WITH([consumerd32-bin],
 248         AS_HELP_STRING([--with-consumerd32-bin],
 249         [Location of the 32-bit consumerd executable (including the filename)]),
 250         [CONSUMERD32_BIN="$withval"],
 251         [CONSUMERD32_BIN=''])
 252 AC_SUBST([CONSUMERD32_BIN])
 253
 254 AC_ARG_WITH([consumerd64-bin],
 255         AS_HELP_STRING([--with-consumerd64-bin],
 256         [Location of the 64-bit consumerd executable (including the filename)]),
 257         [CONSUMERD64_BIN="$withval"],
 258         [CONSUMERD64_BIN=''])
 259 AC_SUBST([CONSUMERD64_BIN])
 260
 261 AC_ARG_WITH([consumerd32-libdir],
 262         AS_HELP_STRING([--with-consumerd32-libdir],
 263         [Directory containing the 32-bit consumerd libraries]),
 264         [CONSUMERD32_LIBDIR="$withval"],
 265         [CONSUMERD32_LIBDIR=''])
 266 AC_SUBST([CONSUMERD32_LIBDIR])
 267
 268 AC_ARG_WITH([consumerd64-libdir],
 269         AS_HELP_STRING([--with-consumerd64-libdir],
 270         [Directory containing the 64-bit consumerd libraries]),
 271         [CONSUMERD64_LIBDIR="$withval"],
 272         [CONSUMERD64_LIBDIR=''])
 273 AC_SUBST([CONSUMERD64_LIBDIR])
 274
 275 AC_ARG_WITH([sessiond-bin],
 276         AS_HELP_STRING([--with-sessiond-bin],
 277         [Location of the sessiond executable (including the filename)]),
 278         [SESSIOND_BIN="$withval"],
 279         [SESSIOND_BIN=''])
 280 AC_SUBST([SESSIOND_BIN])
 281
 282 AC_ARG_WITH([lttng-system-rundir],
 283         AS_HELP_STRING([--with-lttng-system-rundir],
 284         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 285         [LTTNG_SYSTEM_RUNDIR="$withval"],
 286         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 287 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 288
 289 AC_ARG_ENABLE([test-java-agent-jul],
 290         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 291         [test_java_agent_jul=$enableval],
 292         [test_java_agent_jul=no]
 293 )
 294
 295 AC_ARG_ENABLE([test-java-agent-log4j],
 296         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 297         [test_java_agent_log4j=$enableval],
 298         [test_java_agent_log4j=no]
 299 )
 300
 301 AC_ARG_ENABLE([test-java-agent-all],
 302         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 303         [test_java_agent_jul=$enableval
 304          test_java_agent_log4j=$enableval],
 305         [:]
 306 )
 307
 308 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 309 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 310 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 311 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 312 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 313 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 314 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 315 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 316
 317 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 318         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 319         $1="$2"
 320         AC_SUBST([$1])
 321 ])
 322
 323 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 324         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 325         $1="$2"
 326         AC_SUBST([$1])
 327 ])
 328
 329 # Default values
 330 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 331 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 332 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 333 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 334 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 335 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 336 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 337 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 338 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 339 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 340 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 341 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 342 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 343 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 344 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 345 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 365 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 366 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 367 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 370 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 373 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 374 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 375 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 376 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 377
 378 # Command short descriptions
 379 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 380 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 381 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 382 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 383 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 384 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 385 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 386 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 387 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 388 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 389 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 400
 401 if test "x$prefix" = "xNONE"; then
 402         prefix=$ac_default_prefix
 403 fi
 404 CONFDIR=`eval echo $sysconfdir`
 405 AC_SUBST(CONFDIR)
 406 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 407
 408 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 409
 410 # Check libpopt
 411 PKG_CHECK_MODULES([POPT], [popt],
 412   [
 413     dnl PKG_CHECK_MODULES defines POPT_LIBS
 414   ],
 415   [
 416     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 417     AC_MSG_WARN([Finding libpopt without pkg-config.])
 418     AC_CHECK_LIB([popt],
 419       [poptGetContext],
 420       [POPT_LIBS="-lpopt"],
 421       [
 422         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 423       ]
 424     )
 425   ]
 426 )
 427 AC_SUBST(POPT_LIBS)
 428
 429 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 430
 431 # First, check for uuid in system libs
 432 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 433 AC_CHECK_FUNCS([uuid_generate],
 434   [
 435     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 436     UUID_LIBS=""
 437   ],
 438   [
 439     # Then, check if the pkg-config module is available, otherwise explicitly check
 440     # for libuuid, or uuid support in the C-library.
 441     PKG_CHECK_MODULES([UUID], [uuid],
 442       [
 443         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 444         dnl PKG_CHECK_MODULES defines UUID_LIBS
 445       ],
 446       [
 447         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 448         AC_MSG_WARN([Finding libuuid without pkg-config.])
 449         AC_CHECK_LIB([uuid], [uuid_generate],
 450           [
 451             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 452             UUID_LIBS="-luuid"
 453           ],
 454           [
 455             # libuuid not found, check for uuid_create in libc.
 456             AC_CHECK_LIB([c], [uuid_create],
 457               [
 458                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 459                 UUID_LIBS="-lc"
 460               ],
 461               [
 462                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 463               ]
 464             )
 465           ]
 466         )
 467       ]
 468     )
 469   ]
 470 )
 471 AC_SUBST(UUID_LIBS)
 472
 473 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 474
 475 # URCU library version needed or newer
 476 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 477
 478 # Check liburcu needed function calls
 479 AC_CHECK_DECL([cds_list_add], [],
 480         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 481 AC_CHECK_DECL([cds_wfcq_init], [],
 482         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 483 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 484         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 485 AC_CHECK_DECL([futex_async], [],
 486         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 487 AC_CHECK_DECL([rcu_thread_offline], [],
 488         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 489 AC_CHECK_DECL([rcu_thread_online], [],
 490         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 491 AC_CHECK_DECL([caa_likely], [],
 492         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 493 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 495
 496 #Function added in urcu 0.7.0
 497 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 498         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 499 )
 500
 501 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 502 # it can be explicitly disabled with --without-kmod
 503 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 504 AC_ARG_WITH([kmod],
 505   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 506   [],
 507   [with_kmod=check]
 508 )
 509
 510 AS_IF([test "x$with_kmod" != "xno"],
 511   [
 512     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 513       [
 514         AC_DEFINE([HAVE_KMOD], [1])
 515         KMOD_LIBS="-lkmod"
 516       ],
 517       [
 518         if test "x$with_kmod" != xcheck; then
 519           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 520         else
 521           with_kmod=no
 522         fi
 523       ]
 524     )
 525   ]
 526 )
 527 AC_SUBST(KMOD_LIBS)
 528
 529 # Check for liblttng-ust-ctl, fail if it's not found,
 530 # it can be explicitly disabled with --without-lttng-ust
 531 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 532 AC_ARG_WITH([lttng-ust],
 533   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 534   [],
 535   [with_lttng_ust=yes]
 536 )
 537
 538 AS_IF([test "x$with_lttng_ust" = "xyes"],
 539   [
 540     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 541       [
 542         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 543       ],
 544       [
 545         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 546       ],
 547       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 548     )
 549   ]
 550 )
 551 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 552
 553
 554 # Check for fmemopen
 555 AC_CHECK_LIB([c], [fmemopen],
 556 [
 557         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 558 ]
 559 )
 560
 561 # Check for open_memstream
 562 AC_CHECK_LIB([c], [open_memstream],
 563 [
 564         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 565 ]
 566 )
 567
 568 # check for libpfm
 569 AC_CHECK_LIB([pfm], [pfm_initialize],
 570              [
 571               have_libpfm=yes
 572               ])
 573 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 574
 575 AC_ARG_ENABLE([git-version],
 576               [AC_HELP_STRING([--disable-git-version],
 577                               [Do not use the git version for the build])],
 578               [have_git_version=$enableval], [have_git_version=yes]
 579 )
 580
 581 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 582         [test "x${have_git_version}" = "xyes"])
 583
 584 # For Python
 585 # SWIG version needed or newer:
 586 swig_version=2.0.0
 587
 588 AC_ARG_ENABLE([python-bindings],
 589               [AC_HELP_STRING([--enable-python-bindings],
 590                               [compile Python bindings])],
 591               [enable_python_binding=$enableval], [enable_python_binding=no])
 592
 593 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 594
 595 if test "x$enable_python_binding" = xyes; then
 596   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 597   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 598   AM_PATH_PYTHON([3.0])
 599
 600   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 601   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 602   AS_IF([test -z "$PYTHON_INCLUDE"], [
 603     AS_IF([test -z "$PYTHON_CONFIG"], [
 604       AC_PATH_PROGS([PYTHON_CONFIG],
 605                     [python$PYTHON_VERSION-config python-config],
 606                     [no],
 607                     [`dirname $PYTHON`])
 608       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 609     ])
 610     AC_MSG_CHECKING([python include flags])
 611     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 612     AC_MSG_RESULT([$PYTHON_INCLUDE])
 613   ])
 614
 615 else
 616     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 617 [if you want Python bindings.])
 618
 619 fi
 620
 621 # Epoll check. If not present, the build will fallback on poll() API
 622 AX_HAVE_EPOLL(
 623         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 624         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 625 )
 626 AX_CONFIG_FEATURE(
 627         [epoll], [This platform supports epoll(7)],
 628         [HAVE_EPOLL], [This platform supports epoll(7).],
 629         [enable_epoll="yes"], [enable_epoll="no"]
 630 )
 631 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 632
 633 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 634 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 635
 636 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 637         AX_JAVA_OPTIONS
 638         AX_PROG_JAVAC
 639         AX_PROG_JAVA
 640         AX_PROG_JAR
 641
 642         AX_CHECK_CLASSPATH
 643
 644         # Check for Java UST agent common class first
 645         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 646         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 647                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 648         fi
 649
 650         if test "x$test_java_agent_jul" = "xyes"; then
 651                 # Check for JUL agent class
 652                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 653                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 654                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 655                 fi
 656         fi
 657
 658         if test "x$test_java_agent_log4j" = "xyes"; then
 659                 # Check for Log4j agent class
 660                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 661                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 662                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 663                 fi
 664
 665                 # Check for Log4j class
 666                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 667                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 668                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 669                 fi
 670         fi
 671 fi
 672
 673 # enable building man pages (user's intention)
 674 AC_ARG_ENABLE(
 675         man-pages,
 676         AS_HELP_STRING(
 677                 [--disable-man-pages],
 678                 [Do not build and install man pages (already built in a distributed tarball)]
 679         ),
 680         [man_pages_opt=$enableval],
 681         [man_pages_opt=yes]
 682 )
 683
 684 # check for asciidoc and xmlto if we enabled building the man pages
 685 have_asciidoc_xmlto=no
 686 warn_prebuilt_man_pages=no
 687
 688 AS_IF([test "x$man_pages_opt" = "xyes"], [
 689         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 690         AC_PATH_PROG([XMLTO], [xmlto], [no])
 691
 692         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 693                 AS_IF([test "x$in_git_repo" = "xyes"], [
 694                         # this is an error because we're in the Git repo, which
 695                         # means the man pages are not already generated for us,
 696                         # thus asciidoc/xmlto are required because we were asked
 697                         # to build the man pages
 698                         AC_MSG_ERROR([
 699 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 700 --disable-man-pages to disable building the man pages, in which case
 701 they will not be installed.
 702                         ])
 703                 ], [
 704                         # only warn here: since we're in the tarball, the man
 705                         # pages should already be generated at this point, thus
 706                         # asciidoc/xmlto are not strictly required
 707                         warn_prebuilt_man_pages=yes
 708                 ])
 709         ], [
 710                 have_asciidoc_xmlto=yes
 711         ])
 712 ])
 713
 714 # export man page build condition: build the man pages if the user
 715 # asked for it, and if the tools are available
 716 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 717 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 718
 719 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 720
 721 # embedded --help message
 722 AC_ARG_ENABLE(
 723         [embedded-help],
 724         AS_HELP_STRING(
 725                 [--enable-embedded-help],
 726                 [Embed the --help messages in the executable files]
 727         ),
 728         [embedded_help=$enableval],
 729         [embedded_help=no]
 730 )
 731 AS_IF([test "x$embedded_help" = "xyes"], [
 732         AS_IF([test "x$man_pages_opt" = "xno"], [
 733                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 734         ])
 735         AC_PATH_PROG([man_prog_path], [man], [no])
 736         AS_IF([test "x$man_prog_path" = "xno"], [
 737                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 738         ])
 739         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 740         AC_SUBST([MANPROG], [$man_prog_path])
 741 ])
 742 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 743
 744 # Python agent test
 745 UST_PYTHON_AGENT="lttngust"
 746
 747 AC_ARG_ENABLE(test-python2-agent,
 748         AS_HELP_STRING([--enable-test-python2-agent],
 749                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 750         ),[:],[test_python2_agent_autodetect=yes]
 751 )
 752
 753 AC_ARG_ENABLE(test-python3-agent,
 754         AS_HELP_STRING([--enable-test-python3-agent],
 755                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 756         ),[:],[test_python3_agent_autodetect=yes]
 757 )
 758
 759 AC_ARG_ENABLE(test-python-agent-all,
 760         AS_HELP_STRING([--enable-test-python-agent-all],
 761                 [enable test for all python{2/3} agent.]
 762         ),
 763 )
 764
 765 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 766        unset test_python2_agent_autodetect
 767        unset test_python3_agent_autodetect
 768 ])
 769
 770 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 771        enable_test_python2_agent=yes
 772        enable_test_python3_agent=yes
 773 ])
 774
 775 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 776        enable_test_python2_agent=no
 777        enable_test_python3_agent=no
 778 ])
 779
 780
 781 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 782         AS_IF([test -z "$PYTHON2"], [
 783                         PYTHON2=python2
 784                 ], [
 785                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 786         ])
 787
 788         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 789         AS_IF([test -z "$PYTHON2_BIN"], [
 790                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 791                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 792                 ])
 793         ], [
 794                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 795                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 796                         PYTHON2_AGENT=$PYTHON2_BIN
 797                         AC_MSG_RESULT([yes])
 798                         RUN_PYTHON_AGENT_TEST=yes
 799                 ], [
 800                         AC_MSG_RESULT([no])
 801                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 802                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 803                         ])
 804                 ])
 805
 806         ])
 807
 808 ])
 809
 810 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 811         AS_IF([test -z "$PYTHON3"], [
 812                 PYTHON3=python3
 813         ], [
 814                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 815         ])
 816
 817         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 818         AS_IF([test -z "$PYTHON3_BIN"], [
 819                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 820                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 821                 ])
 822         ], [
 823                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 824                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 825                         PYTHON3_AGENT=$PYTHON3_BIN
 826                         AC_MSG_RESULT([yes])
 827                         RUN_PYTHON_AGENT_TEST=yes
 828                 ], [
 829                         AC_MSG_RESULT([no])
 830                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 831                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 832                         ])
 833                 ])
 834
 835         ])
 836 ])
 837 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 838 AC_SUBST([PYTHON2_AGENT])
 839 AC_SUBST([PYTHON3_AGENT])
 840
 841 # Arguments for binaries build exclusion
 842 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 843 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 844               [Disable the build of lttng-consumerd binaries]))
 845 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 846 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 847               [Disable the build of lttng-relayd binaries]))
 848 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 849               [Disable the build of lttng-sessiond binaries]))
 850 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 851               [Disable the build of the extra components]))
 852
 853
 854 # Always build libconfig since it a dependency of libcommon
 855 build_lib_config=yes
 856
 857 build_lib_compat=no
 858 build_lib_consumer=no
 859 build_lib_hashtable=no
 860 build_lib_health=no
 861 build_lib_index=no
 862 build_lib_kernel_consumer=no
 863 build_lib_kernel_ctl=no
 864 build_lib_lttng_ctl=no
 865 build_lib_relayd=no
 866 build_lib_sessiond_comm=no
 867 build_lib_testpoint=no
 868 build_lib_ust_consumer=no
 869
 870 # There is an overlap for enabled dependencies, but this makes everything
 871 # simpler. libcommon and libconfig are always compiled so they are not repeated
 872 # here.
 873
 874 # Enable binary dependencies.
 875 AS_IF([test x$enable_bin_lttng != xno],
 876       [
 877        build_lib_lttng_ctl=yes
 878       ]
 879 )
 880
 881 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 882       [
 883        build_lib_consumer=yes
 884        build_lib_sessiond_comm=yes
 885        build_lib_index=yes
 886        build_lib_health=yes
 887        build_lib_testpoint=yes
 888       ]
 889 )
 890
 891 AS_IF([test x$enable_bin_lttng_crash != xno],
 892       # Do nothing since libconfig and libcommon are built by default.
 893       []
 894 )
 895
 896 AS_IF([test x$enable_bin_lttng_relayd != xno],
 897       [
 898        build_lib_lttng_ctl=yes
 899        build_lib_sessiond_comm=yes
 900        build_lib_hashtable=yes
 901        build_lib_compat=yes
 902        build_lib_index=yes
 903        build_lib_health=yes
 904        build_lib_testpoint=yes
 905       ]
 906 )
 907 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 908       [
 909        build_lib_lttng_ctl=yes
 910        build_lib_sessiond_comm=yes
 911        build_lib_kernel_ctl=yes
 912        build_lib_hashtable=yes
 913        build_lib_compat=yes
 914        build_lib_relayd=yes
 915        build_lib_testpoint=yes
 916        build_lib_health=yes
 917        build_lib_health=yes
 918       ]
 919 )
 920
 921 # Libraries dependencies enabling
 922 AS_IF([test x$build_lib_lttng_ctl = xyes],
 923       [
 924        build_lib_sessiond_comm=yes
 925        build_lib_hashtable=yes
 926       ]
 927 )
 928
 929 AS_IF([test x$build_lib_consumer = xyes],
 930       [
 931        build_lib_sessiond_comm=yes
 932        build_lib_kernel_consumer=yes
 933        build_lib_hashtable=yes
 934        build_lib_compat=yes
 935        build_lib_relayd=yes
 936        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 937       ]
 938 )
 939
 940 AS_IF([test x$build_lib_kernel_consumer = xyes],
 941       [
 942        build_lib_kernel_ctl=yes
 943        build_lib_relayd=yes
 944       ]
 945 )
 946
 947 AS_IF([test x$build_lib_relayd = xyes],
 948       [
 949        build_lib_sessiond_comm=yes
 950       ]
 951 )
 952
 953
 954 # Export binaries build conditions.
 955 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 956 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 957 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 958 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 959 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 960
 961 # Export the tests and extras build conditions.
 962 AS_IF([\
 963 test "x$enable_bin_lttng" != "xno" && \
 964 test "x$enable_bin_lttng_consumerd" != "xno" && \
 965 test "x$enable_bin_lttng_crash" != "xno" && \
 966 test "x$enable_bin_lttng_relayd" != "xno" && \
 967 test "x$enable_bin_lttng_sessiond" != "xno"],
 968 [build_tests=yes],
 969 [build_tests=no]
 970 )
 971
 972 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 973 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 974
 975 # Export libraries build conditions.
 976 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 977 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 978 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 979 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 980 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 981 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 982 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 983 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 984 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 985 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 986 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 987 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 988 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 989
 990 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
 991 AC_SUBST(AM_CFLAGS)
 992
 993 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
 994 AC_SUBST(AM_CPPFLAGS)
 995
 996 lttngincludedir="${includedir}/lttng"
 997 AC_SUBST(lttngincludedir)
 998
 999 lttngactionincludedir="${includedir}/lttng/action"
1000 AC_SUBST(lttngactionincludedir)
1001
1002 lttngconditionincludedir="${includedir}/lttng/condition"
1003 AC_SUBST(lttngconditionincludedir)
1004
1005 lttngnotificationincludedir="${includedir}/lttng/notification"
1006 AC_SUBST(lttngnotificationincludedir)
1007
1008 lttngtriggerincludedir="${includedir}/lttng/trigger"
1009 AC_SUBST(lttngtriggerincludedir)
1010
1011 lttnglibexecdir="${libdir}/lttng/libexec"
1012 AC_SUBST(lttnglibexecdir)
1013
1014 AC_CONFIG_FILES([
1015         Makefile
1016         doc/Makefile
1017         doc/man/Makefile
1018         doc/man/asciidoc-attrs.conf
1019         include/Makefile
1020         extras/Makefile
1021         extras/bindings/Makefile
1022         extras/bindings/swig/Makefile
1023         extras/bindings/swig/python/Makefile
1024         extras/core-handler/Makefile
1025         src/Makefile
1026         src/common/Makefile
1027         src/common/kernel-ctl/Makefile
1028         src/common/kernel-consumer/Makefile
1029         src/common/consumer/Makefile
1030         src/common/ust-consumer/Makefile
1031         src/common/hashtable/Makefile
1032         src/common/sessiond-comm/Makefile
1033         src/common/compat/Makefile
1034         src/common/relayd/Makefile
1035         src/common/testpoint/Makefile
1036         src/common/index/Makefile
1037         src/common/health/Makefile
1038         src/common/config/Makefile
1039         src/common/string-utils/Makefile
1040         src/lib/Makefile
1041         src/lib/lttng-ctl/Makefile
1042         src/lib/lttng-ctl/filter/Makefile
1043         src/lib/lttng-ctl/lttng-ctl.pc
1044         src/bin/Makefile
1045         src/bin/lttng-consumerd/Makefile
1046         src/bin/lttng-sessiond/Makefile
1047         src/bin/lttng-relayd/Makefile
1048         src/bin/lttng/Makefile
1049         src/bin/lttng-crash/Makefile
1050         tests/Makefile
1051         tests/destructive/Makefile
1052         tests/regression/Makefile
1053         tests/regression/kernel/Makefile
1054         tests/regression/tools/Makefile
1055         tests/regression/tools/streaming/Makefile
1056         tests/regression/tools/filtering/Makefile
1057         tests/regression/tools/health/Makefile
1058         tests/regression/tools/tracefile-limits/Makefile
1059         tests/regression/tools/snapshots/Makefile
1060         tests/regression/tools/live/Makefile
1061         tests/regression/tools/exclusion/Makefile
1062         tests/regression/tools/save-load/Makefile
1063         tests/regression/tools/save-load/configuration/Makefile
1064         tests/regression/tools/mi/Makefile
1065         tests/regression/tools/wildcard/Makefile
1066         tests/regression/tools/crash/Makefile
1067         tests/regression/tools/regen-metadata/Makefile
1068         tests/regression/tools/regen-statedump/Makefile
1069         tests/regression/tools/notification/Makefile
1070         tests/regression/ust/Makefile
1071         tests/regression/ust/nprocesses/Makefile
1072         tests/regression/ust/high-throughput/Makefile
1073         tests/regression/ust/low-throughput/Makefile
1074         tests/regression/ust/before-after/Makefile
1075         tests/regression/ust/buffers-pid/Makefile
1076         tests/regression/ust/periodical-metadata-flush/Makefile
1077         tests/regression/ust/multi-session/Makefile
1078         tests/regression/ust/overlap/Makefile
1079         tests/regression/ust/overlap/demo/Makefile
1080         tests/regression/ust/linking/Makefile
1081         tests/regression/ust/daemon/Makefile
1082         tests/regression/ust/exit-fast/Makefile
1083         tests/regression/ust/fork/Makefile
1084         tests/regression/ust/libc-wrapper/Makefile
1085         tests/regression/ust/baddr-statedump/Makefile
1086         tests/regression/ust/ust-dl/Makefile
1087         tests/regression/ust/java-jul/Makefile
1088         tests/regression/ust/java-log4j/Makefile
1089         tests/regression/ust/python-logging/Makefile
1090         tests/regression/ust/getcpu-override/Makefile
1091         tests/regression/ust/clock-override/Makefile
1092         tests/regression/ust/type-declarations/Makefile
1093         tests/regression/ust/rotation-destroy-flush/Makefile
1094         tests/regression/ust/blocking/Makefile
1095         tests/stress/Makefile
1096         tests/unit/Makefile
1097         tests/unit/ini_config/Makefile
1098         tests/perf/Makefile
1099         tests/utils/Makefile
1100         tests/utils/tap/Makefile
1101         tests/utils/testapp/Makefile
1102         tests/utils/testapp/gen-ust-events/Makefile
1103         tests/utils/testapp/gen-ust-nevents/Makefile
1104         tests/utils/testapp/gen-ust-nevents-str/Makefile
1105         tests/utils/testapp/gen-ust-tracef/Makefile
1106 ])
1107
1108 # Inject variable into python test script.
1109 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1110 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1111 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1112 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1113
1114 AC_OUTPUT
1115
1116 #
1117 # Mini-report on what will be built.
1118 #
1119
1120 PPRINT_INIT
1121 PPRINT_SET_INDENT(1)
1122 PPRINT_SET_TS(38)
1123
1124 AS_ECHO
1125 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1126 AS_ECHO
1127
1128 AS_IF([test -n "$report_fold"], [
1129         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1130 ], [
1131         AS_ECHO("$version_description")
1132 ])
1133
1134 AS_ECHO
1135 PPRINT_SUBTITLE([Features])
1136
1137 # Target architecture we're building for.
1138 target_arch=$host_cpu
1139 [
1140 for f in $CFLAGS; do
1141         if test $f = "-m32"; then
1142                         target_arch="32-bit"
1143         elif test $f = "-m64"; then
1144                         target_arch="64-bit"
1145         fi
1146 done
1147 ]
1148 PPRINT_PROP_STRING([Target architecture], $target_arch)
1149
1150 # kmod enabled/disabled
1151 test "x$with_kmod" != "xno" && value=1 || value=0
1152 PPRINT_PROP_BOOL([libkmod support], $value)
1153
1154 # LTTng-UST enabled/disabled
1155 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1156 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1157
1158 AS_ECHO
1159 PPRINT_SUBTITLE([Binaries])
1160
1161 # List binaries to be built
1162 test x$enable_bin_lttng != xno && value=1 || value=0
1163 PPRINT_PROP_BOOL([lttng], $value)
1164
1165 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1166 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1167
1168 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1169 PPRINT_PROP_BOOL([lttng-crash], $value)
1170
1171 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1172 PPRINT_PROP_BOOL([lttng-relayd], $value)
1173
1174 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1175 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1176
1177 # Extras
1178 test x$enable_extras != xno && value=1 || value=0
1179 AS_ECHO
1180 PPRINT_SET_INDENT(0)
1181 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1182 PPRINT_SET_INDENT(1)
1183
1184 AS_ECHO
1185 PPRINT_SUBTITLE([Tests])
1186
1187 # Print clear message that tests won't be built
1188 AS_IF([test "x$build_tests" = "xno"],[
1189         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1190 ])
1191
1192 # LTTng UST Java agent JUL tests enabled/disabled
1193 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1194 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1195
1196 # LTTng UST Java agent Log4j tests enabled/disabled
1197 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1198 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1199
1200 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1201 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1202
1203 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1204 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1205
1206 #Python binding enabled/disabled
1207 test "x$enable_python_binding" = xyes && value=1 || value=0
1208 AS_ECHO
1209 PPRINT_SET_INDENT(0)
1210 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1211
1212 # man pages build enabled/disabled
1213 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1214
1215 AS_IF([test "x$man_pages_opt" != "xno"], [
1216         AS_IF([test "x$in_git_repo" = "xyes"], [
1217                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1218         ], [
1219                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1220                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1221                 ], [
1222                         PPRINT_PROP_STRING([build_man_pages_msg],
1223                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1224                                 $PPRINT_COLOR_SUBTITLE)
1225                 ])
1226         ])
1227 ], [
1228         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1229 ])
1230
1231 m4_popdef([build_man_pages_msg])
1232
1233 test "x$embedded_help" = xyes && value=1 || value=0
1234 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1235
1236 PPRINT_SET_INDENT(1)
1237
1238 report_bindir="`eval eval echo $bindir`"
1239 report_libdir="`eval eval echo $libdir`"
1240
1241 # Print the bindir and libdir this `make install' will install into.
1242 AS_ECHO
1243 PPRINT_SUBTITLE([Install directories])
1244 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1245 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1246
1247 AS_ECHO
1248 PPRINT_SUBTITLE([Search directories])
1249
1250 # If we build the sessiond, print the paths it will use
1251 AS_IF([test "$SESSIOND_BIN" = ""],[
1252         path="$report_bindir/lttng-sessiond"
1253 ],[
1254         path="$SESSIOND_BIN"
1255 ])
1256 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1257
1258 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1259         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1260 ],[
1261         path="$CONSUMERD32_BIN"
1262 ])
1263 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1264
1265 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1266         path="`eval eval echo $libdir`"
1267 ],[
1268         path="$CONSUMERD32_LIBDIR"
1269 ])
1270 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1271
1272 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1273         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1274 ],[
1275         path="$CONSUMERD64_BIN"
1276 ])
1277 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1278
1279 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1280         path="`eval eval echo $libdir`"
1281 ],[
1282         path="$CONSUMERD64_LIBDIR"
1283 ])
1284 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1285 PPRINT_SET_INDENT(0)
1286
1287 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1288         AS_ECHO
1289         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1290
1291 Note that the man pages are already built in this distribution tarball,
1292 therefore asciidoc and xmlto are only needed if you intend to modify
1293 their sources.
1294
1295 Also note that the installed man pages will contain the project's
1296 default command-line option and environment variable values.
1297
1298 Use --disable-man-pages to completely disable building and installing
1299 the man pages.])
1300 ])