configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu], [0.6.5], [mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CANONICAL_TARGET
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_CONFIG_SRCDIR([urcu.h])
  18 AM_PROG_MKDIR_P
  19
  20 AC_CONFIG_HEADERS([config.h urcu/config.h])
  21
  22 # Keep at the end to do not pollute installed header.
  23 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  26 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
  27 cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction is available for use on ARM.])
  29
  30 # Checks for programs.
  31 AC_PROG_CC
  32 AC_PROG_MAKE_SET
  33 AC_PROG_LIBTOOL
  34
  35 # Checks for typedefs, structures, and compiler characteristics.
  36 AC_C_INLINE
  37 AC_TYPE_PID_T
  38 AC_TYPE_SIZE_T
  39
  40 # Checks for library functions.
  41 AC_FUNC_MALLOC
  42 AC_FUNC_MMAP
  43 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  44
  45 # Find arch type
  46 case $host_cpu in
  47         i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
  48         i486) ARCHTYPE="x86";;
  49         i586) ARCHTYPE="x86";;
  50         i686) ARCHTYPE="x86";;
  51         x86_64) ARCHTYPE="x86";;
  52         powerpc) ARCHTYPE="ppc" ;;
  53         ppc64) ARCHTYPE="ppc" ;;
  54         powerpc64) ARCHTYPE="ppc" ;;
  55         ppc) ARCHTYPE="ppc" ;;
  56         s390) ARCHTYPE="s390" ;;
  57         s390x) ARCHTYPE="s390" ;;
  58         sparc64) ARCHTYPE="sparc64" ;;
  59         alpha*) ARCHTYPE="alpha" ;;
  60         ia64) ARCHTYPE="gcc" ;;
  61         arm*) ARCHTYPE="arm" ;;
  62         *) ARCHTYPE="unknown";;
  63 esac
  64
  65 if test "x$ARCHTYPE" = "xarm" ; then
  66 AC_MSG_CHECKING([checking for dmb instruction])
  67 AC_TRY_COMPILE(
  68 [
  69 ],
  70 [
  71 asm volatile("dmb":::"memory");
  72 ],
  73 [
  74         AC_MSG_RESULT([yes])
  75         AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
  76 ]
  77 ,
  78 [
  79         AC_MSG_RESULT([no])
  80 ]
  81 )
  82 fi
  83
  84 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  85 ARCHSRC=urcu/arch/$ARCHTYPE.h
  86 if test "$ARCHTYPE" == "armv7l"; then
  87         CFLAGS="-mcpu=cortex-a9 -mtune=cortex-a9 -O"
  88 fi
  89
  90 AC_SUBST(ARCHTYPE)
  91 AC_SUBST(SUBARCHTYPE)
  92
  93 [
  94 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
  95 #For now, using lock; addl compatibility mode even for i686, because the
  96 #Pentium III is seen as a i686, but lacks mfence instruction.
  97 #Only using fence for x86_64.
  98 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
  99 ]
 100         AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 101 [
 102 fi
 103 ]
 104
 105 AC_MSG_CHECKING([sys_futex()])
 106 AC_TRY_COMPILE(
 107 [
 108 #include <sys/syscall.h>
 109 ],
 110 [
 111 #ifndef __NR_futex
 112 #error "futexes not available"
 113 #endif
 114 ],
 115 [
 116         AC_MSG_RESULT([yes])
 117         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 118         compat_futex_test=0
 119 ]
 120 ,
 121 [
 122         AC_MSG_RESULT([no])
 123         compat_futex_test=1
 124 ]
 125 )
 126
 127 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
 128
 129 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
 130
 131 [
 132 if test "x$SUBARCHTYPE" = xx86compat; then
 133 ]
 134         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 135 [
 136 fi
 137 ]
 138
 139 AC_ARG_ENABLE([smp-support], [  --disable-smp-support   Disable SMP support. Warning: only use this
 140                           on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
 141
 142 [
 143 if test "$def_smp_support" = "no"; then
 144         echo "SMP support disabled."
 145 else
 146 ]
 147         AC_DEFINE([CONFIG_RCU_SMP], [1])
 148 [
 149         echo "SMP support enabled."
 150 fi
 151 ]
 152
 153 # From the sched_setaffinity(2)'s man page:
 154 # ~~~~
 155 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 156 # The library interfaces were introduced in glibc 2.3.  Initially, the
 157 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 158 # the cpuset size argument was removed, but this argument was
 159 # restored in glibc 2.3.4.
 160 # ~~~~
 161
 162 # In addition to that, some vendors ported the system call to 2.4
 163 # kernels.
 164
 165 # Furthermore, when the function first appeared, the MASK argument was
 166 # an unsigned long pointer, while later it was made into a cpu_set_t
 167 # pointer.  Systems that have the cpu_set_t version also should have
 168 # the CPU_ZERO, CPU_SET, etc. macros.
 169
 170 # All this mess means we have to cater for at least 3 different
 171 # sched_setaffinity prototypes:
 172
 173 # ~~~~
 174 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 175 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 176 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 177 # ~~~~
 178
 179 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
 180 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
 181 dnl sched_setaffinity bits differently.
 182 saved_CFLAGS=$CFLAGS
 183 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 184
 185 # First check if the function is available at all.
 186 AC_CHECK_FUNCS(
 187   [sched_setaffinity],
 188   [ # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 189     # then we have the first version using unsigned long, and no
 190     # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 191     # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 192     # should also be present, but we confirm nonetheless.
 193
 194     AC_CHECK_TYPES(
 195       [cpu_set_t],
 196       [ # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 197         AC_MSG_CHECKING([whether CPU_ZERO works])
 198         AH_TEMPLATE([HAVE_CPU_ZERO],
 199                     [Define to 1 if we have CPU_ZERO and if it works])
 200         AC_COMPILE_IFELSE(
 201           [AC_LANG_PROGRAM(
 202             [#define _GNU_SOURCE
 203             #include <sched.h>],
 204             [cpu_set_t foo; CPU_ZERO (&foo);])
 205           ],
 206           [ # Works!
 207             AC_DEFINE(HAVE_CPU_ZERO, 1)
 208             AC_MSG_RESULT([yes])
 209           ],
 210           [AC_MSG_RESULT([no])]
 211         )
 212
 213         # Check how many arguments does sched_setaffinity take.
 214         # Should be 3 or 2.
 215         AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 216         AC_COMPILE_IFELSE(
 217           [AC_LANG_PROGRAM(
 218             [#include <sched.h>],
 219             [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
 220           ],
 221           [sched_set_affinity_args=3],
 222           [sched_set_affinity_args=2])
 223         AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 224          [Define to sched_setaffinity's number of arguments.])
 225         AC_MSG_RESULT([$sched_set_affinity_args])
 226       ],
 227       [ # No cpu_set_t, always 3 args.
 228         AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
 229       [#include <sched.h>]
 230     )
 231   ]
 232 )
 233
 234 CFLAGS=$saved_CFLAGS
 235
 236 AC_CONFIG_LINKS([
 237         urcu/arch.h:$ARCHSRC
 238         urcu/uatomic.h:$UATOMICSRC
 239 ])
 240 AC_CONFIG_FILES([
 241         Makefile
 242         tests/Makefile
 243         liburcu-cds.pc
 244         liburcu.pc
 245         liburcu-bp.pc
 246         liburcu-qsbr.pc
 247         liburcu-mb.pc
 248         liburcu-signal.pc
 249 ])
 250 AC_OUTPUT