[urcu.git] / configure.ac

dnl SPDX-License-Identifier: LGPL-2.1-only
dnl
dnl Copyright (C) 2021 EfficiOS, Inc.
dnl
dnl Process this file with autoconf to produce a configure script.

# Project version information
m4_define([urcu_version_major], [0])
m4_define([urcu_version_minor], [15])
m4_define([urcu_version_patch], [0])
m4_define([urcu_version_dev_stage], [-pre])
m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)

# Library version information of "liburcu"
# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
m4_define([urcu_lib_version_current], [9])
m4_define([urcu_lib_version_revision], [0])
m4_define([urcu_lib_version_age], [1])
m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)


##                     ##
## Autoconf base setup ##
##                     ##

AC_PREREQ([2.69])
AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])

AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST


##                     ##
## Automake base setup ##
##                     ##

AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
AM_MAINTAINER_MODE([enable])

# Enable silent rules by default
AM_SILENT_RULES([yes])


##                               ##
## OS and Arch specific defaults ##
##                               ##

AS_CASE([$host],
  [*-cygwin* | *-msys*], [LT_NO_UNDEFINED="-no-undefined"]
)


##                   ##
## C compiler checks ##
##                   ##

# Choose the C compiler
AC_PROG_CC
# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])

# Make sure the C compiler supports C99
AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])

# Enable available system extensions and LFS support
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE

# Check if the selected C compiler supports atomic builtins
AE_CC_ATOMIC_BUILTINS


##                     ##
## C++ compiler checks ##
##                     ##

# Require a C++11 compiler without GNU extensions (-std=c++11)
AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])

# Make sure the C compiler supports __attribute__
AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

# Make sure we have pthread support
AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_C_TYPEOF
AC_TYPE_INT32_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

# Detect warning flags supported by the C compiler and append them to
# WARN_CFLAGS.
m4_define([WARN_FLAGS_LIST], [ dnl
  -Wall dnl
  -Wextra dnl
  -Wmissing-prototypes dnl
  -Wmissing-declarations dnl
  -Wnull-dereference dnl
  -Wundef dnl
  -Wshadow dnl
  -Wjump-misses-init dnl
  -Wsuggest-attribute=format dnl
  -Wtautological-constant-out-of-range-compare dnl
  -Wnested-externs dnl
  -Wwrite-strings dnl
  -Wformat=2 dnl
  -Wstrict-aliasing dnl
  -Wmissing-noreturn dnl
  -Winit-self dnl
  -Wduplicated-cond dnl
  -Wduplicated-branches dnl
  -Wlogical-op dnl
  dnl
  dnl-Wredundant-decls dnl
  -Wno-null-dereference dnl
])

# Pass -Werror as an extra flag during the test: this is needed to make the
# -Wunknown-warning-option diagnostic fatal with clang.
AC_LANG_PUSH([C])
AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
AC_LANG_POP([C])

AC_LANG_PUSH([C++])
AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
AC_LANG_POP([C++])

AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
AE_IF_FEATURE_ENABLED([Werror], [WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"])


##               ##
## Header checks ##
##               ##

AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	limits.h \
	stddef.h \
	sys/param.h \
	sys/time.h \
])


##                 ##
## Programs checks ##
##                 ##

AC_PROG_AWK
AC_PROG_GREP
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
AC_CHECK_PROGS(GETCONF, [getconf])
AC_CHECK_PROGS(TIME, [time])

# Initialize and configure libtool
LT_INIT


##                ##
## Library checks ##
##                ##

# Checks for library functions.
AC_FUNC_MMAP
AC_FUNC_FORK
AC_CHECK_FUNCS([ \
	atexit \
	getcpuid \
	gettid \
	gettimeofday \
	memeset \
	memset \
	munmap \
	rand_r \
	sched_getcpu \
	sched_setaffinity \
	strerror \
	strtoul \
	sysconf \
])

# AC_FUNC_MALLOC causes problems when cross-compiling.
#AC_FUNC_MALLOC

# Search for clock_gettime() in -lrt
AC_SEARCH_LIBS([clock_gettime], [rt], [
  AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
])


##                             ##
## Optional features selection ##
##                             ##

# Allow to fallback to FIXME if the membarrier syscall is unavailable on the
# running kernel, when disabled, abort if the syscall is unavailable. Applies
# to default and bulletproof flavors.
# Enabled by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])

# Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
# Enabled by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])

# smp-support configure option
# Enabled by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])

# RCU debugging option
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])

# rculfhash iterator debugging
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])

# Use compiler atomic builtins, when disabled use our legacy uatomic implementation.
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([compiler-atomic-builtins], [Enable the use of compiler atomic builtins.])

# emit legacy memory barriers
# Enable by default
AE_FEATURE_DEFAULT_ENABLE
AE_FEATURE([legacy-mb], [Disable legacy memory barriers.])

# When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
# Disabled by default
AE_FEATURE_DEFAULT_DISABLE
AE_FEATURE([Werror],[Treat compiler warnings as errors.])

##                                                                    ##
## Set defines for optional features conditionnals in the source code ##
##                                                                    ##

AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
  AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
])

AE_IF_FEATURE_ENABLED([compiler-tls], [
  AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
])

AE_IF_FEATURE_ENABLED([smp-support], [
  AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
])

AE_IF_FEATURE_ENABLED([rcu-debug], [
  AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
])

AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
  AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
])

AE_IF_FEATURE_ENABLED([compiler-atomic-builtins], [
  AC_DEFINE([CONFIG_RCU_USE_ATOMIC_BUILTINS], [1], [Use compiler atomic builtins.])
])

AE_IF_FEATURE_ENABLED([legacy-mb], [
  AC_DEFINE([CONFIG_RCU_EMIT_LEGACY_MB], [1], [Emit legacy memory barriers that were documented in the APIs.])
])

##                                                                          ##
## Set automake variables for optional feature conditionnals in Makefile.am ##
##                                                                          ##

# Building the examples requires the shared libraries to be enabled
AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared]))


##                                          ##
## Check for optional features dependencies ##
##                                          ##


AE_IF_FEATURE_ENABLED([compiler-atomic-builtins], [
  AS_IF([test "x$ae_cv_cc_atomic_builtins" != xyes], [
     AC_MSG_ERROR([The compiler does not support atomic builtins.])
  ])
])

##                                             ##
## Substitute variables for use in Makefile.am ##
##                                             ##

# Library versions for libtool
AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])

AC_SUBST(LT_NO_UNDEFINED)

# The order in which the include folders are searched is important.
# The top_builddir should always be searched first in the event that a build
# time generated file is included.
AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
AC_SUBST(AM_CPPFLAGS)

AM_CFLAGS="$WARN_CFLAGS $PTHREAD_CFLAGS"
AC_SUBST(AM_CFLAGS)

AM_CXXFLAGS="$WARN_CXXFLAGS $PTHREAD_CFLAGS"
AC_SUBST(AM_CXXFLAGS)


##                                     ##
## Output files generated by configure ##
##                                     ##

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	extras/Makefile
	include/Makefile
	src/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/utils/Makefile
	src/liburcu.pc
	src/liburcu-bp.pc
	src/liburcu-cds.pc
	src/liburcu-qsbr.pc
	src/liburcu-mb.pc
	src/liburcu-memb.pc
	src/liburcu-signal.pc
])

AC_CONFIG_FILES([tests/utils/env.sh],[chmod +x tests/utils/env.sh])


AC_OUTPUT

#
# Mini-report on what will be built.
#

AE_PPRINT_INIT
AE_PPRINT_SET_INDENT(1)
AE_PPRINT_SET_TS(38)

AS_ECHO
AS_ECHO("${AE_PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${AE_PPRINT_COLOR_RST}")
AS_ECHO

AE_PPRINT_SUBTITLE([Features])

AE_PPRINT_PROP_STRING([Target architecture], $host_cpu)

# SMP support enabled/disabled
AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0
AE_PPRINT_PROP_BOOL([SMP support], $value)

# TLS
AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()"
AE_PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])

# clock_gettime() available
test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0
AE_PPRINT_PROP_BOOL([clock_gettime()], $value)

# Require membarrier
AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1
AE_PPRINT_PROP_BOOL([Require membarrier], $value)

# RCU debug enabled/disabled
AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0
AE_PPRINT_PROP_BOOL([Internal debugging], $value)

# rculfhash iterator debug enabled/disabled
AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0
AE_PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)

AE_PPRINT_PROP_BOOL([Multi-flavor support], 1)

# atomic builtins enabled/disabled
AE_IS_FEATURE_ENABLED([compiler-atomic-builtins]) && value=1 || value=0
AE_PPRINT_PROP_BOOL([Use compiler atomic builtins], $value)

