[urcu.git] / configure.ac

AC_PREREQ(2.59)
AC_INIT([userspace-rcu],[0.10.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])

AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
AM_MAINTAINER_MODE([enable])

# Enable silent rules if available (Introduced in AM 1.11)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.])

# Allow requiring the operating system to support the membarrier system
# call. Applies to default and bulletproof flavors.
AC_ARG_ENABLE([sys-membarrier-fallback],
	AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
	[def_sys_membarrier_fallback=$enableval],
	[def_sys_membarrier_fallback="yes"])
AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

# If not overridden, use ax_tls.m4 to check if TLS is available.
AS_IF([test "x$def_compiler_tls" = "xyes"],
	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	[:])

AS_IF([test "x$def_tls_detect" = "x"],
	[:],
	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])

# Checks for C compiler
AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AC_PROG_CC_STDC

# Checks for programs.
AC_PROG_AWK
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
AC_CHECK_PROGS(GETCONF, [getconf])
AS_IF([test "x$NPROC" != "x"],
	[NPROC_CMD=$NPROC],
	[AS_IF([test "x$GETCONF" != "x"],
		[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
		[NPROC_CMD="echo 1"]
	)]
)
AC_SUBST([NPROC_CMD], [$NPROC_CMD])

LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_INT32_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	[:],
	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])

# Checks for library functions.
AC_FUNC_MMAP
AC_FUNC_FORK
AC_CHECK_FUNCS([ \
	atexit \
	getcpuid \
	gettid \
	gettimeofday \
	memeset \
	memset \
	munmap \
	rand_r \
	sched_getcpu \
	strerror \
	strtoul \
	sysconf \
])

# AC_FUNC_MALLOC causes problems when cross-compiling.
#AC_FUNC_MALLOC

# Check for headers
AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	limits.h \
	stddef.h \
	sys/param.h \
	sys/time.h \
])

# Find arch type
AS_CASE([$host_cpu],
	[k1om], [ARCHTYPE="x86"],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[powerpc64le], [ARCHTYPE="ppc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc], [ARCHTYPE="sparc64"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="ia64"],
	[arm*], [ARCHTYPE="arm"],
	[aarch64*], [ARCHTYPE="aarch64"],
	[mips*], [ARCHTYPE="mips"],
	[nios2*], [ARCHTYPE="nios2"],
	[tile*], [ARCHTYPE="tile"],
	[hppa*], [ARCHTYPE="hppa"],
	[ARCHTYPE="unknown"]
)

AS_CASE([$host],[*-cygwin*],
	[AM_CONDITIONAL(USE_CYGWIN, true)],
	[AM_CONDITIONAL(USE_CYGWIN, false)]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
ARCHSRC=include/urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	#
	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	#variant but lacks fence instructions.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
		config_rcu_have_fence=yes
	],[
		AC_MSG_RESULT([no])
		config_rcu_have_fence=no
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

# Search for clock_gettime
AC_SEARCH_LIBS([clock_gettime], [rt], [
	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
	config_rcu_have_clock_gettime=yes
], [])

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])

# RCU debugging option
AC_ARG_ENABLE([rcu-debug],
      AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
		      self-checks. Introduce performance penalty.]))
AS_IF([test "x$enable_rcu_debug" = "xyes"], [
       AC_DEFINE([CONFIG_RCU_DEBUG], [1])
])

# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

