configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  29
  30 # Allow overriding storage used for TLS variables.
  31 AC_ARG_ENABLE([compiler-tls],
  32         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  33         [def_compiler_tls=$enableval],
  34         [def_compiler_tls="yes"])
  35
  36 # If not overridden, use ax_tls.m4 to check if TLS is available.
  37 AS_IF([test "x$def_compiler_tls" = "xyes"],
  38         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  39         [:])
  40
  41 AS_IF([test "x$def_tls_detect" = "x"],
  42         [:],
  43         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  44
  45 # Checks for C compiler
  46 AC_USE_SYSTEM_EXTENSIONS
  47 AC_PROG_CC
  48 AC_PROG_CC_STDC
  49
  50 # Checks for programs.
  51 AC_PROG_AWK
  52 AC_PROG_MAKE_SET
  53 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  54 AC_CHECK_PROGS(GETCONF, [getconf])
  55 AS_IF([test "x$NPROC" != "x"],
  56         [NPROC_CMD=$NPROC],
  57         [AS_IF([test "x$GETCONF" != "x"],
  58                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  59                 [NPROC_CMD="echo 1"]
  60         )]
  61 )
  62 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  63
  64 LT_INIT
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_INLINE
  68 AC_TYPE_PID_T
  69 AC_TYPE_SIZE_T
  70 AC_TYPE_SSIZE_T
  71 AC_TYPE_UINT16_T
  72 AC_TYPE_INT32_T
  73 AC_TYPE_UINT32_T
  74 AC_TYPE_UINT64_T
  75 AC_TYPE_UINT8_T
  76
  77 AX_C___ATTRIBUTE__
  78 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  79         [:],
  80         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  81
  82 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  83 LIBS="$PTHREAD_LIBS $LIBS"
  84 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  85 CC="$PTHREAD_CC"
  86
  87 # Checks for library functions.
  88 AC_FUNC_MALLOC
  89 AC_FUNC_MMAP
  90 AC_FUNC_FORK
  91 AC_CHECK_FUNCS([ \
  92         atexit \
  93         getcpuid \
  94         gettid \
  95         gettimeofday \
  96         memeset \
  97         memset \
  98         munmap \
  99         sched_getcpu \
 100         strerror \
 101         strtoul \
 102         sysconf \
 103 ])
 104
 105 # Check for headers
 106 AC_HEADER_STDBOOL
 107 AC_CHECK_HEADERS([ \
 108         limits.h \
 109         stddef.h \
 110         sys/param.h \
 111         sys/time.h \
 112 ])
 113
 114 # Find arch type
 115 AS_CASE([$host_cpu],
 116         [k1om], [ARCHTYPE="x86"],
 117         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 118         [i486], [ARCHTYPE="x86"],
 119         [i586], [ARCHTYPE="x86"],
 120         [i686], [ARCHTYPE="x86"],
 121         [amd64], [ARCHTYPE="x86"],
 122         [x86_64], [ARCHTYPE="x86"],
 123         [powerpc], [ARCHTYPE="ppc"],
 124         [ppc64], [ARCHTYPE="ppc"],
 125         [powerpc64], [ARCHTYPE="ppc"],
 126         [powerpc64le], [ARCHTYPE="ppc"],
 127         [ppc], [ARCHTYPE="ppc"],
 128         [s390], [ARCHTYPE="s390"],
 129         [s390x], [ARCHTYPE="s390"],
 130         [sparc], [ARCHTYPE="sparc64"],
 131         [sparc64], [ARCHTYPE="sparc64"],
 132         [alpha*], [ARCHTYPE="alpha"],
 133         [ia64], [ARCHTYPE="ia64"],
 134         [arm*], [ARCHTYPE="arm"],
 135         [aarch64*], [ARCHTYPE="aarch64"],
 136         [mips*], [ARCHTYPE="mips"],
 137         [nios2*], [ARCHTYPE="nios2"],
 138         [tile*], [ARCHTYPE="tile"],
 139         [hppa*], [ARCHTYPE="hppa"],
 140         [ARCHTYPE="unknown"]
 141 )
 142
 143 AS_CASE([$host],[*-cygwin*],
 144         [AM_CONDITIONAL(USE_CYGWIN, true)],
 145         [AM_CONDITIONAL(USE_CYGWIN, false)]
 146 )
 147
 148 AC_SUBST(ARCHTYPE)
 149 AC_SUBST(SUBARCHTYPE)
 150
 151 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 152 ARCHSRC=urcu/arch/$ARCHTYPE.h
 153
 154 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 155         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 156 ])
 157
 158 AS_IF([test "$host_cpu" = "armv7l"],[
 159         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 160 ])
 161
 162 # ARM-specific checks
 163 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 164         AC_MSG_CHECKING([for dmb instruction])
 165         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 166                                 int main()
 167                                 {
 168                                         asm volatile("dmb":::"memory");
 169                                         return 0;
 170                                 }
 171                 ]])
 172         ],[
 173                 AC_MSG_RESULT([yes])
 174                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 175         ],[
 176                 AC_MSG_RESULT([no])
 177         ])
 178 ])
 179
 180 # Tile-specific checks
 181 AS_IF([echo "$host_cpu" | grep "^tile"],[
 182         AC_MSG_CHECKING([for Tile architecture type])
 183         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 184                                 #ifndef __tilegx__
 185                                 #error
 186                                 #endif
 187                 ]])
 188         ],[
 189                 AC_MSG_RESULT([ok])
 190         ],[
 191                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 192         ])
 193 ])
 194
 195 # x86-specific checks
 196 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 197         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 198         #For now, using lock; addl compatibility mode even for i686, because the
 199         #Pentium III is seen as a i686, but lacks mfence instruction.
 200         #Only using fence for x86_64.
 201         #
 202         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 203         #variant but lacks fence instructions.
 204         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 205                 AC_MSG_RESULT([yes])
 206                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 207         ],[
 208                 AC_MSG_RESULT([no])
 209         ])
 210 ])
 211
 212 # Check if sys_futex() is available
 213 AC_MSG_CHECKING([for sys_futex()])
 214 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 215                 #include <sys/syscall.h>
 216                 #ifndef __NR_futex
 217                 #error "futexes not available"
 218                 #endif
 219         ]])
 220 ],[
 221         AC_MSG_RESULT([yes])
 222         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 223         compat_futex_test=0
 224 ],[
 225         AC_MSG_RESULT([no])
 226         compat_futex_test=1
 227 ])
 228
 229 # Search for clock_gettime
 230 AC_SEARCH_LIBS([clock_gettime], [rt], [
 231         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 232 ], [])
 233
 234 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 235 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 236 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 237
 238 # smp-support configure option
 239 AC_ARG_ENABLE([smp-support],
 240         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 241         [def_smp_support=$enableval],
 242         [def_smp_support="yes"])
 243 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 244
 245
 246 # From the sched_setaffinity(2)'s man page:
 247 # ~~~~
 248 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 249 # The library interfaces were introduced in glibc 2.3.  Initially, the
 250 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 251 # the cpuset size argument was removed, but this argument was
 252 # restored in glibc 2.3.4.
 253 # ~~~~
 254
 255 # In addition to that, some vendors ported the system call to 2.4
 256 # kernels.
 257
 258 # Furthermore, when the function first appeared, the MASK argument was
 259 # an unsigned long pointer, while later it was made into a cpu_set_t
 260 # pointer.  Systems that have the cpu_set_t version also should have
 261 # the CPU_ZERO, CPU_SET, etc. macros.
 262
 263 # All this mess means we have to cater for at least 3 different
 264 # sched_setaffinity prototypes:
 265
 266 # ~~~~
 267 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 268 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 269 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 270 # ~~~~
 271
 272 # Since we define _GNU_SOURCE in the sources, must do so too in the
 273 # autoconf tests, as defining _GNU_SOURCE or not exposes
 274 # sched_setaffinity bits differently.
 275 saved_CFLAGS=$CFLAGS
 276 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 277
 278 AC_CHECK_TYPES([cpu_set_t],
 279         [have_cpu_set_t="yes"],
 280         [have_cpu_set_t="no"],
 281         [#include <sched.h>])
 282
 283 # Confirm that we have CPU_ZERO, and it actually works.
 284 AC_MSG_CHECKING([whether CPU_ZERO works])
 285 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 286 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 287                 #define _GNU_SOURCE
 288                 #include <sched.h>
 289                 int main()
 290                 {
 291                         cpu_set_t foo; CPU_ZERO(&foo);
 292                         return 0;
 293                 }
 294         ]])
 295 ],[
 296         AC_DEFINE(HAVE_CPU_ZERO, 1)
 297         AC_MSG_RESULT([yes])
 298 ],[
 299         AC_MSG_RESULT([no])
 300 ])
 301
 302 # Confirm that we have CPU_SET, and it actually works.
 303 AC_MSG_CHECKING([whether CPU_SET works])
 304 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 305 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 306                 #define _GNU_SOURCE
 307                 #include <sched.h>
 308                 int main()
 309                 {
 310                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 311                         return 0;
 312                 }
 313         ]])
 314 ],[
 315         AC_DEFINE(HAVE_CPU_SET, 1)
 316         AC_MSG_RESULT([yes])
 317 ],[
 318         AC_MSG_RESULT([no])
 319 ])
 320
 321 # First check if the function is available at all.
 322 AC_CHECK_FUNCS([sched_setaffinity],[
 323         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 324         # then we have the first version using unsigned long, and no
 325         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 326         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 327         # should also be present, but we confirm nonetheless.
 328
 329         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 330                 # We do have it.
 331                 # Check how many arguments does sched_setaffinity take.
 332                 # Should be 3 or 2.
 333                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 334                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 335                                 #include <sched.h>
 336                                 int main()
 337                                 {
 338                                         cpu_set_t foo;
 339                                         sched_setaffinity(0, sizeof (foo), &foo);
 340                                         return 0;
 341                                 }
 342                         ]])
 343                 ],
 344                 [sched_set_affinity_args=3],
 345                 [sched_set_affinity_args=2])
 346                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 347                         $sched_set_affinity_args,
 348                         [Defined to sched_setaffinity's number of arguments.])
 349                 AC_MSG_RESULT([$sched_set_affinity_args])
 350         ],[
 351                 # No cpu_set_t, always 3 args.
 352                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 353         ])
 354 ])
 355
 356 CFLAGS=$saved_CFLAGS
 357
 358 AC_CONFIG_LINKS([
 359         urcu/arch.h:$ARCHSRC
 360         urcu/uatomic.h:$UATOMICSRC
 361 ])
 362 AC_CONFIG_FILES([
 363         Makefile
 364         doc/Makefile
 365         doc/examples/Makefile
 366         tests/Makefile
 367         tests/common/Makefile
 368         tests/unit/Makefile
 369         tests/benchmark/Makefile
 370         tests/regression/Makefile
 371         tests/regression/regression_tests
 372         tests/utils/Makefile
 373         liburcu.pc
 374         liburcu-bp.pc
 375         liburcu-cds.pc
 376         liburcu-qsbr.pc
 377         liburcu-mb.pc
 378         liburcu-signal.pc
 379 ])
 380 AC_OUTPUT
 381
 382 # Report on selected configure options
 383 AS_IF([test "x$def_smp_support" = "xyes"],[
 384         AS_ECHO("SMP support enabled.")
 385 ],[
 386         AS_ECHO("SMP support disabled.")
 387 ])
 388
 389 AS_IF([test "x$def_tls_detect" = "x"],[
 390         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 391 ],[
 392         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 393 ])