configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 # Project version information
   8 m4_define([urcu_version_major], [0])
   9 m4_define([urcu_version_minor], [12])
  10 m4_define([urcu_version_patch], [0])
  11 m4_define([urcu_version_dev_stage], [])
  12 m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
  13
  14 # Library version information of "liburcu"
  15 # Following the numbering scheme proposed by libtool for the library version
  16 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  17 m4_define([urcu_lib_version_current], [7])
  18 m4_define([urcu_lib_version_revision], [0])
  19 m4_define([urcu_lib_version_age], [1])
  20 m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
  21
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
  29
  30 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
  31 AC_CONFIG_AUX_DIR([config])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 AC_CANONICAL_TARGET
  35 AC_CANONICAL_HOST
  36
  37 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc])
  38 AM_MAINTAINER_MODE([enable])
  39
  40 # Enable silent rules if available (Introduced in AM 1.11)
  41 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  42
  43 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  44
  45 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  46 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  47 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  48 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
  49 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduces a performance penalty.])
  50 AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
  51
  52 # Allow requiring the operating system to support the membarrier system
  53 # call. Applies to default and bulletproof flavors.
  54 AC_ARG_ENABLE([sys-membarrier-fallback],
  55         AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
  56         [def_sys_membarrier_fallback=$enableval],
  57         [def_sys_membarrier_fallback="yes"])
  58 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
  59
  60 # Allow overriding storage used for TLS variables.
  61 AC_ARG_ENABLE([compiler-tls],
  62         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  63         [def_compiler_tls=$enableval],
  64         [def_compiler_tls="yes"])
  65
  66 # Checks for C compiler
  67 AC_USE_SYSTEM_EXTENSIONS
  68 AC_PROG_CC
  69 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  70 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  71 AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:])
  72
  73 # Checks for programs.
  74 AC_PROG_AWK
  75 AC_PROG_MAKE_SET
  76 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  77 AC_CHECK_PROGS(GETCONF, [getconf])
  78 AS_IF([test "x$NPROC" != "x"],
  79         [NPROC_CMD=$NPROC],
  80         [AS_IF([test "x$GETCONF" != "x"],
  81                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
  82                 [NPROC_CMD="echo 1"]
  83         )]
  84 )
  85 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
  86
  87 LT_INIT
  88
  89 # Checks for typedefs, structures, and compiler characteristics.
  90 AC_C_INLINE
  91 AC_TYPE_PID_T
  92 AC_TYPE_SIZE_T
  93 AC_TYPE_SSIZE_T
  94 AC_TYPE_UINT16_T
  95 AC_TYPE_INT32_T
  96 AC_TYPE_UINT32_T
  97 AC_TYPE_UINT64_T
  98 AC_TYPE_UINT8_T
  99
 100 AX_C___ATTRIBUTE__
 101 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 102         [:],
 103         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 104
 105 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 106
 107 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 108
 109 # Checks for library functions.
 110 AC_FUNC_MMAP
 111 AC_FUNC_FORK
 112 AC_CHECK_FUNCS([ \
 113         atexit \
 114         getcpuid \
 115         gettid \
 116         gettimeofday \
 117         memeset \
 118         memset \
 119         munmap \
 120         rand_r \
 121         sched_getcpu \
 122         strerror \
 123         strtoul \
 124         sysconf \
 125 ])
 126
 127 # AC_FUNC_MALLOC causes problems when cross-compiling.
 128 #AC_FUNC_MALLOC
 129
 130 # Check for headers
 131 AC_HEADER_STDBOOL
 132 AC_CHECK_HEADERS([ \
 133         limits.h \
 134         stddef.h \
 135         sys/param.h \
 136         sys/time.h \
 137 ])
 138
 139 AS_CASE([$host],[*-cygwin*],
 140         [AM_CONDITIONAL(USE_CYGWIN, true)],
 141         [AM_CONDITIONAL(USE_CYGWIN, false)]
 142 )
 143
 144 # Search for clock_gettime
 145 AC_SEARCH_LIBS([clock_gettime], [rt], [
 146         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 147         config_rcu_have_clock_gettime=yes
 148 ], [])
 149
 150 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 151
 152 # smp-support configure option
 153 AC_ARG_ENABLE([smp-support],
 154         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 155         [def_smp_support=$enableval],
 156         [def_smp_support="yes"])
 157 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 158
 159 # RCU debugging option
 160 AC_ARG_ENABLE([rcu-debug],
 161       AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
 162                       self-checks. Introduces a performance penalty.]))
 163 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
 164        AC_DEFINE([CONFIG_RCU_DEBUG], [1])
 165 ])
 166
 167 # rculfhash iterator debugging
 168 AC_ARG_ENABLE([cds-lfht-iter-debug],
 169       AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
 170 AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
 171        AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
 172 ])
 173
 174 # From the sched_setaffinity(2)'s man page:
 175 # ~~~~
 176 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 177 # The library interfaces were introduced in glibc 2.3.  Initially, the
 178 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 179 # the cpuset size argument was removed, but this argument was
 180 # restored in glibc 2.3.4.
 181 # ~~~~
 182
 183 # In addition to that, some vendors ported the system call to 2.4
 184 # kernels.
 185
 186 # Furthermore, when the function first appeared, the MASK argument was
 187 # an unsigned long pointer, while later it was made into a cpu_set_t
 188 # pointer.  Systems that have the cpu_set_t version also should have
 189 # the CPU_ZERO, CPU_SET, etc. macros.
 190
 191 # All this mess means we have to cater for at least 3 different
 192 # sched_setaffinity prototypes:
 193
 194 # ~~~~
 195 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 196 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 197 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 198 # ~~~~
 199
 200 AC_CHECK_TYPES([cpu_set_t],
 201         [have_cpu_set_t="yes"],
 202         [have_cpu_set_t="no"],
 203         [#include <sched.h>])
 204
 205 # Confirm that we have CPU_ZERO, and it actually works.
 206 AC_MSG_CHECKING([whether CPU_ZERO works])
 207 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 208 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 209                 #include <sched.h>
 210                 int main()
 211                 {
 212                         cpu_set_t foo; CPU_ZERO(&foo);
 213                         return 0;
 214                 }
 215         ]])
 216 ],[
 217         AC_DEFINE(HAVE_CPU_ZERO, 1)
 218         AC_MSG_RESULT([yes])
 219 ],[
 220         AC_MSG_RESULT([no])
 221 ])
 222
 223 # Confirm that we have CPU_SET, and it actually works.
 224 AC_MSG_CHECKING([whether CPU_SET works])
 225 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 226 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 227                 #include <sched.h>
 228                 int main()
 229                 {
 230                         cpu_set_t foo; CPU_SET(0, &foo);
 231                         return 0;
 232                 }
 233         ]])
 234 ],[
 235         AC_DEFINE(HAVE_CPU_SET, 1)
 236         AC_MSG_RESULT([yes])
 237 ],[
 238         AC_MSG_RESULT([no])
 239 ])
 240
 241 # First check if the function is available at all.
 242 AC_CHECK_FUNCS([sched_setaffinity],[
 243         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 244         # then we have the first version using unsigned long, and no
 245         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 246         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 247         # should also be present, but we confirm nonetheless.
 248
 249         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 250                 # We do have it.
 251                 # Check how many arguments does sched_setaffinity take.
 252                 # Should be 3 or 2.
 253                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 254                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 255                                 #include <sched.h>
 256                                 int main()
 257                                 {
 258                                         cpu_set_t foo;
 259                                         sched_setaffinity(0, sizeof (foo), &foo);
 260                                         return 0;
 261                                 }
 262                         ]])
 263                 ],
 264                 [sched_set_affinity_args=3],
 265                 [sched_set_affinity_args=2])
 266                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 267                         $sched_set_affinity_args,
 268                         [Defined to sched_setaffinity's number of arguments.])
 269                 AC_MSG_RESULT([$sched_set_affinity_args])
 270         ],[
 271                 # No cpu_set_t, always 3 args.
 272                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 273         ])
 274 ])
 275
 276 ##                                             ##
 277 ## Substitute variables for use in Makefile.am ##
 278 ##                                             ##
 279
 280 # Library versions for libtool
 281 AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
 282
 283 AM_CPPFLAGS="-include config.h"
 284 AC_SUBST(AM_CPPFLAGS)
 285
 286 AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
 287 AC_SUBST(AM_CFLAGS)
 288
 289 AC_CONFIG_FILES([
 290         Makefile
 291         doc/Makefile
 292         doc/examples/Makefile
 293         include/Makefile
 294         src/Makefile
 295         tests/Makefile
 296         tests/common/Makefile
 297         tests/unit/Makefile
 298         tests/benchmark/Makefile
 299         tests/regression/Makefile
 300         tests/utils/Makefile
 301         src/liburcu.pc
 302         src/liburcu-bp.pc
 303         src/liburcu-cds.pc
 304         src/liburcu-qsbr.pc
 305         src/liburcu-mb.pc
 306         src/liburcu-signal.pc
 307 ])
 308
 309 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 310 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 311 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 312 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 313 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 314 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 315 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 316 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 317 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 318 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 319 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 320 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 321 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 322 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 323 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 324 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 325 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 326 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 327 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 328 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 329 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 330 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 331 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 332 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 333 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 334 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 335 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 336 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 337 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 338 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 339 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 340 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 341 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 342 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 343 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 344 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 345 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 346 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 347 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 348 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 349 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 350 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 351 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 352 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 353 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 354 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 355 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 356 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 357 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 358 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 359 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 360 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 361 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 362 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 363 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 364 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 365 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 366 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 367 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 368 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 369
 370
 371 AC_OUTPUT
 372
 373 #
 374 # Mini-report on what will be built.
 375 #
 376
 377 PPRINT_INIT
 378 PPRINT_SET_INDENT(1)
 379 PPRINT_SET_TS(38)
 380
 381 AS_ECHO
 382 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 383 AS_ECHO
 384
 385 PPRINT_SUBTITLE([Features])
 386
 387 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 388
 389 # SMP support enabled/disabled
 390 test "x$def_smp_support" = "xyes" && value=1 || value=0
 391 PPRINT_PROP_BOOL([SMP support], $value)
 392
 393 # TLS
 394 test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()"
 395 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 396
 397 # clock_gettime() available
 398 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
 399 PPRINT_PROP_BOOL([clock_gettime()], $value)
 400
 401 # Require membarrier
 402 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
 403 PPRINT_PROP_BOOL([Require membarrier], $value)
 404
 405 # RCU debug enabled/disabled
 406 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
 407 PPRINT_PROP_BOOL([Internal debugging], $value)
 408
 409 # rculfhash iterator debug enabled/disabled
 410 test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
 411 PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
 412
 413 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 414
 415 report_bindir="`eval eval echo $bindir`"
 416 report_libdir="`eval eval echo $libdir`"
 417
 418 # Print the bindir and libdir this `make install' will install into.
 419 AS_ECHO
 420 PPRINT_SUBTITLE([Install directories])
 421 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 422 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 423