AC_CHECK_TYPES([cpu_set_t],
	[have_cpu_set_t="yes"],
	[have_cpu_set_t="no"],
	[#include <sched.h>])

# Confirm that we have CPU_ZERO, and it actually works.
AC_MSG_CHECKING([whether CPU_ZERO works])
AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sched.h>
		int main()
		{
			cpu_set_t foo; CPU_ZERO(&foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_ZERO, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# Confirm that we have CPU_SET, and it actually works.
AC_MSG_CHECKING([whether CPU_SET works])
AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sched.h>
		int main()
		{
			cpu_set_t foo, mask; CPU_SET(0, &foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_SET, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
		# We do have it.
		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity(0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
			$sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	])
])

AM_CPPFLAGS="-include config.h"
AC_SUBST(AM_CPPFLAGS)

AC_SUBST(AM_CFLAGS)

AC_CONFIG_LINKS([
	include/urcu/arch.h:$ARCHSRC
	include/urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	src/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/regression/regression_tests
	tests/utils/Makefile
	src/liburcu.pc
	src/liburcu-bp.pc
	src/liburcu-cds.pc
	src/liburcu-qsbr.pc
	src/liburcu-mb.pc
	src/liburcu-signal.pc
])
AC_OUTPUT

#
# Mini-report on what will be built.
#

PPRINT_INIT
PPRINT_SET_INDENT(1)
PPRINT_SET_TS(38)

AS_ECHO
AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
AS_ECHO

PPRINT_SUBTITLE([Features])

PPRINT_PROP_STRING([Target architecture], $host_cpu)

# SMP support enabled/disabled
test "x$def_smp_support" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([SMP support], $value)

# Memory fence support available
test "x$config_rcu_have_fence" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([Memory fence instructions], $value)

# Futex support available
test "x$compat_futex_test" = "x0" && value=1 || value=0
PPRINT_PROP_BOOL([Futex support], $value)

# TLS
test "x$def_tls_detect" = "x" && value="pthread_getspecific()" || value="$def_tls_detect"
PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])

# clock_gettime() available
test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([clock_gettime()], $value)

# Require membarrier
test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([Require membarrier], $value)

# RCU debug enabled/disabled
test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
PPRINT_PROP_BOOL([Internal debugging], $value)

report_bindir="`eval eval echo $bindir`"
report_libdir="`eval eval echo $libdir`"

# Print the bindir and libdir this `make install' will install into.
AS_ECHO
PPRINT_SUBTITLE([Install directories])
PPRINT_PROP_STRING([Binaries], [$report_bindir])
PPRINT_PROP_STRING([Libraries], [$report_libdir])
Commit	Line	Data
074c3a1b	1	AC_PREREQ(2.59)
d5edb898	2	AC_INIT([userspace-rcu],[0.10.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
98bc124a YB	3
	4	# Following the numbering scheme proposed by libtool for the library version
	5	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9e5f4ff4	6	AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
98bc124a	7
6893800a	8	AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
48d848c7	9	AC_CONFIG_AUX_DIR([config])
074c3a1b MJ	10	AC_CONFIG_MACRO_DIR([m4])
074c3a1b MJ	11
7d413817 MD	12	AC_CANONICAL_TARGET
7d413817 MD	13	AC_CANONICAL_HOST
074c3a1b	14
6893800a	15	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
35eb2d6c	16	AM_MAINTAINER_MODE([enable])
7d413817	17
074c3a1b MJ	18	# Enable silent rules if available (Introduced in AM 1.11)
074c3a1b MJ	19	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
e72596d1	20
02be5561 MD	21	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	22	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	23	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
a6412536 AM	24	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
a6412536 AM	25	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
a767fdc3	26	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
a0307b90	27	AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
d8d9a340	28	AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
d4e640c0	29	AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.])
d8d9a340 MD	30
	31	# Allow requiring the operating system to support the membarrier system
	32	# call. Applies to default and bulletproof flavors.
	33	AC_ARG_ENABLE([sys-membarrier-fallback],
	34	AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
	35	[def_sys_membarrier_fallback=$enableval],
	36	[def_sys_membarrier_fallback="yes"])
	37	AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
a767fdc3	38
75478b32 MD	39	# Allow overriding storage used for TLS variables.
	40	AC_ARG_ENABLE([compiler-tls],
	41	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	42	[def_compiler_tls=$enableval],
	43	[def_compiler_tls="yes"])
	44
	45	# If not overridden, use ax_tls.m4 to check if TLS is available.
	46	AS_IF([test "x$def_compiler_tls" = "xyes"],
	47	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	48	[:])
	49
	50	AS_IF([test "x$def_tls_detect" = "x"],
	51	[:],
	52	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
48d848c7	53
074c3a1b MJ	54	# Checks for C compiler
074c3a1b MJ	55	AC_USE_SYSTEM_EXTENSIONS
48d848c7	56	AC_PROG_CC
074c3a1b MJ	57	AC_PROG_CC_STDC
	58
	59	# Checks for programs.
27d5e306	60	AC_PROG_AWK
48d848c7	61	AC_PROG_MAKE_SET
074c3a1b	62	AC_CHECK_PROGS(NPROC, [nproc gnproc])
2350bf7b MJ	63	AC_CHECK_PROGS(GETCONF, [getconf])
	64	AS_IF([test "x$NPROC" != "x"],
	65	[NPROC_CMD=$NPROC],
	66	[AS_IF([test "x$GETCONF" != "x"],
	67	[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
	68	[NPROC_CMD="echo 1"]
	69	)]
	70	)
	71	AC_SUBST([NPROC_CMD], [$NPROC_CMD])
	72
b14a378a	73	LT_INIT
48d848c7 PMF	74
	75	# Checks for typedefs, structures, and compiler characteristics.
	76	AC_C_INLINE
	77	AC_TYPE_PID_T
	78	AC_TYPE_SIZE_T
27d5e306 MJ	79	AC_TYPE_SSIZE_T
27d5e306 MJ	80	AC_TYPE_UINT16_T
991d28ca JR	81	AC_TYPE_INT32_T
	82	AC_TYPE_UINT32_T
	83	AC_TYPE_UINT64_T
	84	AC_TYPE_UINT8_T
48d848c7	85
074c3a1b MJ	86	AX_C___ATTRIBUTE__
	87	AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	88	[:],
	89	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	90
	91	AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
074c3a1b	92
48d848c7	93	# Checks for library functions.
48d848c7	94	AC_FUNC_MMAP
27d5e306 MJ	95	AC_FUNC_FORK
	96	AC_CHECK_FUNCS([ \
	97	atexit \
27d5e306 MJ	98	getcpuid \
	99	gettid \
	100	gettimeofday \
	101	memeset \
	102	memset \
	103	munmap \
3e4ae45a	104	rand_r \
27d5e306 MJ	105	sched_getcpu \
	106	strerror \
	107	strtoul \
	108	sysconf \
	109	])
48d848c7	110
9a62b0f0 MJ	111	# AC_FUNC_MALLOC causes problems when cross-compiling.
	112	#AC_FUNC_MALLOC
	113
bb6afa9a	114	# Check for headers
7dea28e7	115	AC_HEADER_STDBOOL
27d5e306 MJ	116	AC_CHECK_HEADERS([ \
	117	limits.h \
	118	stddef.h \
	119	sys/param.h \
	120	sys/time.h \
	121	])
bb6afa9a	122
48d848c7	123	# Find arch type
58e9f838	124	AS_CASE([$host_cpu],
52fe6e60	125	[k1om], [ARCHTYPE="x86"],
a6412536 AM	126	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	127	[i486], [ARCHTYPE="x86"],
	128	[i586], [ARCHTYPE="x86"],
	129	[i686], [ARCHTYPE="x86"],
	130	[amd64], [ARCHTYPE="x86"],
	131	[x86_64], [ARCHTYPE="x86"],
	132	[powerpc], [ARCHTYPE="ppc"],
	133	[ppc64], [ARCHTYPE="ppc"],
	134	[powerpc64], [ARCHTYPE="ppc"],
61126bd9	135	[powerpc64le], [ARCHTYPE="ppc"],
a6412536 AM	136	[ppc], [ARCHTYPE="ppc"],
	137	[s390], [ARCHTYPE="s390"],
	138	[s390x], [ARCHTYPE="s390"],
171ff3a3	139	[sparc], [ARCHTYPE="sparc64"],
a6412536 AM	140	[sparc64], [ARCHTYPE="sparc64"],
a6412536 AM	141	[alpha*], [ARCHTYPE="alpha"],
c21a8d01	142	[ia64], [ARCHTYPE="ia64"],
a6412536	143	[arm*], [ARCHTYPE="arm"],
d1c67842	144	[aarch64*], [ARCHTYPE="aarch64"],
e1259cb1	145	[mips*], [ARCHTYPE="mips"],
859050b3	146	[nios2*], [ARCHTYPE="nios2"],
c23069c6	147	[tile*], [ARCHTYPE="tile"],
13e0bc72	148	[hppa*], [ARCHTYPE="hppa"],
a6412536 AM	149	[ARCHTYPE="unknown"]
a6412536 AM	150	)
91b0650a	151
b129d5d7 SB	152	AS_CASE([$host],[-cygwin],
	153	[AM_CONDITIONAL(USE_CYGWIN, true)],
	154	[AM_CONDITIONAL(USE_CYGWIN, false)]
	155	)
	156
a6412536 AM	157	AC_SUBST(ARCHTYPE)
a6412536 AM	158	AC_SUBST(SUBARCHTYPE)
5e626e0e	159
6893800a MJ	160	UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
6893800a MJ	161	ARCHSRC=include/urcu/arch/$ARCHTYPE.h
455b809a	162
a6412536 AM	163	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	164	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	165	])
	166
58e9f838	167	AS_IF([test "$host_cpu" = "armv7l"],[
9a79c612	168	AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
a6412536	169	])
48d848c7	170
a6412536 AM	171	# ARM-specific checks
	172	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	173	AC_MSG_CHECKING([for dmb instruction])
fe0707ab MD	174	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	175	int main()
	176	{
	177	asm volatile("dmb":::"memory");
	178	return 0;
	179	}
	180	]])
	181	],[
a6412536 AM	182	AC_MSG_RESULT([yes])
	183	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	184	],[
	185	AC_MSG_RESULT([no])
	186	])
	187	])
	188
