configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_LIST], [ dnl
  61   -Wall dnl
  62   dnl We currently get this warning when building with Clang:
  63   dnl
  64   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  65   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  66   dnl            ^
  67   -Wno-incomplete-setjmp-declaration dnl
  68   -Wdiscarded-qualifiers dnl
  69   -Wmissing-declarations dnl
  70   -Wmissing-prototypes dnl
  71   -Wmissing-parameter-type dnl
  72   -Wshadow dnl
  73   -Wno-gnu-folding-constant dnl
  74   -Wsuggest-attribute=format dnl
  75   dnl GCC enables this with -Wall in C++, and that generates a
  76   dnl lot of warnings that have on average a low value to fix.
  77   -Wno-sign-compare dnl
  78 ])
  79
  80 # Pass -Werror as an extra flag during the test: this is needed to make the
  81 # -Wunknown-warning-option diagnostic fatal with clang.
  82 AC_LANG_PUSH([C])
  83 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
  84 AC_LANG_POP([C])
  85
  86 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
  87 # written in such a way that it triggers warnings with the following warning
  88 # flags.  So they would always end up disabled if we put them there, because
  89 # the test program would not build.
  90 #
  91 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
  92 # Clang >= 3.3 (required by the project) and are only valid for C code.
  93 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
  94
  95 # Disable 'strict aliasing' if the C compiler supports it.
  96 AC_LANG_PUSH([C])
  97 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
  98 AC_LANG_POP([C])
  99
 100
 101 ##                     ##
 102 ## C++ compiler checks ##
 103 ##                     ##
 104
 105 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 106 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 107
 108 # Pass -Werror as an extra flag during the test: this is needed to make the
 109 # -Wunknown-warning-option diagnostic fatal with clang.
 110 AC_LANG_PUSH([C++])
 111 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
 112 AC_LANG_POP([C++])
 113
 114 # Disable 'strict aliasing' if the C++ compiler supports it.
 115 AC_LANG_PUSH([C++])
 116 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 117 AC_LANG_POP([C++])
 118
 119
 120 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 121 AC_ARG_ENABLE([Werror],[
 122   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 123 ])
 124
 125 AS_IF([test "x$enable_Werror" = "xyes"], [
 126   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 127   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 128 ])
 129
 130 # Checks for programs.
 131 AC_PROG_GREP
 132 AC_PROG_MAKE_SET
 133 AC_PROG_SED
 134 AC_PATH_PROG([report_fold], [fold])
 135 LT_INIT
 136
 137 # Check for objcopy, required by the base address statedump and dynamic linker tests
 138 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
 139 AS_IF([test "x$OBJCOPY" = "xno"],
 140         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 141 )
 142 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
 143
 144 # check for pgrep
 145 AC_PATH_PROG([PGREP], [pgrep], [no])
 146 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
 147
 148 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 149 # is not distributed in tarballs
 150 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 151 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 152
 153 # check for bison
 154 AC_PROG_YACC
 155 BISON=$YACC
 156 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 157
 158 AS_IF([test "x$have_bison" != "xyes"], [
 159   AS_IF([test "x$in_git_repo" = "xyes"], [
 160     AC_MSG_FAILURE([
 161 Bison >= 2.4 is required when building from the Git repository. You can
 162 set the YACC variable to override automatic detection.
 163     ])
 164   ], [
 165     AC_MSG_WARN([
 166 Missing Bison >= 2.4. Note that the parser files are already built in
 167 this distribution tarball, so Bison is only needed if you intend to
 168 modify their sources. You can set the YACC variable to override automatic
 169 detection.
 170     ])
 171   ])
 172 ])
 173 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 174
 175 # check for flex
 176 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 177 # problem since the argument is silently ignored by older versions.
 178 AC_PROG_LEX([noyywrap])
 179 FLEX=$LEX
 180 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 181
 182 AS_IF([test "x$have_flex" != "xyes"], [
 183   AS_IF([test "x$in_git_repo" = "xyes"], [
 184     AC_MSG_FAILURE([
 185 Flex >= 2.5.35 is required when building from the Git repository. You can
 186 set the LEX variable to override automatic detection.
 187     ])
 188   ], [
 189     AC_MSG_WARN([
 190 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 191 this distribution tarball, so Flex is only needed if you intend to
 192 modify their sources. You can set the LEX variable to override automatic
 193 detection.
 194     ])
 195   ])
 196 ])
 197 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 198
 199
 200
 201 # Check if linker has the -no-pie option.
 202 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 203 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 204
 205 AX_LIB_SOCKET_NSL
 206
 207 LT_NO_UNDEFINED=""
 208 AS_CASE([$host_os],
 209   [cygwin*],
 210     [
 211       LT_NO_UNDEFINED="-no-undefined"
 212     ],
 213   [cygwin*|darwin*|mingw*|solaris*],
 214     [
 215       # On platforms where we only support the relayd, disable the other binaries by default
 216       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 217       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 218       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 219       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 220       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 221       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 222     ]
 223 )
 224
 225 AC_SUBST(LT_NO_UNDEFINED)
 226
 227 # Compute minor/major/patchlevel version numbers
 228 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 229 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 230 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 231
 232 AC_SUBST([MAJOR_VERSION], [$major_version])
 233 AC_SUBST([MINOR_VERSION], [$minor_version])
 234 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 235 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 236 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 237 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 238
 239 version_name="O-Beer"
 240 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 241 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 242
 243 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 244 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 245
 246 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 247 AC_ARG_ENABLE(libtool-linkdep-fixup,
 248         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 249                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 250         libtool_fixup=$enableval,
 251         libtool_fixup=yes)
 252
 253 AS_IF([test "x$libtool_fixup" = "xyes"],
 254             [
 255             libtool_m4="$srcdir/m4/libtool.m4"
 256             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 257             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 258             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 259             AS_IF([test $libtool_flag_pattern_count -ne 0],
 260             [
 261                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 262                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 263                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 264                   ],
 265                   [
 266                   AC_MSG_RESULT([none])
 267                   ])
 268             ])
 269
 270 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 271
 272 AC_CHECK_HEADERS([ \
 273         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 274         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 275         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 276         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 277         sys/mount.h sys/param.h sys/time.h elf.h
 278 ])
 279
 280 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 281
 282 # Basic functions check
 283 AC_CHECK_FUNCS([ \
 284         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 285         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 286         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 287         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 288         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 289         sched_getcpu sysconf sync_file_range
 290 ])
 291
 292 # Check for pthread_setname_np and pthread_getname_np
 293 LTTNG_PTHREAD_SETNAME_NP
 294 LTTNG_PTHREAD_GETNAME_NP
 295
 296 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 297 # add -lrt to LIBS
 298 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 299
 300 # Checks for dl.
 301 AC_CHECK_LIB([dl], [dlopen], [
 302         have_libdl=yes
 303         libdl_name=dl
 304         DL_LIBS="-ldl"
 305 ], [
 306         # libdl not found, check for dlopen in libc.
 307         AC_CHECK_LIB([c], [dlopen], [
 308                 have_libc_dl=yes
 309                 libdl_name=c
 310                 DL_LIBS="-lc"
 311         ], [
 312                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 313         ])
 314 ])
 315 AC_SUBST(DL_LIBS)
 316
 317 # Check if libdl has dlmopen support.
 318 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 319 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 320         AC_DEFINE([HAVE_DLMOPEN], [1])
 321         HAVE_DLMOPEN=1
 322 ], [
 323         HAVE_DLMOPEN=0
 324 ])
 325 AC_SUBST(HAVE_DLMOPEN)
 326
 327 # Babeltrace viewer check
 328 AC_ARG_WITH([babeltrace-bin],
 329         AS_HELP_STRING([--with-babeltrace-bin],
 330         [Location of the babeltrace viewer executable (including the filename)]),
 331         [BABELTRACE_BIN="$withval"],
 332         [BABELTRACE_BIN=''])
 333 AC_SUBST([BABELTRACE_BIN])
 334
 335 AC_ARG_WITH([babeltrace2-bin],
 336         AS_HELP_STRING([--with-babeltrace2-bin],
 337         [Location of the babeltrace2 viewer executable (including the filename)]),
 338         [BABELTRACE2_BIN="$withval"],
 339         [BABELTRACE2_BIN=''])
 340 AC_SUBST([BABELTRACE2_BIN])
 341
 342 AC_ARG_WITH([consumerd32-bin],
 343         AS_HELP_STRING([--with-consumerd32-bin],
 344         [Location of the 32-bit consumerd executable (including the filename)]),
 345         [CONSUMERD32_BIN="$withval"],
 346         [CONSUMERD32_BIN=''])
 347 AC_SUBST([CONSUMERD32_BIN])
 348
 349 AC_ARG_WITH([consumerd64-bin],
 350         AS_HELP_STRING([--with-consumerd64-bin],
 351         [Location of the 64-bit consumerd executable (including the filename)]),
 352         [CONSUMERD64_BIN="$withval"],
 353         [CONSUMERD64_BIN=''])
 354 AC_SUBST([CONSUMERD64_BIN])
 355
 356 AC_ARG_WITH([consumerd32-libdir],
 357         AS_HELP_STRING([--with-consumerd32-libdir],
 358         [Directory containing the 32-bit consumerd libraries]),
 359         [CONSUMERD32_LIBDIR="$withval"],
 360         [CONSUMERD32_LIBDIR=''])
 361 AC_SUBST([CONSUMERD32_LIBDIR])
 362
 363 AC_ARG_WITH([consumerd64-libdir],
 364         AS_HELP_STRING([--with-consumerd64-libdir],
 365         [Directory containing the 64-bit consumerd libraries]),
 366         [CONSUMERD64_LIBDIR="$withval"],
 367         [CONSUMERD64_LIBDIR=''])
 368 AC_SUBST([CONSUMERD64_LIBDIR])
 369
 370 AC_ARG_WITH([sessiond-bin],
 371         AS_HELP_STRING([--with-sessiond-bin],
 372         [Location of the sessiond executable (including the filename)]),
 373         [SESSIOND_BIN="$withval"],
 374         [SESSIOND_BIN=''])
 375 AC_SUBST([SESSIOND_BIN])
 376
 377 AC_ARG_WITH([lttng-system-rundir],
 378         AS_HELP_STRING([--with-lttng-system-rundir],
 379         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 380         [LTTNG_SYSTEM_RUNDIR="$withval"],
 381         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 382 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 383
 384 AC_ARG_ENABLE([test-java-agent-jul],
 385         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 386         [test_java_agent_jul=$enableval],
 387         [test_java_agent_jul=no]
 388 )
 389
 390 AC_ARG_ENABLE([test-java-agent-log4j],
 391         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 392         [test_java_agent_log4j=$enableval],
 393         [test_java_agent_log4j=no]
 394 )
 395
 396 AC_ARG_ENABLE([test-java-agent-all],
 397         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 398         [test_java_agent_jul=$enableval
 399          test_java_agent_log4j=$enableval],
 400         [:]
 401 )
 402
 403 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 404 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 405 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 406 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 407 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 408 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 409 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 410 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 411
 412 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 413         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 414         $1="$2"
 415         AC_SUBST([$1])
 416 ])
 417
 418 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 419         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 420         $1="$2"
 421         AC_SUBST([$1])
 422 ])
 423
 424 # Default values
 425 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 426 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 427 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 428 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 429 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 430 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 431 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 432 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 433 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 434 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 435 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 436 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 437 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 438 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 439 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 440 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 441 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 442 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 443 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 444 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 445 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 446 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 447 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 448 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 449 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 450 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 451 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 452 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 453 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 454 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 455 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 456 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 457 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 458 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 459 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 460 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 461 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 462 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 463 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 464 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 465 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 466 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 467 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 468 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 469 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 470 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 471 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 472 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 475
 476 # Command short descriptions
 477 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 478 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 479 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 480 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 481 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 482 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 483 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 484 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 485 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 486 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 487 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 488 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 489 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 490 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 491 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 492 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 493 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 494 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 495 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 496 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 497 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 498 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 499 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 500 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 501 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 502 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 503 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 504 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 505
 506 if test "x$prefix" = "xNONE"; then
 507         prefix=$ac_default_prefix
 508 fi
 509 CONFDIR=`eval echo $sysconfdir`
 510 AC_SUBST(CONFDIR)
 511 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 512
 513 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 514
 515 # Check libpopt
 516 PKG_CHECK_MODULES([POPT], [popt],
 517   [
 518     dnl PKG_CHECK_MODULES defines POPT_LIBS
 519   ],
 520   [
 521     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 522     AC_MSG_WARN([Finding libpopt without pkg-config.])
 523     AC_CHECK_LIB([popt],
 524       [poptGetContext],
 525       [POPT_LIBS="-lpopt"],
 526       [
 527         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 528       ]
 529     )
 530   ]
 531 )
 532 AC_SUBST(POPT_LIBS)
 533
 534 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 535
 536 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 537
 538 # URCU library version needed or newer
 539 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 540 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 541 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 542
 543 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 544 # it can be explicitly disabled with --without-kmod
 545 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 546 AC_ARG_WITH([kmod],
 547   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 548   [],
 549   [with_kmod=check]
 550 )
 551
 552 AS_IF([test "x$with_kmod" != "xno"],
 553   [
 554     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 555       [
 556         AC_DEFINE([HAVE_KMOD], [1])
 557         KMOD_LIBS="-lkmod"
 558       ],
 559       [
 560         if test "x$with_kmod" != xcheck; then
 561           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 562         else
 563           with_kmod=no
 564         fi
 565       ]
 566     )
 567   ]
 568 )
 569 AC_SUBST(KMOD_LIBS)
 570
 571 # Check for liblttng-ust-ctl, fail if it's not found,
 572 # it can be explicitly disabled with --without-lttng-ust
 573 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 574 AC_ARG_WITH([lttng-ust],
 575   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 576   [],
 577   [with_lttng_ust=yes]
 578 )
 579
 580 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 581   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 582
 583   # Check for liblttng-ust
 584   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 585
 586   # Check for liblttng-ust-ctl
 587   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 588
 589   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 590 ])
 591
 592 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 593
 594
 595 # Check for fmemopen
 596 AC_CHECK_LIB([c], [fmemopen],
 597 [
 598         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 599 ]
 600 )
 601
 602 # check for libpfm
 603 AC_CHECK_LIB([pfm], [pfm_initialize],
 604              [
 605               have_libpfm=yes
 606               ])
 607 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 608
 609 # For Python
 610 # SWIG version needed or newer:
 611 swig_version=2.0.0
 612
 613 AC_ARG_ENABLE([python-bindings],
 614               [AS_HELP_STRING([--enable-python-bindings],
 615                               [compile Python bindings])],
 616               [enable_python_binding=$enableval], [enable_python_binding=no])
 617
 618 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 619
 620 if test "x$enable_python_binding" = xyes; then
 621   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 622   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 623   AM_PATH_PYTHON([3.0])
 624
 625   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 626   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 627   AS_IF([test -z "$PYTHON_INCLUDE"], [
 628     AS_IF([test -z "$PYTHON_CONFIG"], [
 629       AC_PATH_PROGS([PYTHON_CONFIG],
 630                     [python$PYTHON_VERSION-config python-config],
 631                     [no],
 632                     [`dirname $PYTHON`])
 633       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 634     ])
 635     AC_MSG_CHECKING([python include flags])
 636     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 637     AC_MSG_RESULT([$PYTHON_INCLUDE])
 638   ])
 639
 640 else
 641     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 642 [if you want Python bindings.])
 643
 644 fi
 645
 646 # Epoll check. If not present, the build will fallback on poll() API
 647 AX_HAVE_EPOLL(
 648         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 649         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 650 )
 651 AX_CONFIG_FEATURE(
 652         [epoll], [This platform supports epoll(7)],
 653         [HAVE_EPOLL], [This platform supports epoll(7).]
 654 )
 655
 656 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 657         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 658         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 659 )
 660 AX_CONFIG_FEATURE(
 661         [dirfd], [Use directory file descriptors],
 662         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 663 )
 664
 665 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 666 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 667
 668 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 669         AX_JAVA_OPTIONS
 670         AX_PROG_JAVAC
 671         AX_PROG_JAVA
 672         AX_PROG_JAR
 673
 674         AX_CHECK_CLASSPATH
 675
 676         # Check for Java UST agent common class first
 677         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 678         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 679                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 680         fi
 681
 682         if test "x$test_java_agent_jul" = "xyes"; then
 683                 # Check for JUL agent class
 684                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 685                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 686                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 687                 fi
 688         fi
 689
 690         if test "x$test_java_agent_log4j" = "xyes"; then
 691                 # Check for Log4j agent class
 692                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 693                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 694                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 695                 fi
 696
 697                 # Check for Log4j class
 698                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 699                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 700                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 701                 fi
 702         fi
 703 fi
 704
 705 # enable building man pages (user's intention)
 706 AC_ARG_ENABLE(
 707         man-pages,
 708         AS_HELP_STRING(
 709                 [--disable-man-pages],
 710                 [Do not build and install man pages (already built in a distributed tarball)]
 711         ),
 712         [man_pages_opt=$enableval],
 713         [man_pages_opt=yes]
 714 )
 715
 716 # check for asciidoc and xmlto if we enabled building the man pages
 717 have_asciidoc_xmlto=no
 718 warn_prebuilt_man_pages=no
 719
 720 AS_IF([test "x$man_pages_opt" = "xyes"], [
 721         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 722         AC_PATH_PROG([XMLTO], [xmlto], [no])
 723
 724         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 725                 AS_IF([test "x$in_git_repo" = "xyes"], [
 726                         # this is an error because we're in the Git repo, which
 727                         # means the man pages are not already generated for us,
 728                         # thus asciidoc/xmlto are required because we were asked
 729                         # to build the man pages
 730                         AC_MSG_ERROR([
 731 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 732 --disable-man-pages to disable building the man pages, in which case
 733 they will not be installed.
 734                         ])
 735                 ], [
 736                         # only warn here: since we're in the tarball, the man
 737                         # pages should already be generated at this point, thus
 738                         # asciidoc/xmlto are not strictly required
 739                         warn_prebuilt_man_pages=yes
 740                 ])
 741         ], [
 742                 have_asciidoc_xmlto=yes
 743         ])
 744 ])
 745
 746 # export man page build condition: build the man pages if the user
 747 # asked for it, and if the tools are available
 748 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 749 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 750
 751 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 752
 753 # embedded --help message
 754 AC_ARG_ENABLE(
 755         [embedded-help],
 756         AS_HELP_STRING(
 757                 [--enable-embedded-help],
 758                 [Embed the --help messages in the executable files]
 759         ),
 760         [embedded_help=$enableval],
 761         [embedded_help=no]
 762 )
 763 AS_IF([test "x$embedded_help" = "xyes"], [
 764         AS_IF([test "x$man_pages_opt" = "xno"], [
 765                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 766         ])
 767         AC_PATH_PROG([man_prog_path], [man], [no])
 768         AS_IF([test "x$man_prog_path" = "xno"], [
 769                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 770         ])
 771         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 772         AC_SUBST([MANPROG], [$man_prog_path])
 773 ])
 774 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 775
 776 # Python agent test
 777 UST_PYTHON_AGENT="lttngust"
 778
 779 AC_ARG_ENABLE(test-python2-agent,
 780         AS_HELP_STRING([--enable-test-python2-agent],
 781                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 782         ),[:],[test_python2_agent_autodetect=yes]
 783 )
 784
 785 AC_ARG_ENABLE(test-python3-agent,
 786         AS_HELP_STRING([--enable-test-python3-agent],
 787                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 788         ),[:],[test_python3_agent_autodetect=yes]
 789 )
 790
 791 AC_ARG_ENABLE(test-python-agent-all,
 792         AS_HELP_STRING([--enable-test-python-agent-all],
 793                 [enable test for all python{2/3} agent.]
 794         ),
 795 )
 796
 797 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 798        unset test_python2_agent_autodetect
 799        unset test_python3_agent_autodetect
 800 ])
 801
 802 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 803        enable_test_python2_agent=yes
 804        enable_test_python3_agent=yes
 805 ])
 806
 807 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 808        enable_test_python2_agent=no
 809        enable_test_python3_agent=no
 810 ])
 811
 812
 813 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 814         AS_IF([test -z "$PYTHON2"], [
 815                         PYTHON2=python2
 816                 ], [
 817                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 818         ])
 819
 820         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 821         AS_IF([test -z "$PYTHON2_BIN"], [
 822                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 823                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 824                 ])
 825         ], [
 826                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 827                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 828                         PYTHON2_AGENT=$PYTHON2_BIN
 829                         AC_MSG_RESULT([yes])
 830                         RUN_PYTHON_AGENT_TEST=yes
 831                 ], [
 832                         AC_MSG_RESULT([no])
 833                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 834                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 835                         ])
 836                 ])
 837
 838         ])
 839
 840 ])
 841
 842 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 843         AS_IF([test -z "$PYTHON3"], [
 844                 PYTHON3=python3
 845         ], [
 846                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 847         ])
 848
 849         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 850         AS_IF([test -z "$PYTHON3_BIN"], [
 851                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 852                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 853                 ])
 854         ], [
 855                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 856                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 857                         PYTHON3_AGENT=$PYTHON3_BIN
 858                         AC_MSG_RESULT([yes])
 859                         RUN_PYTHON_AGENT_TEST=yes
 860                 ], [
 861                         AC_MSG_RESULT([no])
 862                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 863                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 864                         ])
 865                 ])
 866
 867         ])
 868 ])
 869 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 870 AC_SUBST([PYTHON2_AGENT])
 871 AC_SUBST([PYTHON3_AGENT])
 872
 873 AC_ARG_ENABLE([test-sdt-uprobe],
 874   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 875   [test_sdt_uprobe="$enableval"],
 876   [test_sdt_uprobe=autodetect]
 877 )
 878
 879 AS_IF([test "$test_sdt_uprobe" != "no"], [
 880   LTTNG_CHECK_SDT_WORKS
 881   AC_PATH_PROG([DTRACE], [dtrace])
 882 ])
 883
 884 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 885   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 886     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 887   ])
 888   AS_IF([test "x$DTRACE" = "x"], [
 889     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 890   ])
 891 ])
 892
 893 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 894   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 895     AS_IF([test "x$DTRACE" != "x"], [
 896       test_sdt_uprobe=yes
 897     ])
 898   ])
 899 ])
 900
 901 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 902
 903 # Arguments for binaries build exclusion
 904 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 905 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 906               [Disable the build of lttng-consumerd binaries]))
 907 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 908 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 909               [Disable the build of lttng-relayd binaries]))
 910 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 911               [Disable the build of lttng-sessiond binaries]))
 912 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 913               [Disable the build of the extra components]))
 914
 915
 916 build_lib_consumer=no
 917 build_lib_health=no
 918 build_lib_index=no
 919 build_lib_kernel_consumer=no
 920 build_lib_kernel_ctl=no
 921 build_lib_lttng_ctl=no
 922 build_lib_relayd=no
 923 build_lib_sessiond_comm=no
 924 build_lib_testpoint=no
 925 build_lib_ust_consumer=no
 926
 927 # There is an overlap for enabled dependencies, but this makes everything
 928 # simpler. libcommon and libconfig are always compiled so they are not repeated
 929 # here.
 930
 931 # Enable binary dependencies.
 932 AS_IF([test x$enable_bin_lttng != xno],
 933       [
 934        build_lib_lttng_ctl=yes
 935       ]
 936 )
 937
 938 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 939       [
 940        build_lib_consumer=yes
 941        build_lib_sessiond_comm=yes
 942        build_lib_index=yes
 943        build_lib_health=yes
 944        build_lib_testpoint=yes
 945       ]
 946 )
 947
 948 AS_IF([test x$enable_bin_lttng_crash != xno],
 949       # Do nothing since libconfig and libcommon are built by default.
 950       []
 951 )
 952
 953 AS_IF([test x$enable_bin_lttng_relayd != xno],
 954       [
 955        build_lib_sessiond_comm=yes
 956        build_lib_index=yes
 957        build_lib_health=yes
 958        build_lib_testpoint=yes
 959       ]
 960 )
 961 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 962       [
 963        build_lib_lttng_ctl=yes
 964        build_lib_sessiond_comm=yes
 965        build_lib_kernel_ctl=yes
 966        build_lib_relayd=yes
 967        build_lib_testpoint=yes
 968        build_lib_health=yes
 969       ]
 970 )
 971
 972 # Libraries dependencies enabling
 973 AS_IF([test x$build_lib_lttng_ctl = xyes],
 974       [
 975        build_lib_sessiond_comm=yes
 976       ]
 977 )
 978
 979 AS_IF([test x$build_lib_consumer = xyes],
 980       [
 981        build_lib_sessiond_comm=yes
 982        build_lib_kernel_consumer=yes
 983        build_lib_relayd=yes
 984        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 985       ]
 986 )
 987
 988 AS_IF([test x$build_lib_kernel_consumer = xyes],
 989       [
 990        build_lib_kernel_ctl=yes
 991        build_lib_relayd=yes
 992       ]
 993 )
 994
 995 AS_IF([test x$build_lib_relayd = xyes],
 996       [
 997        build_lib_sessiond_comm=yes
 998       ]
 999 )
