configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 AX_TLS(AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $ac_cv_tls), [:])
  32
  33 # Checks for programs.
  34 AC_PROG_CC
  35 AC_PROG_MAKE_SET
  36 LT_INIT
  37
  38 # Checks for typedefs, structures, and compiler characteristics.
  39 AC_C_INLINE
  40 AC_TYPE_PID_T
  41 AC_TYPE_SIZE_T
  42
  43 # Checks for library functions.
  44 AC_FUNC_MALLOC
  45 AC_FUNC_MMAP
  46 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  47
  48 # Find arch type
  49 AS_CASE([$host_cpu],
  50         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  51         [i486], [ARCHTYPE="x86"],
  52         [i586], [ARCHTYPE="x86"],
  53         [i686], [ARCHTYPE="x86"],
  54         [amd64], [ARCHTYPE="x86"],
  55         [x86_64], [ARCHTYPE="x86"],
  56         [powerpc], [ARCHTYPE="ppc"],
  57         [ppc64], [ARCHTYPE="ppc"],
  58         [powerpc64], [ARCHTYPE="ppc"],
  59         [ppc], [ARCHTYPE="ppc"],
  60         [s390], [ARCHTYPE="s390"],
  61         [s390x], [ARCHTYPE="s390"],
  62         [sparc64], [ARCHTYPE="sparc64"],
  63         [alpha*], [ARCHTYPE="alpha"],
  64         [ia64], [ARCHTYPE="gcc"],
  65         [arm*], [ARCHTYPE="arm"],
  66         [mips*], [ARCHTYPE="mips"],
  67         [ARCHTYPE="unknown"]
  68 )
  69
  70 AC_SUBST(ARCHTYPE)
  71 AC_SUBST(SUBARCHTYPE)
  72
  73 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  74 ARCHSRC=urcu/arch/$ARCHTYPE.h
  75
  76 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  77         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  78 ])
  79
  80 AS_IF([test "$host_cpu" = "armv7l"],[
  81         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  82 ])
  83
  84 # ARM-specific checks
  85 AS_IF([test "x$ARCHTYPE" = "xarm"],[
  86         AC_MSG_CHECKING([for dmb instruction])
  87         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  88                                 int main()
  89                                 {
  90                                         asm volatile("dmb":::"memory");
  91                                         return 0;
  92                                 }
  93                 ]])
  94         ],[
  95                 AC_MSG_RESULT([yes])
  96                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
  97         ],[
  98                 AC_MSG_RESULT([no])
  99         ])
 100 ])
 101
 102 # x86-specific checks
 103 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 104         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 105         #For now, using lock; addl compatibility mode even for i686, because the
 106         #Pentium III is seen as a i686, but lacks mfence instruction.
 107         #Only using fence for x86_64.
 108         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 109                 AC_MSG_RESULT([yes])
 110                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 111         ],[
 112                 AC_MSG_RESULT([no])
 113         ])
 114 ])
 115
 116 # Check if sys_futex() is available
 117 AC_MSG_CHECKING([for sys_futex()])
 118 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 119                 #include <sys/syscall.h>
 120                 #ifndef __NR_futex
 121                 #error "futexes not available"
 122                 #endif
 123         ]])
 124 ],[
 125         AC_MSG_RESULT([yes])
 126         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 127         compat_futex_test=0
 128 ],[
 129         AC_MSG_RESULT([no])
 130         compat_futex_test=1
 131 ])
 132
 133 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 134 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 135
 136 # smp-support configure option
 137 AC_ARG_ENABLE([smp-support],
 138         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 139         [def_smp_support=$enableval],
 140         [def_smp_support="yes"])
 141 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 142
 143
 144 # From the sched_setaffinity(2)'s man page:
 145 # ~~~~
 146 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 147 # The library interfaces were introduced in glibc 2.3.  Initially, the
 148 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 149 # the cpuset size argument was removed, but this argument was
 150 # restored in glibc 2.3.4.
 151 # ~~~~
 152
 153 # In addition to that, some vendors ported the system call to 2.4
 154 # kernels.
 155
 156 # Furthermore, when the function first appeared, the MASK argument was
 157 # an unsigned long pointer, while later it was made into a cpu_set_t
 158 # pointer.  Systems that have the cpu_set_t version also should have
 159 # the CPU_ZERO, CPU_SET, etc. macros.
 160
 161 # All this mess means we have to cater for at least 3 different
 162 # sched_setaffinity prototypes:
 163
 164 # ~~~~
 165 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 166 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 167 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 168 # ~~~~
 169
 170 # Since we define _GNU_SOURCE in the sources, must do so too in the
 171 # autoconf tests, as defining _GNU_SOURCE or not exposes
 172 # sched_setaffinity bits differently.
 173 saved_CFLAGS=$CFLAGS
 174 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 175
 176 # First check if the function is available at all.
 177 AC_CHECK_FUNCS([sched_setaffinity],[
 178         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 179         # then we have the first version using unsigned long, and no
 180         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 181         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 182         # should also be present, but we confirm nonetheless.
 183
 184         AC_CHECK_TYPES([cpu_set_t],[
 185                 # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 186                 AC_MSG_CHECKING([whether CPU_ZERO works])
 187                 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 188                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 189                                 #define _GNU_SOURCE
 190                                 #include <sched.h>
 191                                 int main()
 192                                 {
 193                                         cpu_set_t foo; CPU_ZERO (&foo);
 194                                         return 0;
 195                                 }
 196                         ]])
 197                 ],[
 198                         # Works!
 199                         AC_DEFINE(HAVE_CPU_ZERO, 1)
 200                         AC_MSG_RESULT([yes])
 201                 ],[
 202                         AC_MSG_RESULT([no])
 203                 ])
 204
 205                 # Check how many arguments does sched_setaffinity take.
 206                 # Should be 3 or 2.
 207                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 208                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 209                                 #include <sched.h>
 210                                 int main()
 211                                 {
 212                                         cpu_set_t foo;
 213                                         sched_setaffinity (0, sizeof (foo), &foo);
 214                                         return 0;
 215                                 }
 216                         ]])
 217                 ],
 218                 [sched_set_affinity_args=3],
 219                 [sched_set_affinity_args=2])
 220                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 221                         [Defined to sched_setaffinity's number of arguments.])
 222                 AC_MSG_RESULT([$sched_set_affinity_args])
 223         ],[
 224                 # No cpu_set_t, always 3 args.
 225                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 226         ],
 227         [#include <sched.h>])
 228 ])
 229
 230 CFLAGS=$saved_CFLAGS
 231
 232 AC_CONFIG_LINKS([
 233         urcu/arch.h:$ARCHSRC
 234         urcu/uatomic.h:$UATOMICSRC
 235 ])
 236 AC_CONFIG_FILES([
 237         Makefile
 238         doc/Makefile
 239         tests/Makefile
 240         liburcu.pc
 241         liburcu-bp.pc
 242         liburcu-cds.pc
 243         liburcu-qsbr.pc
 244         liburcu-mb.pc
 245         liburcu-signal.pc
 246 ])
 247 AC_OUTPUT
 248
 249 # Report on selected configure options
 250 AS_IF([test "x$def_smp_support" = "xyes"],[
 251         AS_ECHO("SMP support enabled.")
 252 ],[
 253         AS_ECHO("SMP support disabled.")
 254 ])