274773cf SM	189	# Tile-specific checks
	190	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	191	AC_MSG_CHECKING([for Tile architecture type])
	192	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	193	#ifndef __tilegx__
	194	#error
	195	#endif
	196	]])
	197	],[
	198	AC_MSG_RESULT([ok])
	199	],[
	200	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	201	])
	202	])
	203
a6412536 AM	204	# x86-specific checks
	205	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	206	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	207	#For now, using lock; addl compatibility mode even for i686, because the
	208	#Pentium III is seen as a i686, but lacks mfence instruction.
	209	#Only using fence for x86_64.
8496c886 SM	210	#
	211	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	212	#variant but lacks fence instructions.
52fe6e60	213	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
a6412536 AM	214	AC_MSG_RESULT([yes])
a6412536 AM	215	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
628a1a72	216	config_rcu_have_fence=yes
a6412536 AM	217	],[
a6412536 AM	218	AC_MSG_RESULT([no])
628a1a72	219	config_rcu_have_fence=no
a6412536 AM	220	])
	221	])
	222
	223	# Check if sys_futex() is available
	224	AC_MSG_CHECKING([for sys_futex()])
fe0707ab	225	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536	226	#include <sys/syscall.h>
a6412536 AM	227	#ifndef __NR_futex
	228	#error "futexes not available"
	229	#endif
