configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [ppc], [ARCHTYPE="ppc"],
  73         [s390], [ARCHTYPE="s390"],
  74         [s390x], [ARCHTYPE="s390"],
  75         [sparc64], [ARCHTYPE="sparc64"],
  76         [alpha*], [ARCHTYPE="alpha"],
  77         [ia64], [ARCHTYPE="gcc"],
  78         [arm*], [ARCHTYPE="arm"],
  79         [mips*], [ARCHTYPE="mips"],
  80         [ARCHTYPE="unknown"]
  81 )
  82
  83 AC_SUBST(ARCHTYPE)
  84 AC_SUBST(SUBARCHTYPE)
  85
  86 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  87 ARCHSRC=urcu/arch/$ARCHTYPE.h
  88
  89 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  90         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  91 ])
  92
  93 AS_IF([test "$host_cpu" = "armv7l"],[
  94         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  95 ])
  96
  97 # ARM-specific checks
  98 AS_IF([test "x$ARCHTYPE" = "xarm"],[
  99         AC_MSG_CHECKING([for dmb instruction])
 100         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 101                                 int main()
 102                                 {
 103                                         asm volatile("dmb":::"memory");
 104                                         return 0;
 105                                 }
 106                 ]])
 107         ],[
 108                 AC_MSG_RESULT([yes])
 109                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 110         ],[
 111                 AC_MSG_RESULT([no])
 112         ])
 113 ])
 114
 115 # x86-specific checks
 116 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 117         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 118         #For now, using lock; addl compatibility mode even for i686, because the
 119         #Pentium III is seen as a i686, but lacks mfence instruction.
 120         #Only using fence for x86_64.
 121         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 122                 AC_MSG_RESULT([yes])
 123                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 124         ],[
 125                 AC_MSG_RESULT([no])
 126         ])
 127 ])
 128
 129 # Check if sys_futex() is available
 130 AC_MSG_CHECKING([for sys_futex()])
 131 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 132                 #include <sys/syscall.h>
 133                 #ifndef __NR_futex
 134                 #error "futexes not available"
 135                 #endif
 136         ]])
 137 ],[
 138         AC_MSG_RESULT([yes])
 139         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 140         compat_futex_test=0
 141 ],[
 142         AC_MSG_RESULT([no])
 143         compat_futex_test=1
 144 ])
 145
 146 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 147 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 148
 149 # smp-support configure option
 150 AC_ARG_ENABLE([smp-support],
 151         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 152         [def_smp_support=$enableval],
 153         [def_smp_support="yes"])
 154 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 155
 156
 157 # From the sched_setaffinity(2)'s man page:
 158 # ~~~~
 159 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 160 # The library interfaces were introduced in glibc 2.3.  Initially, the
 161 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 162 # the cpuset size argument was removed, but this argument was
 163 # restored in glibc 2.3.4.
 164 # ~~~~
 165
 166 # In addition to that, some vendors ported the system call to 2.4
 167 # kernels.
 168
 169 # Furthermore, when the function first appeared, the MASK argument was
 170 # an unsigned long pointer, while later it was made into a cpu_set_t
 171 # pointer.  Systems that have the cpu_set_t version also should have
 172 # the CPU_ZERO, CPU_SET, etc. macros.
 173
 174 # All this mess means we have to cater for at least 3 different
 175 # sched_setaffinity prototypes:
 176
 177 # ~~~~
 178 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 179 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 180 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 181 # ~~~~
 182
 183 # Since we define _GNU_SOURCE in the sources, must do so too in the
 184 # autoconf tests, as defining _GNU_SOURCE or not exposes
 185 # sched_setaffinity bits differently.
 186 saved_CFLAGS=$CFLAGS
 187 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 188
 189 # First check if the function is available at all.
 190 AC_CHECK_FUNCS([sched_setaffinity],[
 191         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 192         # then we have the first version using unsigned long, and no
 193         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 194         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 195         # should also be present, but we confirm nonetheless.
 196
 197         AC_CHECK_TYPES([cpu_set_t],[
 198                 # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 199                 AC_MSG_CHECKING([whether CPU_ZERO works])
 200                 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 201                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 202                                 #define _GNU_SOURCE
 203                                 #include <sched.h>
 204                                 int main()
 205                                 {
 206                                         cpu_set_t foo; CPU_ZERO (&foo);
 207                                         return 0;
 208                                 }
 209                         ]])
 210                 ],[
 211                         # Works!
 212                         AC_DEFINE(HAVE_CPU_ZERO, 1)
 213                         AC_MSG_RESULT([yes])
 214                 ],[
 215                         AC_MSG_RESULT([no])
 216                 ])
 217
 218                 # Check how many arguments does sched_setaffinity take.
 219                 # Should be 3 or 2.
 220                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 221                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 222                                 #include <sched.h>
 223                                 int main()
 224                                 {
 225                                         cpu_set_t foo;
 226                                         sched_setaffinity (0, sizeof (foo), &foo);
 227                                         return 0;
 228                                 }
 229                         ]])
 230                 ],
 231                 [sched_set_affinity_args=3],
 232                 [sched_set_affinity_args=2])
 233                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 234                         [Defined to sched_setaffinity's number of arguments.])
 235                 AC_MSG_RESULT([$sched_set_affinity_args])
 236         ],[
 237                 # No cpu_set_t, always 3 args.
 238                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 239         ],
 240         [#include <sched.h>])
 241 ])
 242
 243 CFLAGS=$saved_CFLAGS
 244
 245 AC_CONFIG_LINKS([
 246         urcu/arch.h:$ARCHSRC
 247         urcu/uatomic.h:$UATOMICSRC
 248 ])
 249 AC_CONFIG_FILES([
 250         Makefile
 251         doc/Makefile
 252         tests/Makefile
 253         liburcu.pc
 254         liburcu-bp.pc
 255         liburcu-cds.pc
 256         liburcu-qsbr.pc
 257         liburcu-mb.pc
 258         liburcu-signal.pc
 259 ])
 260 AC_OUTPUT
 261
 262 # Report on selected configure options
 263 AS_IF([test "x$def_smp_support" = "xyes"],[
 264         AS_ECHO("SMP support enabled.")
 265 ],[
 266         AS_ECHO("SMP support disabled.")
 267 ])
 268
 269 AS_IF([test "x$def_tls_detect" = "x"],[
 270         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 271 ],[
 272         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 273 ])