1000
1001 # Find arch type
1002 AS_CASE([$host_cpu],
1003         [k1om], [ARCHTYPE="x86"],
1004         [i386], [ARCHTYPE="x86"],
1005         [i486], [ARCHTYPE="x86"],
1006         [i586], [ARCHTYPE="x86"],
1007         [i686], [ARCHTYPE="x86"],
1008         [amd64], [ARCHTYPE="x86"],
1009         [x86_64], [ARCHTYPE="x86"],
1010         [powerpc], [ARCHTYPE="ppc"],
1011         [ppc64], [ARCHTYPE="ppc"],
1012         [powerpc64], [ARCHTYPE="ppc"],
1013         [powerpc64le], [ARCHTYPE="ppc"],
1014         [ppc], [ARCHTYPE="ppc"],
1015         [s390], [ARCHTYPE="s390"],
1016         [s390x], [ARCHTYPE="s390"],
1017         [sparc], [ARCHTYPE="sparc64"],
1018         [sparc64], [ARCHTYPE="sparc64"],
1019         [alpha*], [ARCHTYPE="alpha"],
1020         [ia64], [ARCHTYPE="ia64"],
1021         [arm*], [ARCHTYPE="arm"],
1022         [aarch64*], [ARCHTYPE="aarch64"],
1023         [mips*], [ARCHTYPE="mips"],
1024         [nios2*], [ARCHTYPE="nios2"],
1025         [tile*], [ARCHTYPE="tile"],
1026         [hppa*], [ARCHTYPE="hppa"],
1027         [m68k], [ARCHTYPE="m68k"],
1028         [riscv*], [ARCHTYPE="riscv"],
1029         [ARCHTYPE="unknown"]
1030 )
1031
1032 AC_SUBST(ARCHTYPE)
1033
1034 AS_CASE([$host_os],
1035         [linux*], [OSTYPE="linux"],
1036         [freebsd*], [OSTYPE="freebsd"],
1037         [solaris*], [OSTYPE="solaris"],
1038         [cygwin*], [OSTYPE="cygwin"],
1039         [mingw*], [OSTYPE="mingw"],
1040         [OSTYPE="unknown"]
1041 )
1042 AC_SUBST(OSTYPE)
1043 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1044
1045
1046
1047 # Userspace callstack capture is only supported by the Linux kernel on x86.
1048 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1049 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1050         have_modules_userspace_callstack_context=yes
1051         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1052 ])
1053 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1054
1055 # Export binaries build conditions.
1056 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1057 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1058 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1059 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1060 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1061
1062 # Export the tests and extras build conditions.
1063 AS_IF([\
1064 test "x$enable_bin_lttng" != "xno" && \
1065 test "x$enable_bin_lttng_consumerd" != "xno" && \
1066 test "x$enable_bin_lttng_crash" != "xno" && \
1067 test "x$enable_bin_lttng_relayd" != "xno" && \
1068 test "x$enable_bin_lttng_sessiond" != "xno"],
1069 [build_tests=yes],
1070 [build_tests=no]
1071 )
1072
1073 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1074 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1075
1076 # Export libraries build conditions.
1077 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1078 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1079 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1080 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1081 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1082 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1083 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1084 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1085 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1086 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1087
1088 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1089 AC_SUBST(AM_CFLAGS)
1090
1091 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1092 AC_SUBST(AM_CXXFLAGS)
1093
1094 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1095 AM_LDFLAGS=""
1096 AC_SUBST(AM_LDFLAGS)
1097
1098 # The order in which the include folders are searched is important.
1099 # The top_builddir should always be searched first in the event that a build
1100 # time generated file is included. An example of this is the "version.i" file.
1101 # In a scenario where lttng-tools is built from a distribution tarball and in a
1102 # out-of-tree manner, the generated "version.i" has priority on the one from
1103 # the source (distribution tarball) and must be found first.
1104 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1105 AC_SUBST(AM_CPPFLAGS)
1106
1107 lttngincludedir="${includedir}/lttng"
1108 AC_SUBST(lttngincludedir)
1109
1110 lttngactionincludedir="${includedir}/lttng/action"
1111 AC_SUBST(lttngactionincludedir)
1112
1113 lttngconditionincludedir="${includedir}/lttng/condition"
1114 AC_SUBST(lttngconditionincludedir)
1115
1116 lttngnotificationincludedir="${includedir}/lttng/notification"
1117 AC_SUBST(lttngnotificationincludedir)
1118
1119 lttngtriggerincludedir="${includedir}/lttng/trigger"
1120 AC_SUBST(lttngtriggerincludedir)
1121
1122 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1123 AC_SUBST(lttngeventruleincludedir)
1124
1125 lttnglibexecdir="${libdir}/lttng/libexec"
1126 AC_SUBST(lttnglibexecdir)
1127
1128 AC_CONFIG_FILES([
1129         Makefile
1130         doc/Makefile
1131         doc/examples/Makefile
1132         doc/examples/rotation/Makefile
1133         doc/examples/trigger-condition-event-matches/Makefile
1134         doc/man/Makefile
1135         doc/man/asciidoc-attrs.conf
1136         include/Makefile
1137         extras/Makefile
1138         extras/bindings/Makefile
1139         extras/bindings/swig/Makefile
1140         extras/bindings/swig/python/Makefile
1141         extras/core-handler/Makefile
1142         src/Makefile
1143         src/common/Makefile
1144         src/common/argpar/Makefile
1145         src/common/bytecode/Makefile
1146         src/common/kernel-ctl/Makefile
1147         src/common/kernel-consumer/Makefile
1148         src/common/consumer/Makefile
1149         src/common/ust-consumer/Makefile
1150         src/common/hashtable/Makefile
1151         src/common/sessiond-comm/Makefile
1152         src/common/compat/Makefile
1153         src/common/relayd/Makefile
1154         src/common/testpoint/Makefile
1155         src/common/index/Makefile
1156         src/common/health/Makefile
1157         src/common/config/Makefile
1158         src/common/ini-config/Makefile
1159         src/common/string-utils/Makefile
1160         src/common/fd-tracker/Makefile
1161         src/common/filter/Makefile
1162         src/lib/Makefile
1163         src/lib/lttng-ctl/Makefile
1164         src/lib/lttng-ctl/lttng-ctl.pc
1165         src/bin/Makefile
1166         src/bin/lttng-consumerd/Makefile
1167         src/bin/lttng-sessiond/Makefile
1168         src/bin/lttng-relayd/Makefile
1169         src/bin/lttng/Makefile
1170         src/bin/lttng-crash/Makefile
1171         src/vendor/Makefile
1172         src/vendor/msgpack/Makefile
1173         tests/Makefile
1174         tests/destructive/Makefile
1175         tests/regression/Makefile
1176         tests/regression/kernel/Makefile
1177         tests/regression/tools/Makefile
1178         tests/regression/tools/streaming/Makefile
1179         tests/regression/tools/filtering/Makefile
1180         tests/regression/tools/health/Makefile
1181         tests/regression/tools/tracefile-limits/Makefile
1182         tests/regression/tools/snapshots/Makefile
1183         tests/regression/tools/live/Makefile
1184         tests/regression/tools/exclusion/Makefile
1185         tests/regression/tools/save-load/Makefile
1186         tests/regression/tools/save-load/configuration/Makefile
1187         tests/regression/tools/mi/Makefile
1188         tests/regression/tools/wildcard/Makefile
1189         tests/regression/tools/channel/Makefile
1190         tests/regression/tools/crash/Makefile
1191         tests/regression/tools/regen-metadata/Makefile
1192         tests/regression/tools/regen-statedump/Makefile
1193         tests/regression/tools/notification/Makefile
1194         tests/regression/tools/rotation/Makefile
1195         tests/regression/tools/base-path/Makefile
1196         tests/regression/tools/metadata/Makefile
1197         tests/regression/tools/tracker/Makefile
1198         tests/regression/tools/working-directory/Makefile
1199         tests/regression/tools/relayd-grouping/Makefile
1200         tests/regression/tools/clear/Makefile
1201         tests/regression/tools/trigger/Makefile
1202         tests/regression/tools/trigger/rate-policy/Makefile
1203         tests/regression/tools/trigger/start-stop/Makefile
1204         tests/regression/tools/trigger/utils/Makefile
1205         tests/regression/tools/trigger/name/Makefile
1206         tests/regression/tools/trigger/hidden/Makefile
1207         tests/regression/ust/Makefile
1208         tests/regression/ust/nprocesses/Makefile
1209         tests/regression/ust/high-throughput/Makefile
1210         tests/regression/ust/low-throughput/Makefile
1211         tests/regression/ust/before-after/Makefile
1212         tests/regression/ust/buffers-pid/Makefile
1213         tests/regression/ust/periodical-metadata-flush/Makefile
1214         tests/regression/ust/multi-session/Makefile
1215         tests/regression/ust/multi-lib/Makefile
1216         tests/regression/ust/overlap/Makefile
1217         tests/regression/ust/overlap/demo/Makefile
1218         tests/regression/ust/linking/Makefile
1219         tests/regression/ust/daemon/Makefile
1220         tests/regression/ust/exit-fast/Makefile
1221         tests/regression/ust/fork/Makefile
1222         tests/regression/ust/libc-wrapper/Makefile
1223         tests/regression/ust/baddr-statedump/Makefile
1224         tests/regression/ust/ust-dl/Makefile
1225         tests/regression/ust/java-jul/Makefile
1226         tests/regression/ust/java-log4j/Makefile
1227         tests/regression/ust/getcpu-override/Makefile
1228         tests/regression/ust/clock-override/Makefile
1229         tests/regression/ust/type-declarations/Makefile
1230         tests/regression/ust/rotation-destroy-flush/Makefile
1231         tests/regression/ust/blocking/Makefile
1232         tests/regression/ust/namespaces/Makefile
1233         tests/stress/Makefile
1234         tests/unit/Makefile
1235         tests/unit/ini_config/Makefile
1236         tests/perf/Makefile
1237         tests/utils/Makefile
1238         tests/utils/tap/Makefile
1239         tests/utils/testapp/Makefile
1240         tests/utils/testapp/gen-ns-events/Makefile
1241         tests/utils/testapp/gen-kernel-test-events/Makefile
1242         tests/utils/testapp/gen-py-events/Makefile
1243         tests/utils/testapp/gen-ust-events/Makefile
1244         tests/utils/testapp/gen-ust-events-ns/Makefile
1245         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1246         tests/utils/testapp/gen-ust-nevents/Makefile
1247         tests/utils/testapp/gen-ust-nevents-str/Makefile
1248         tests/utils/testapp/gen-syscall-events/Makefile
1249         tests/utils/testapp/gen-ust-tracef/Makefile
1250         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1251         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1252         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1253         tests/utils/xml-utils/Makefile
1254 ])
1255
1256 # Inject variable into python test script.
1257 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1258 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1259 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1260 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1261
1262 AC_OUTPUT
1263
1264 #
1265 # Mini-report on what will be built.
1266 #
1267
1268 PPRINT_INIT
1269 PPRINT_SET_INDENT(1)
1270 PPRINT_SET_TS(38)
1271
1272 AS_ECHO
1273 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1274 AS_ECHO
1275
1276 AS_IF([test -n "$report_fold"], [
1277         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1278 ], [
1279         AS_ECHO("$version_description")
1280 ])
1281
1282 AS_ECHO
1283 PPRINT_SUBTITLE([Features])
1284
1285 # Target architecture we're building for.
1286 target_arch=$host_cpu
1287 [
1288 for f in $CFLAGS; do
1289         if test $f = "-m32"; then
1290                         target_arch="32-bit"
1291         elif test $f = "-m64"; then
1292                         target_arch="64-bit"
1293         fi
1294 done
1295 ]
1296 PPRINT_PROP_STRING([Target architecture], $target_arch)
1297
1298 # kmod enabled/disabled
1299 test "x$with_kmod" != "xno" && value=1 || value=0
1300 PPRINT_PROP_BOOL([libkmod support], $value)
1301
1302 # LTTng-UST enabled/disabled
1303 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1304 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1305
1306 AS_ECHO
1307 PPRINT_SUBTITLE([Binaries])
1308
1309 # List binaries to be built
1310 test x$enable_bin_lttng != xno && value=1 || value=0
1311 PPRINT_PROP_BOOL([lttng], $value)
1312
1313 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1314 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1315
1316 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1317 PPRINT_PROP_BOOL([lttng-crash], $value)
1318
1319 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1320 PPRINT_PROP_BOOL([lttng-relayd], $value)
1321
1322 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1323 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1324
1325 # Extras
1326 test x$enable_extras != xno && value=1 || value=0
1327 AS_ECHO
1328 PPRINT_SET_INDENT(0)
1329 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1330 PPRINT_SET_INDENT(1)
1331
1332 AS_ECHO
1333 PPRINT_SUBTITLE([Tests])
1334
1335 # Print clear message that tests won't be built
1336 AS_IF([test "x$build_tests" = "xno"],[
1337         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1338 ])
1339
1340 # LTTng UST Java agent JUL tests enabled/disabled
1341 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1342 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1343
1344 # LTTng UST Java agent Log4j tests enabled/disabled
1345 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1346 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1347
1348 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1349 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1350
1351 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1352 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1353
1354 # userspace-probe SDT instrumentation tests enabled/disabled
1355 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1356 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1357
1358 #Python binding enabled/disabled
1359 test "x$enable_python_binding" = xyes && value=1 || value=0
1360 AS_ECHO
1361 PPRINT_SET_INDENT(0)
1362 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1363
1364 # man pages build enabled/disabled
1365 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1366
1367 AS_IF([test "x$man_pages_opt" != "xno"], [
1368         AS_IF([test "x$in_git_repo" = "xyes"], [
1369                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1370         ], [
1371                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1372                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1373                 ], [
1374                         PPRINT_PROP_STRING([build_man_pages_msg],
1375                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1376                                 $PPRINT_COLOR_SUBTITLE)
1377                 ])
1378         ])
1379 ], [
1380         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1381 ])
1382
1383 m4_popdef([build_man_pages_msg])
1384
1385 test "x$embedded_help" = xyes && value=1 || value=0
1386 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1387
1388 PPRINT_SET_INDENT(1)
1389
1390 report_bindir="`eval eval echo $bindir`"
1391 report_libdir="`eval eval echo $libdir`"
1392
1393 # Print the bindir and libdir this `make install' will install into.
1394 AS_ECHO
1395 PPRINT_SUBTITLE([Install directories])
1396 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1397 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1398
1399 AS_ECHO
1400 PPRINT_SUBTITLE([Search directories])
1401
1402 # If we build the sessiond, print the paths it will use
1403 AS_IF([test "$SESSIOND_BIN" = ""],[
1404         path="$report_bindir/lttng-sessiond"
1405 ],[
1406         path="$SESSIOND_BIN"
1407 ])
1408 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1409
1410 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1411         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1412 ],[
1413         path="$CONSUMERD32_BIN"
1414 ])
1415 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1416
1417 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1418         path="`eval eval echo $libdir`"
1419 ],[
1420         path="$CONSUMERD32_LIBDIR"
1421 ])
1422 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1423
1424 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1425         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1426 ],[
1427         path="$CONSUMERD64_BIN"
1428 ])
1429 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1430
1431 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1432         path="`eval eval echo $libdir`"
1433 ],[
1434         path="$CONSUMERD64_LIBDIR"
1435 ])
1436 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1437 PPRINT_SET_INDENT(0)
1438
1439 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1440         AS_ECHO
1441         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1442
1443 Note that the man pages are already built in this distribution tarball,
1444 therefore asciidoc and xmlto are only needed if you intend to modify
1445 their sources.
1446
1447 Also note that the installed man pages will contain the project's
1448 default command-line option and environment variable values.
1449
1450 Use --disable-man-pages to completely disable building and installing
1451 the man pages.])
1452 ])