fe0707ab	230	]])
a6412536	231	],[
0854ccff	232	AC_MSG_RESULT([yes])
02be5561	233	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
0854ccff	234	compat_futex_test=0
91b0650a	235	],[
0854ccff MD	236	AC_MSG_RESULT([no])
0854ccff MD	237	compat_futex_test=1
91b0650a	238	])
0854ccff	239
8be0fb5f	240	# Search for clock_gettime
a0307b90 MD	241	AC_SEARCH_LIBS([clock_gettime], [rt], [
a0307b90 MD	242	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
628a1a72	243	config_rcu_have_clock_gettime=yes
a0307b90	244	], [])
8be0fb5f	245
a6412536 AM	246	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
a6412536 AM	247	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
2f49a496	248	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
0854ccff	249
a6412536 AM	250	# smp-support configure option
	251	AC_ARG_ENABLE([smp-support],
	252	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	253	[def_smp_support=$enableval],
	254	[def_smp_support="yes"])
	255	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
7d413817	256
d4e640c0 JR	257	# RCU debugging option
	258	AC_ARG_ENABLE([rcu-debug],
	259	AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
	260	self-checks. Introduce performance penalty.]))
	261	AS_IF([test "x$enable_rcu_debug" = "xyes"], [
	262	AC_DEFINE([CONFIG_RCU_DEBUG], [1])
	263	])