# legacy memory barriers
AE_IS_FEATURE_ENABLED([legacy-mb]) && value=1 || value=0
AE_PPRINT_PROP_BOOL([Emit legacy memory barriers], $value)

report_bindir="`eval eval echo $bindir`"
report_libdir="`eval eval echo $libdir`"

# Print the bindir and libdir this 'make install' will install into.
AS_ECHO
AE_PPRINT_SUBTITLE([Install directories])
AE_PPRINT_PROP_STRING([Binaries], [$report_bindir])
AE_PPRINT_PROP_STRING([Libraries], [$report_libdir])
Commit	Line	Data
23975ca7 MJ	1	dnl SPDX-License-Identifier: LGPL-2.1-only
	2	dnl
	3	dnl Copyright (C) 2021 EfficiOS, Inc.
	4	dnl
	5	dnl Process this file with autoconf to produce a configure script.
	6
	7	# Project version information
	8	m4_define([urcu_version_major], [0])
d5a39857	9	m4_define([urcu_version_minor], [15])
23975ca7	10	m4_define([urcu_version_patch], [0])
d5a39857	11	m4_define([urcu_version_dev_stage], [-pre])
23975ca7 MJ	12	m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
	13
	14	# Library version information of "liburcu"
98bc124a YB	15	# Following the numbering scheme proposed by libtool for the library version
98bc124a YB	16	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
5feb4925	17	m4_define([urcu_lib_version_current], [9])
23975ca7	18	m4_define([urcu_lib_version_revision], [0])
5feb4925	19	m4_define([urcu_lib_version_age], [1])
23975ca7 MJ	20	m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
	21
	22
	23	## ##
	24	## Autoconf base setup ##
	25	## ##
	26
afb6113f	27	AC_PREREQ([2.69])
23975ca7	28	AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
98bc124a	29
6893800a	30	AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
48d848c7	31	AC_CONFIG_AUX_DIR([config])
074c3a1b MJ	32	AC_CONFIG_MACRO_DIR([m4])
074c3a1b MJ	33
7d413817 MD	34	AC_CANONICAL_TARGET
7d413817 MD	35	AC_CANONICAL_HOST
074c3a1b	36
afb6113f MJ	37
	38	## ##
	39	## Automake base setup ##
	40	## ##
	41
	42	AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
35eb2d6c	43	AM_MAINTAINER_MODE([enable])
7d413817	44
afb6113f MJ	45	# Enable silent rules by default
afb6113f MJ	46	AM_SILENT_RULES([yes])
e72596d1	47
514079bb MJ	48
	49	## ##
	50	## OS and Arch specific defaults ##
	51	## ##
	52
	53	AS_CASE([$host],
5159c1cf	54	[-cygwin \| -msys], [LT_NO_UNDEFINED="-no-undefined"]
514079bb MJ	55	)
	56
	57
8b2f0590 MJ	58	## ##
	59	## C compiler checks ##
	60	## ##
	61
	62	# Choose the C compiler
	63	AC_PROG_CC
	64	# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
	65	m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
	66
	67	# Make sure the C compiler supports C99
	68	AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
	69
	70	# Enable available system extensions and LFS support
	71	AC_USE_SYSTEM_EXTENSIONS
	72	AC_SYS_LARGEFILE
	73
3afcf5a0 OD	74	# Check if the selected C compiler supports atomic builtins
	75	AE_CC_ATOMIC_BUILTINS
	76
	77
153b081a SM	78	## ##
	79	## C++ compiler checks ##
	80	## ##
	81
	82	# Require a C++11 compiler without GNU extensions (-std=c++11)
	83	AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])
	84
