configure.ac

   1 AC_INIT([lttng-tools],[2.2.0-rc1],[dgoulet@efficios.com],[],[http://lttng.org])
   2 AC_CONFIG_AUX_DIR([config])
   3 AC_CANONICAL_TARGET
   4 AC_CANONICAL_HOST
   5 AC_CONFIG_MACRO_DIR([config])
   6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 version_name="Cuda"
  10 version_description="Brewed at the Benelux microbrewery, this IPA has huge floral, citric and resinous hop aroma, simply an amazing nose. The flavor is very fresh with a light caramel malting touch completing a strong body. Huge amounts of hops, lots of grapefruit, lemon and oranges. This is an outstanding IPA!"
  11
  12 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  13 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  14
  15 AC_CONFIG_HEADERS([include/config.h])
  16
  17 AC_PROG_GREP
  18 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  19 AC_ARG_ENABLE(libtool-linkdep-fixup,
  20         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  21                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  22         libtool_fixup=$enableval,
  23         libtool_fixup=yes)
  24
  25 AS_IF([test "x$libtool_fixup" = "xyes"],
  26             [
  27             libtool_m4="$srcdir/config/libtool.m4"
  28             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  29             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  30             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  31             AS_IF([test $libtool_flag_pattern_count -ne 0],
  32             [
  33                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  34                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  35                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  36                   ],
  37                   [
  38                   AC_MSG_RESULT([none])
  39                   ])
  40             ])
  41
  42 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  43
  44 AC_CHECK_HEADERS([ \
  45         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  46         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  47         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  48 ])
  49
  50 # Babeltrace viewer check
  51 AC_ARG_WITH([babeltrace-bin],
  52         AS_HELP_STRING([--with-babeltrace-bin],
  53         [Location of the babeltrace viewer executable (including the filename)]),
  54         [BABELTRACE_BIN="$withval"],
  55         [BABELTRACE_BIN=''])
  56 AC_SUBST([BABELTRACE_BIN])
  57
  58 # lttv-gui
  59 AC_ARG_WITH([lttv-gui-bin],
  60         AS_HELP_STRING([--with-lttv-gui-bin],
  61    [Location of the lttv GUI viewer executable (including the filename)]),
  62    [LTTV_GUI_BIN="$withval"],
  63    [LTTV_GUI_BIN=''])
  64 AC_SUBST([LTTV_GUI_BIN])
  65
  66 AC_ARG_WITH([consumerd32-bin],
  67         AS_HELP_STRING([--with-consumerd32-bin],
  68         [Location of the 32-bit consumerd executable (including the filename)]),
  69         [CONSUMERD32_BIN="$withval"],
  70         [CONSUMERD32_BIN=''])
  71 AC_SUBST([CONSUMERD32_BIN])
  72
  73 AC_ARG_WITH([consumerd64-bin],
  74         AS_HELP_STRING([--with-consumerd64-bin],
  75         [Location of the 64-bit consumerd executable (including the filename)]),
  76         [CONSUMERD64_BIN="$withval"],
  77         [CONSUMERD64_BIN=''])
  78 AC_SUBST([CONSUMERD64_BIN])
  79
  80 AC_ARG_WITH([consumerd32-libdir],
  81         AS_HELP_STRING([--with-consumerd32-libdir],
  82         [Directory containing the 32-bit consumerd libraries]),
  83         [CONSUMERD32_LIBDIR="$withval"],
  84         [CONSUMERD32_LIBDIR=''])
  85 AC_SUBST([CONSUMERD32_LIBDIR])
  86
  87 AC_ARG_WITH([consumerd64-libdir],
  88         AS_HELP_STRING([--with-consumerd64-libdir],
  89         [Directory containing the 64-bit consumerd libraries]),
  90         [CONSUMERD64_LIBDIR="$withval"],
  91         [CONSUMERD64_LIBDIR=''])
  92 AC_SUBST([CONSUMERD64_LIBDIR])
  93
  94 AC_ARG_WITH([sessiond-bin],
  95         AS_HELP_STRING([--with-sessiond-bin],
  96         [Location of the sessiond executable (including the filename)]),
  97         [SESSIOND_BIN="$withval"],
  98         [SESSIOND_BIN=''])
  99 AC_SUBST([SESSIOND_BIN])
 100
 101 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 102 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 103 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 104 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 105 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 106 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 107 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 108
 109 # Check for pthread
 110 AC_CHECK_LIB([pthread], [pthread_create], [],
 111         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 112 )
 113
 114 # Check libpopt
 115 AC_CHECK_LIB([popt], [poptGetContext], [],
 116         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 117 )
 118
 119 # Check for libuuid
 120 AC_CHECK_LIB([uuid], [uuid_generate],
 121 [
 122         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 123         have_libuuid=yes
 124 ],
 125 [
 126         # libuuid not found, check for uuid_create in libc.
 127         AC_CHECK_LIB([c], [uuid_create],
 128         [
 129                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 130                 have_libc_uuid=yes
 131         ],
 132         [
 133                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 134         ])
 135 ]
 136 )
 137 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 138 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 139
 140 # URCU library version needed or newer
 141 liburcu_version=">= 0.7.2"
 142
 143 # Check liburcu needed function calls
 144 AC_CHECK_DECL([cds_list_add], [],
 145         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 146 )
 147 AC_CHECK_DECL([cds_wfq_init], [],
 148         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 149 )
 150 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
 151     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 152 )
 153 AC_CHECK_DECL([futex_async], [],
 154         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 155 )
 156 AC_CHECK_DECL([rcu_thread_offline], [],
 157         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 158 )
 159 AC_CHECK_DECL([rcu_thread_online], [],
 160         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 161 )
 162 AC_CHECK_DECL([caa_likely], [],
 163         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 164 )
 165
 166 # Check liblttng-ust-ctl library
 167 AC_ARG_ENABLE(lttng-ust,
 168         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 169         lttng_ust_support=$enableval, lttng_ust_support=yes)
 170
 171 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 172         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_set_filter],
 173                 [
 174                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 175                         lttng_ust_ctl_found=yes
 176                 ],
 177                 [AC_MSG_ERROR([Cannot find LTTng-UST 2.1.x. Use [LDFLAGS]=-Ldir to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 178                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 179         )
 180 ])
 181 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 182 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 183
 184 # check for dlopen
 185 AC_CHECK_LIB([dl], [dlopen],
 186 [
 187         have_libdl=yes
 188 ],
 189 [
 190         #libdl not found, check for dlopen in libc.
 191         AC_CHECK_LIB([c], [dlopen],
 192         [
 193                 have_libc_dl=yes
 194         ],
 195         [
 196                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 197         ])
 198 ])
 199 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 200 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 201
 202 # Check for fmemopen
 203 AC_CHECK_LIB([c], [fmemopen],
 204 [
 205         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 206 ]
 207 )
 208
 209 # Check for open_memstream
 210 AC_CHECK_LIB([c], [open_memstream],
 211 [
 212         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 213 ]
 214 )
 215
 216 # For Python
 217 # SWIG version needed or newer:
 218 swig_version=2.0.0
 219
 220 AC_ARG_ENABLE([python-bindings],
 221               [AC_HELP_STRING([--enable-python-bindings],
 222                               [compile Python bindings])],
 223               [enable_python=yes], [enable_python=no])
 224
 225 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 226
 227 if test "x${enable_python:-yes}" = xyes; then
 228   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 229   AM_PATH_PYTHON
 230
 231   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 232   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 233   AS_IF([test -z "$PYTHON_INCLUDE"], [
 234     AS_IF([test -z "$PYTHON_CONFIG"], [
 235       AC_PATH_PROGS([PYTHON_CONFIG],
 236                     [python$PYTHON_VERSION-config python-config],
 237                     [no],
 238                     [`dirname $PYTHON`])
 239       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 240     ])
 241     AC_MSG_CHECKING([python include flags])
 242     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 243     AC_MSG_RESULT([$PYTHON_INCLUDE])
 244   ])
 245
 246 else
 247     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 248 [if you want Python bindings.])
 249
 250 fi
 251
 252 # Option to only build the consumer daemon and its libraries
 253 AC_ARG_WITH([consumerd-only],
 254         AS_HELP_STRING([--with-consumerd-only],[Only build the consumer daemon [default=no]]),
 255         [consumerd_only=$withval],
 256         [consumerd_only=no])
 257 AM_CONDITIONAL([BUILD_CONSUMERD_ONLY], [test "x$consumerd_only" = "xyes"])
 258
 259 # Epoll check. If not present, the build will fallback on poll() API
 260 AX_HAVE_EPOLL(
 261         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 262         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 263 )
 264 AX_CONFIG_FEATURE(
 265         [epoll], [This platform supports epoll(7)],
 266         [HAVE_EPOLL], [This platform supports epoll(7).],
 267         [enable_epoll="yes"], [enable_epoll="no"]
 268 )
 269 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 270
 271 AC_SYS_LARGEFILE
 272 AC_PROG_CC
 273 LT_INIT
 274 AC_PROG_YACC
 275 AC_PROG_LEX
 276
 277 AC_DEFUN([AC_PROG_BISON], [AC_CHECK_PROGS(BISON, bison, bison)])
 278
 279 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 280
 281 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 282
 283 lttngincludedir="${includedir}/lttng"
 284
 285 AC_SUBST(lttngincludedir)
 286 AC_SUBST(DEFAULT_INCLUDES)
 287
 288 lttnglibexecdir="${libdir}/lttng/libexec"
 289 AC_SUBST(lttnglibexecdir)
 290
 291 AC_CONFIG_FILES([
 292         Makefile
 293         doc/Makefile
 294         doc/man/Makefile
 295         include/Makefile
 296         extras/Makefile
 297         extras/bindings/Makefile
 298         extras/bindings/swig/Makefile
 299         extras/bindings/swig/python/Makefile
 300         src/Makefile
 301         src/common/Makefile
 302         src/common/kernel-ctl/Makefile
 303         src/common/kernel-consumer/Makefile
 304         src/common/ust-consumer/Makefile
 305         src/common/hashtable/Makefile
 306         src/common/sessiond-comm/Makefile
 307         src/common/compat/Makefile
 308         src/common/relayd/Makefile
 309         src/common/testpoint/Makefile
 310         src/lib/Makefile
 311         src/lib/lttng-ctl/Makefile
 312         src/lib/lttng-ctl/filter/Makefile
 313         src/lib/lttng-ctl/lttng-ctl.pc
 314         src/bin/Makefile
 315         src/bin/lttng-consumerd/Makefile
 316         src/bin/lttng-sessiond/Makefile
 317         src/bin/lttng-relayd/Makefile
 318         src/bin/lttng/Makefile
 319         tests/Makefile
 320         tests/regression/Makefile
 321         tests/regression/kernel/Makefile
 322         tests/regression/tools/Makefile
 323         tests/regression/tools/streaming/Makefile
 324         tests/regression/tools/filtering/Makefile
 325         tests/regression/tools/health/Makefile
 326         tests/regression/ust/Makefile
 327         tests/regression/ust/nprocesses/Makefile
 328         tests/regression/ust/high-throughput/Makefile
 329         tests/regression/ust/low-throughput/Makefile
 330         tests/regression/ust/before-after/Makefile
 331         tests/regression/ust/buffers-uid/Makefile
 332         tests/regression/ust/periodical-metadata-flush/Makefile
 333         tests/regression/ust/multi-session/Makefile
 334         tests/regression/ust/overlap/Makefile
 335         tests/regression/ust/overlap/demo/Makefile
 336         tests/regression/ust/linking/Makefile
 337         tests/regression/ust/daemon/Makefile
 338         tests/regression/ust/exit-fast/Makefile
 339         tests/regression/ust/fork/Makefile
 340         tests/regression/ust/libc-wrapper/Makefile
 341         tests/unit/Makefile
 342         tests/utils/Makefile
 343         tests/utils/tap/Makefile
 344 ])
 345
 346 AC_OUTPUT
 347
 348 #
 349 # Mini-report on what will be built
 350 #
 351 AS_ECHO()
 352
 353 AS_ECHO("Version name: $version_name")
 354 AS_ECHO("$version_description")
 355
 356 AS_ECHO()
 357
 358 # Target architecture we're building for
 359 target_arch=$host_cpu
 360 [
 361 for f in $CFLAGS; do
 362         if test $f = "-m32"; then
 363                         target_arch="32-bit"
 364         elif test $f = "-m64"; then
 365                         target_arch="64-bit"
 366         fi
 367 done
 368 ]
 369 AS_ECHO_N("Target architecture: ")
 370 AS_ECHO($target_arch)
 371
 372 # LTTng-UST enabled/disabled
 373 AS_ECHO_N("Lttng-UST support: ")
 374 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 375         AS_ECHO("Enabled")
 376 ],[
 377         AS_ECHO("Disabled")
 378 ])
 379
 380 #Python binding enabled/disabled
 381 AS_ECHO_N("Python binding: ")
 382 AS_IF([test "x${enable_python:-yes}" = xyes], [
 383         AS_ECHO("Enabled")
 384 ],[
 385         AS_ECHO("Disabled")
 386 ])
 387
 388 # Do we build only the consumerd, or everything
 389 AS_IF([test "x$consumerd_only" = "xyes"],[
 390         AS_ECHO("Only the consumerd daemon will be built.")
 391 ],[
 392         AS_ECHO("All binaries will be built.")
 393 ])
 394
 395 # Print the bindir and libdir this `make install' will install into.
 396 AS_ECHO()
 397 AS_ECHO_N("Binaries will be installed in:  ")
 398 AS_ECHO("`eval eval echo $bindir`")
 399 AS_ECHO_N("Libraries will be installed in: ")
 400 AS_ECHO("`eval eval echo $libdir`")
 401
 402 # If we build the sessiond, print the paths it will use
 403 AS_IF([test "x$consumerd_only" = "xno"],[
 404         AS_ECHO()
 405         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 406         AS_IF([test "$SESSIOND_BIN" = ""],[
 407                 AS_ECHO_N("`eval eval echo $bindir`")
 408                 AS_ECHO("/lttng-sessiond")
 409         ],[
 410                 AS_ECHO("$SESSIOND_BIN")
 411         ])
 412
 413         AS_ECHO()
 414         AS_ECHO("The sessiond daemon will look in the following directories: ")
 415         AS_ECHO_N("32-bit consumerd executable at: ")
 416         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 417                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 418                 AS_ECHO("/lttng-consumerd")
 419         ],[
 420                 AS_ECHO("$CONSUMERD32_BIN")
 421         ])
 422
 423         AS_ECHO_N("32-bit consumer libraries in:   ")
 424         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 425                 AS_ECHO("`eval eval echo $libdir`")
 426         ],[
 427                 AS_ECHO("$CONSUMERD32_LIBDIR")
 428         ])
 429
 430         AS_ECHO_N("64-bit consumerd executable at: ")
 431         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 432                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 433                 AS_ECHO("/lttng-consumerd")
 434         ],[
 435                 AS_ECHO("$CONSUMERD64_BIN")
 436         ])
 437
 438         AS_ECHO_N("64-bit consumer libraries in:   ")
 439         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 440                 AS_ECHO("`eval eval echo $libdir`")
 441         ],[
 442                 AS_ECHO("$CONSUMERD64_LIBDIR")
 443         ])
 444 ])
 445
 446 AS_ECHO()
 447