configure.ac

   1 dnl SPDX-License-Identifier: LGPL-2.1-only
   2 dnl
   3 dnl Copyright (C) 2021 EfficiOS, Inc.
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script.
   6
   7 # Project version information
   8 m4_define([urcu_version_major], [0])
   9 m4_define([urcu_version_minor], [13])
  10 m4_define([urcu_version_patch], [0])
  11 m4_define([urcu_version_dev_stage], [])
  12 m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage)
  13
  14 # Library version information of "liburcu"
  15 # Following the numbering scheme proposed by libtool for the library version
  16 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  17 m4_define([urcu_lib_version_current], [8])
  18 m4_define([urcu_lib_version_revision], [0])
  19 m4_define([urcu_lib_version_age], [0])
  20 m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age)
  21
  22
  23 ##                     ##
  24 ## Autoconf base setup ##
  25 ##                     ##
  26
  27 AC_PREREQ([2.69])
  28 AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/])
  29
  30 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
  31 AC_CONFIG_AUX_DIR([config])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 AC_CANONICAL_TARGET
  35 AC_CANONICAL_HOST
  36
  37
  38 ##                     ##
  39 ## Automake base setup ##
  40 ##                     ##
  41
  42 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror])
  43 AM_MAINTAINER_MODE([enable])
  44
  45 # Enable silent rules by default
  46 AM_SILENT_RULES([yes])
  47
  48
  49 ##                               ##
  50 ## OS and Arch specific defaults ##
  51 ##                               ##
  52
  53 AS_CASE([$host],
  54   [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"]
  55 )
  56
  57
  58 ##                   ##
  59 ## C compiler checks ##
  60 ##                   ##
  61
  62 # Choose the C compiler
  63 AC_PROG_CC
  64 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  65 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  66
  67 # Make sure the C compiler supports C99
  68 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  69
  70 # Enable available system extensions and LFS support
  71 AC_USE_SYSTEM_EXTENSIONS
  72 AC_SYS_LARGEFILE
  73
  74 ##                     ##
  75 ## C++ compiler checks ##
  76 ##                     ##
  77
  78 # Require a C++11 compiler without GNU extensions (-std=c++11)
  79 AX_CXX_COMPILE_STDCXX([11], [noext], [mandatory])
  80
  81 # Make sure the C compiler supports __attribute__
  82 AX_C___ATTRIBUTE__
  83 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  84   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  85
  86 # Make sure we have pthread support
  87 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  88
  89 # Checks for typedefs, structures, and compiler characteristics.
  90 AC_C_INLINE
  91 AC_C_TYPEOF
  92 AC_TYPE_INT32_T
  93 AC_TYPE_PID_T
  94 AC_TYPE_SIZE_T
  95 AC_TYPE_SSIZE_T
  96 AC_TYPE_UINT16_T
  97 AC_TYPE_UINT32_T
  98 AC_TYPE_UINT64_T
  99 AC_TYPE_UINT8_T
 100
 101 # Detect warning flags supported by the C compiler and append them to
 102 # WARN_CFLAGS.
 103 m4_define([WARN_FLAGS_LIST], [ dnl
 104   -Wall dnl
 105   -Wextra dnl
 106   -Wmissing-prototypes dnl
 107   -Wmissing-declarations dnl
 108   -Wnull-dereference dnl
 109   -Wundef dnl
 110   -Wshadow dnl
 111   -Wjump-misses-init dnl
 112   -Wsuggest-attribute=format dnl
 113   -Wtautological-constant-out-of-range-compare dnl
 114   -Wnested-externs dnl
 115   -Wwrite-strings dnl
 116   -Wformat=2 dnl
 117   -Wstrict-aliasing dnl
 118   -Wmissing-noreturn dnl
 119   -Winit-self dnl
 120   -Wduplicated-cond dnl
 121   -Wduplicated-branches dnl
 122   -Wlogical-op dnl
 123   dnl
 124   dnl-Wredundant-decls dnl
 125   -Wno-null-dereference dnl
 126 ])
 127
 128 # Pass -Werror as an extra flag during the test: this is needed to make the
 129 # -Wunknown-warning-option diagnostic fatal with clang.
 130 AC_LANG_PUSH([C])
 131 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
 132 AC_LANG_POP([C])
 133
 134 AC_LANG_PUSH([C++])
 135 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
 136 AC_LANG_POP([C++])
 137
 138 AE_IF_FEATURE_ENABLED([Werror], [WARN_CFLAGS="${WARN_CFLAGS} -Werror"])
 139 AE_IF_FEATURE_ENABLED([Werror], [WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"])
 140
 141
 142 ##               ##
 143 ## Header checks ##
 144 ##               ##
 145
 146 AC_HEADER_STDBOOL
 147 AC_CHECK_HEADERS([ \
 148         limits.h \
 149         stddef.h \
 150         sys/param.h \
 151         sys/time.h \
 152 ])
 153
 154
 155 ##                 ##
 156 ## Programs checks ##
 157 ##                 ##
 158
 159 AC_PROG_AWK
 160 AC_PROG_GREP
 161 AC_PROG_MAKE_SET
 162 AC_CHECK_PROGS(NPROC, [nproc gnproc])
 163 AC_CHECK_PROGS(GETCONF, [getconf])
 164 AS_IF([test "x$NPROC" != "x"],
 165         [NPROC_CMD=$NPROC],
 166         [AS_IF([test "x$GETCONF" != "x"],
 167                 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
 168                 [NPROC_CMD="echo 1"]
 169         )]
 170 )
 171 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
 172
 173 # Initialize and configure libtool
 174 LT_INIT
 175
 176
 177 ##                ##
 178 ## Library checks ##
 179 ##                ##
 180
 181 # Checks for library functions.
 182 AC_FUNC_MMAP
 183 AC_FUNC_FORK
 184 AC_CHECK_FUNCS([ \
 185         atexit \
 186         getcpuid \
 187         gettid \
 188         gettimeofday \
 189         memeset \
 190         memset \
 191         munmap \
 192         rand_r \
 193         sched_getcpu \
 194         sched_setaffinity \
 195         strerror \
 196         strtoul \
 197         sysconf \
 198 ])
 199
 200 # AC_FUNC_MALLOC causes problems when cross-compiling.
 201 #AC_FUNC_MALLOC
 202
 203 # Search for clock_gettime() in -lrt
 204 AC_SEARCH_LIBS([clock_gettime], [rt], [
 205   AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.])
 206 ])
 207
 208
 209 ##                             ##
 210 ## Optional features selection ##
 211 ##                             ##
 212
 213 # Allow to fallback to FIXME if the membarrier syscall is unavailable on the
 214 # running kernel, when disabled, abort if the syscall is unavailable. Applies
 215 # to default and bulletproof flavors.
 216 # Enabled by default
 217 AE_FEATURE_DEFAULT_ENABLE
 218 AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.])
 219
 220 # Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS.
 221 # Enabled by default
 222 AE_FEATURE_DEFAULT_ENABLE
 223 AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.])
 224
 225 # smp-support configure option
 226 # Enabled by default
 227 AE_FEATURE_DEFAULT_ENABLE
 228 AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.])
 229
 230 # RCU debugging option
 231 # Disabled by default
 232 AE_FEATURE_DEFAULT_DISABLE
 233 AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.])
 234
 235 # rculfhash iterator debugging
 236 # Disabled by default
 237 AE_FEATURE_DEFAULT_DISABLE
 238 AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 239
 240 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 241 # Disabled by default
 242 AE_FEATURE_DEFAULT_DISABLE
 243 AE_FEATURE([Werror],[Treat compiler warnings as errors.])
 244
 245 ##                                                                    ##
 246 ## Set defines for optional features conditionnals in the source code ##
 247 ##                                                                    ##
 248
 249 AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [
 250   AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
 251 ])
 252
 253 AE_IF_FEATURE_ENABLED([compiler-tls], [
 254   AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.])
 255 ])
 256
 257 AE_IF_FEATURE_ENABLED([smp-support], [
 258   AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
 259 ])
 260
 261 AE_IF_FEATURE_ENABLED([rcu-debug], [
 262   AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.])
 263 ])
 264
 265 AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [
 266   AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
 267 ])
 268
 269
 270 ##                                                                          ##
 271 ## Set automake variables for optional feature conditionnals in Makefile.am ##
 272 ##                                                                          ##
 273
 274 # Building the examples requires the shared libraries to be enabled
 275 AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared]))
 276
 277
 278 ##                                             ##
 279 ## Substitute variables for use in Makefile.am ##
 280 ##                                             ##
 281
 282 # Library versions for libtool
 283 AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version])
 284
 285 AC_SUBST(LT_NO_UNDEFINED)
 286
 287 # The order in which the include folders are searched is important.
 288 # The top_builddir should always be searched first in the event that a build
 289 # time generated file is included.
 290 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 291 AC_SUBST(AM_CPPFLAGS)
 292
 293 AM_CFLAGS="$WARN_CFLAGS $PTHREAD_CFLAGS"
 294 AC_SUBST(AM_CFLAGS)
 295
 296 AM_CXXFLAGS="$WARN_CXXFLAGS $PTHREAD_CFLAGS"
 297 AC_SUBST(AM_CXXFLAGS)
 298
 299
 300 ##                                     ##
 301 ## Output files generated by configure ##
 302 ##                                     ##
 303
 304 AC_CONFIG_FILES([
 305         Makefile
 306         doc/Makefile
 307         doc/examples/Makefile
 308         extras/Makefile
 309         include/Makefile
 310         src/Makefile
 311         tests/Makefile
 312         tests/common/Makefile
 313         tests/unit/Makefile
 314         tests/benchmark/Makefile
 315         tests/regression/Makefile
 316         tests/utils/Makefile
 317         src/liburcu.pc
 318         src/liburcu-bp.pc
 319         src/liburcu-cds.pc
 320         src/liburcu-qsbr.pc
 321         src/liburcu-mb.pc
 322         src/liburcu-signal.pc
 323 ])
 324
 325 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
 326 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global_cxx.tap])
 327 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
 328 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu_cxx.tap])
 329 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
 330 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread_cxx.tap])
 331 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
 332 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global_cxx.tap])
 333 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
 334 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu_cxx.tap])
 335 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
 336 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread_cxx.tap])
 337 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
 338 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global_cxx.tap])
 339 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
 340 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu_cxx.tap])
 341 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
 342 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread_cxx.tap])
 343 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
 344 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global_cxx.tap])
 345 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
 346 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu_cxx.tap])
 347 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
 348 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread_cxx.tap])
 349 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
 350 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global_cxx.tap])
 351 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
 352 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu_cxx.tap])
 353 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
 354 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread_cxx.tap])
 355 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
 356 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global_cxx.tap])
 357 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
 358 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu_cxx.tap])
 359 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
 360 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread_cxx.tap])
 361 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
 362 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global_cxx.tap])
 363 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
 364 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu_cxx.tap])
 365 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
 366 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread_cxx.tap])
 367 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
 368 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global_cxx.tap])
 369 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
 370 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu_cxx.tap])
 371 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
 372 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread_cxx.tap])
 373 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
 374 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global_cxx.tap])
 375 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
 376 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu_cxx.tap])
 377 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
 378 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread_cxx.tap])
 379 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
 380 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global_cxx.tap])
 381 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
 382 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu_cxx.tap])
 383 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
 384 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread_cxx.tap])
 385 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
 386 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global_cxx.tap])
 387 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
 388 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu_cxx.tap])
 389 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
 390 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread_cxx.tap])
 391 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
 392 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global_cxx.tap])
 393 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
 394 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu_cxx.tap])
 395 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
 396 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread_cxx.tap])
 397 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
 398 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global_cxx.tap])
 399 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
 400 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu_cxx.tap])
 401 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
 402 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread_cxx.tap])
 403 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
 404 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global_cxx.tap])
 405 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
 406 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu_cxx.tap])
 407 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
 408 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread_cxx.tap])
 409 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
 410 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global_cxx.tap])
 411 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
 412 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu_cxx.tap])
 413 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
 414 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread_cxx.tap])
 415 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
 416 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global_cxx.tap])
 417 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
 418 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu_cxx.tap])
 419 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
 420 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread_cxx.tap])
 421 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
 422 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global_cxx.tap])
 423 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
 424 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu_cxx.tap])
 425 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
 426 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread_cxx.tap])
 427 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
 428 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global_cxx.tap])
 429 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
 430 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu_cxx.tap])
 431 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
 432 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread_cxx.tap])
 433 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
 434 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global_cxx.tap])
 435 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
 436 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu_cxx.tap])
 437 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
 438 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread_cxx.tap])
 439 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
 440 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global_cxx.tap])
 441 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
 442 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu_cxx.tap])
 443 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
 444 AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread_cxx.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread_cxx.tap])
 445
 446
 447 AC_OUTPUT
 448
 449 #
 450 # Mini-report on what will be built.
 451 #
 452
 453 PPRINT_INIT
 454 PPRINT_SET_INDENT(1)
 455 PPRINT_SET_TS(38)
 456
 457 AS_ECHO
 458 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
 459 AS_ECHO
 460
 461 PPRINT_SUBTITLE([Features])
 462
 463 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 464
 465 # SMP support enabled/disabled
 466 AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0
 467 PPRINT_PROP_BOOL([SMP support], $value)
 468
 469 # TLS
 470 AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()"
 471 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
 472
 473 # clock_gettime() available
 474 test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0
 475 PPRINT_PROP_BOOL([clock_gettime()], $value)
 476
 477 # Require membarrier
 478 AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1
 479 PPRINT_PROP_BOOL([Require membarrier], $value)
 480
 481 # RCU debug enabled/disabled
 482 AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0
 483 PPRINT_PROP_BOOL([Internal debugging], $value)
 484
 485 # rculfhash iterator debug enabled/disabled
 486 AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0
 487 PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value)
 488
 489 PPRINT_PROP_BOOL([Multi-flavor support], 1)
 490
 491 report_bindir="`eval eval echo $bindir`"
 492 report_libdir="`eval eval echo $libdir`"
 493
 494 # Print the bindir and libdir this 'make install' will install into.
 495 AS_ECHO
 496 PPRINT_SUBTITLE([Install directories])
 497 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 498 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 499