configure: host specific config

[urcu.git] / configure.ac

diff --git a/configure.ac b/configure.ac
index daa967a738a057a61dc69b5e93c9c047c4b71524..30d2056656ed471727311899b9ddba7b50fe517e 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -1,9 +1,31 @@
-AC_PREREQ(2.59)
-AC_INIT([userspace-rcu],[0.12.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
-
+dnl SPDX-License-Identifier: LGPL-2.1-only
+dnl
+dnl Copyright (C) 2021 EfficiOS, Inc.
+dnl
+dnl Process this file with autoconf to produce a configure script.
+
+# Project version information
+m4_define([urcu_version_major], [0])
+m4_define([urcu_version_minor], [12])
+m4_define([urcu_version_patch], [0])
+m4_define([urcu_version_dev_stage], [])
+m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
+
+# Library version information of "liburcu"
 # Following the numbering scheme proposed by libtool for the library version
 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
-AC_SUBST([URCU_LIBRARY_VERSION], [7:0:1])
+m4_define([urcu_lib_version_current], [7])
+m4_define([urcu_lib_version_revision], [0])
+m4_define([urcu_lib_version_age], [1])
+m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
+
+
+##                     ##
+## Autoconf base setup ##
+##                     ##
+
+AC_PREREQ([2.69])
+AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
 
 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
 AC_CONFIG_AUX_DIR([config])
@@ -12,13 +34,26 @@ AC_CONFIG_MACRO_DIR([m4])
 AC_CANONICAL_TARGET
 AC_CANONICAL_HOST
 
-AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc])
+
+##                     ##
+## Automake base setup ##
+##                     ##
+
+AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
 AM_MAINTAINER_MODE([enable])
 
-# Enable silent rules if available (Introduced in AM 1.11)
-m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
+# Enable silent rules by default
+AM_SILENT_RULES([yes])
+
+
+##                               ##
+## OS and Arch specific defaults ##
+##                               ##
+
+AS_CASE([$host],
+  [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"]
+)
 
-AC_REQUIRE_AUX_FILE([tap-driver.sh])
 
 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
@@ -44,8 +79,8 @@ AC_ARG_ENABLE([compiler-tls],
 # Checks for C compiler
 AC_USE_SYSTEM_EXTENSIONS
 AC_PROG_CC
-AC_PROG_CC_STDC
-
+# AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
+m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
 
 # Checks for programs.
@@ -114,15 +149,6 @@ AC_CHECK_HEADERS([ \
        sys/time.h \
 ])
 
-AS_CASE([$host],[*-cygwin*],
-       [AM_CONDITIONAL(USE_CYGWIN, true)],
-       [AM_CONDITIONAL(USE_CYGWIN, false)]
-)
-
-AS_IF([test "$host_cpu" = "armv7l"],[
-       AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
-])
-
 # Search for clock_gettime
 AC_SEARCH_LIBS([clock_gettime], [rt], [
        AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
@@ -255,6 +281,15 @@ AC_CHECK_FUNCS([sched_setaffinity],[
        ])
 ])
 
+##                                             ##
+## Substitute variables for use in Makefile.am ##
+##                                             ##
+
+# Library versions for libtool
+AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
+
+AC_SUBST(LT_NO_UNDEFINED)
+
 AM_CPPFLAGS="-include config.h"
 AC_SUBST(AM_CPPFLAGS)