configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu], [0.4.4], [mathieu dot desnoyers at efficios dot com])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_HOST
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11
  12 AC_CONFIG_SRCDIR([urcu.h])
  13 AM_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h urcu/config.h])
  16
  17 # Keep at the end to do not pollute installed header.
  18 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  19 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  20 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  21 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
  22 cmpxchg instruction.])
  23
  24 # Checks for programs.
  25 AC_PROG_CC
  26 AC_PROG_MAKE_SET
  27 AC_PROG_LIBTOOL
  28
  29 # Checks for typedefs, structures, and compiler characteristics.
  30 AC_C_INLINE
  31 AC_TYPE_PID_T
  32 AC_TYPE_SIZE_T
  33
  34 # Checks for library functions.
  35 AC_FUNC_MALLOC
  36 AC_FUNC_MMAP
  37 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  38
  39 # Find arch type
  40 case $host_cpu in
  41         i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
  42         i486) ARCHTYPE="x86";;
  43         i586) ARCHTYPE="x86";;
  44         i686) ARCHTYPE="x86";;
  45         x86_64) ARCHTYPE="x86";;
  46         powerpc) ARCHTYPE="ppc" ;;
  47         ppc64) ARCHTYPE="ppc" ;;
  48         powerpc64) ARCHTYPE="ppc" ;;
  49         ppc) ARCHTYPE="ppc" ;;
  50         s390) ARCHTYPE="s390" ;;
  51         s390x) ARCHTYPE="s390" ;;
  52         sparc64) ARCHTYPE="sparc64" ;;
  53         alpha*) ARCHTYPE="alpha" ;;
  54         ia64) ARCHTYPE="gcc" ;;
  55         armv7l) ARCHTYPE="armv7l" ;;
  56         *) ARCHTYPE="unknown";;
  57 esac
  58
  59 if test "$ARCHTYPE" != "unknown"; then
  60         UATOMICSRC=urcu/uatomic_arch_$ARCHTYPE.h
  61         ARCHSRC=urcu/arch_$ARCHTYPE.h
  62 else
  63         UATOMICSRC=urcu/uatomic_generic.h
  64         ARCHSRC=urcu/arch_generic.h
  65 fi
  66 if test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc; then
  67         APISRC=tests/api_gcc.h
  68 else
  69         APISRC=tests/api_$ARCHTYPE.h
  70 fi
  71 if test "$ARCHTYPE" == "armv7l"; then
  72         CFLAGS="-mcpu=cortex-a9 -mtune=cortex-a9 -O"
  73 fi
  74
  75 AC_SUBST(ARCHTYPE)
  76 AC_SUBST(SUBARCHTYPE)
  77
  78 [
  79 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
  80 #For now, using lock; addl compatibility mode even for i686, because the
  81 #Pentium III is seen as a i686, but lacks mfence instruction.
  82 #Only using fence for x86_64.
  83 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
  84 ]
  85         AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
  86 [
  87 fi
  88 ]
  89
  90 AC_MSG_CHECKING([sys_futex()])
  91 AC_TRY_COMPILE(
  92 [
  93 #include <sys/syscall.h>
  94 ],
  95 [
  96 #ifndef __NR_futex
  97 #error "futexes not available"
  98 #endif
  99 ],
 100 [
 101         AC_MSG_RESULT([yes])
 102         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 103         compat_futex_test=0
 104 ]
 105 ,
 106 [
 107         AC_MSG_RESULT([no])
 108         compat_futex_test=1
 109 ]
 110 )
 111
 112 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
 113
 114 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
 115
 116 [
 117 if test "x$SUBARCHTYPE" = xx86compat; then
 118 ]
 119         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 120 [
 121 fi
 122 ]
 123
 124 AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
 125                           on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
 126
 127 [
 128 if test "$def_smp_support" = "no"; then
 129         echo "SMP support disabled."
 130 else
 131 ]
 132         AC_DEFINE([CONFIG_RCU_SMP], [1])
 133 [
 134         echo "SMP support enabled."
 135 fi
 136 ]
 137
 138 # From the sched_setaffinity(2)'s man page:
 139 # ~~~~
 140 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 141 # The library interfaces were introduced in glibc 2.3.  Initially, the
 142 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 143 # the cpuset size argument was removed, but this argument was
 144 # restored in glibc 2.3.4.
 145 # ~~~~
 146
 147 # In addition to that, some vendors ported the system call to 2.4
 148 # kernels.
 149
 150 # Furthermore, when the function first appeared, the MASK argument was
 151 # an unsigned long pointer, while later it was made into a cpu_set_t
 152 # pointer.  Systems that have the cpu_set_t version also should have
 153 # the CPU_ZERO, CPU_SET, etc. macros.
 154
 155 # All this mess means we have to cater for at least 3 different
 156 # sched_setaffinity prototypes:
 157
 158 # ~~~~
 159 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 160 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 161 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 162 # ~~~~
 163
 164 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
 165 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
 166 dnl sched_setaffinity bits differently.
 167 saved_CFLAGS=$CFLAGS
 168 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 169
 170 # First check if the function is available at all.
 171 AC_CHECK_FUNCS(
 172   [sched_setaffinity],
 173   [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 174     # then we have the first version using unsigned long, and no
 175     # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 176     # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 177     # should also be present, but we confirm nonetheless.
 178
 179     AC_CHECK_TYPES(
 180       [cpu_set_t],
 181       [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 182         AC_MSG_CHECKING([whether CPU_ZERO works])
 183         AH_TEMPLATE([HAVE_CPU_ZERO],
 184                     [Define to 1 if we have CPU_ZERO and if it works])
 185         AC_COMPILE_IFELSE(
 186           [AC_LANG_PROGRAM(
 187             [#define _GNU_SOURCE
 188             #include <sched.h>],
 189             [cpu_set_t foo; CPU_ZERO (&foo);])
 190           ],
 191           [ # Works!
 192             AC_DEFINE(HAVE_CPU_ZERO, 1)
 193             AC_MSG_RESULT([yes])
 194           ],
 195           [AC_MSG_RESULT([no])]
 196         )
 197
 198         # Check how many arguments does sched_setaffinity take.
 199         # Should be 3 or 2.
 200         AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 201         AC_COMPILE_IFELSE(
 202           [AC_LANG_PROGRAM(
 203             [#include <sched.h>],
 204             [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
 205           ],
 206           [sched_set_affinity_args=3],
 207           [sched_set_affinity_args=2])
 208         AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 209          [Define to sched_setaffinity's number of arguments.])
 210         AC_MSG_RESULT([$sched_set_affinity_args])
 211       ],
 212       [ # No cpu_set_t, always 3 args.
 213         AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
 214       [#include <sched.h>]
 215     )
 216   ]
 217 )
 218
 219 CFLAGS=$saved_CFLAGS
 220
 221 AC_CONFIG_LINKS([
 222         urcu/arch.h:$ARCHSRC
 223         urcu/uatomic_arch.h:$UATOMICSRC
 224         tests/api.h:$APISRC
 225 ])
 226 AC_CONFIG_FILES([
 227         Makefile
 228         tests/Makefile
 229 ])
 230 AC_OUTPUT