configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28
  29 # Allow overriding storage used for TLS variables.
  30 AC_ARG_ENABLE([compiler-tls],
  31         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  32         [def_compiler_tls=$enableval],
  33         [def_compiler_tls="yes"])
  34
  35 # If not overridden, use ax_tls.m4 to check if TLS is available.
  36 AS_IF([test "x$def_compiler_tls" = "xyes"],
  37         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  38         [:])
  39
  40 AS_IF([test "x$def_tls_detect" = "x"],
  41         [:],
  42         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  43
  44 # Checks for C compiler
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_PROG_CC
  47 AC_PROG_CC_STDC
  48
  49 # Checks for programs.
  50 AC_PROG_AWK
  51 AC_PROG_MAKE_SET
  52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  53 LT_INIT
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_INLINE
  57 AC_TYPE_PID_T
  58 AC_TYPE_SIZE_T
  59 AC_TYPE_SSIZE_T
  60 AC_TYPE_UINT16_T
  61 AC_TYPE_INT32_T
  62 AC_TYPE_UINT32_T
  63 AC_TYPE_UINT64_T
  64 AC_TYPE_UINT8_T
  65
  66 AX_C___ATTRIBUTE__
  67 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  68         [:],
  69         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  70
  71 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  72 LIBS="$PTHREAD_LIBS $LIBS"
  73 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  74 CC="$PTHREAD_CC"
  75
  76 # Checks for library functions.
  77 AC_FUNC_MALLOC
  78 AC_FUNC_MMAP
  79 AC_FUNC_FORK
  80 AC_CHECK_FUNCS([ \
  81         atexit \
  82         clock_gettime \
  83         getcpuid \
  84         gettid \
  85         gettimeofday \
  86         memeset \
  87         memset \
  88         munmap \
  89         sched_getcpu \
  90         strerror \
  91         strtoul \
  92         sysconf \
  93 ])
  94
  95 # Check for headers
  96 AC_HEADER_STDBOOL
  97 AC_CHECK_HEADERS([ \
  98         limits.h \
  99         stddef.h \
 100         sys/param.h \
 101         sys/time.h \
 102 ])
 103
 104 # Find arch type
 105 AS_CASE([$host_cpu],
 106         [k1om], [ARCHTYPE="x86"],
 107         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 108         [i486], [ARCHTYPE="x86"],
 109         [i586], [ARCHTYPE="x86"],
 110         [i686], [ARCHTYPE="x86"],
 111         [amd64], [ARCHTYPE="x86"],
 112         [x86_64], [ARCHTYPE="x86"],
 113         [powerpc], [ARCHTYPE="ppc"],
 114         [ppc64], [ARCHTYPE="ppc"],
 115         [powerpc64], [ARCHTYPE="ppc"],
 116         [powerpc64le], [ARCHTYPE="ppc"],
 117         [ppc], [ARCHTYPE="ppc"],
 118         [s390], [ARCHTYPE="s390"],
 119         [s390x], [ARCHTYPE="s390"],
 120         [sparc], [ARCHTYPE="sparc64"],
 121         [sparc64], [ARCHTYPE="sparc64"],
 122         [alpha*], [ARCHTYPE="alpha"],
 123         [ia64], [ARCHTYPE="ia64"],
 124         [arm*], [ARCHTYPE="arm"],
 125         [aarch64], [ARCHTYPE="aarch64"],
 126         [mips*], [ARCHTYPE="mips"],
 127         [nios2*], [ARCHTYPE="nios2"],
 128         [tile*], [ARCHTYPE="tile"],
 129         [hppa*], [ARCHTYPE="hppa"],
 130         [ARCHTYPE="unknown"]
 131 )
 132
 133 AS_CASE([$host],[*-*-linux-androideabi],
 134         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 135         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 136 )
 137
 138 AC_SUBST(ARCHTYPE)
 139 AC_SUBST(SUBARCHTYPE)
 140
 141 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 142 ARCHSRC=urcu/arch/$ARCHTYPE.h
 143
 144 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 145         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 146 ])
 147
 148 AS_IF([test "$host_cpu" = "armv7l"],[
 149         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 150 ])
 151
 152 # ARM-specific checks
 153 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 154         AC_MSG_CHECKING([for dmb instruction])
 155         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 156                                 int main()
 157                                 {
 158                                         asm volatile("dmb":::"memory");
 159                                         return 0;
 160                                 }
 161                 ]])
 162         ],[
 163                 AC_MSG_RESULT([yes])
 164                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 165         ],[
 166                 AC_MSG_RESULT([no])
 167         ])
 168 ])
 169
 170 # Tile-specific checks
 171 AS_IF([echo "$host_cpu" | grep "^tile"],[
 172         AC_MSG_CHECKING([for Tile architecture type])
 173         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 174                                 #ifndef __tilegx__
 175                                 #error
 176                                 #endif
 177                 ]])
 178         ],[
 179                 AC_MSG_RESULT([ok])
 180         ],[
 181                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 182         ])
 183 ])
 184
 185 # x86-specific checks
 186 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 187         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 188         #For now, using lock; addl compatibility mode even for i686, because the
 189         #Pentium III is seen as a i686, but lacks mfence instruction.
 190         #Only using fence for x86_64.
 191         #
 192         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 193         #variant but lacks fence instructions.
 194         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 195                 AC_MSG_RESULT([yes])
 196                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 197         ],[
 198                 AC_MSG_RESULT([no])
 199         ])
 200 ])
 201
 202 # Check if sys_futex() is available
 203 AC_MSG_CHECKING([for sys_futex()])
 204 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 205                 #include <sys/syscall.h>
 206                 #ifndef __NR_futex
 207                 #error "futexes not available"
 208                 #endif
 209         ]])
 210 ],[
 211         AC_MSG_RESULT([yes])
 212         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 213         compat_futex_test=0
 214 ],[
 215         AC_MSG_RESULT([no])
 216         compat_futex_test=1
 217 ])
 218
 219 # Check for pthread
 220 AC_CHECK_LIB([pthread], [pthread_create],
 221         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 222         [AC_CHECK_LIB([c], [pthread_create],
 223                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 224                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 225         )]
 226 )
 227
 228 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 229 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 230 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 231
 232 # smp-support configure option
 233 AC_ARG_ENABLE([smp-support],
 234         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 235         [def_smp_support=$enableval],
 236         [def_smp_support="yes"])
 237 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 238
 239
 240 # From the sched_setaffinity(2)'s man page:
 241 # ~~~~
 242 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 243 # The library interfaces were introduced in glibc 2.3.  Initially, the
 244 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 245 # the cpuset size argument was removed, but this argument was
 246 # restored in glibc 2.3.4.
 247 # ~~~~
 248
 249 # In addition to that, some vendors ported the system call to 2.4
 250 # kernels.
 251
 252 # Furthermore, when the function first appeared, the MASK argument was
 253 # an unsigned long pointer, while later it was made into a cpu_set_t
 254 # pointer.  Systems that have the cpu_set_t version also should have
 255 # the CPU_ZERO, CPU_SET, etc. macros.
 256
 257 # All this mess means we have to cater for at least 3 different
 258 # sched_setaffinity prototypes:
 259
 260 # ~~~~
 261 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 262 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 263 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 264 # ~~~~
 265
 266 # Since we define _GNU_SOURCE in the sources, must do so too in the
 267 # autoconf tests, as defining _GNU_SOURCE or not exposes
 268 # sched_setaffinity bits differently.
 269 saved_CFLAGS=$CFLAGS
 270 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 271
 272 AC_CHECK_TYPES([cpu_set_t],
 273         [have_cpu_set_t="yes"],
 274         [have_cpu_set_t="no"],
 275         [#include <sched.h>])
 276
 277 # Confirm that we have CPU_ZERO, and it actually works.
 278 AC_MSG_CHECKING([whether CPU_ZERO works])
 279 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 280 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 281                 #define _GNU_SOURCE
 282                 #include <sched.h>
 283                 int main()
 284                 {
 285                         cpu_set_t foo; CPU_ZERO(&foo);
 286                         return 0;
 287                 }
 288         ]])
 289 ],[
 290         AC_DEFINE(HAVE_CPU_ZERO, 1)
 291         AC_MSG_RESULT([yes])
 292 ],[
 293         AC_MSG_RESULT([no])
 294 ])
 295
 296 # Confirm that we have CPU_SET, and it actually works.
 297 AC_MSG_CHECKING([whether CPU_SET works])
 298 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 299 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 300                 #define _GNU_SOURCE
 301                 #include <sched.h>
 302                 int main()
 303                 {
 304                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 305                         return 0;
 306                 }
 307         ]])
 308 ],[
 309         AC_DEFINE(HAVE_CPU_SET, 1)
 310         AC_MSG_RESULT([yes])
 311 ],[
 312         AC_MSG_RESULT([no])
 313 ])
 314
 315 # First check if the function is available at all.
 316 AC_CHECK_FUNCS([sched_setaffinity],[
 317         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 318         # then we have the first version using unsigned long, and no
 319         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 320         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 321         # should also be present, but we confirm nonetheless.
 322
 323         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 324                 # We do have it.
 325                 # Check how many arguments does sched_setaffinity take.
 326                 # Should be 3 or 2.
 327                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 328                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 329                                 #include <sched.h>
 330                                 int main()
 331                                 {
 332                                         cpu_set_t foo;
 333                                         sched_setaffinity(0, sizeof (foo), &foo);
 334                                         return 0;
 335                                 }
 336                         ]])
 337                 ],
 338                 [sched_set_affinity_args=3],
 339                 [sched_set_affinity_args=2])
 340                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 341                         $sched_set_affinity_args,
 342                         [Defined to sched_setaffinity's number of arguments.])
 343                 AC_MSG_RESULT([$sched_set_affinity_args])
 344         ],[
 345                 # No cpu_set_t, always 3 args.
 346                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 347         ])
 348 ])
 349
 350 CFLAGS=$saved_CFLAGS
 351
 352 AC_CONFIG_LINKS([
 353         urcu/arch.h:$ARCHSRC
 354         urcu/uatomic.h:$UATOMICSRC
 355 ])
 356 AC_CONFIG_FILES([
 357         Makefile
 358         doc/Makefile
 359         doc/examples/Makefile
 360         tests/Makefile
 361         tests/common/Makefile
 362         tests/unit/Makefile
 363         tests/benchmark/Makefile
 364         tests/regression/Makefile
 365         tests/regression/regression_tests
 366         tests/utils/Makefile
 367         liburcu.pc
 368         liburcu-bp.pc
 369         liburcu-cds.pc
 370         liburcu-qsbr.pc
 371         liburcu-mb.pc
 372         liburcu-signal.pc
 373 ])
 374 AC_OUTPUT
 375
 376 # Report on selected configure options
 377 AS_IF([test "x$def_smp_support" = "xyes"],[
 378         AS_ECHO("SMP support enabled.")
 379 ],[
 380         AS_ECHO("SMP support disabled.")
 381 ])
 382
 383 AS_IF([test "x$def_tls_detect" = "x"],[
 384         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 385 ],[
 386         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 387 ])