48d848c7	264
d8540fc5 PA	265	# From the sched_setaffinity(2)'s man page:
	266	# ~~~~
	267	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	268	# The library interfaces were introduced in glibc 2.3. Initially, the
	269	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	270	# the cpuset size argument was removed, but this argument was
	271	# restored in glibc 2.3.4.
	272	# ~~~~
	273
	274	# In addition to that, some vendors ported the system call to 2.4
	275	# kernels.
	276
	277	# Furthermore, when the function first appeared, the MASK argument was
	278	# an unsigned long pointer, while later it was made into a cpu_set_t
	279	# pointer. Systems that have the cpu_set_t version also should have
	280	# the CPU_ZERO, CPU_SET, etc. macros.
	281
	282	# All this mess means we have to cater for at least 3 different
	283	# sched_setaffinity prototypes:
	284
	285	# ~~~~
	286	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	287	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	288	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	289	# ~~~~
	290
b3231c17 MD	291	AC_CHECK_TYPES([cpu_set_t],
	292	[have_cpu_set_t="yes"],
	293	[have_cpu_set_t="no"],
	294	[#include <sched.h>])
	295
	296	# Confirm that we have CPU_ZERO, and it actually works.
	297	AC_MSG_CHECKING([whether CPU_ZERO works])
	298	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	299	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b3231c17 MD	300	#include <sched.h>
	301	int main()
	302	{
	303	cpu_set_t foo; CPU_ZERO(&foo);
	304	return 0;
	305	}
	306	]])
	307	],[
	308	AC_DEFINE(HAVE_CPU_ZERO, 1)
	309	AC_MSG_RESULT([yes])
	310	],[
	311	AC_MSG_RESULT([no])
	312	])
	313
	314	# Confirm that we have CPU_SET, and it actually works.
	315	AC_MSG_CHECKING([whether CPU_SET works])
	316	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	317	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b3231c17 MD	318	#include <sched.h>
	319	int main()
	320	{
	321	cpu_set_t foo, mask; CPU_SET(0, &foo);
	322	return 0;
	323	}
	324	]])
	325	],[
	326	AC_DEFINE(HAVE_CPU_SET, 1)
	327	AC_MSG_RESULT([yes])
	328	],[
	329	AC_MSG_RESULT([no])
	330	])
	331
d8540fc5	332	# First check if the function is available at all.
a6412536 AM	333	AC_CHECK_FUNCS([sched_setaffinity],[
	334	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	335	# then we have the first version using unsigned long, and no
	336	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	337	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	338	# should also be present, but we confirm nonetheless.
	339
b3231c17 MD	340	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
b3231c17 MD	341	# We do have it.
a6412536 AM	342	# Check how many arguments does sched_setaffinity take.
	343	# Should be 3 or 2.
	344	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
ec5e2d14	345	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536	346	#include <sched.h>
fe0707ab MD	347	int main()
	348	{
	349	cpu_set_t foo;
b3231c17	350	sched_setaffinity(0, sizeof (foo), &foo);
fe0707ab MD	351	return 0;
fe0707ab MD	352	}
a6412536 AM	353	]])
	354	],
	355	[sched_set_affinity_args=3],
	356	[sched_set_affinity_args=2])
