configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu], [0.4.4], [mathieu dot desnoyers at efficios dot com])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CANONICAL_TARGET
   8 AC_CANONICAL_HOST
   9 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11
  12 AC_CONFIG_SRCDIR([urcu.h])
  13 AM_PROG_MKDIR_P
  14
  15 AC_CONFIG_HEADERS([config.h urcu/config.h])
  16
  17 # Keep at the end to do not pollute installed header.
  18 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  19 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  20 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  21 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
  22 cmpxchg instruction.])
  23
  24 # Checks for programs.
  25 AC_PROG_CC
  26 AC_PROG_MAKE_SET
  27 AC_PROG_LIBTOOL
  28
  29 # Checks for typedefs, structures, and compiler characteristics.
  30 AC_C_INLINE
  31 AC_TYPE_PID_T
  32 AC_TYPE_SIZE_T
  33
  34 # Checks for library functions.
  35 AC_FUNC_MALLOC
  36 AC_FUNC_MMAP
  37 AC_CHECK_FUNCS([bzero gettimeofday munmap strtoul])
  38
  39 # Find arch type
  40 case $host_cpu in
  41         i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
  42         i486) ARCHTYPE="x86";;
  43         i586) ARCHTYPE="x86";;
  44         i686) ARCHTYPE="x86";;
  45         x86_64) ARCHTYPE="x86";;
  46         powerpc) ARCHTYPE="ppc" ;;
  47         ppc64) ARCHTYPE="ppc" ;;
  48         powerpc64) ARCHTYPE="ppc" ;;
  49         ppc) ARCHTYPE="ppc" ;;
  50         s390) ARCHTYPE="s390" ;;
  51         s390x) ARCHTYPE="s390" ;;
  52         sparc64) ARCHTYPE="sparc64" ;;
  53         alpha*) ARCHTYPE="alpha" ;;
  54         ia64) ARCHTYPE="gcc" ;;
  55         *) ARCHTYPE="unknown";;
  56 esac
  57
  58 if test "$ARCHTYPE" != "unknown"; then
  59         UATOMICSRC=urcu/uatomic_arch_$ARCHTYPE.h
  60         ARCHSRC=urcu/arch_$ARCHTYPE.h
  61 else
  62         UATOMICSRC=urcu/uatomic_generic.h
  63         ARCHSRC=urcu/arch_generic.h
  64 fi
  65 if test "x$ARCHTYPE" != xx86 -a "x$ARCHTYPE" != xppc; then
  66         APISRC=tests/api_gcc.h
  67 else
  68         APISRC=tests/api_$ARCHTYPE.h
  69 fi
  70
  71 AC_SUBST(ARCHTYPE)
  72 AC_SUBST(SUBARCHTYPE)
  73
  74 [
  75 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
  76 #For now, using lock; addl compatibility mode even for i686, because the
  77 #Pentium III is seen as a i686, but lacks mfence instruction.
  78 #Only using fence for x86_64.
  79 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
  80 ]
  81         AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
  82 [
  83 fi
  84 ]
  85
  86 AC_MSG_CHECKING([sys_futex()])
  87 AC_TRY_COMPILE(
  88 [
  89 #include <sys/syscall.h>
  90 ],
  91 [
  92 #ifndef __NR_futex
  93 #error "futexes not available"
  94 #endif
  95 ],
  96 [
  97         AC_MSG_RESULT([yes])
  98         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
  99         compat_futex_test=0
 100 ]
 101 ,
 102 [
 103         AC_MSG_RESULT([no])
 104         compat_futex_test=1
 105 ]
 106 )
 107
 108 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
 109
 110 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
 111
 112 [
 113 if test "x$SUBARCHTYPE" = xx86compat; then
 114 ]
 115         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 116 [
 117 fi
 118 ]
 119
 120 AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
 121                           on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
 122
 123 [
 124 if test "$def_smp_support" = "no"; then
 125         echo "SMP support disabled."
 126 else
 127 ]
 128         AC_DEFINE([CONFIG_RCU_SMP], [1])
 129 [
 130         echo "SMP support enabled."
 131 fi
 132 ]
 133
 134 # From the sched_setaffinity(2)'s man page:
 135 # ~~~~
 136 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 137 # The library interfaces were introduced in glibc 2.3.  Initially, the
 138 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 139 # the cpuset size argument was removed, but this argument was
 140 # restored in glibc 2.3.4.
 141 # ~~~~
 142
 143 # In addition to that, some vendors ported the system call to 2.4
 144 # kernels.
 145
 146 # Furthermore, when the function first appeared, the MASK argument was
 147 # an unsigned long pointer, while later it was made into a cpu_set_t
 148 # pointer.  Systems that have the cpu_set_t version also should have
 149 # the CPU_ZERO, CPU_SET, etc. macros.
 150
 151 # All this mess means we have to cater for at least 3 different
 152 # sched_setaffinity prototypes:
 153
 154 # ~~~~
 155 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 156 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 157 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 158 # ~~~~
 159
 160 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
 161 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
 162 dnl sched_setaffinity bits differently.
 163 saved_CFLAGS=$CFLAGS
 164 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 165
 166 # First check if the function is available at all.
 167 AC_CHECK_FUNCS(
 168   [sched_setaffinity],
 169   [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 170     # then we have the first version using unsigned long, and no
 171     # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 172     # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 173     # should also be present, but we confirm nonetheless.
 174
 175     AC_CHECK_TYPES(
 176       [cpu_set_t],
 177       [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 178         AC_MSG_CHECKING([whether CPU_ZERO works])
 179         AH_TEMPLATE([HAVE_CPU_ZERO],
 180                     [Define to 1 if we have CPU_ZERO and if it works])
 181         AC_COMPILE_IFELSE(
 182           [AC_LANG_PROGRAM(
 183             [#define _GNU_SOURCE
 184             #include <sched.h>],
 185             [cpu_set_t foo; CPU_ZERO (&foo);])
 186           ],
 187           [ # Works!
 188             AC_DEFINE(HAVE_CPU_ZERO, 1)
 189             AC_MSG_RESULT([yes])
 190           ],
 191           [AC_MSG_RESULT([no])]
 192         )
 193
 194         # Check how many arguments does sched_setaffinity take.
 195         # Should be 3 or 2.
 196         AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 197         AC_COMPILE_IFELSE(
 198           [AC_LANG_PROGRAM(
 199             [#include <sched.h>],
 200             [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
 201           ],
 202           [sched_set_affinity_args=3],
 203           [sched_set_affinity_args=2])
 204         AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 205          [Define to sched_setaffinity's number of arguments.])
 206         AC_MSG_RESULT([$sched_set_affinity_args])
 207       ],
 208       [ # No cpu_set_t, always 3 args.
 209         AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
 210       [#include <sched.h>]
 211     )
 212   ]
 213 )
 214
 215 CFLAGS=$saved_CFLAGS
 216
 217 AC_CONFIG_LINKS([
 218         urcu/arch.h:$ARCHSRC
 219         urcu/uatomic_arch.h:$UATOMICSRC
 220         tests/api.h:$APISRC
 221 ])
 222 AC_CONFIG_FILES([
 223         Makefile
 224         tests/Makefile
 225 ])
 226 AC_OUTPUT