Introduce AE_FEATURE to manage configure features
[urcu.git] / configure.ac
1 dnl SPDX-License-Identifier: LGPL-2.1-only
2 dnl
3 dnl Copyright (C) 2021 EfficiOS, Inc.
4 dnl
5 dnl Process this file with autoconf to produce a configure script.
6
7 # Project version information
8 m4_define([urcu_version_major], [0])
9 m4_define([urcu_version_minor], [12])
10 m4_define([urcu_version_patch], [0])
11 m4_define([urcu_version_dev_stage], [])
12 m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
13
14 # Library version information of "liburcu"
15 # Following the numbering scheme proposed by libtool for the library version
16 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
17 m4_define([urcu_lib_version_current], [7])
18 m4_define([urcu_lib_version_revision], [0])
19 m4_define([urcu_lib_version_age], [1])
20 m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
21
22
23 ## ##
24 ## Autoconf base setup ##
25 ## ##
26
27 AC_PREREQ([2.69])
28 AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
29
30 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
31 AC_CONFIG_AUX_DIR([config])
32 AC_CONFIG_MACRO_DIR([m4])
33
34 AC_CANONICAL_TARGET
35 AC_CANONICAL_HOST
36
37
38 ## ##
39 ## Automake base setup ##
40 ## ##
41
42 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
43 AM_MAINTAINER_MODE([enable])
44
45 # Enable silent rules by default
46 AM_SILENT_RULES([yes])
47
48
49 ## ##
50 ## OS and Arch specific defaults ##
51 ## ##
52
53 AS_CASE([$host],
54 [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"]
55 )
56
57
58 ## ##
59 ## C compiler checks ##
60 ## ##
61
62 # Choose the C compiler
63 AC_PROG_CC
64 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
65 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
66
67 # Make sure the C compiler supports C99
68 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
69
70 # Enable available system extensions and LFS support
71 AC_USE_SYSTEM_EXTENSIONS
72 AC_SYS_LARGEFILE
73
74 # Make sure the C compiler supports __attribute__
75 AX_C___ATTRIBUTE__
76 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
77 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
78
79 # Make sure we have pthread support
80 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
81
82 # Make sure the C compiler supports weak symbols
83 AX_SYS_WEAK_ALIAS
84 AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"],
85 [AC_MSG_ERROR([Your platform doesn't support weak symbols.])])
86
87 # Checks for typedefs, structures, and compiler characteristics.
88 AC_C_INLINE
89 AC_C_TYPEOF
90 AC_TYPE_INT32_T
91 AC_TYPE_PID_T
92 AC_TYPE_SIZE_T
93 AC_TYPE_SSIZE_T
94 AC_TYPE_UINT16_T
95 AC_TYPE_UINT32_T
96 AC_TYPE_UINT64_T
97 AC_TYPE_UINT8_T
98
99
100 ## ##
101 ## Header checks ##
102 ## ##
103
104 AC_HEADER_STDBOOL
105 AC_CHECK_HEADERS([ \
106 limits.h \
107 stddef.h \
108 sys/param.h \
109 sys/time.h \
110 ])
111
112
113 ## ##
114 ## Programs checks ##
115 ## ##
116
117 AC_PROG_AWK
118 AC_PROG_GREP
119 AC_PROG_MAKE_SET
120 AC_CHECK_PROGS(NPROC, [nproc gnproc])
121 AC_CHECK_PROG(GETCONF, [getconf])
122 AS_IF([test "x$NPROC" != "x"],
123 [NPROC_CMD=$NPROC],
124 [AS_IF([test "x$GETCONF" != "x"],
125 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
126 [NPROC_CMD="echo 1"]
127 )]
128 )
129 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
130
131 # Initialize and configure libtool
132 LT_INIT
133
134
135 ## ##
136 ## Library checks ##
137 ## ##
138
139 # Checks for library functions.
140 AC_FUNC_MMAP
141 AC_FUNC_FORK
142 AC_CHECK_FUNCS([ \
143 atexit \
144 getcpuid \
145 gettid \
146 gettimeofday \
147 memeset \
148 memset \
149 munmap \
150 rand_r \
151 sched_getcpu \
152 strerror \
153 strtoul \
154 sysconf \
155 ])
156
157 # AC_FUNC_MALLOC causes problems when cross-compiling.
158 #AC_FUNC_MALLOC
159
160 # Search for clock_gettime() in -lrt
161 AC_SEARCH_LIBS([clock_gettime], [rt], [
162 AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
163 ])
164
165
166 ## ##
167 ## Optionnal features selection ##
168 ## ##
169
170 # Allow to fallback to FIXME if the membarrier syscall is unavailable on the
171 # running kernel, when disabled, abort if the syscall is unavailable. Applies
172 # to default and bulletproof flavors.
173 # Enabled by default
174 AE_FEATURE_DEFAULT_ENABLE
175 AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])
176
177 # Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
178 # Enabled by default
179 AE_FEATURE_DEFAULT_ENABLE
180 AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])
181
182 # smp-support configure option
183 # Enabled by default
184 AE_FEATURE_DEFAULT_ENABLE
185 AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])
186
187 # RCU debugging option
188 # Disabled by default
189 AE_FEATURE_DEFAULT_DISABLE
190 AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])
191
192 # rculfhash iterator debugging
193 # Disabled by default
194 AE_FEATURE_DEFAULT_DISABLE
195 AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
196
197
198 ## ##
199 ## Set defines for optional features conditionnals in the source code ##
200 ## ##
201
202 AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
203 AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
204 ])
205
206 AE_IF_FEATURE_ENABLED([compiler-tls], [
207 AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
208 ])
209
210 AE_IF_FEATURE_ENABLED([smp-support], [
211 AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
212 ])
213
214 AE_IF_FEATURE_ENABLED([rcu-debug], [
215 AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
216 ])
217
218 AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
219 AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
220 ])
221
222 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
223
224 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
225
226
227
228 # From the sched_setaffinity(2)'s man page:
229 # ~~~~
230 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
231 # The library interfaces were introduced in glibc 2.3. Initially, the
232 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
233 # the cpuset size argument was removed, but this argument was
234 # restored in glibc 2.3.4.
235 # ~~~~
236
237 # In addition to that, some vendors ported the system call to 2.4
238 # kernels.
239
240 # Furthermore, when the function first appeared, the MASK argument was
241 # an unsigned long pointer, while later it was made into a cpu_set_t
242 # pointer. Systems that have the cpu_set_t version also should have
243 # the CPU_ZERO, CPU_SET, etc. macros.
244
245 # All this mess means we have to cater for at least 3 different
246 # sched_setaffinity prototypes:
247
248 # ~~~~
249 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
250 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
251 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
252 # ~~~~
253
254 AC_CHECK_TYPES([cpu_set_t],
255 [have_cpu_set_t="yes"],
256 [have_cpu_set_t="no"],
257 [#include <sched.h>])
258
259 # Confirm that we have CPU_ZERO, and it actually works.
260 AC_MSG_CHECKING([whether CPU_ZERO works])
261 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
262 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
263 #include <sched.h>
264 int main()
265 {
266 cpu_set_t foo; CPU_ZERO(&foo);
267 return 0;
268 }
269 ]])
270 ],[
271 AC_DEFINE(HAVE_CPU_ZERO, 1)
272 AC_MSG_RESULT([yes])
273 ],[
274 AC_MSG_RESULT([no])
275 ])
276
277 # Confirm that we have CPU_SET, and it actually works.
278 AC_MSG_CHECKING([whether CPU_SET works])
279 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
280 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
281 #include <sched.h>
282 int main()
283 {
284 cpu_set_t foo; CPU_SET(0, &foo);
285 return 0;
286 }
287 ]])
288 ],[
289 AC_DEFINE(HAVE_CPU_SET, 1)
290 AC_MSG_RESULT([yes])
291 ],[
292 AC_MSG_RESULT([no])
293 ])
294
295 # First check if the function is available at all.
296 AC_CHECK_FUNCS([sched_setaffinity],[
297 # Okay, we have it. Check if also have cpu_set_t. If we don't,
298 # then we have the first version using unsigned long, and no
299 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
300 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
301 # should also be present, but we confirm nonetheless.
302
303 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
304 # We do have it.
305 # Check how many arguments does sched_setaffinity take.
306 # Should be 3 or 2.
307 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
308 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
309 #include <sched.h>
310 int main()
311 {
312 cpu_set_t foo;
313 sched_setaffinity(0, sizeof (foo), &foo);
314 return 0;
315 }
316 ]])
317 ],
318 [sched_set_affinity_args=3],
319 [sched_set_affinity_args=2])
320 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
321 $sched_set_affinity_args,
322 [Defined to sched_setaffinity's number of arguments.])
323 AC_MSG_RESULT([$sched_set_affinity_args])
324 ],[
325 # No cpu_set_t, always 3 args.
326 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
327 ])
328 ])
329
330 ## ##
331 ## Substitute variables for use in Makefile.am ##
332 ## ##
333
334 # Library versions for libtool
335 AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
336
337 AC_SUBST(LT_NO_UNDEFINED)
338
339 AM_CPPFLAGS="-include config.h"
340 AC_SUBST(AM_CPPFLAGS)
341
342 AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
343 AC_SUBST(AM_CFLAGS)
344
345 AC_CONFIG_FILES([
346 Makefile
347 doc/Makefile
348 doc/examples/Makefile
349 include/Makefile
350 src/Makefile
351 tests/Makefile
352 tests/common/Makefile
353 tests/unit/Makefile
354 tests/benchmark/Makefile
355 tests/regression/Makefile
356 tests/utils/Makefile
357 src/liburcu.pc
358 src/liburcu-bp.pc
359 src/liburcu-cds.pc
360 src/liburcu-qsbr.pc
361 src/liburcu-mb.pc
362 src/liburcu-signal.pc
363 ])
364
365 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
366 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
367 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
368 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
369 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
370 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
371 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
372 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
373 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
374 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
375 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
376 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
377 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
378 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
379 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
380 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
381 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
382 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
383 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
384 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
385 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
386 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
387 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
388 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
389 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
390 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
391 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
392 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
393 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
394 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
395 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
396 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
397 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
398 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
399 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
400 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
401 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
402 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
403 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
404 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
405 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
406 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
407 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
408 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
409 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
410 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
411 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
412 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
413 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
414 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
415 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
416 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
417 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
418 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
419 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
420 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
421 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
422 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
423 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
424 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
425
426
427 AC_OUTPUT
428
429 #
430 # Mini-report on what will be built.
431 #
432
433 PPRINT_INIT
434 PPRINT_SET_INDENT(1)
435 PPRINT_SET_TS(38)
436
437 AS_ECHO
438 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
439 AS_ECHO
440
441 PPRINT_SUBTITLE([Features])
442
443 PPRINT_PROP_STRING([Target architecture], $host_cpu)
444
445 # SMP support enabled/disabled
446 AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0
447 PPRINT_PROP_BOOL([SMP support], $value)
448
449 # TLS
450 AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()"
451 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
452
453 # clock_gettime() available
454 test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0
455 PPRINT_PROP_BOOL([clock_gettime()], $value)
456
457 # Require membarrier
458 AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1
459 PPRINT_PROP_BOOL([Require membarrier], $value)
460
461 # RCU debug enabled/disabled
462 AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0
463 PPRINT_PROP_BOOL([Internal debugging], $value)
464
465 # rculfhash iterator debug enabled/disabled
466 AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0
467 PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)
468
469 PPRINT_PROP_BOOL([Multi-flavor support], 1)
470
471 report_bindir="`eval eval echo $bindir`"
472 report_libdir="`eval eval echo $libdir`"
473
474 # Print the bindir and libdir this 'make install' will install into.
475 AS_ECHO
476 PPRINT_SUBTITLE([Install directories])
477 PPRINT_PROP_STRING([Binaries], [$report_bindir])
478 PPRINT_PROP_STRING([Libraries], [$report_libdir])
479
This page took 0.060403 seconds and 4 git commands to generate.