Introduce AE_FEATURE to manage configure features
authorMichael Jeanson <mjeanson@efficios.com>
Thu, 18 Mar 2021 23:53:28 +0000 (19:53 -0400)
committerMathieu Desnoyers <mathieu.desnoyers@efficios.com>
Fri, 19 Mar 2021 18:32:14 +0000 (14:32 -0400)
The new AE_FEATURE set of macros are wrappers over autoconf's
AC_ARG_ENABLE. The main objective is to make the m4sh code more readable
to the less seasoned autotools enthusiast among us and reduce the
duplication of code with its associated bugs.

The AE prefix was chosen to mean "Autotools EfficiOS" and is part of an
effort to standardize our custom macros across all our autotools based
projects.

Change-Id: Ief565473b38150fe2104492c6339bac73efba895
Signed-off-by: Michael Jeanson <mjeanson@efficios.com>
Signed-off-by: Mathieu Desnoyers <mathieu.desnoyers@efficios.com>
configure.ac
m4/ae_config_feature.m4 [new file with mode: 0644]

index c7492df594c081bcd9a723a4dd1e40ef4bc704c0..70e8e01b7a687275a23e41c32d6735eda1adfdfe 100644 (file)
@@ -163,56 +163,68 @@ AC_SEARCH_LIBS([clock_gettime], [rt], [
 ])
 
 
+##                              ##
+## Optionnal features selection ##
+##                              ##
+
+# Allow to fallback to FIXME if the membarrier syscall is unavailable on the
+# running kernel, when disabled, abort if the syscall is unavailable. Applies
+# to default and bulletproof flavors.
+# Enabled by default
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])
+
+# Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
+# Enabled by default
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])
 
-AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
-AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
-AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
-AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduces a performance penalty.])
-AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
+# smp-support configure option
+# Enabled by default
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])
 
-# Allow requiring the operating system to support the membarrier system
-# call. Applies to default and bulletproof flavors.
-AC_ARG_ENABLE([sys-membarrier-fallback],
-       AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
-       [def_sys_membarrier_fallback=$enableval],
-       [def_sys_membarrier_fallback="yes"])
-AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
+# RCU debugging option
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])
 
-# Allow overriding storage used for TLS variables.
-AC_ARG_ENABLE([compiler-tls],
-       AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
-       [def_compiler_tls=$enableval],
-       [def_compiler_tls="yes"])
+# rculfhash iterator debugging
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 
-AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
 
+##                                                                    ##
+## Set defines for optional features conditionnals in the source code ##
+##                                                                    ##
 
-AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
+AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
+  AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
+])
 
-AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
+AE_IF_FEATURE_ENABLED([compiler-tls], [
+  AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
+])
 
-# smp-support configure option
-AC_ARG_ENABLE([smp-support], 
-       AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
-       [def_smp_support=$enableval],
-       [def_smp_support="yes"])
-AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
+AE_IF_FEATURE_ENABLED([smp-support], [
+  AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
+])
 
-# RCU debugging option
-AC_ARG_ENABLE([rcu-debug],
-      AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
-                     self-checks. Introduces a performance penalty.]))
-AS_IF([test "x$enable_rcu_debug" = "xyes"], [
-       AC_DEFINE([CONFIG_RCU_DEBUG], [1])
+AE_IF_FEATURE_ENABLED([rcu-debug], [
+  AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
 ])
 
-# rculfhash iterator debugging
-AC_ARG_ENABLE([cds-lfht-iter-debug],
-      AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
-AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
-       AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
+AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
+  AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 ])
 
+AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
+
+AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
+
+
+
 # From the sched_setaffinity(2)'s man page:
 # ~~~~
 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
@@ -431,11 +443,11 @@ PPRINT_SUBTITLE([Features])
 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 
 # SMP support enabled/disabled
-test "x$def_smp_support" = "xyes" && value=1 || value=0
+AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0
 PPRINT_PROP_BOOL([SMP support], $value)
 
 # TLS
-test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()"
+AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()"
 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 
 # clock_gettime() available
@@ -443,23 +455,23 @@ test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0
 PPRINT_PROP_BOOL([clock_gettime()], $value)
 
 # Require membarrier
-test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
+AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1
 PPRINT_PROP_BOOL([Require membarrier], $value)
 
 # RCU debug enabled/disabled
-test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
+AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0
 PPRINT_PROP_BOOL([Internal debugging], $value)
 
 # rculfhash iterator debug enabled/disabled
-test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
-PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
+AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0
+PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)
 
 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 
 report_bindir="`eval eval echo $bindir`"
 report_libdir="`eval eval echo $libdir`"
 
