configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 # Project version information
   8 m4_define([urcu_version_major], [0])
   9 m4_define([urcu_version_minor], [12])
  10 m4_define([urcu_version_patch], [0])
  11 m4_define([urcu_version_dev_stage], [])
  12 m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
  13
  14 # Library version information of "liburcu"
  15 # Following the numbering scheme proposed by libtool for the library version
  16 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  17 m4_define([urcu_lib_version_current], [7])
  18 m4_define([urcu_lib_version_revision], [0])
  19 m4_define([urcu_lib_version_age], [1])
  20 m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
  21
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.69])
  28 AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
  29
  30 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
  31 AC_CONFIG_AUX_DIR([config])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 AC_CANONICAL_TARGET
  35 AC_CANONICAL_HOST
  36
  37
  38 ##                     ##
  39 ## Automake base setup ##
  40 ##                     ##
  41
  42 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
  43 AM_MAINTAINER_MODE([enable])
  44
  45 # Enable silent rules by default
  46 AM_SILENT_RULES([yes])
  47
  48 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  49
  50 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  51 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  52 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  53 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
  54 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduces a performance penalty.])
  55 AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
  56
  57 # Allow requiring the operating system to support the membarrier system
  58 # call. Applies to default and bulletproof flavors.
  59 AC_ARG_ENABLE([sys-membarrier-fallback],
  60         AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
  61         [def_sys_membarrier_fallback=$enableval],
  62         [def_sys_membarrier_fallback="yes"])
  63 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
  64
  65 # Allow overriding storage used for TLS variables.
  66 AC_ARG_ENABLE([compiler-tls],
  67         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  68         [def_compiler_tls=$enableval],
  69         [def_compiler_tls="yes"])
  70
  71 # Checks for C compiler
  72 AC_USE_SYSTEM_EXTENSIONS
  73 AC_PROG_CC
  74 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  75 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  76 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
  77
  78 # Checks for programs.
  79 AC_PROG_AWK
  80 AC_PROG_MAKE_SET
  81 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  82 AC_CHECK_PROGS(GETCONF, [getconf])
  83 AS_IF([test "x$NPROC" != "x"],
  84         [NPROC_CMD=$NPROC],
  85         [AS_IF([test "x$GETCONF" != "x"],
  86                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  87                 [NPROC_CMD="echo 1"]
  88         )]
  89 )
  90 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  91
  92 LT_INIT
  93
  94 # Checks for typedefs, structures, and compiler characteristics.
  95 AC_C_INLINE
  96 AC_TYPE_PID_T
  97 AC_TYPE_SIZE_T
  98 AC_TYPE_SSIZE_T
  99 AC_TYPE_UINT16_T
 100 AC_TYPE_INT32_T
 101 AC_TYPE_UINT32_T
 102 AC_TYPE_UINT64_T
 103 AC_TYPE_UINT8_T
 104
 105 AX_C___ATTRIBUTE__
 106 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 107         [:],
 108         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 109
 110 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 111
 112 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 113
 114 # Checks for library functions.
 115 AC_FUNC_MMAP
 116 AC_FUNC_FORK
 117 AC_CHECK_FUNCS([ \
 118         atexit \
 119         getcpuid \
 120         gettid \
 121         gettimeofday \
 122         memeset \
 123         memset \
 124         munmap \
 125         rand_r \
 126         sched_getcpu \
 127         strerror \
 128         strtoul \
 129         sysconf \
 130 ])
 131
 132 # AC_FUNC_MALLOC causes problems when cross-compiling.
 133 #AC_FUNC_MALLOC
 134
 135 # Check for headers
 136 AC_HEADER_STDBOOL
 137 AC_CHECK_HEADERS([ \
 138         limits.h \
 139         stddef.h \
 140         sys/param.h \
 141         sys/time.h \
 142 ])
 143
 144 AS_CASE([$host],[*-cygwin*],
 145         [AM_CONDITIONAL(USE_CYGWIN, true)],
 146         [AM_CONDITIONAL(USE_CYGWIN, false)]
 147 )
 148
 149 # Search for clock_gettime
 150 AC_SEARCH_LIBS([clock_gettime], [rt], [
 151         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 152         config_rcu_have_clock_gettime=yes
 153 ], [])
 154
 155 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 156
 157 # smp-support configure option
 158 AC_ARG_ENABLE([smp-support],
 159         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 160         [def_smp_support=$enableval],
 161         [def_smp_support="yes"])
 162 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 163
 164 # RCU debugging option
 165 AC_ARG_ENABLE([rcu-debug],
 166       AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
 167                       self-checks. Introduces a performance penalty.]))
 168 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
 169        AC_DEFINE([CONFIG_RCU_DEBUG], [1])
 170 ])
 171
 172 # rculfhash iterator debugging
 173 AC_ARG_ENABLE([cds-lfht-iter-debug],
 174       AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
 175 AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
 176        AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
 177 ])
 178
 179 # From the sched_setaffinity(2)'s man page:
 180 # ~~~~
 181 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 182 # The library interfaces were introduced in glibc 2.3.  Initially, the
 183 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 184 # the cpuset size argument was removed, but this argument was
 185 # restored in glibc 2.3.4.
 186 # ~~~~
 187
 188 # In addition to that, some vendors ported the system call to 2.4
 189 # kernels.
 190
 191 # Furthermore, when the function first appeared, the MASK argument was
 192 # an unsigned long pointer, while later it was made into a cpu_set_t
 193 # pointer.  Systems that have the cpu_set_t version also should have
 194 # the CPU_ZERO, CPU_SET, etc. macros.
 195
 196 # All this mess means we have to cater for at least 3 different
 197 # sched_setaffinity prototypes:
 198
 199 # ~~~~
 200 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 201 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 202 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 203 # ~~~~
 204
 205 AC_CHECK_TYPES([cpu_set_t],
 206         [have_cpu_set_t="yes"],
 207         [have_cpu_set_t="no"],
 208         [#include <sched.h>])
 209
 210 # Confirm that we have CPU_ZERO, and it actually works.
 211 AC_MSG_CHECKING([whether CPU_ZERO works])
 212 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 213 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 214                 #include <sched.h>
 215                 int main()
 216                 {
 217                         cpu_set_t foo; CPU_ZERO(&foo);
 218                         return 0;
 219                 }
 220         ]])
 221 ],[
 222         AC_DEFINE(HAVE_CPU_ZERO, 1)
 223         AC_MSG_RESULT([yes])
 224 ],[
 225         AC_MSG_RESULT([no])
 226 ])
 227
 228 # Confirm that we have CPU_SET, and it actually works.
 229 AC_MSG_CHECKING([whether CPU_SET works])
 230 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 231 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 232                 #include <sched.h>
 233                 int main()
 234                 {
 235                         cpu_set_t foo; CPU_SET(0, &foo);
 236                         return 0;
 237                 }
 238         ]])
 239 ],[
 240         AC_DEFINE(HAVE_CPU_SET, 1)
 241         AC_MSG_RESULT([yes])
 242 ],[
 243         AC_MSG_RESULT([no])
 244 ])
 245
 246 # First check if the function is available at all.
 247 AC_CHECK_FUNCS([sched_setaffinity],[
 248         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 249         # then we have the first version using unsigned long, and no
 250         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 251         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 252         # should also be present, but we confirm nonetheless.
 253
 254         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 255                 # We do have it.
 256                 # Check how many arguments does sched_setaffinity take.
 257                 # Should be 3 or 2.
 258                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 259                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 260                                 #include <sched.h>
 261                                 int main()
 262                                 {
 263                                         cpu_set_t foo;
 264                                         sched_setaffinity(0, sizeof (foo), &foo);
 265                                         return 0;
 266                                 }
 267                         ]])
 268                 ],
 269                 [sched_set_affinity_args=3],
 270                 [sched_set_affinity_args=2])
 271                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 272                         $sched_set_affinity_args,
 273                         [Defined to sched_setaffinity's number of arguments.])
 274                 AC_MSG_RESULT([$sched_set_affinity_args])
 275         ],[
 276                 # No cpu_set_t, always 3 args.
 277                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 278         ])
 279 ])
 280
 281 ##                                             ##
 282 ## Substitute variables for use in Makefile.am ##
 283 ##                                             ##
 284
 285 # Library versions for libtool
 286 AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
 287
 288 AM_CPPFLAGS="-include config.h"
 289 AC_SUBST(AM_CPPFLAGS)
 290
 291 AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
 292 AC_SUBST(AM_CFLAGS)
 293
 294 AC_CONFIG_FILES([
 295         Makefile
 296         doc/Makefile
 297         doc/examples/Makefile
 298         include/Makefile
 299         src/Makefile
 300         tests/Makefile
 301         tests/common/Makefile
 302         tests/unit/Makefile
 303         tests/benchmark/Makefile
 304         tests/regression/Makefile
 305         tests/utils/Makefile
 306         src/liburcu.pc
 307         src/liburcu-bp.pc
 308         src/liburcu-cds.pc
 309         src/liburcu-qsbr.pc
 310         src/liburcu-mb.pc
 311         src/liburcu-signal.pc
 312 ])
 313
 314 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 315 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 316 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 317 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 318 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 319 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 320 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 321 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 322 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 323 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 324 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 325 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 326 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 327 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 328 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 329 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 330 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 331 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 332 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 333 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 334 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 335 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 336 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 337 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 338 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 339 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 340 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 341 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 342 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 343 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 344 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 345 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 346 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 347 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 348 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 349 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 350 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 351 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 352 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 353 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 354 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 355 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 356 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 357 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 358 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 359 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 360 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 361 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 362 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 363 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 364 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 365 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 366 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 367 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 368 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 369 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 370 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 371 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 372 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 373 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 374
 375
 376 AC_OUTPUT
 377
 378 #
 379 # Mini-report on what will be built.
 380 #
 381
 382 PPRINT_INIT
 383 PPRINT_SET_INDENT(1)
 384 PPRINT_SET_TS(38)
 385
 386 AS_ECHO
 387 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 388 AS_ECHO
 389
 390 PPRINT_SUBTITLE([Features])
 391
 392 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 393
 394 # SMP support enabled/disabled
 395 test "x$def_smp_support" = "xyes" && value=1 || value=0
 396 PPRINT_PROP_BOOL([SMP support], $value)
 397
 398 # TLS
 399 test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()"
 400 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 401
 402 # clock_gettime() available
 403 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
 404 PPRINT_PROP_BOOL([clock_gettime()], $value)
 405
 406 # Require membarrier
 407 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
 408 PPRINT_PROP_BOOL([Require membarrier], $value)
 409
 410 # RCU debug enabled/disabled
 411 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
 412 PPRINT_PROP_BOOL([Internal debugging], $value)
 413
 414 # rculfhash iterator debug enabled/disabled
 415 test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
 416 PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
 417
 418 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 419
 420 report_bindir="`eval eval echo $bindir`"
 421 report_libdir="`eval eval echo $libdir`"
 422
 423 # Print the bindir and libdir this `make install' will install into.
 424 AS_ECHO
 425 PPRINT_SUBTITLE([Install directories])
 426 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 427 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 428