configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 AM_MAINTAINER_MODE([enable])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18
  19 m4_include([config/ax_tls.m4])
  20
  21 AC_CONFIG_SRCDIR([urcu.h])
  22
  23 AC_CONFIG_HEADERS([config.h urcu/config.h])
  24
  25 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  27 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  28 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  29 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  30 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  31
  32 # Allow overriding storage used for TLS variables.
  33 AC_ARG_ENABLE([compiler-tls],
  34         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  35         [def_compiler_tls=$enableval],
  36         [def_compiler_tls="yes"])
  37
  38 # If not overridden, use ax_tls.m4 to check if TLS is available.
  39 AS_IF([test "x$def_compiler_tls" = "xyes"],
  40         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  41         [:])
  42
  43 AS_IF([test "x$def_tls_detect" = "x"],
  44         [:],
  45         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  46
  47 # Checks for programs.
  48 AC_PROG_CC
  49 AC_PROG_MAKE_SET
  50 LT_INIT
  51
  52 # Checks for typedefs, structures, and compiler characteristics.
  53 AC_C_INLINE
  54 AC_TYPE_PID_T
  55 AC_TYPE_SIZE_T
  56
  57 # Checks for library functions.
  58 AC_FUNC_MALLOC
  59 AC_FUNC_MMAP
  60 AC_CHECK_FUNCS(
  61         [bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid memeset strerror]
  62 )
  63
  64 # Find arch type
  65 AS_CASE([$host_cpu],
  66         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  67         [i486], [ARCHTYPE="x86"],
  68         [i586], [ARCHTYPE="x86"],
  69         [i686], [ARCHTYPE="x86"],
  70         [amd64], [ARCHTYPE="x86"],
  71         [x86_64], [ARCHTYPE="x86"],
  72         [powerpc], [ARCHTYPE="ppc"],
  73         [ppc64], [ARCHTYPE="ppc"],
  74         [powerpc64], [ARCHTYPE="ppc"],
  75         [powerpc64le], [ARCHTYPE="gcc"],
  76         [ppc], [ARCHTYPE="ppc"],
  77         [s390], [ARCHTYPE="s390"],
  78         [s390x], [ARCHTYPE="s390"],
  79         [sparc], [ARCHTYPE="sparc64"],
  80         [sparc64], [ARCHTYPE="sparc64"],
  81         [alpha*], [ARCHTYPE="alpha"],
  82         [ia64], [ARCHTYPE="gcc"],
  83         [arm*], [ARCHTYPE="arm"],
  84         [aarch64], [ARCHTYPE="gcc"],
  85         [mips*], [ARCHTYPE="mips"],
  86         [tile*], [ARCHTYPE="gcc"],
  87         [hppa*], [ARCHTYPE="hppa"],
  88         [ARCHTYPE="unknown"]
  89 )
  90
  91 AS_CASE([$host],[*-*-linux-androideabi],
  92         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
  93         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
  94 )
  95
  96 AC_SUBST(ARCHTYPE)
  97 AC_SUBST(SUBARCHTYPE)
  98
  99 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 100 ARCHSRC=urcu/arch/$ARCHTYPE.h
 101
 102 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 103         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 104 ])
 105
 106 AS_IF([test "$host_cpu" = "armv7l"],[
 107         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 108 ])
 109
 110 # ARM-specific checks
 111 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 112         AC_MSG_CHECKING([for dmb instruction])
 113         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 114                                 int main()
 115                                 {
 116                                         asm volatile("dmb":::"memory");
 117                                         return 0;
 118                                 }
 119                 ]])
 120         ],[
 121                 AC_MSG_RESULT([yes])
 122                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 123         ],[
 124                 AC_MSG_RESULT([no])
 125         ])
 126 ])
 127
 128 # Tile-specific checks
 129 AS_IF([echo "$host_cpu" | grep "^tile"],[
 130         AC_MSG_CHECKING([for Tile architecture type])
 131         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 132                                 #ifndef __tilegx__
 133                                 #error
 134                                 #endif
 135                 ]])
 136         ],[
 137                 AC_MSG_RESULT([ok])
 138         ],[
 139                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 140         ])
 141 ])
 142
 143 # x86-specific checks
 144 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 145         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 146         #For now, using lock; addl compatibility mode even for i686, because the
 147         #Pentium III is seen as a i686, but lacks mfence instruction.
 148         #Only using fence for x86_64.
 149         #
 150         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 151         #variant but lacks fence instructions.
 152         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
 153                 AC_MSG_RESULT([yes])
 154                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 155         ],[
 156                 AC_MSG_RESULT([no])
 157         ])
 158 ])
 159
 160 # Check if sys_futex() is available
 161 AC_MSG_CHECKING([for sys_futex()])
 162 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 163                 #include <sys/syscall.h>
 164                 #ifndef __NR_futex
 165                 #error "futexes not available"
 166                 #endif
 167         ]])
 168 ],[
 169         AC_MSG_RESULT([yes])
 170         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 171         compat_futex_test=0
 172 ],[
 173         AC_MSG_RESULT([no])
 174         compat_futex_test=1
 175 ])
 176
 177 # Check for pthread
 178 AC_CHECK_LIB([pthread], [pthread_create],
 179         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 180         [AC_CHECK_LIB([c], [pthread_create],
 181                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 182                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 183         )]
 184 )
 185
 186 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 187 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 188 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 189
 190 # smp-support configure option
 191 AC_ARG_ENABLE([smp-support],
 192         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 193         [def_smp_support=$enableval],
 194         [def_smp_support="yes"])
 195 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 196
 197
 198 # From the sched_setaffinity(2)'s man page:
 199 # ~~~~
 200 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 201 # The library interfaces were introduced in glibc 2.3.  Initially, the
 202 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 203 # the cpuset size argument was removed, but this argument was
 204 # restored in glibc 2.3.4.
 205 # ~~~~
 206
 207 # In addition to that, some vendors ported the system call to 2.4
 208 # kernels.
 209
 210 # Furthermore, when the function first appeared, the MASK argument was
 211 # an unsigned long pointer, while later it was made into a cpu_set_t
 212 # pointer.  Systems that have the cpu_set_t version also should have
 213 # the CPU_ZERO, CPU_SET, etc. macros.
 214
 215 # All this mess means we have to cater for at least 3 different
 216 # sched_setaffinity prototypes:
 217
 218 # ~~~~
 219 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 220 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 221 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 222 # ~~~~
 223
 224 # Since we define _GNU_SOURCE in the sources, must do so too in the
 225 # autoconf tests, as defining _GNU_SOURCE or not exposes
 226 # sched_setaffinity bits differently.
 227 saved_CFLAGS=$CFLAGS
 228 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 229
 230 AC_CHECK_TYPES([cpu_set_t],
 231         [have_cpu_set_t="yes"],
 232         [have_cpu_set_t="no"],
 233         [#include <sched.h>])
 234
 235 # Confirm that we have CPU_ZERO, and it actually works.
 236 AC_MSG_CHECKING([whether CPU_ZERO works])
 237 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 238 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 239                 #define _GNU_SOURCE
 240                 #include <sched.h>
 241                 int main()
 242                 {
 243                         cpu_set_t foo; CPU_ZERO(&foo);
 244                         return 0;
 245                 }
 246         ]])
 247 ],[
 248         AC_DEFINE(HAVE_CPU_ZERO, 1)
 249         AC_MSG_RESULT([yes])
 250 ],[
 251         AC_MSG_RESULT([no])
 252 ])
 253
 254 # Confirm that we have CPU_SET, and it actually works.
 255 AC_MSG_CHECKING([whether CPU_SET works])
 256 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 257 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 258                 #define _GNU_SOURCE
 259                 #include <sched.h>
 260                 int main()
 261                 {
 262                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 263                         return 0;
 264                 }
 265         ]])
 266 ],[
 267         AC_DEFINE(HAVE_CPU_SET, 1)
 268         AC_MSG_RESULT([yes])
 269 ],[
 270         AC_MSG_RESULT([no])
 271 ])
 272
 273 # First check if the function is available at all.
 274 AC_CHECK_FUNCS([sched_setaffinity],[
 275         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 276         # then we have the first version using unsigned long, and no
 277         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 278         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 279         # should also be present, but we confirm nonetheless.
 280
 281         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 282                 # We do have it.
 283                 # Check how many arguments does sched_setaffinity take.
 284                 # Should be 3 or 2.
 285                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 286                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 287                                 #include <sched.h>
 288                                 int main()
 289                                 {
 290                                         cpu_set_t foo;
 291                                         sched_setaffinity(0, sizeof (foo), &foo);
 292                                         return 0;
 293                                 }
 294                         ]])
 295                 ],
 296                 [sched_set_affinity_args=3],
 297                 [sched_set_affinity_args=2])
 298                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 299                         $sched_set_affinity_args,
 300                         [Defined to sched_setaffinity's number of arguments.])
 301                 AC_MSG_RESULT([$sched_set_affinity_args])
 302         ],[
 303                 # No cpu_set_t, always 3 args.
 304                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 305         ])
 306 ])
 307
 308 CFLAGS=$saved_CFLAGS
 309
 310 AC_CONFIG_LINKS([
 311         urcu/arch.h:$ARCHSRC
 312         urcu/uatomic.h:$UATOMICSRC
 313 ])
 314 AC_CONFIG_FILES([
 315         Makefile
 316         doc/Makefile
 317         doc/examples/Makefile
 318         tests/Makefile
 319         tests/common/Makefile
 320         tests/unit/Makefile
 321         tests/benchmark/Makefile
 322         tests/regression/Makefile
 323         liburcu.pc
 324         liburcu-bp.pc
 325         liburcu-cds.pc
 326         liburcu-qsbr.pc
 327         liburcu-mb.pc
 328         liburcu-signal.pc
 329 ])
 330 AC_OUTPUT
 331
 332 # Report on selected configure options
 333 AS_IF([test "x$def_smp_support" = "xyes"],[
 334         AS_ECHO("SMP support enabled.")
 335 ],[
 336         AS_ECHO("SMP support disabled.")
 337 ])
 338
 339 AS_IF([test "x$def_tls_detect" = "x"],[
 340         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 341 ],[
 342         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 343 ])