8b2f0590 MJ	85	# Make sure the C compiler supports __attribute__
	86	AX_C___ATTRIBUTE__
	87	AS_IF([test "x$ax_cv___attribute__" != "xyes"],
	88	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	89
	90	# Make sure we have pthread support
	91	AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
	92
8b2f0590 MJ	93	# Checks for typedefs, structures, and compiler characteristics.
	94	AC_C_INLINE
	95	AC_C_TYPEOF
	96	AC_TYPE_INT32_T
	97	AC_TYPE_PID_T
	98	AC_TYPE_SIZE_T
	99	AC_TYPE_SSIZE_T
	100	AC_TYPE_UINT16_T
	101	AC_TYPE_UINT32_T
	102	AC_TYPE_UINT64_T
	103	AC_TYPE_UINT8_T
	104
ee334e48 MJ	105	# Detect warning flags supported by the C compiler and append them to
	106	# WARN_CFLAGS.
	107	m4_define([WARN_FLAGS_LIST], [ dnl
	108	-Wall dnl
	109	-Wextra dnl
	110	-Wmissing-prototypes dnl
	111	-Wmissing-declarations dnl
	112	-Wnull-dereference dnl
	113	-Wundef dnl
	114	-Wshadow dnl
	115	-Wjump-misses-init dnl
	116	-Wsuggest-attribute=format dnl
	117	-Wtautological-constant-out-of-range-compare dnl
	118	-Wnested-externs dnl
	119	-Wwrite-strings dnl
	120	-Wformat=2 dnl
	121	-Wstrict-aliasing dnl
	122	-Wmissing-noreturn dnl
	123	-Winit-self dnl
	124	-Wduplicated-cond dnl
	125	-Wduplicated-branches dnl
	126	-Wlogical-op dnl
	127	dnl
	128	dnl-Wredundant-decls dnl
	129	-Wno-null-dereference dnl
	130	])
	131
	132	# Pass -Werror as an extra flag during the test: this is needed to make the
	133	# -Wunknown-warning-option diagnostic fatal with clang.
	134	AC_LANG_PUSH([C])
	135	AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
	136	AC_LANG_POP([C])
	137
153b081a SM	138	AC_LANG_PUSH([C++])
	139	AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
	140	AC_LANG_POP([C++])
	141
35701ce9	142	AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
153b081a	143	AE_IF_FEATURE_ENABLED([Werror], [WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"])
35701ce9	144
8b2f0590	145
6b5533b0 MJ	146	## ##
	147	## Header checks ##
	148	## ##
	149
	150	AC_HEADER_STDBOOL
	151	AC_CHECK_HEADERS([ \
	152	limits.h \
	153	stddef.h \
	154	sys/param.h \
	155	sys/time.h \
	156	])
	157
	158
	159	## ##
	160	## Programs checks ##
	161	## ##
	162
	163	AC_PROG_AWK
	164	AC_PROG_GREP
	165	AC_PROG_MAKE_SET
	166	AC_CHECK_PROGS(NPROC, [nproc gnproc])
f0124a5a	167	AC_CHECK_PROGS(GETCONF, [getconf])
de6cb9d5	168	AC_CHECK_PROGS(TIME, [time])
6b5533b0 MJ	169
	170	# Initialize and configure libtool
	171	LT_INIT
	172
	173
c673679b MJ	174	## ##
	175	## Library checks ##
	176	## ##
	177
	178	# Checks for library functions.
	179	AC_FUNC_MMAP
	180	AC_FUNC_FORK
	181	AC_CHECK_FUNCS([ \
	182	atexit \
	183	getcpuid \
	184	gettid \
	185	gettimeofday \
	186	memeset \
	187	memset \
	188	munmap \
	189	rand_r \
	190	sched_getcpu \
0614a2e6	191	sched_setaffinity \
c673679b MJ	192	strerror \
	193	strtoul \
	194	sysconf \
	195	])
	196
	197	# AC_FUNC_MALLOC causes problems when cross-compiling.
	198	#AC_FUNC_MALLOC
	199
	200	# Search for clock_gettime() in -lrt
	201	AC_SEARCH_LIBS([clock_gettime], [rt], [
	202	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
	203	])
	204
	205
f99c6e92 MJ	206	## ##
	207	## Optional features selection ##
	208	## ##
86bc2ad8 MJ	209
	210	# Allow to fallback to FIXME if the membarrier syscall is unavailable on the
	211	# running kernel, when disabled, abort if the syscall is unavailable. Applies
	212	# to default and bulletproof flavors.
	213	# Enabled by default
	214	AE_FEATURE_DEFAULT_ENABLE
	215	AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])
	216
	217	# Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
	218	# Enabled by default
	219	AE_FEATURE_DEFAULT_ENABLE
	220	AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])
c673679b	221
86bc2ad8 MJ	222	# smp-support configure option
	223	# Enabled by default
	224	AE_FEATURE_DEFAULT_ENABLE
	225	AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])