b3231c17 MD	357	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
b3231c17 MD	358	$sched_set_affinity_args,
a6412536 AM	359	[Defined to sched_setaffinity's number of arguments.])
	360	AC_MSG_RESULT([$sched_set_affinity_args])
	361	],[
	362	# No cpu_set_t, always 3 args.
	363	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
b3231c17	364	])
a6412536	365	])
d8540fc5	366
9a79c612 MJ	367	AM_CPPFLAGS="-include config.h"
	368	AC_SUBST(AM_CPPFLAGS)
	369
	370	AC_SUBST(AM_CFLAGS)
d8540fc5	371
455b809a	372	AC_CONFIG_LINKS([
6893800a MJ	373	include/urcu/arch.h:$ARCHSRC
6893800a MJ	374	include/urcu/uatomic.h:$UATOMICSRC
455b809a	375	])
48d848c7 PMF	376	AC_CONFIG_FILES([
48d848c7 PMF	377	Makefile
fe999c05	378	doc/Makefile
8bad63a0	379	doc/examples/Makefile
6893800a MJ	380	include/Makefile
6893800a MJ	381	src/Makefile
48d848c7	382	tests/Makefile
f5ab766e MD	383	tests/common/Makefile
	384	tests/unit/Makefile
	385	tests/benchmark/Makefile
	386	tests/regression/Makefile
074c3a1b	387	tests/regression/regression_tests
1b387491	388	tests/utils/Makefile
6893800a MJ	389	src/liburcu.pc
	390	src/liburcu-bp.pc
	391	src/liburcu-cds.pc
	392	src/liburcu-qsbr.pc
	393	src/liburcu-mb.pc
	394	src/liburcu-signal.pc
48d848c7 PMF	395	])
48d848c7 PMF	396	AC_OUTPUT
a6412536	397
628a1a72 MJ	398	#
	399	# Mini-report on what will be built.
	400	#
	401
	402	PPRINT_INIT
	403	PPRINT_SET_INDENT(1)
	404	PPRINT_SET_TS(38)
	405
	406	AS_ECHO
	407	AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
	408	AS_ECHO
	409
	410	PPRINT_SUBTITLE([Features])
	411
	412	PPRINT_PROP_STRING([Target architecture], $host_cpu)
	413
	414	# SMP support enabled/disabled
	415	test "x$def_smp_support" = "xyes" && value=1 \|\| value=0
	416	PPRINT_PROP_BOOL([SMP support], $value)
	417
	418	# Memory fence support available
	419	test "x$config_rcu_have_fence" = "xyes" && value=1 \|\| value=0
	420	PPRINT_PROP_BOOL([Memory fence instructions], $value)
	421
	422	# Futex support available
	423	test "x$compat_futex_test" = "x0" && value=1 \|\| value=0
	424	PPRINT_PROP_BOOL([Futex support], $value)
	425
	426	# TLS
	427	test "x$def_tls_detect" = "x" && value="pthread_getspecific()" \|\| value="$def_tls_detect"
	428	PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
	429
	430	# clock_gettime() available
	431	test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 \|\| value=0
	432	PPRINT_PROP_BOOL([clock_gettime()], $value)
	433
	434	# Require membarrier
	435	test "x$def_sys_membarrier_fallback" != "xyes" && value=1 \|\| value=0
	436	PPRINT_PROP_BOOL([Require membarrier], $value)
	437
	438	# RCU debug enabled/disabled
	439	test "x$enable_rcu_debug" = "xyes" && value=1 \|\| value=0
	440	PPRINT_PROP_BOOL([Internal debugging], $value)
	441
	442	report_bindir="`eval eval echo $bindir`"
	443	report_libdir="`eval eval echo $libdir`"
	444
	445	# Print the bindir and libdir this `make install' will install into.
	446	AS_ECHO
	447	PPRINT_SUBTITLE([Install directories])
	448	PPRINT_PROP_STRING([Binaries], [$report_bindir])
	449	PPRINT_PROP_STRING([Libraries], [$report_libdir])
75478b32	450