[urcu.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.


AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

m4_include([config/ax_tls.m4])

AC_CONFIG_SRCDIR([urcu.h])

AC_CONFIG_HEADERS([config.h urcu/config.h])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

# If not overridden, use ax_tls.m4 to check if TLS is available.
AS_IF([test "x$def_compiler_tls" = "xyes"],
	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	[:])

AS_IF([test "x$def_tls_detect" = "x"],
	[:],
	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])

# Checks for programs.
AC_PROG_CC
AC_PROG_MAKE_SET
LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_CHECK_FUNCS(
	[bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid memeset strerror]
)

# Check for headers
AC_CHECK_HEADERS([limits.h stddef.h sys/time.h])

# Find arch type
AS_CASE([$host_cpu],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[powerpc64le], [ARCHTYPE="gcc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc], [ARCHTYPE="sparc64"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="gcc"],
	[arm*], [ARCHTYPE="arm"],
	[aarch64], [ARCHTYPE="gcc"],
	[mips*], [ARCHTYPE="mips"],
	[tile*], [ARCHTYPE="gcc"],
	[hppa*], [ARCHTYPE="hppa"],
	[ARCHTYPE="unknown"]
)

AS_CASE([$host],[*-*-linux-androideabi],
	[AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
	[AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
ARCHSRC=urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	#
	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	#variant but lacks fence instructions.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

# Check for pthread
AC_CHECK_LIB([pthread], [pthread_create],
	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
	[AC_CHECK_LIB([c], [pthread_create],
		[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
		[AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
	)]
)

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])


# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

# Since we define _GNU_SOURCE in the sources, must do so too in the
# autoconf tests, as defining _GNU_SOURCE or not exposes
# sched_setaffinity bits differently.
saved_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS -D_GNU_SOURCE"

AC_CHECK_TYPES([cpu_set_t],
	[have_cpu_set_t="yes"],
	[have_cpu_set_t="no"],
	[#include <sched.h>])

# Confirm that we have CPU_ZERO, and it actually works.
AC_MSG_CHECKING([whether CPU_ZERO works])
AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define _GNU_SOURCE
		#include <sched.h>
		int main()
		{
			cpu_set_t foo; CPU_ZERO(&foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_ZERO, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# Confirm that we have CPU_SET, and it actually works.
AC_MSG_CHECKING([whether CPU_SET works])
AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define _GNU_SOURCE
		#include <sched.h>
		int main()
		{
			cpu_set_t foo, mask; CPU_SET(0, &foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_SET, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
		# We do have it.
		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity(0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
			$sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	])
])

CFLAGS=$saved_CFLAGS

AC_CONFIG_LINKS([
	urcu/arch.h:$ARCHSRC
	urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	liburcu.pc
	liburcu-bp.pc
	liburcu-cds.pc
	liburcu-qsbr.pc
	liburcu-mb.pc
	liburcu-signal.pc
])
AC_OUTPUT

# Report on selected configure options
AS_IF([test "x$def_smp_support" = "xyes"],[
	AS_ECHO("SMP support enabled.")
],[
	AS_ECHO("SMP support disabled.")
])

AS_IF([test "x$def_tls_detect" = "x"],[
	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
],[
	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
])
Commit	Line	Data
	1	# -- Autoconf --
	2	# Process this file with autoconf to produce a configure script.
	3
	4
	5	AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
	6
	7	# Following the numbering scheme proposed by libtool for the library version
	8	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	9	AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
	10
	11	AC_CONFIG_AUX_DIR([config])
	12	AC_CONFIG_MACRO_DIR([config])
	13	AC_CANONICAL_TARGET
	14	AC_CANONICAL_HOST
	15	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
	16	AM_MAINTAINER_MODE([enable])
	17	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	18
	19	m4_include([config/ax_tls.m4])
	20
	21	AC_CONFIG_SRCDIR([urcu.h])
	22
	23	AC_CONFIG_HEADERS([config.h urcu/config.h])
	24
	25	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	26	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	27	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
	28	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
	29	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
	30	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
	31
	32	# Allow overriding storage used for TLS variables.
	33	AC_ARG_ENABLE([compiler-tls],
	34	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	35	[def_compiler_tls=$enableval],
	36	[def_compiler_tls="yes"])
	37
	38	# If not overridden, use ax_tls.m4 to check if TLS is available.
	39	AS_IF([test "x$def_compiler_tls" = "xyes"],
	40	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	41	[:])
	42
	43	AS_IF([test "x$def_tls_detect" = "x"],
	44	[:],
	45	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
	46
	47	# Checks for programs.
	48	AC_PROG_CC
	49	AC_PROG_MAKE_SET
	50	LT_INIT
	51
	52	# Checks for typedefs, structures, and compiler characteristics.
	53	AC_C_INLINE
	54	AC_TYPE_PID_T
	55	AC_TYPE_SIZE_T
	56
	57	# Checks for library functions.
	58	AC_FUNC_MALLOC
	59	AC_FUNC_MMAP
	60	AC_CHECK_FUNCS(
	61	[bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid memeset strerror]
	62	)
	63
	64	# Check for headers
	65	AC_CHECK_HEADERS([limits.h stddef.h sys/time.h])
	66
	67	# Find arch type
	68	AS_CASE([$host_cpu],
	69	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	70	[i486], [ARCHTYPE="x86"],
	71	[i586], [ARCHTYPE="x86"],
	72	[i686], [ARCHTYPE="x86"],
	73	[amd64], [ARCHTYPE="x86"],
	74	[x86_64], [ARCHTYPE="x86"],
	75	[powerpc], [ARCHTYPE="ppc"],
	76	[ppc64], [ARCHTYPE="ppc"],
	77	[powerpc64], [ARCHTYPE="ppc"],
	78	[powerpc64le], [ARCHTYPE="gcc"],
	79	[ppc], [ARCHTYPE="ppc"],
	80	[s390], [ARCHTYPE="s390"],
	81	[s390x], [ARCHTYPE="s390"],
	82	[sparc], [ARCHTYPE="sparc64"],
	83	[sparc64], [ARCHTYPE="sparc64"],
	84	[alpha*], [ARCHTYPE="alpha"],
	85	[ia64], [ARCHTYPE="gcc"],
	86	[arm*], [ARCHTYPE="arm"],
	87	[aarch64], [ARCHTYPE="gcc"],
	88	[mips*], [ARCHTYPE="mips"],
	89	[tile*], [ARCHTYPE="gcc"],
	90	[hppa*], [ARCHTYPE="hppa"],
	91	[ARCHTYPE="unknown"]
	92	)
	93
	94	AS_CASE([$host],[--linux-androideabi],
	95	[AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
	96	[AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
	97	)
	98
	99	AC_SUBST(ARCHTYPE)
	100	AC_SUBST(SUBARCHTYPE)
	101
	102	UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
	103	ARCHSRC=urcu/arch/$ARCHTYPE.h
	104
	105	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	106	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	107	])
	108
	109	AS_IF([test "$host_cpu" = "armv7l"],[
	110	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
	111	])
	112
	113	# ARM-specific checks
	114	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	115	AC_MSG_CHECKING([for dmb instruction])
	116	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	117	int main()
	118	{
	119	asm volatile("dmb":::"memory");
	120	return 0;
	121	}
	122	]])
	123	],[
	124	AC_MSG_RESULT([yes])
	125	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	126	],[
	127	AC_MSG_RESULT([no])
	128	])
	129	])
	130
	131	# Tile-specific checks
	132	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	133	AC_MSG_CHECKING([for Tile architecture type])
	134	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	135	#ifndef __tilegx__
	136	#error
	137	#endif
	138	]])
	139	],[
	140	AC_MSG_RESULT([ok])
	141	],[
	142	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	143	])
	144	])
	145
	146	# x86-specific checks
	147	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	148	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	149	#For now, using lock; addl compatibility mode even for i686, because the
	150	#Pentium III is seen as a i686, but lacks mfence instruction.
	151	#Only using fence for x86_64.
	152	#
	153	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	154	#variant but lacks fence instructions.
	155	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
	156	AC_MSG_RESULT([yes])
	157	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	158	],[
	159	AC_MSG_RESULT([no])
	160	])
	161	])
	162
	163	# Check if sys_futex() is available
	164	AC_MSG_CHECKING([for sys_futex()])
	165	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	166	#include <sys/syscall.h>
	167	#ifndef __NR_futex
	168	#error "futexes not available"
	169	#endif
	170	]])
	171	],[
	172	AC_MSG_RESULT([yes])
	173	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	174	compat_futex_test=0
	175	],[
	176	AC_MSG_RESULT([no])
	177	compat_futex_test=1
	178	])
	179
	180	# Check for pthread
	181	AC_CHECK_LIB([pthread], [pthread_create],
	182	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
	183	[AC_CHECK_LIB([c], [pthread_create],
	184	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
	185	[AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
	186	)]
	187	)
	188
	189	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
	190	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
	191	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	192
	193	# smp-support configure option
	194	AC_ARG_ENABLE([smp-support],
	195	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	196	[def_smp_support=$enableval],
	197	[def_smp_support="yes"])
	198	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
	199
	200
	201	# From the sched_setaffinity(2)'s man page:
	202	# ~~~~
	203	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	204	# The library interfaces were introduced in glibc 2.3. Initially, the
	205	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	206	# the cpuset size argument was removed, but this argument was
	207	# restored in glibc 2.3.4.
	208	# ~~~~
	209
	210	# In addition to that, some vendors ported the system call to 2.4
	211	# kernels.
	212
	213	# Furthermore, when the function first appeared, the MASK argument was
	214	# an unsigned long pointer, while later it was made into a cpu_set_t
	215	# pointer. Systems that have the cpu_set_t version also should have
	216	# the CPU_ZERO, CPU_SET, etc. macros.
	217
	218	# All this mess means we have to cater for at least 3 different
	219	# sched_setaffinity prototypes:
	220
	221	# ~~~~
	222	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	223	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	224	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	225	# ~~~~
	226
	227	# Since we define _GNU_SOURCE in the sources, must do so too in the
	228	# autoconf tests, as defining _GNU_SOURCE or not exposes
	229	# sched_setaffinity bits differently.
	230	saved_CFLAGS=$CFLAGS
	231	CFLAGS="$CFLAGS -D_GNU_SOURCE"
	232
	233	AC_CHECK_TYPES([cpu_set_t],
	234	[have_cpu_set_t="yes"],
	235	[have_cpu_set_t="no"],
	236	[#include <sched.h>])
	237
	238	# Confirm that we have CPU_ZERO, and it actually works.
	239	AC_MSG_CHECKING([whether CPU_ZERO works])
	240	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	241	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	242	#define _GNU_SOURCE
	243	#include <sched.h>
	244	int main()
	245	{
	246	cpu_set_t foo; CPU_ZERO(&foo);
	247	return 0;
	248	}
	249	]])
	250	],[
	251	AC_DEFINE(HAVE_CPU_ZERO, 1)
	252	AC_MSG_RESULT([yes])
	253	],[
	254	AC_MSG_RESULT([no])
	255	])
	256
	257	# Confirm that we have CPU_SET, and it actually works.
	258	AC_MSG_CHECKING([whether CPU_SET works])
	259	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	260	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	261	#define _GNU_SOURCE
	262	#include <sched.h>
	263	int main()
	264	{
	265	cpu_set_t foo, mask; CPU_SET(0, &foo);
	266	return 0;
	267	}
	268	]])
	269	],[
	270	AC_DEFINE(HAVE_CPU_SET, 1)
	271	AC_MSG_RESULT([yes])
	272	],[
	273	AC_MSG_RESULT([no])
	274	])
	275
	276	# First check if the function is available at all.
	277	AC_CHECK_FUNCS([sched_setaffinity],[
	278	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	279	# then we have the first version using unsigned long, and no
	280	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	281	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	282	# should also be present, but we confirm nonetheless.
	283
	284	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
	285	# We do have it.
	286	# Check how many arguments does sched_setaffinity take.
	287	# Should be 3 or 2.
	288	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
	289	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	290	#include <sched.h>
	291	int main()
	292	{
	293	cpu_set_t foo;
	294	sched_setaffinity(0, sizeof (foo), &foo);
	295	return 0;
	296	}
	297	]])
	298	],
	299	[sched_set_affinity_args=3],
	300	[sched_set_affinity_args=2])
	301	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
	302	$sched_set_affinity_args,
	303	[Defined to sched_setaffinity's number of arguments.])
	304	AC_MSG_RESULT([$sched_set_affinity_args])
	305	],[
	306	# No cpu_set_t, always 3 args.
	307	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	308	])
	309	])
	310
	311	CFLAGS=$saved_CFLAGS
	312
	313	AC_CONFIG_LINKS([
	314	urcu/arch.h:$ARCHSRC
	315	urcu/uatomic.h:$UATOMICSRC
	316	])
	317	AC_CONFIG_FILES([
	318	Makefile
	319	doc/Makefile
	320	doc/examples/Makefile
	321	tests/Makefile
	322	tests/common/Makefile
	323	tests/unit/Makefile
	324	tests/benchmark/Makefile
	325	tests/regression/Makefile
	326	liburcu.pc
	327	liburcu-bp.pc
	328	liburcu-cds.pc
	329	liburcu-qsbr.pc
	330	liburcu-mb.pc
	331	liburcu-signal.pc
	332	])
	333	AC_OUTPUT
	334
	335	# Report on selected configure options
	336	AS_IF([test "x$def_smp_support" = "xyes"],[
	337	AS_ECHO("SMP support enabled.")
	338	],[
	339	AS_ECHO("SMP support disabled.")
	340	])
	341
	342	AS_IF([test "x$def_tls_detect" = "x"],[
	343	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
	344	],[
	345	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
	346	])