d8d9a340	226
86bc2ad8 MJ	227	# RCU debugging option
	228	# Disabled by default
	229	AE_FEATURE_DEFAULT_DISABLE
	230	AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])
a767fdc3	231
86bc2ad8 MJ	232	# rculfhash iterator debugging
	233	# Disabled by default
	234	AE_FEATURE_DEFAULT_DISABLE
	235	AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
75478b32	236
3afcf5a0 OD	237	# Use compiler atomic builtins, when disabled use our legacy uatomic implementation.
	238	# Disabled by default
	239	AE_FEATURE_DEFAULT_DISABLE
	240	AE_FEATURE([compiler-atomic-builtins], [Enable the use of compiler atomic builtins.])
	241
0e2125fb OD	242	# emit legacy memory barriers
	243	# Enable by default
	244	AE_FEATURE_DEFAULT_ENABLE
	245	AE_FEATURE([legacy-mb], [Disable legacy memory barriers.])
	246
35701ce9 SM	247	# When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
	248	# Disabled by default
	249	AE_FEATURE_DEFAULT_DISABLE
	250	AE_FEATURE([Werror],[Treat compiler warnings as errors.])
48d848c7	251
86bc2ad8 MJ	252	## ##
	253	## Set defines for optional features conditionnals in the source code ##
	254	## ##
48d848c7	255
86bc2ad8 MJ	256	AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
	257	AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
	258	])
cdadd34c	259
86bc2ad8 MJ	260	AE_IF_FEATURE_ENABLED([compiler-tls], [
	261	AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
	262	])
0854ccff	263
86bc2ad8 MJ	264	AE_IF_FEATURE_ENABLED([smp-support], [
	265	AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	266	])
7d413817	267
86bc2ad8 MJ	268	AE_IF_FEATURE_ENABLED([rcu-debug], [
86bc2ad8 MJ	269	AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
d4e640c0	270	])
48d848c7	271
86bc2ad8 MJ	272	AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
86bc2ad8 MJ	273	AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
d7c76f85 MD	274	])
d7c76f85 MD	275
3afcf5a0 OD	276	AE_IF_FEATURE_ENABLED([compiler-atomic-builtins], [
	277	AC_DEFINE([CONFIG_RCU_USE_ATOMIC_BUILTINS], [1], [Use compiler atomic builtins.])
	278	])
86bc2ad8	279
0e2125fb OD	280	AE_IF_FEATURE_ENABLED([legacy-mb], [
	281	AC_DEFINE([CONFIG_RCU_EMIT_LEGACY_MB], [1], [Emit legacy memory barriers that were documented in the APIs.])
	282	])
	283
1136f454 MJ	284	## ##
	285	## Set automake variables for optional feature conditionnals in Makefile.am ##
	286	## ##
	287
	288	# Building the examples requires the shared libraries to be enabled
	289	AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared]))
	290
	291
3afcf5a0 OD	292	## ##
	293	## Check for optional features dependencies ##
	294	## ##
	295
	296
	297	AE_IF_FEATURE_ENABLED([compiler-atomic-builtins], [
	298	AS_IF([test "x$ae_cv_cc_atomic_builtins" != xyes], [
	299	AC_MSG_ERROR([The compiler does not support atomic builtins.])
	300	])
	301	])
	302
23975ca7 MJ	303	## ##
	304	## Substitute variables for use in Makefile.am ##
	305	## ##
	306
	307	# Library versions for libtool
	308	AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
	309
514079bb MJ	310	AC_SUBST(LT_NO_UNDEFINED)
514079bb MJ	311
01956342 MJ	312	# The order in which the include folders are searched is important.
	313	# The top_builddir should always be searched first in the event that a build
	314	# time generated file is included.
	315	AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
9a79c612 MJ	316	AC_SUBST(AM_CPPFLAGS)
9a79c612 MJ	317
ee334e48	318	AM_CFLAGS="$WARN_CFLAGS $PTHREAD_CFLAGS"
9a79c612	319	AC_SUBST(AM_CFLAGS)
d8540fc5	320
153b081a SM	321	AM_CXXFLAGS="$WARN_CXXFLAGS $PTHREAD_CFLAGS"
	322	AC_SUBST(AM_CXXFLAGS)
	323
0614a2e6 MJ	324
	325	## ##
	326	## Output files generated by configure ##
	327	## ##
	328
