configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18
  19 m4_include([config/ax_tls.m4])
  20
  21 AC_CONFIG_SRCDIR([urcu.h])
  22
  23 AC_CONFIG_HEADERS([config.h urcu/config.h])
  24
  25 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  28 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  29 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  30 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  31
  32 # Allow overriding storage used for TLS variables.
  33 AC_ARG_ENABLE([compiler-tls],
  34         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  35         [def_compiler_tls=$enableval],
  36         [def_compiler_tls="yes"])
  37
  38 # If not overridden, use ax_tls.m4 to check if TLS is available.
  39 AS_IF([test "x$def_compiler_tls" = "xyes"],
  40         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  41         [:])
  42
  43 AS_IF([test "x$def_tls_detect" = "x"],
  44         [:],
  45         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  46
  47 # Checks for programs.
  48 AC_PROG_CC
  49 AC_PROG_MAKE_SET
  50 LT_INIT
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_INLINE
  54 AC_TYPE_PID_T
  55 AC_TYPE_SIZE_T
  56
  57 # Checks for library functions.
  58 AC_FUNC_MALLOC
  59 AC_FUNC_MMAP
  60 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid])
  61
  62 # Find arch type
  63 AS_CASE([$host_cpu],
  64         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  65         [i486], [ARCHTYPE="x86"],
  66         [i586], [ARCHTYPE="x86"],
  67         [i686], [ARCHTYPE="x86"],
  68         [amd64], [ARCHTYPE="x86"],
  69         [x86_64], [ARCHTYPE="x86"],
  70         [powerpc], [ARCHTYPE="ppc"],
  71         [ppc64], [ARCHTYPE="ppc"],
  72         [powerpc64], [ARCHTYPE="ppc"],
  73         [powerpc64le], [ARCHTYPE="gcc"],
  74         [ppc], [ARCHTYPE="ppc"],
  75         [s390], [ARCHTYPE="s390"],
  76         [s390x], [ARCHTYPE="s390"],
  77         [sparc], [ARCHTYPE="sparc64"],
  78         [sparc64], [ARCHTYPE="sparc64"],
  79         [alpha*], [ARCHTYPE="alpha"],
  80         [ia64], [ARCHTYPE="gcc"],
  81         [arm*], [ARCHTYPE="arm"],
  82         [aarch64], [ARCHTYPE="gcc"],
  83         [mips*], [ARCHTYPE="mips"],
  84         [tile*], [ARCHTYPE="gcc"],
  85         [ARCHTYPE="unknown"]
  86 )
  87
  88 AS_CASE([$host],[*-*-linux-androideabi],
  89         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
  90         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
  91 )
  92
  93 AC_SUBST(ARCHTYPE)
  94 AC_SUBST(SUBARCHTYPE)
  95
  96 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  97 ARCHSRC=urcu/arch/$ARCHTYPE.h
  98
  99 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 100         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 101 ])
 102
 103 AS_IF([test "$host_cpu" = "armv7l"],[
 104         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 105 ])
 106
 107 # ARM-specific checks
 108 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 109         AC_MSG_CHECKING([for dmb instruction])
 110         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 111                                 int main()
 112                                 {
 113                                         asm volatile("dmb":::"memory");
 114                                         return 0;
 115                                 }
 116                 ]])
 117         ],[
 118                 AC_MSG_RESULT([yes])
 119                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 120         ],[
 121                 AC_MSG_RESULT([no])
 122         ])
 123 ])
 124
 125 # Tile-specific checks
 126 AS_IF([echo "$host_cpu" | grep "^tile"],[
 127         AC_MSG_CHECKING([for Tile architecture type])
 128         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 129                                 #ifndef __tilegx__
 130                                 #error
 131                                 #endif
 132                 ]])
 133         ],[
 134                 AC_MSG_RESULT([ok])
 135         ],[
 136                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 137         ])
 138 ])
 139
 140 # x86-specific checks
 141 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 142         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 143         #For now, using lock; addl compatibility mode even for i686, because the
 144         #Pentium III is seen as a i686, but lacks mfence instruction.
 145         #Only using fence for x86_64.
 146         #
 147         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 148         #variant but lacks fence instructions.
 149         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
 150                 AC_MSG_RESULT([yes])
 151                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 152         ],[
 153                 AC_MSG_RESULT([no])
 154         ])
 155 ])
 156
 157 # Check if sys_futex() is available
 158 AC_MSG_CHECKING([for sys_futex()])
 159 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 160                 #include <sys/syscall.h>
 161                 #ifndef __NR_futex
 162                 #error "futexes not available"
 163                 #endif
 164         ]])
 165 ],[
 166         AC_MSG_RESULT([yes])
 167         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 168         compat_futex_test=0
 169 ],[
 170         AC_MSG_RESULT([no])
 171         compat_futex_test=1
 172 ])
 173
 174 # Check for pthread
 175 AC_CHECK_LIB([pthread], [pthread_create],
 176         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 177         [AC_CHECK_LIB([c], [pthread_create],
 178                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 179                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 180         )]
 181 )
 182
 183 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 184 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 185 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 186
 187 # smp-support configure option
 188 AC_ARG_ENABLE([smp-support],
 189         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 190         [def_smp_support=$enableval],
 191         [def_smp_support="yes"])
 192 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 193
 194
 195 # From the sched_setaffinity(2)'s man page:
 196 # ~~~~
 197 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 198 # The library interfaces were introduced in glibc 2.3.  Initially, the
 199 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 200 # the cpuset size argument was removed, but this argument was
 201 # restored in glibc 2.3.4.
 202 # ~~~~
 203
 204 # In addition to that, some vendors ported the system call to 2.4
 205 # kernels.
 206
 207 # Furthermore, when the function first appeared, the MASK argument was
 208 # an unsigned long pointer, while later it was made into a cpu_set_t
 209 # pointer.  Systems that have the cpu_set_t version also should have
 210 # the CPU_ZERO, CPU_SET, etc. macros.
 211
 212 # All this mess means we have to cater for at least 3 different
 213 # sched_setaffinity prototypes:
 214
 215 # ~~~~
 216 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 217 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 218 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 219 # ~~~~
 220
 221 # Since we define _GNU_SOURCE in the sources, must do so too in the
 222 # autoconf tests, as defining _GNU_SOURCE or not exposes
 223 # sched_setaffinity bits differently.
 224 saved_CFLAGS=$CFLAGS
 225 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 226
 227 AC_CHECK_TYPES([cpu_set_t],
 228         [have_cpu_set_t="yes"],
 229         [have_cpu_set_t="no"],
 230         [#include <sched.h>])
 231
 232 # Confirm that we have CPU_ZERO, and it actually works.
 233 AC_MSG_CHECKING([whether CPU_ZERO works])
 234 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 235 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 236                 #define _GNU_SOURCE
 237                 #include <sched.h>
 238                 int main()
 239                 {
 240                         cpu_set_t foo; CPU_ZERO(&foo);
 241                         return 0;
 242                 }
 243         ]])
 244 ],[
 245         AC_DEFINE(HAVE_CPU_ZERO, 1)
 246         AC_MSG_RESULT([yes])
 247 ],[
 248         AC_MSG_RESULT([no])
 249 ])
 250
 251 # Confirm that we have CPU_SET, and it actually works.
 252 AC_MSG_CHECKING([whether CPU_SET works])
 253 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 254 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 255                 #define _GNU_SOURCE
 256                 #include <sched.h>
 257                 int main()
 258                 {
 259                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 260                         return 0;
 261                 }
 262         ]])
 263 ],[
 264         AC_DEFINE(HAVE_CPU_SET, 1)
 265         AC_MSG_RESULT([yes])
 266 ],[
 267         AC_MSG_RESULT([no])
 268 ])
 269
 270 # First check if the function is available at all.
 271 AC_CHECK_FUNCS([sched_setaffinity],[
 272         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 273         # then we have the first version using unsigned long, and no
 274         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 275         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 276         # should also be present, but we confirm nonetheless.
 277
 278         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 279                 # We do have it.
 280                 # Check how many arguments does sched_setaffinity take.
 281                 # Should be 3 or 2.
 282                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 283                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 284                                 #include <sched.h>
 285                                 int main()
 286                                 {
 287                                         cpu_set_t foo;
 288                                         sched_setaffinity(0, sizeof (foo), &foo);
 289                                         return 0;
 290                                 }
 291                         ]])
 292                 ],
 293                 [sched_set_affinity_args=3],
 294                 [sched_set_affinity_args=2])
 295                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 296                         $sched_set_affinity_args,
 297                         [Defined to sched_setaffinity's number of arguments.])
 298                 AC_MSG_RESULT([$sched_set_affinity_args])
 299         ],[
 300                 # No cpu_set_t, always 3 args.
 301                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 302         ])
 303 ])
 304
 305 CFLAGS=$saved_CFLAGS
 306
 307 AC_CONFIG_LINKS([
 308         urcu/arch.h:$ARCHSRC
 309         urcu/uatomic.h:$UATOMICSRC
 310 ])
 311 AC_CONFIG_FILES([
 312         Makefile
 313         doc/Makefile
 314         doc/examples/Makefile
 315         tests/Makefile
 316         tests/common/Makefile
 317         tests/unit/Makefile
 318         tests/benchmark/Makefile
 319         tests/regression/Makefile
 320         liburcu.pc
 321         liburcu-bp.pc
 322         liburcu-cds.pc
 323         liburcu-qsbr.pc
 324         liburcu-mb.pc
 325         liburcu-signal.pc
 326 ])
 327 AC_OUTPUT
 328
 329 # Report on selected configure options
 330 AS_IF([test "x$def_smp_support" = "xyes"],[
 331         AS_ECHO("SMP support enabled.")
 332 ],[
 333         AS_ECHO("SMP support disabled.")
 334 ])
 335
 336 AS_IF([test "x$def_tls_detect" = "x"],[
 337         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 338 ],[
 339         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 340 ])