configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
   7
   8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
  16 AM_MAINTAINER_MODE([enable])
  17
  18 # Enable silent rules if available (Introduced in AM 1.11)
  19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  20
  21 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  22 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  24 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  25 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  26 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  28
  29 # Allow overriding storage used for TLS variables.
  30 AC_ARG_ENABLE([compiler-tls],
  31         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  32         [def_compiler_tls=$enableval],
  33         [def_compiler_tls="yes"])
  34
  35 # If not overridden, use ax_tls.m4 to check if TLS is available.
  36 AS_IF([test "x$def_compiler_tls" = "xyes"],
  37         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  38         [:])
  39
  40 AS_IF([test "x$def_tls_detect" = "x"],
  41         [:],
  42         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  43
  44 # Checks for C compiler
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_PROG_CC
  47 AC_PROG_CC_STDC
  48
  49 # Checks for programs.
  50 AC_PROG_AWK
  51 AC_PROG_MAKE_SET
  52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  53 AC_CHECK_PROGS(GETCONF, [getconf])
  54 AS_IF([test "x$NPROC" != "x"],
  55         [NPROC_CMD=$NPROC],
  56         [AS_IF([test "x$GETCONF" != "x"],
  57                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  58                 [NPROC_CMD="echo 1"]
  59         )]
  60 )
  61 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  62
  63 LT_INIT
  64
  65 # Checks for typedefs, structures, and compiler characteristics.
  66 AC_C_INLINE
  67 AC_TYPE_PID_T
  68 AC_TYPE_SIZE_T
  69 AC_TYPE_SSIZE_T
  70 AC_TYPE_UINT16_T
  71 AC_TYPE_INT32_T
  72 AC_TYPE_UINT32_T
  73 AC_TYPE_UINT64_T
  74 AC_TYPE_UINT8_T
  75
  76 AX_C___ATTRIBUTE__
  77 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  78         [:],
  79         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  80
  81 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  82 LIBS="$PTHREAD_LIBS $LIBS"
  83 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  84 CC="$PTHREAD_CC"
  85
  86 # Checks for library functions.
  87 AC_FUNC_MMAP
  88 AC_FUNC_FORK
  89 AC_CHECK_FUNCS([ \
  90         atexit \
  91         getcpuid \
  92         gettid \
  93         gettimeofday \
  94         memeset \
  95         memset \
  96         munmap \
  97         sched_getcpu \
  98         strerror \
  99         strtoul \
 100         sysconf \
 101 ])
 102
 103 # AC_FUNC_MALLOC causes problems when cross-compiling.
 104 #AC_FUNC_MALLOC
 105
 106 # Check for headers
 107 AC_HEADER_STDBOOL
 108 AC_CHECK_HEADERS([ \
 109         limits.h \
 110         stddef.h \
 111         sys/param.h \
 112         sys/time.h \
 113 ])
 114
 115 # Find arch type
 116 AS_CASE([$host_cpu],
 117         [k1om], [ARCHTYPE="x86"],
 118         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 119         [i486], [ARCHTYPE="x86"],
 120         [i586], [ARCHTYPE="x86"],
 121         [i686], [ARCHTYPE="x86"],
 122         [amd64], [ARCHTYPE="x86"],
 123         [x86_64], [ARCHTYPE="x86"],
 124         [powerpc], [ARCHTYPE="ppc"],
 125         [ppc64], [ARCHTYPE="ppc"],
 126         [powerpc64], [ARCHTYPE="ppc"],
 127         [powerpc64le], [ARCHTYPE="ppc"],
 128         [ppc], [ARCHTYPE="ppc"],
 129         [s390], [ARCHTYPE="s390"],
 130         [s390x], [ARCHTYPE="s390"],
 131         [sparc], [ARCHTYPE="sparc64"],
 132         [sparc64], [ARCHTYPE="sparc64"],
 133         [alpha*], [ARCHTYPE="alpha"],
 134         [ia64], [ARCHTYPE="ia64"],
 135         [arm*], [ARCHTYPE="arm"],
 136         [aarch64*], [ARCHTYPE="aarch64"],
 137         [mips*], [ARCHTYPE="mips"],
 138         [nios2*], [ARCHTYPE="nios2"],
 139         [tile*], [ARCHTYPE="tile"],
 140         [hppa*], [ARCHTYPE="hppa"],
 141         [ARCHTYPE="unknown"]
 142 )
 143
 144 AS_CASE([$host],[*-cygwin*],
 145         [AM_CONDITIONAL(USE_CYGWIN, true)],
 146         [AM_CONDITIONAL(USE_CYGWIN, false)]
 147 )
 148
 149 AC_SUBST(ARCHTYPE)
 150 AC_SUBST(SUBARCHTYPE)
 151
 152 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
 153 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
 154
 155 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 156         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 157 ])
 158
 159 AS_IF([test "$host_cpu" = "armv7l"],[
 160         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 161 ])
 162
 163 # ARM-specific checks
 164 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 165         AC_MSG_CHECKING([for dmb instruction])
 166         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 167                                 int main()
 168                                 {
 169                                         asm volatile("dmb":::"memory");
 170                                         return 0;
 171                                 }
 172                 ]])
 173         ],[
 174                 AC_MSG_RESULT([yes])
 175                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 176         ],[
 177                 AC_MSG_RESULT([no])
 178         ])
 179 ])
 180
 181 # Tile-specific checks
 182 AS_IF([echo "$host_cpu" | grep "^tile"],[
 183         AC_MSG_CHECKING([for Tile architecture type])
 184         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 185                                 #ifndef __tilegx__
 186                                 #error
 187                                 #endif
 188                 ]])
 189         ],[
 190                 AC_MSG_RESULT([ok])
 191         ],[
 192                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 193         ])
 194 ])
 195
 196 # x86-specific checks
 197 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 198         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 199         #For now, using lock; addl compatibility mode even for i686, because the
 200         #Pentium III is seen as a i686, but lacks mfence instruction.
 201         #Only using fence for x86_64.
 202         #
 203         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 204         #variant but lacks fence instructions.
 205         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 206                 AC_MSG_RESULT([yes])
 207                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 208         ],[
 209                 AC_MSG_RESULT([no])
 210         ])
 211 ])
 212
 213 # Check if sys_futex() is available
 214 AC_MSG_CHECKING([for sys_futex()])
 215 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 216                 #include <sys/syscall.h>
 217                 #ifndef __NR_futex
 218                 #error "futexes not available"
 219                 #endif
 220         ]])
 221 ],[
 222         AC_MSG_RESULT([yes])
 223         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 224         compat_futex_test=0
 225 ],[
 226         AC_MSG_RESULT([no])
 227         compat_futex_test=1
 228 ])
 229
 230 # Search for clock_gettime
 231 AC_SEARCH_LIBS([clock_gettime], [rt], [
 232         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 233 ], [])
 234
 235 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 236 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 237 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 238
 239 # smp-support configure option
 240 AC_ARG_ENABLE([smp-support],
 241         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 242         [def_smp_support=$enableval],
 243         [def_smp_support="yes"])
 244 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 245
 246
 247 # From the sched_setaffinity(2)'s man page:
 248 # ~~~~
 249 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 250 # The library interfaces were introduced in glibc 2.3.  Initially, the
 251 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 252 # the cpuset size argument was removed, but this argument was
 253 # restored in glibc 2.3.4.
 254 # ~~~~
 255
 256 # In addition to that, some vendors ported the system call to 2.4
 257 # kernels.
 258
 259 # Furthermore, when the function first appeared, the MASK argument was
 260 # an unsigned long pointer, while later it was made into a cpu_set_t
 261 # pointer.  Systems that have the cpu_set_t version also should have
 262 # the CPU_ZERO, CPU_SET, etc. macros.
 263
 264 # All this mess means we have to cater for at least 3 different
 265 # sched_setaffinity prototypes:
 266
 267 # ~~~~
 268 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 269 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 270 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 271 # ~~~~
 272
 273 AC_CHECK_TYPES([cpu_set_t],
 274         [have_cpu_set_t="yes"],
 275         [have_cpu_set_t="no"],
 276         [#include <sched.h>])
 277
 278 # Confirm that we have CPU_ZERO, and it actually works.
 279 AC_MSG_CHECKING([whether CPU_ZERO works])
 280 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 281 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 282                 #include <sched.h>
 283                 int main()
 284                 {
 285                         cpu_set_t foo; CPU_ZERO(&foo);
 286                         return 0;
 287                 }
 288         ]])
 289 ],[
 290         AC_DEFINE(HAVE_CPU_ZERO, 1)
 291         AC_MSG_RESULT([yes])
 292 ],[
 293         AC_MSG_RESULT([no])
 294 ])
 295
 296 # Confirm that we have CPU_SET, and it actually works.
 297 AC_MSG_CHECKING([whether CPU_SET works])
 298 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 299 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 300                 #include <sched.h>
 301                 int main()
 302                 {
 303                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 304                         return 0;
 305                 }
 306         ]])
 307 ],[
 308         AC_DEFINE(HAVE_CPU_SET, 1)
 309         AC_MSG_RESULT([yes])
 310 ],[
 311         AC_MSG_RESULT([no])
 312 ])
 313
 314 # First check if the function is available at all.
 315 AC_CHECK_FUNCS([sched_setaffinity],[
 316         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 317         # then we have the first version using unsigned long, and no
 318         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 319         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 320         # should also be present, but we confirm nonetheless.
 321
 322         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 323                 # We do have it.
 324                 # Check how many arguments does sched_setaffinity take.
 325                 # Should be 3 or 2.
 326                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 327                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 328                                 #include <sched.h>
 329                                 int main()
 330                                 {
 331                                         cpu_set_t foo;
 332                                         sched_setaffinity(0, sizeof (foo), &foo);
 333                                         return 0;
 334                                 }
 335                         ]])
 336                 ],
 337                 [sched_set_affinity_args=3],
 338                 [sched_set_affinity_args=2])
 339                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 340                         $sched_set_affinity_args,
 341                         [Defined to sched_setaffinity's number of arguments.])
 342                 AC_MSG_RESULT([$sched_set_affinity_args])
 343         ],[
 344                 # No cpu_set_t, always 3 args.
 345                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 346         ])
 347 ])
 348
 349 DEFAULT_INCLUDES="-include config.h"
 350 AC_SUBST(DEFAULT_INCLUDES)
 351
 352 AC_CONFIG_LINKS([
 353         include/urcu/arch.h:$ARCHSRC
 354         include/urcu/uatomic.h:$UATOMICSRC
 355 ])
 356 AC_CONFIG_FILES([
 357         Makefile
 358         doc/Makefile
 359         doc/examples/Makefile
 360         include/Makefile
 361         src/Makefile
 362         tests/Makefile
 363         tests/common/Makefile
 364         tests/unit/Makefile
 365         tests/benchmark/Makefile
 366         tests/regression/Makefile
 367         tests/regression/regression_tests
 368         tests/utils/Makefile
 369         src/liburcu.pc
 370         src/liburcu-bp.pc
 371         src/liburcu-cds.pc
 372         src/liburcu-qsbr.pc
 373         src/liburcu-mb.pc
 374         src/liburcu-signal.pc
 375 ])
 376 AC_OUTPUT
 377
 378 # Report on selected configure options
 379 AS_IF([test "x$def_smp_support" = "xyes"],[
 380         AS_ECHO("SMP support enabled.")
 381 ],[
 382         AS_ECHO("SMP support disabled.")
 383 ])
 384
 385 AS_IF([test "x$def_tls_detect" = "x"],[
 386         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 387 ],[
 388         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 389 ])