-# Print the bindir and libdir this `make install' will install into.
+# Print the bindir and libdir this 'make install' will install into.
 AS_ECHO
 PPRINT_SUBTITLE([Install directories])
 PPRINT_PROP_STRING([Binaries], [$report_bindir])
diff --git a/m4/ae_config_feature.m4 b/m4/ae_config_feature.m4
new file mode 100644 (file)
index 0000000..7582c00
--- /dev/null
@@ -0,0 +1,258 @@
+#
+# SYNOPSIS
+#
+#   AE_FEATURE(FEATURE-NAME, FEATURE-DESCRIPTION,
+#              ACTION-IF-GIVEN?, ACTION-IF-NOT-GIVEN?,
+#              ACTION-IF-ENABLED?, ACTION-IF-NOT-ENABLED?)
+#
+# DESCRIPTION
+#
+#   AE_FEATURE is a simple wrapper for AC_ARG_ENABLE.
+#
+#   FEATURE-NAME should consist only of alphanumeric characters, dashes,
+#   plus signs, and dots.
+#
+#   FEATURE-DESCRIPTION will be formatted with AS_HELP_STRING.
+#
+#   If the user gave configure the option --enable-FEATURE or --disable-FEATURE,
+#   run shell commands ACTION-IF-GIVEN. If neither option was given, run shell
+#   commands ACTION-IF-NOT-GIVEN. The name feature indicates an optional
+#
+#   If the feature is enabled, run shell commands ACTION-IF-ENABLED, if it is
+#   disabled, run shell commands ACTION-IF-NOT-ENABLED.
+#
+#   A FEATURE has 3 different states, enabled, disabled and undefined. The first
+#   two are self explanatory, the third state means it's disabled by default
+#   and it was not explicitly enabled or disabled by the user or by the
+#   AE_FEATURE_ENABLE and AE_FEATURE_DISABLE macros.
+#
+#   A feature is disabled by default, in order to change this behaviour use the
+#   AE_FEATURE_DEFAULT_ENABLE and AE_FEATURE_DEFAULT_DISABLE
+#   macros.
+#
+#   A simple example:
+#
+#     AE_FEATURE_DEFAULT_ENABLE
+#     AE_FEATURE(feature_xxxxx, [turns on/off XXXXX support])
+#
+#     ...
+#
+#     AE_FEATURE_DEFAULT_DISABLE
+#     AE_FEATURE(feature_yyyyy, [turns on/off YYYYY support])
+#     AM_CONDITIONAL(YYYYY, AE_IS_FEATURE_ENABLED([feature_yyyyy]))
+#
+#     AE_FEATURE_DEFAULT_ENABLE
+#     AE_FEATURE(...)
+#
+#     ...
+#
+#   Use AE_FEATURE_ENABLE or AE_FEATURE_DISABLE in order to
+#   enable or disable a specific feature.
+#
+#   Another simple example:
+#
+#     AS_IF([some_test_here],[AE_FEATURE_ENABLE(feature_xxxxx)],[])
+#
+#     AE_FEATURE(feature_xxxxx, [turns on/off XXXXX support],
+#                       HAVE_XXXXX, [Define if you want XXXXX support])
+#     AE_FEATURE(feature_yyyyy, [turns on/off YYYYY support],
+#                       HAVE_YYYYY, [Define if you want YYYYY support])
+#
+#     ...
+#
+#   NOTE: AE_FEATURE_ENABLE/DISABLE() must be placed first of the relative
+#   AE_FEATURE() macro if you want the the proper ACTION-IF-ENABLED and
+#   ACTION-IF-NOT-ENABLED to run.
+#
+# LICENSE
+#
+#   Copyright (c) 2020 Michael Jeanson <mjeanson@efficios.com>
+#   Copyright (c) 2008 Francesco Salvestrini <salvestrini@users.sourceforge.net>
+#
+#   This program is free software; you can redistribute it and/or modify it
+#   under the terms of the GNU General Public License as published by the
+#   Free Software Foundation; either version 2 of the License, or (at your
+#   option) any later version.
+#
+#   This program is distributed in the hope that it will be useful, but
+#   WITHOUT ANY WARRANTY; without even the implied warranty of
+#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+#   Public License for more details.
+#
+#   You should have received a copy of the GNU General Public License along
+#   with this program. If not, see <https://www.gnu.org/licenses/>.
+#
+#   As a special exception, the respective Autoconf Macro's copyright owner
+#   gives unlimited permission to copy, distribute and modify the configure
+#   scripts that are the output of Autoconf when processing the Macro. You
+#   need not follow the terms of the GNU General Public License when using
+#   or distributing such scripts, even though portions of the text of the
+#   Macro appear in them. The GNU General Public License (GPL) does govern
+#   all other use of the material that constitutes the Autoconf Macro.
+#
+#   This special exception to the GPL applies to versions of the Autoconf
+#   Macro released by the Autoconf Archive. When you make and distribute a
+#   modified version of the Autoconf Macro, you may extend this special
+#   exception to the GPL to apply to your modified version as well.
+
+#serial 1
+
+
+# AE_FEATURE_DEFAULT_ENABLE: The next feature defined with AE_FEATURE will
+# default to enable.
+AC_DEFUN([AE_FEATURE_DEFAULT_ENABLE], [
+  m4_define([ae_feature_default_arg], [yes])
+  m4_define([ae_feature_default_switch], [disable])
+])
+
+
+# AE_FEATURE_DEFAULT_DISABLE: The next feature defined with AE_FEATURE will
+# default to disable.
+#
+AC_DEFUN([AE_FEATURE_DEFAULT_DISABLE], [
+  m4_define([ae_feature_default_arg], [no])
+  m4_define([ae_feature_default_switch], [enable])
+])
+
+
+# AE_FEATURE_ENABLE(FEATURE-NAME): Enable the FEATURE, this will override the
+# user's choice if it was made.
+#
+AC_DEFUN([AE_FEATURE_ENABLE],[ dnl
+  enable_[]patsubst([$1], -, _)[]=yes
+])
+
+
+# AE_FEATURE_DISABLE(FEATURE-NAME): Disable the FEATURE, this will override the
+# user's choice if it was made.
+#
+AC_DEFUN([AE_FEATURE_DISABLE],[ dnl
+  enable_[]patsubst([$1], -, _)[]=no
+])
+
+
+# AE_IF_FEATURE_ENABLED(FEATURE-NAME, ACTION-IF-ENABLED, ACTION-IF-NOT-ENABLED?):
+# Run shell code ACTION-IF-ENABLED if the FEATURE is enabled, otherwise run
+# shell code ACTION-IF-NOT-ENABLED.
+#
+AC_DEFUN([AE_IF_FEATURE_ENABLED],[ dnl
+m4_pushdef([FEATURE], patsubst([$1], -, _))dnl
+
+  AS_IF([test "$enable_[]FEATURE[]" = yes],[ dnl
+    $2
+  ],[: dnl
+    $3
+  ])
+])
+
+
+# AE_IF_FEATURE_NOT_ENABLED(FEATURE-NAME, ACTION-IF-NOT-ENABLED,
+#                           ACTION-IF-NOT-NOT-ENABLED?):
+# Run shell code ACTION-IF-NOT-ENABLED if the FEATURE is not explicitly
+# enabled, otherwise run shell code ACTION-IF-NOT-NOT-DISABLED.
+#
+# The distinction with AE_IF_FEATURE_DISABLED is that this will also
+# match a feature that is undefined.
+#
+# A feature is undefined when it's disabled by default and was not explicitly
+# enabled or disabled by the user or by AE_FEATURE_ENABLE/DISABLE.
+#
+AC_DEFUN([AE_IF_FEATURE_NOT_ENABLED],[ dnl
+m4_pushdef([FEATURE], patsubst([$1], -, _))dnl
+
+  AS_IF([test "$enable_[]FEATURE[]" != yes],[ dnl
+    $2
+  ],[: dnl
+    $3
+  ])
+])
+
+
+# AE_IF_FEATURE_DISABLED(FEATURE-NAME, ACTION-IF-DISABLED, ACTION-IF-NOT-DISABLED?):
+# Run shell code ACTION-IF-DISABLED if the FEATURE is disabled, otherwise run
+# shell code ACTION-IF-NOT-DISABLED.
+#
+AC_DEFUN([AE_IF_FEATURE_DISABLED],[ dnl
+m4_pushdef([FEATURE], patsubst([$1], -, _))dnl
+
+  AS_IF([test "$enable_[]FEATURE[]" = no],[ dnl
+    $2
+  ],[: dnl
+    $3
+  ])
+])
+
+
+# AE_IF_FEATURE_UNDEF(FEATURE-NAME, ACTION-IF-UNDEF, ACTION-IF-NOT-UNDEF?):
+# Run shell code ACTION-IF-UNDEF if the FEATURE is undefined, otherwise run
+# shell code ACTION-IF-NOT-UNDEF.
+#
+# A feature is undefined when it's disabled by default and was not explicitly
+# enabled or disabled by the user or by AE_FEATURE_ENABLE/DISABLE.
+#
+AC_DEFUN([AE_IF_FEATURE_UNDEF],[ dnl
+m4_pushdef([FEATURE], patsubst([$1], -, _))dnl
+
+  AS_IF([test "x$enable_[]FEATURE[]" = x],[ dnl
+    $2
+  ],[: dnl
+    $3
+  ])
+])
+
+
+# AE_IS_FEATURE_ENABLED(FEATURE-NAME): outputs a shell condition (suitable
+# for use in a shell if statement) that will return true if the FEATURE is
+# enabled.
+#
+AC_DEFUN([AE_IS_FEATURE_ENABLED],[dnl
+m4_pushdef([FEATURE], patsubst([$1], -, _))dnl
+ test "x$enable_[]FEATURE[]" = xyes dnl
+])
+
+
+dnl Disabled by default, unless already overriden
+m4_ifndef([ae_feature_default_arg],[AE_FEATURE_DEFAULT_DISABLE])
+
+
+# AE_FEATURE(FEATURE-NAME, FEATURE-DESCRIPTION,
+#            ACTION-IF-GIVEN?, ACTION-IF-NOT-GIVEN?,
+#            ACTION-IF-ENABLED?, ACTION-IF-NOT-ENABLED?):
+#
+#
+AC_DEFUN([AE_FEATURE],[ dnl
+m4_pushdef([FEATURE], patsubst([$1], -, _))dnl
+
+dnl If the option wasn't specified and the default is enabled, set enable_FEATURE to yes
+AS_IF([test "x$enable_[]FEATURE[]" = x && test "ae_feature_default_arg" = yes],[ dnl
+  enable_[]FEATURE[]="ae_feature_default_arg"
+])
+
+AC_ARG_ENABLE([$1],
+  AS_HELP_STRING([--ae_feature_default_switch-$1],dnl
+                 [$2 [default=ae_feature_default_arg]]),[
+case "${enableval}" in
+   yes)
+     enable_[]FEATURE[]=yes
+     ;;
+   no)
+     enable_[]FEATURE[]=no
+     ;;
+   *)
+     AC_MSG_ERROR([bad value ${enableval} for feature --$1])
+     ;;
+esac
+
+$3
+],[: dnl
+$4
+])
+
+AS_IF([test "$enable_[]FEATURE[]" = yes],[: dnl
+  $5
+],[: dnl
+  $6
+])
+
+m4_popdef([FEATURE])dnl
+])
This page took 0.040767 seconds and 4 git commands to generate.