48d848c7 PMF	329	AC_CONFIG_FILES([
48d848c7 PMF	330	Makefile
fe999c05	331	doc/Makefile
8bad63a0	332	doc/examples/Makefile
c0ecb6ea	333	extras/Makefile
6893800a MJ	334	include/Makefile
6893800a MJ	335	src/Makefile
48d848c7	336	tests/Makefile
f5ab766e MD	337	tests/common/Makefile
	338	tests/unit/Makefile
	339	tests/benchmark/Makefile
	340	tests/regression/Makefile
1b387491	341	tests/utils/Makefile
6893800a MJ	342	src/liburcu.pc
	343	src/liburcu-bp.pc
	344	src/liburcu-cds.pc
	345	src/liburcu-qsbr.pc
	346	src/liburcu-mb.pc
799d344f	347	src/liburcu-memb.pc
6893800a	348	src/liburcu-signal.pc
48d848c7	349	])
03c5782e	350
de6cb9d5	351	AC_CONFIG_FILES([tests/utils/env.sh],[chmod +x tests/utils/env.sh])
03c5782e MJ	352
03c5782e MJ	353
48d848c7	354	AC_OUTPUT
a6412536	355
628a1a72 MJ	356	#
	357	# Mini-report on what will be built.
	358	#
	359
d001c886 MJ	360	AE_PPRINT_INIT
	361	AE_PPRINT_SET_INDENT(1)
	362	AE_PPRINT_SET_TS(38)
628a1a72 MJ	363
628a1a72 MJ	364	AS_ECHO
d001c886	365	AS_ECHO("${AE_PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${AE_PPRINT_COLOR_RST}")
628a1a72 MJ	366	AS_ECHO
628a1a72 MJ	367
d001c886	368	AE_PPRINT_SUBTITLE([Features])
628a1a72	369
d001c886	370	AE_PPRINT_PROP_STRING([Target architecture], $host_cpu)
628a1a72 MJ	371
628a1a72 MJ	372	# SMP support enabled/disabled
86bc2ad8	373	AE_IS_FEATURE_ENABLED([smp-support]) && value=1 \|\| value=0
d001c886	374	AE_PPRINT_PROP_BOOL([SMP support], $value)
628a1a72	375
628a1a72	376	# TLS
86bc2ad8	377	AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" \|\| value="pthread_getspecific()"
d001c886	378	AE_PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
628a1a72 MJ	379
628a1a72 MJ	380	# clock_gettime() available
c673679b	381	test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 \|\| value=0
d001c886	382	AE_PPRINT_PROP_BOOL([clock_gettime()], $value)
628a1a72 MJ	383
628a1a72 MJ	384	# Require membarrier
86bc2ad8	385	AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 \|\| value=1
d001c886	386	AE_PPRINT_PROP_BOOL([Require membarrier], $value)
628a1a72 MJ	387
628a1a72 MJ	388	# RCU debug enabled/disabled
86bc2ad8	389	AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 \|\| value=0
d001c886	390	AE_PPRINT_PROP_BOOL([Internal debugging], $value)
628a1a72	391
d7c76f85	392	# rculfhash iterator debug enabled/disabled
86bc2ad8	393	AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 \|\| value=0
d001c886	394	AE_PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)
d7c76f85	395
d001c886	396	AE_PPRINT_PROP_BOOL([Multi-flavor support], 1)
4477a870	397
3afcf5a0 OD	398	# atomic builtins enabled/disabled
	399	AE_IS_FEATURE_ENABLED([compiler-atomic-builtins]) && value=1 \|\| value=0
	400	AE_PPRINT_PROP_BOOL([Use compiler atomic builtins], $value)
	401
0e2125fb OD	402	# legacy memory barriers
	403	AE_IS_FEATURE_ENABLED([legacy-mb]) && value=1 \|\| value=0
	404	AE_PPRINT_PROP_BOOL([Emit legacy memory barriers], $value)
	405
628a1a72 MJ	406	report_bindir="`eval eval echo $bindir`"
	407	report_libdir="`eval eval echo $libdir`"
	408
86bc2ad8	409	# Print the bindir and libdir this 'make install' will install into.
628a1a72	410	AS_ECHO
d001c886 MJ	411	AE_PPRINT_SUBTITLE([Install directories])
	412	AE_PPRINT_PROP_STRING([Binaries], [$report_bindir])
	413	AE_PPRINT_PROP_STRING([Libraries], [$report_libdir])
75478b32	414