configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18
  19 m4_include([config/ax_tls.m4])
  20
  21 AC_CONFIG_SRCDIR([urcu.h])
  22
  23 AC_CONFIG_HEADERS([config.h urcu/config.h])
  24
  25 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  28 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  29 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  30 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  31
  32 # Allow overriding storage used for TLS variables.
  33 AC_ARG_ENABLE([compiler-tls],
  34         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  35         [def_compiler_tls=$enableval],
  36         [def_compiler_tls="yes"])
  37
  38 # If not overridden, use ax_tls.m4 to check if TLS is available.
  39 AS_IF([test "x$def_compiler_tls" = "xyes"],
  40         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  41         [:])
  42
  43 AS_IF([test "x$def_tls_detect" = "x"],
  44         [:],
  45         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  46
  47 # Checks for programs.
  48 AC_PROG_CC
  49 AC_PROG_MAKE_SET
  50 LT_INIT
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_INLINE
  54 AC_TYPE_PID_T
  55 AC_TYPE_SIZE_T
  56 AC_TYPE_INT32_T
  57 AC_TYPE_UINT32_T
  58 AC_TYPE_UINT64_T
  59 AC_TYPE_UINT8_T
  60
  61 # Checks for library functions.
  62 AC_FUNC_MALLOC
  63 AC_FUNC_MMAP
  64 AC_CHECK_FUNCS(
  65         [bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid memeset strerror]
  66 )
  67
  68 # Check for headers
  69 AC_CHECK_HEADERS([limits.h stddef.h sys/time.h])
  70
  71 # Find arch type
  72 AS_CASE([$host_cpu],
  73         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  74         [i486], [ARCHTYPE="x86"],
  75         [i586], [ARCHTYPE="x86"],
  76         [i686], [ARCHTYPE="x86"],
  77         [amd64], [ARCHTYPE="x86"],
  78         [x86_64], [ARCHTYPE="x86"],
  79         [powerpc], [ARCHTYPE="ppc"],
  80         [ppc64], [ARCHTYPE="ppc"],
  81         [powerpc64], [ARCHTYPE="ppc"],
  82         [powerpc64le], [ARCHTYPE="gcc"],
  83         [ppc], [ARCHTYPE="ppc"],
  84         [s390], [ARCHTYPE="s390"],
  85         [s390x], [ARCHTYPE="s390"],
  86         [sparc], [ARCHTYPE="sparc64"],
  87         [sparc64], [ARCHTYPE="sparc64"],
  88         [alpha*], [ARCHTYPE="alpha"],
  89         [ia64], [ARCHTYPE="gcc"],
  90         [arm*], [ARCHTYPE="arm"],
  91         [aarch64], [ARCHTYPE="gcc"],
  92         [mips*], [ARCHTYPE="mips"],
  93         [tile*], [ARCHTYPE="gcc"],
  94         [hppa*], [ARCHTYPE="hppa"],
  95         [ARCHTYPE="unknown"]
  96 )
  97
  98 AS_CASE([$host],[*-*-linux-androideabi],
  99         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 100         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 101 )
 102
 103 AC_SUBST(ARCHTYPE)
 104 AC_SUBST(SUBARCHTYPE)
 105
 106 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 107 ARCHSRC=urcu/arch/$ARCHTYPE.h
 108
 109 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 110         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 111 ])
 112
 113 AS_IF([test "$host_cpu" = "armv7l"],[
 114         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 115 ])
 116
 117 # ARM-specific checks
 118 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 119         AC_MSG_CHECKING([for dmb instruction])
 120         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 121                                 int main()
 122                                 {
 123                                         asm volatile("dmb":::"memory");
 124                                         return 0;
 125                                 }
 126                 ]])
 127         ],[
 128                 AC_MSG_RESULT([yes])
 129                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 130         ],[
 131                 AC_MSG_RESULT([no])
 132         ])
 133 ])
 134
 135 # Tile-specific checks
 136 AS_IF([echo "$host_cpu" | grep "^tile"],[
 137         AC_MSG_CHECKING([for Tile architecture type])
 138         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 139                                 #ifndef __tilegx__
 140                                 #error
 141                                 #endif
 142                 ]])
 143         ],[
 144                 AC_MSG_RESULT([ok])
 145         ],[
 146                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 147         ])
 148 ])
 149
 150 # x86-specific checks
 151 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 152         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 153         #For now, using lock; addl compatibility mode even for i686, because the
 154         #Pentium III is seen as a i686, but lacks mfence instruction.
 155         #Only using fence for x86_64.
 156         #
 157         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 158         #variant but lacks fence instructions.
 159         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
 160                 AC_MSG_RESULT([yes])
 161                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 162         ],[
 163                 AC_MSG_RESULT([no])
 164         ])
 165 ])
 166
 167 # Check if sys_futex() is available
 168 AC_MSG_CHECKING([for sys_futex()])
 169 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 170                 #include <sys/syscall.h>
 171                 #ifndef __NR_futex
 172                 #error "futexes not available"
 173                 #endif
 174         ]])
 175 ],[
 176         AC_MSG_RESULT([yes])
 177         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 178         compat_futex_test=0
 179 ],[
 180         AC_MSG_RESULT([no])
 181         compat_futex_test=1
 182 ])
 183
 184 # Check for pthread
 185 AC_CHECK_LIB([pthread], [pthread_create],
 186         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 187         [AC_CHECK_LIB([c], [pthread_create],
 188                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 189                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 190         )]
 191 )
 192
 193 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 194 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 195 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 196
 197 # smp-support configure option
 198 AC_ARG_ENABLE([smp-support],
 199         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 200         [def_smp_support=$enableval],
 201         [def_smp_support="yes"])
 202 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 203
 204
 205 # From the sched_setaffinity(2)'s man page:
 206 # ~~~~
 207 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 208 # The library interfaces were introduced in glibc 2.3.  Initially, the
 209 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 210 # the cpuset size argument was removed, but this argument was
 211 # restored in glibc 2.3.4.
 212 # ~~~~
 213
 214 # In addition to that, some vendors ported the system call to 2.4
 215 # kernels.
 216
 217 # Furthermore, when the function first appeared, the MASK argument was
 218 # an unsigned long pointer, while later it was made into a cpu_set_t
 219 # pointer.  Systems that have the cpu_set_t version also should have
 220 # the CPU_ZERO, CPU_SET, etc. macros.
 221
 222 # All this mess means we have to cater for at least 3 different
 223 # sched_setaffinity prototypes:
 224
 225 # ~~~~
 226 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 227 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 228 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 229 # ~~~~
 230
 231 # Since we define _GNU_SOURCE in the sources, must do so too in the
 232 # autoconf tests, as defining _GNU_SOURCE or not exposes
 233 # sched_setaffinity bits differently.
 234 saved_CFLAGS=$CFLAGS
 235 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 236
 237 AC_CHECK_TYPES([cpu_set_t],
 238         [have_cpu_set_t="yes"],
 239         [have_cpu_set_t="no"],
 240         [#include <sched.h>])
 241
 242 # Confirm that we have CPU_ZERO, and it actually works.
 243 AC_MSG_CHECKING([whether CPU_ZERO works])
 244 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 245 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 246                 #define _GNU_SOURCE
 247                 #include <sched.h>
 248                 int main()
 249                 {
 250                         cpu_set_t foo; CPU_ZERO(&foo);
 251                         return 0;
 252                 }
 253         ]])
 254 ],[
 255         AC_DEFINE(HAVE_CPU_ZERO, 1)
 256         AC_MSG_RESULT([yes])
 257 ],[
 258         AC_MSG_RESULT([no])
 259 ])
 260
 261 # Confirm that we have CPU_SET, and it actually works.
 262 AC_MSG_CHECKING([whether CPU_SET works])
 263 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 264 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 265                 #define _GNU_SOURCE
 266                 #include <sched.h>
 267                 int main()
 268                 {
 269                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 270                         return 0;
 271                 }
 272         ]])
 273 ],[
 274         AC_DEFINE(HAVE_CPU_SET, 1)
 275         AC_MSG_RESULT([yes])
 276 ],[
 277         AC_MSG_RESULT([no])
 278 ])
 279
 280 # First check if the function is available at all.
 281 AC_CHECK_FUNCS([sched_setaffinity],[
 282         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 283         # then we have the first version using unsigned long, and no
 284         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 285         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 286         # should also be present, but we confirm nonetheless.
 287
 288         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 289                 # We do have it.
 290                 # Check how many arguments does sched_setaffinity take.
 291                 # Should be 3 or 2.
 292                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 293                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 294                                 #include <sched.h>
 295                                 int main()
 296                                 {
 297                                         cpu_set_t foo;
 298                                         sched_setaffinity(0, sizeof (foo), &foo);
 299                                         return 0;
 300                                 }
 301                         ]])
 302                 ],
 303                 [sched_set_affinity_args=3],
 304                 [sched_set_affinity_args=2])
 305                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 306                         $sched_set_affinity_args,
 307                         [Defined to sched_setaffinity's number of arguments.])
 308                 AC_MSG_RESULT([$sched_set_affinity_args])
 309         ],[
 310                 # No cpu_set_t, always 3 args.
 311                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 312         ])
 313 ])
 314
 315 CFLAGS=$saved_CFLAGS
 316
 317 AC_CONFIG_LINKS([
 318         urcu/arch.h:$ARCHSRC
 319         urcu/uatomic.h:$UATOMICSRC
 320 ])
 321 AC_CONFIG_FILES([
 322         Makefile
 323         doc/Makefile
 324         doc/examples/Makefile
 325         tests/Makefile
 326         tests/common/Makefile
 327         tests/unit/Makefile
 328         tests/benchmark/Makefile
 329         tests/regression/Makefile
 330         tests/utils/Makefile
 331         liburcu.pc
 332         liburcu-bp.pc
 333         liburcu-cds.pc
 334         liburcu-qsbr.pc
 335         liburcu-mb.pc
 336         liburcu-signal.pc
 337 ])
 338 AC_OUTPUT
 339
 340 # Report on selected configure options
 341 AS_IF([test "x$def_smp_support" = "xyes"],[
 342         AS_ECHO("SMP support enabled.")
 343 ],[
 344         AS_ECHO("SMP support disabled.")
 345 ])
 346
 347 AS_IF([test "x$def_tls_detect" = "x"],[
 348         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 349 ],[
 350         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 351 ])