configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 # Checks for C compiler
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  23 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  24 AC_PROG_CXX
  25 RW_PROG_CXX_WORKS
  26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  27
  28 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  29 #
  30 # Pass -Werror as an extra flag during the test: this is needed to make the
  31 # -Wunknown-warning-option diagnostic fatal with clang.
  32 AX_APPEND_COMPILE_FLAGS([ dnl
  33                 -Wall dnl
  34                 dnl We currently get this warning when building with Clang:
  35                 dnl
  36                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  37                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  38                 dnl            ^
  39                 -Wno-incomplete-setjmp-declaration dnl
  40                 -Wdiscarded-qualifiers dnl
  41                 -Wmissing-declarations dnl
  42                 -Wmissing-prototypes dnl
  43                 -Wmissing-parameter-type dnl
  44                 -Wold-style-definition dnl
  45                 -Wstrict-prototypes dnl
  46                 -Wshadow dnl
  47                 -Wno-gnu-folding-constant dnl
  48         ],
  49         [WARN_CFLAGS],
  50         [-Werror])
  51
  52 # When given, add -Werror to WARN_CFLAGS.
  53 AC_ARG_ENABLE([Werror],
  54         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  55 )
  56 AS_IF([test "x$enable_Werror" = "xyes"],
  57         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  58 )
  59
  60 # Checks for programs.
  61 AC_PROG_GREP
  62 AC_PROG_MAKE_SET
  63 AC_PROG_SED
  64 AC_PATH_PROG([report_fold], [fold])
  65 LT_INIT
  66
  67 # Check for objcopy, required by the base address statedump and dynamic linker tests
  68 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  69 AS_IF([test "x$OBJCOPY" = "xno"],
  70         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  71 )
  72 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  73
  74 # check for pgrep
  75 AC_PATH_PROG([PGREP], [pgrep], [no])
  76 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  77
  78 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  79 # is not distributed in tarballs
  80 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  81 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  82
  83 # check for bison
  84 AC_PROG_YACC
  85 BISON=$YACC
  86 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  87
  88 AS_IF([test "x$have_bison" != "xyes"], [
  89   AS_IF([test "x$in_git_repo" = "xyes"], [
  90     AC_MSG_FAILURE([
  91 Bison >= 2.4 is required when building from the Git repository. You can
  92 set the YACC variable to override automatic detection.
  93     ])
  94   ], [
  95     AC_MSG_WARN([
  96 Missing Bison >= 2.4. Note that the parser files are already built in
  97 this distribution tarball, so Bison is only needed if you intend to
  98 modify their sources. You can set the YACC variable to override automatic
  99 detection.
 100     ])
 101   ])
 102 ])
 103 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 104
 105 # check for flex
 106 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 107 # problem since the argument is silently ignored by older versions.
 108 AC_PROG_LEX([noyywrap])
 109 FLEX=$LEX
 110 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 111
 112 AS_IF([test "x$have_flex" != "xyes"], [
 113   AS_IF([test "x$in_git_repo" = "xyes"], [
 114     AC_MSG_FAILURE([
 115 Flex >= 2.5.35 is required when building from the Git repository. You can
 116 set the LEX variable to override automatic detection.
 117     ])
 118   ], [
 119     AC_MSG_WARN([
 120 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 121 this distribution tarball, so Flex is only needed if you intend to
 122 modify their sources. You can set the LEX variable to override automatic
 123 detection.
 124     ])
 125   ])
 126 ])
 127 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 128
 129
 130 # Checks for typedefs, structures, and compiler characteristics.
 131 AC_C_INLINE
 132 AC_TYPE_INT32_T
 133 AC_TYPE_INT64_T
 134 AC_TYPE_MODE_T
 135 AC_TYPE_OFF_T
 136 AC_TYPE_PID_T
 137 AC_TYPE_SIZE_T
 138 AC_TYPE_SSIZE_T
 139 AC_TYPE_UID_T
 140 AC_TYPE_UINT16_T
 141 AC_TYPE_UINT32_T
 142 AC_TYPE_UINT64_T
 143 AC_TYPE_UINT8_T
 144
 145 AX_C___ATTRIBUTE__
 146 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 147         [:],
 148         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 149
 150 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 151
 152 # Check if linker has the -no-pie option.
 153 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 154 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 155
 156 AX_LIB_SOCKET_NSL
 157
 158 LT_NO_UNDEFINED=""
 159 AS_CASE([$host_os],
 160   [cygwin*],
 161     [
 162       LT_NO_UNDEFINED="-no-undefined"
 163     ],
 164   [cygwin*|darwin*|mingw*|solaris*],
 165     [
 166       # On platforms where we only support the relayd, disable the other binaries by default
 167       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 168       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 169       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 170       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 171       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 172       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 173     ]
 174 )
 175
 176 AC_SUBST(LT_NO_UNDEFINED)
 177
 178 # Compute minor/major/patchlevel version numbers
 179 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 180 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 181 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 182
 183 AC_SUBST([MAJOR_VERSION], [$major_version])
 184 AC_SUBST([MINOR_VERSION], [$minor_version])
 185 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 186 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 187 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 188 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 189
 190 version_name="O-Beer"
 191 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 192 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 193
 194 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 195 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 196
 197 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 198 AC_ARG_ENABLE(libtool-linkdep-fixup,
 199         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 200                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 201         libtool_fixup=$enableval,
 202         libtool_fixup=yes)
 203
 204 AS_IF([test "x$libtool_fixup" = "xyes"],
 205             [
 206             libtool_m4="$srcdir/m4/libtool.m4"
 207             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 208             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 209             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 210             AS_IF([test $libtool_flag_pattern_count -ne 0],
 211             [
 212                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 213                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 214                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 215                   ],
 216                   [
 217                   AC_MSG_RESULT([none])
 218                   ])
 219             ])
 220
 221 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 222
 223 AC_CHECK_HEADERS([ \
 224         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 225         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 226         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 227         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 228         sys/mount.h sys/param.h sys/time.h elf.h
 229 ])
 230
 231 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 232
 233 # Basic functions check
 234 AC_CHECK_FUNCS([ \
 235         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 236         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 237         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 238         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 239         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 240         sched_getcpu sysconf sync_file_range
 241 ])
 242
 243 # Check for pthread_setname_np and pthread_getname_np
 244 LTTNG_PTHREAD_SETNAME_NP
 245 LTTNG_PTHREAD_GETNAME_NP
 246
 247 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 248 # add -lrt to LIBS
 249 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 250
 251 # Checks for dl.
 252 AC_CHECK_LIB([dl], [dlopen], [
 253         have_libdl=yes
 254         libdl_name=dl
 255         DL_LIBS="-ldl"
 256 ], [
 257         # libdl not found, check for dlopen in libc.
 258         AC_CHECK_LIB([c], [dlopen], [
 259                 have_libc_dl=yes
 260                 libdl_name=c
 261                 DL_LIBS="-lc"
 262         ], [
 263                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 264         ])
 265 ])
 266 AC_SUBST(DL_LIBS)
 267
 268 # Check if libdl has dlmopen support.
 269 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 270 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 271         AC_DEFINE([HAVE_DLMOPEN], [1])
 272         HAVE_DLMOPEN=1
 273 ], [
 274         HAVE_DLMOPEN=0
 275 ])
 276 AC_SUBST(HAVE_DLMOPEN)
 277
 278 # Babeltrace viewer check
 279 AC_ARG_WITH([babeltrace-bin],
 280         AS_HELP_STRING([--with-babeltrace-bin],
 281         [Location of the babeltrace viewer executable (including the filename)]),
 282         [BABELTRACE_BIN="$withval"],
 283         [BABELTRACE_BIN=''])
 284 AC_SUBST([BABELTRACE_BIN])
 285
 286 AC_ARG_WITH([babeltrace2-bin],
 287         AS_HELP_STRING([--with-babeltrace2-bin],
 288         [Location of the babeltrace2 viewer executable (including the filename)]),
 289         [BABELTRACE2_BIN="$withval"],
 290         [BABELTRACE2_BIN=''])
 291 AC_SUBST([BABELTRACE2_BIN])
 292
 293 AC_ARG_WITH([consumerd32-bin],
 294         AS_HELP_STRING([--with-consumerd32-bin],
 295         [Location of the 32-bit consumerd executable (including the filename)]),
 296         [CONSUMERD32_BIN="$withval"],
 297         [CONSUMERD32_BIN=''])
 298 AC_SUBST([CONSUMERD32_BIN])
 299
 300 AC_ARG_WITH([consumerd64-bin],
 301         AS_HELP_STRING([--with-consumerd64-bin],
 302         [Location of the 64-bit consumerd executable (including the filename)]),
 303         [CONSUMERD64_BIN="$withval"],
 304         [CONSUMERD64_BIN=''])
 305 AC_SUBST([CONSUMERD64_BIN])
 306
 307 AC_ARG_WITH([consumerd32-libdir],
 308         AS_HELP_STRING([--with-consumerd32-libdir],
 309         [Directory containing the 32-bit consumerd libraries]),
 310         [CONSUMERD32_LIBDIR="$withval"],
 311         [CONSUMERD32_LIBDIR=''])
 312 AC_SUBST([CONSUMERD32_LIBDIR])
 313
 314 AC_ARG_WITH([consumerd64-libdir],
 315         AS_HELP_STRING([--with-consumerd64-libdir],
 316         [Directory containing the 64-bit consumerd libraries]),
 317         [CONSUMERD64_LIBDIR="$withval"],
 318         [CONSUMERD64_LIBDIR=''])
 319 AC_SUBST([CONSUMERD64_LIBDIR])
 320
 321 AC_ARG_WITH([sessiond-bin],
 322         AS_HELP_STRING([--with-sessiond-bin],
 323         [Location of the sessiond executable (including the filename)]),
 324         [SESSIOND_BIN="$withval"],
 325         [SESSIOND_BIN=''])
 326 AC_SUBST([SESSIOND_BIN])
 327
 328 AC_ARG_WITH([lttng-system-rundir],
 329         AS_HELP_STRING([--with-lttng-system-rundir],
 330         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 331         [LTTNG_SYSTEM_RUNDIR="$withval"],
 332         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 333 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 334
 335 AC_ARG_ENABLE([test-java-agent-jul],
 336         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 337         [test_java_agent_jul=$enableval],
 338         [test_java_agent_jul=no]
 339 )
 340
 341 AC_ARG_ENABLE([test-java-agent-log4j],
 342         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 343         [test_java_agent_log4j=$enableval],
 344         [test_java_agent_log4j=no]
 345 )
 346
 347 AC_ARG_ENABLE([test-java-agent-all],
 348         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 349         [test_java_agent_jul=$enableval
 350          test_java_agent_log4j=$enableval],
 351         [:]
 352 )
 353
 354 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 357 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 358 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 359 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 360 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 361 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 362
 363 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 364         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 365         $1="$2"
 366         AC_SUBST([$1])
 367 ])
 368
 369 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 370         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 371         $1="$2"
 372         AC_SUBST([$1])
 373 ])
 374
 375 # Default values
 376 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 377 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 378 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 379 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 380 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 381 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 382 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 418 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 419 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 422 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 423 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 424 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 425 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 426
 427 # Command short descriptions
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 454 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 455 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 456
 457 if test "x$prefix" = "xNONE"; then
 458         prefix=$ac_default_prefix
 459 fi
 460 CONFDIR=`eval echo $sysconfdir`
 461 AC_SUBST(CONFDIR)
 462 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 463
 464 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 465
 466 # Check libpopt
 467 PKG_CHECK_MODULES([POPT], [popt],
 468   [
 469     dnl PKG_CHECK_MODULES defines POPT_LIBS
 470   ],
 471   [
 472     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 473     AC_MSG_WARN([Finding libpopt without pkg-config.])
 474     AC_CHECK_LIB([popt],
 475       [poptGetContext],
 476       [POPT_LIBS="-lpopt"],
 477       [
 478         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 479       ]
 480     )
 481   ]
 482 )
 483 AC_SUBST(POPT_LIBS)
 484
 485 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 486
 487 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 488
 489 # URCU library version needed or newer
 490 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 491 PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.11])
 492 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 493 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 494
 495 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 496 # it can be explicitly disabled with --without-kmod
 497 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 498 AC_ARG_WITH([kmod],
 499   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 500   [],
 501   [with_kmod=check]
 502 )
 503
 504 AS_IF([test "x$with_kmod" != "xno"],
 505   [
 506     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 507       [
 508         AC_DEFINE([HAVE_KMOD], [1])
 509         KMOD_LIBS="-lkmod"
 510       ],
 511       [
 512         if test "x$with_kmod" != xcheck; then
 513           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 514         else
 515           with_kmod=no
 516         fi
 517       ]
 518     )
 519   ]
 520 )
 521 AC_SUBST(KMOD_LIBS)
 522
 523 # Check for liblttng-ust-ctl, fail if it's not found,
 524 # it can be explicitly disabled with --without-lttng-ust
 525 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 526 AC_ARG_WITH([lttng-ust],
 527   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 528   [],
 529   [with_lttng_ust=yes]
 530 )
 531
 532 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 533   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 534
 535   # Check for liblttng-ust
 536   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 537
 538   # Check for liblttng-ust-ctl
 539   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 540
 541   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 542 ])
 543
 544 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 545
 546
 547 # Check for fmemopen
 548 AC_CHECK_LIB([c], [fmemopen],
 549 [
 550         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 551 ]
 552 )
 553
 554 # check for libpfm
 555 AC_CHECK_LIB([pfm], [pfm_initialize],
 556              [
 557               have_libpfm=yes
 558               ])
 559 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 560
 561 # For Python
 562 # SWIG version needed or newer:
 563 swig_version=2.0.0
 564
 565 AC_ARG_ENABLE([python-bindings],
 566               [AS_HELP_STRING([--enable-python-bindings],
 567                               [compile Python bindings])],
 568               [enable_python_binding=$enableval], [enable_python_binding=no])
 569
 570 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 571
 572 if test "x$enable_python_binding" = xyes; then
 573   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 574   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 575   AM_PATH_PYTHON([3.0])
 576
 577   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 578   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 579   AS_IF([test -z "$PYTHON_INCLUDE"], [
 580     AS_IF([test -z "$PYTHON_CONFIG"], [
 581       AC_PATH_PROGS([PYTHON_CONFIG],
 582                     [python$PYTHON_VERSION-config python-config],
 583                     [no],
 584                     [`dirname $PYTHON`])
 585       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 586     ])
 587     AC_MSG_CHECKING([python include flags])
 588     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 589     AC_MSG_RESULT([$PYTHON_INCLUDE])
 590   ])
 591
 592 else
 593     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 594 [if you want Python bindings.])
 595
 596 fi
 597
 598 # Epoll check. If not present, the build will fallback on poll() API
 599 AX_HAVE_EPOLL(
 600         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 601         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 602 )
 603 AX_CONFIG_FEATURE(
 604         [epoll], [This platform supports epoll(7)],
 605         [HAVE_EPOLL], [This platform supports epoll(7).]
 606 )
 607
 608 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 609         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 610         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 611 )
 612 AX_CONFIG_FEATURE(
 613         [dirfd], [Use directory file descriptors],
 614         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 615 )
 616
 617 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 618 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 619
 620 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 621         AX_JAVA_OPTIONS
 622         AX_PROG_JAVAC
 623         AX_PROG_JAVA
 624         AX_PROG_JAR
 625
 626         AX_CHECK_CLASSPATH
 627
 628         # Check for Java UST agent common class first
 629         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 630         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 631                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 632         fi
 633
 634         if test "x$test_java_agent_jul" = "xyes"; then
 635                 # Check for JUL agent class
 636                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 637                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 638                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 639                 fi
 640         fi
 641
 642         if test "x$test_java_agent_log4j" = "xyes"; then
 643                 # Check for Log4j agent class
 644                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 645                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 646                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 647                 fi
 648
 649                 # Check for Log4j class
 650                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 651                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 652                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 653                 fi
 654         fi
 655 fi
 656
 657 # enable building man pages (user's intention)
 658 AC_ARG_ENABLE(
 659         man-pages,
 660         AS_HELP_STRING(
 661                 [--disable-man-pages],
 662                 [Do not build and install man pages (already built in a distributed tarball)]
 663         ),
 664         [man_pages_opt=$enableval],
 665         [man_pages_opt=yes]
 666 )
 667
 668 # check for asciidoc and xmlto if we enabled building the man pages
 669 have_asciidoc_xmlto=no
 670 warn_prebuilt_man_pages=no
 671
 672 AS_IF([test "x$man_pages_opt" = "xyes"], [
 673         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 674         AC_PATH_PROG([XMLTO], [xmlto], [no])
 675
 676         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 677                 AS_IF([test "x$in_git_repo" = "xyes"], [
 678                         # this is an error because we're in the Git repo, which
 679                         # means the man pages are not already generated for us,
 680                         # thus asciidoc/xmlto are required because we were asked
 681                         # to build the man pages
 682                         AC_MSG_ERROR([
 683 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 684 --disable-man-pages to disable building the man pages, in which case
 685 they will not be installed.
 686                         ])
 687                 ], [
 688                         # only warn here: since we're in the tarball, the man
 689                         # pages should already be generated at this point, thus
 690                         # asciidoc/xmlto are not strictly required
 691                         warn_prebuilt_man_pages=yes
 692                 ])
 693         ], [
 694                 have_asciidoc_xmlto=yes
 695         ])
 696 ])
 697
 698 # export man page build condition: build the man pages if the user
 699 # asked for it, and if the tools are available
 700 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 701 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 702
 703 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 704
 705 # embedded --help message
 706 AC_ARG_ENABLE(
 707         [embedded-help],
 708         AS_HELP_STRING(
 709                 [--enable-embedded-help],
 710                 [Embed the --help messages in the executable files]
 711         ),
 712         [embedded_help=$enableval],
 713         [embedded_help=no]
 714 )
 715 AS_IF([test "x$embedded_help" = "xyes"], [
 716         AS_IF([test "x$man_pages_opt" = "xno"], [
 717                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 718         ])
 719         AC_PATH_PROG([man_prog_path], [man], [no])
 720         AS_IF([test "x$man_prog_path" = "xno"], [
 721                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 722         ])
 723         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 724         AC_SUBST([MANPROG], [$man_prog_path])
 725 ])
 726 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 727
 728 # Python agent test
 729 UST_PYTHON_AGENT="lttngust"
 730
 731 AC_ARG_ENABLE(test-python2-agent,
 732         AS_HELP_STRING([--enable-test-python2-agent],
 733                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 734         ),[:],[test_python2_agent_autodetect=yes]
 735 )
 736
 737 AC_ARG_ENABLE(test-python3-agent,
 738         AS_HELP_STRING([--enable-test-python3-agent],
 739                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 740         ),[:],[test_python3_agent_autodetect=yes]
 741 )
 742
 743 AC_ARG_ENABLE(test-python-agent-all,
 744         AS_HELP_STRING([--enable-test-python-agent-all],
 745                 [enable test for all python{2/3} agent.]
 746         ),
 747 )
 748
 749 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 750        unset test_python2_agent_autodetect
 751        unset test_python3_agent_autodetect
 752 ])
 753
 754 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 755        enable_test_python2_agent=yes
 756        enable_test_python3_agent=yes
 757 ])
 758
 759 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 760        enable_test_python2_agent=no
 761        enable_test_python3_agent=no
 762 ])
 763
 764
 765 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 766         AS_IF([test -z "$PYTHON2"], [
 767                         PYTHON2=python2
 768                 ], [
 769                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 770         ])
 771
 772         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 773         AS_IF([test -z "$PYTHON2_BIN"], [
 774                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 775                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 776                 ])
 777         ], [
 778                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 779                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 780                         PYTHON2_AGENT=$PYTHON2_BIN
 781                         AC_MSG_RESULT([yes])
 782                         RUN_PYTHON_AGENT_TEST=yes
 783                 ], [
 784                         AC_MSG_RESULT([no])
 785                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 786                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 787                         ])
 788                 ])
 789
 790         ])
 791
 792 ])
 793
 794 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 795         AS_IF([test -z "$PYTHON3"], [
 796                 PYTHON3=python3
 797         ], [
 798                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 799         ])
 800
 801         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 802         AS_IF([test -z "$PYTHON3_BIN"], [
 803                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 804                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 805                 ])
 806         ], [
 807                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 808                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 809                         PYTHON3_AGENT=$PYTHON3_BIN
 810                         AC_MSG_RESULT([yes])
 811                         RUN_PYTHON_AGENT_TEST=yes
 812                 ], [
 813                         AC_MSG_RESULT([no])
 814                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 815                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 816                         ])
 817                 ])
 818
 819         ])
 820 ])
 821 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 822 AC_SUBST([PYTHON2_AGENT])
 823 AC_SUBST([PYTHON3_AGENT])
 824
 825 AC_ARG_ENABLE([test-sdt-uprobe],
 826   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 827   [test_sdt_uprobe="$enableval"],
 828   [test_sdt_uprobe=autodetect]
 829 )
 830
 831 AS_IF([test "$test_sdt_uprobe" != "no"], [
 832   LTTNG_CHECK_SDT_WORKS
 833   AC_PATH_PROG([DTRACE], [dtrace])
 834 ])
 835
 836 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 837   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 838     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 839   ])
 840   AS_IF([test "x$DTRACE" = "x"], [
 841     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 842   ])
 843 ])
 844
 845 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 846   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 847     AS_IF([test "x$DTRACE" != "x"], [
 848       test_sdt_uprobe=yes
 849     ])
 850   ])
 851 ])
 852
 853 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 854
 855 # Arguments for binaries build exclusion
 856 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 857 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 858               [Disable the build of lttng-consumerd binaries]))
 859 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 860 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 861               [Disable the build of lttng-relayd binaries]))
 862 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 863               [Disable the build of lttng-sessiond binaries]))
 864 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 865               [Disable the build of the extra components]))
 866
 867
 868 build_lib_consumer=no
 869 build_lib_health=no
 870 build_lib_index=no
 871 build_lib_kernel_consumer=no
 872 build_lib_kernel_ctl=no
 873 build_lib_lttng_ctl=no
 874 build_lib_relayd=no
 875 build_lib_sessiond_comm=no
 876 build_lib_testpoint=no
 877 build_lib_ust_consumer=no
 878
 879 # There is an overlap for enabled dependencies, but this makes everything
 880 # simpler. libcommon and libconfig are always compiled so they are not repeated
 881 # here.
 882
 883 # Enable binary dependencies.
 884 AS_IF([test x$enable_bin_lttng != xno],
 885       [
 886        build_lib_lttng_ctl=yes
 887       ]
 888 )
 889
 890 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 891       [
 892        build_lib_consumer=yes
 893        build_lib_sessiond_comm=yes
 894        build_lib_index=yes
 895        build_lib_health=yes
 896        build_lib_testpoint=yes
 897       ]
 898 )
 899
 900 AS_IF([test x$enable_bin_lttng_crash != xno],
 901       # Do nothing since libconfig and libcommon are built by default.
 902       []
 903 )
 904
 905 AS_IF([test x$enable_bin_lttng_relayd != xno],
 906       [
 907        build_lib_lttng_ctl=yes
 908        build_lib_sessiond_comm=yes
 909        build_lib_index=yes
 910        build_lib_health=yes
 911        build_lib_testpoint=yes
 912       ]
 913 )
 914 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 915       [
 916        build_lib_lttng_ctl=yes
 917        build_lib_sessiond_comm=yes
 918        build_lib_kernel_ctl=yes
 919        build_lib_relayd=yes
 920        build_lib_testpoint=yes
 921        build_lib_health=yes
 922       ]
 923 )
 924
 925 # Libraries dependencies enabling
 926 AS_IF([test x$build_lib_lttng_ctl = xyes],
 927       [
 928        build_lib_sessiond_comm=yes
 929       ]
 930 )
 931
 932 AS_IF([test x$build_lib_consumer = xyes],
 933       [
 934        build_lib_sessiond_comm=yes
 935        build_lib_kernel_consumer=yes
 936        build_lib_relayd=yes
 937        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 938       ]
 939 )
 940
 941 AS_IF([test x$build_lib_kernel_consumer = xyes],
 942       [
 943        build_lib_kernel_ctl=yes
 944        build_lib_relayd=yes
 945       ]
 946 )
 947
 948 AS_IF([test x$build_lib_relayd = xyes],
 949       [
 950        build_lib_sessiond_comm=yes
 951       ]
 952 )
 953
 954 # Find arch type
 955 AS_CASE([$host_cpu],
 956         [k1om], [ARCHTYPE="x86"],
 957         [i386], [ARCHTYPE="x86"],
 958         [i486], [ARCHTYPE="x86"],
 959         [i586], [ARCHTYPE="x86"],
 960         [i686], [ARCHTYPE="x86"],
 961         [amd64], [ARCHTYPE="x86"],
 962         [x86_64], [ARCHTYPE="x86"],
 963         [powerpc], [ARCHTYPE="ppc"],
 964         [ppc64], [ARCHTYPE="ppc"],
 965         [powerpc64], [ARCHTYPE="ppc"],
 966         [powerpc64le], [ARCHTYPE="ppc"],
 967         [ppc], [ARCHTYPE="ppc"],
 968         [s390], [ARCHTYPE="s390"],
 969         [s390x], [ARCHTYPE="s390"],
 970         [sparc], [ARCHTYPE="sparc64"],
 971         [sparc64], [ARCHTYPE="sparc64"],
 972         [alpha*], [ARCHTYPE="alpha"],
 973         [ia64], [ARCHTYPE="ia64"],
 974         [arm*], [ARCHTYPE="arm"],
 975         [aarch64*], [ARCHTYPE="aarch64"],
 976         [mips*], [ARCHTYPE="mips"],
 977         [nios2*], [ARCHTYPE="nios2"],
 978         [tile*], [ARCHTYPE="tile"],
 979         [hppa*], [ARCHTYPE="hppa"],
 980         [m68k], [ARCHTYPE="m68k"],
 981         [riscv*], [ARCHTYPE="riscv"],
 982         [ARCHTYPE="unknown"]
 983 )
 984
 985 AC_SUBST(ARCHTYPE)
 986
 987 AS_CASE([$host_os],
 988         [linux*], [OSTYPE="linux"],
 989         [freebsd*], [OSTYPE="freebsd"],
 990         [solaris*], [OSTYPE="solaris"],
 991         [cygwin*], [OSTYPE="cygwin"],
 992         [mingw*], [OSTYPE="mingw"],
 993         [OSTYPE="unknown"]
 994 )
 995 AC_SUBST(OSTYPE)
 996 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
 997
 998
 999
1000 # Userspace callstack capture is only supported by the Linux kernel on x86.
1001 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1002 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1003         have_modules_userspace_callstack_context=yes
1004         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1005 ])
1006 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1007
1008 # Export binaries build conditions.
1009 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1010 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1011 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1012 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1013 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1014
1015 # Export the tests and extras build conditions.
1016 AS_IF([\
1017 test "x$enable_bin_lttng" != "xno" && \
1018 test "x$enable_bin_lttng_consumerd" != "xno" && \
1019 test "x$enable_bin_lttng_crash" != "xno" && \
1020 test "x$enable_bin_lttng_relayd" != "xno" && \
1021 test "x$enable_bin_lttng_sessiond" != "xno"],
1022 [build_tests=yes],
1023 [build_tests=no]
1024 )
1025
1026 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1027 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1028
1029 # Export libraries build conditions.
1030 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1031 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1032 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1033 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1034 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1035 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1036 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1039 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1040
1041 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1042 AC_SUBST(AM_CFLAGS)
1043
1044 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1045 AM_LDFLAGS=""
1046 AC_SUBST(AM_LDFLAGS)
1047
1048 # The order in which the include folders are searched is important.
1049 # The top_builddir should always be searched first in the event that a build
1050 # time generated file is included. An example of this is the "version.i" file.
1051 # In a scenario where lttng-tools is built from a distribution tarball and in a
1052 # out-of-tree manner, the generated "version.i" has priority on the one from
1053 # the source (distribution tarball) and must be found first.
1054 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1055 AC_SUBST(AM_CPPFLAGS)
1056
1057 lttngincludedir="${includedir}/lttng"
1058 AC_SUBST(lttngincludedir)
1059
1060 lttngactionincludedir="${includedir}/lttng/action"
1061 AC_SUBST(lttngactionincludedir)
1062
1063 lttngconditionincludedir="${includedir}/lttng/condition"
1064 AC_SUBST(lttngconditionincludedir)
1065
1066 lttngnotificationincludedir="${includedir}/lttng/notification"
1067 AC_SUBST(lttngnotificationincludedir)
1068
1069 lttngtriggerincludedir="${includedir}/lttng/trigger"
1070 AC_SUBST(lttngtriggerincludedir)
1071
1072 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1073 AC_SUBST(lttngeventruleincludedir)
1074
1075 lttnglibexecdir="${libdir}/lttng/libexec"
1076 AC_SUBST(lttnglibexecdir)
1077
1078 AC_CONFIG_FILES([
1079         Makefile
1080         doc/Makefile
1081         doc/examples/Makefile
1082         doc/examples/rotation/Makefile
1083         doc/examples/trigger-condition-event-matches/Makefile
1084         doc/man/Makefile
1085         doc/man/asciidoc-attrs.conf
1086         include/Makefile
1087         extras/Makefile
1088         extras/bindings/Makefile
1089         extras/bindings/swig/Makefile
1090         extras/bindings/swig/python/Makefile
1091         extras/core-handler/Makefile
1092         src/Makefile
1093         src/common/Makefile
1094         src/common/argpar/Makefile
1095         src/common/bytecode/Makefile
1096         src/common/kernel-ctl/Makefile
1097         src/common/kernel-consumer/Makefile
1098         src/common/consumer/Makefile
1099         src/common/ust-consumer/Makefile
1100         src/common/hashtable/Makefile
1101         src/common/sessiond-comm/Makefile
1102         src/common/compat/Makefile
1103         src/common/relayd/Makefile
1104         src/common/testpoint/Makefile
1105         src/common/index/Makefile
1106         src/common/health/Makefile
1107         src/common/config/Makefile
1108         src/common/string-utils/Makefile
1109         src/common/fd-tracker/Makefile
1110         src/common/filter/Makefile
1111         src/lib/Makefile
1112         src/lib/lttng-ctl/Makefile
1113         src/lib/lttng-ctl/lttng-ctl.pc
1114         src/bin/Makefile
1115         src/bin/lttng-consumerd/Makefile
1116         src/bin/lttng-sessiond/Makefile
1117         src/bin/lttng-relayd/Makefile
1118         src/bin/lttng/Makefile
1119         src/bin/lttng-crash/Makefile
1120         src/vendor/Makefile
1121         src/vendor/msgpack/Makefile
1122         tests/Makefile
1123         tests/destructive/Makefile
1124         tests/regression/Makefile
1125         tests/regression/kernel/Makefile
1126         tests/regression/tools/Makefile
1127         tests/regression/tools/streaming/Makefile
1128         tests/regression/tools/filtering/Makefile
1129         tests/regression/tools/health/Makefile
1130         tests/regression/tools/tracefile-limits/Makefile
1131         tests/regression/tools/snapshots/Makefile
1132         tests/regression/tools/live/Makefile
1133         tests/regression/tools/exclusion/Makefile
1134         tests/regression/tools/save-load/Makefile
1135         tests/regression/tools/save-load/configuration/Makefile
1136         tests/regression/tools/mi/Makefile
1137         tests/regression/tools/wildcard/Makefile
1138         tests/regression/tools/channel/Makefile
1139         tests/regression/tools/crash/Makefile
1140         tests/regression/tools/regen-metadata/Makefile
1141         tests/regression/tools/regen-statedump/Makefile
1142         tests/regression/tools/notification/Makefile
1143         tests/regression/tools/rotation/Makefile
1144         tests/regression/tools/base-path/Makefile
1145         tests/regression/tools/metadata/Makefile
1146         tests/regression/tools/tracker/Makefile
1147         tests/regression/tools/working-directory/Makefile
1148         tests/regression/tools/relayd-grouping/Makefile
1149         tests/regression/tools/clear/Makefile
1150         tests/regression/tools/trigger/Makefile
1151         tests/regression/tools/trigger/rate-policy/Makefile
1152         tests/regression/tools/trigger/start-stop/Makefile
1153         tests/regression/tools/trigger/utils/Makefile
1154         tests/regression/tools/trigger/name/Makefile
1155         tests/regression/tools/trigger/hidden/Makefile
1156         tests/regression/ust/Makefile
1157         tests/regression/ust/nprocesses/Makefile
1158         tests/regression/ust/high-throughput/Makefile
1159         tests/regression/ust/low-throughput/Makefile
1160         tests/regression/ust/before-after/Makefile
1161         tests/regression/ust/buffers-pid/Makefile
1162         tests/regression/ust/periodical-metadata-flush/Makefile
1163         tests/regression/ust/multi-session/Makefile
1164         tests/regression/ust/multi-lib/Makefile
1165         tests/regression/ust/overlap/Makefile
1166         tests/regression/ust/overlap/demo/Makefile
1167         tests/regression/ust/linking/Makefile
1168         tests/regression/ust/daemon/Makefile
1169         tests/regression/ust/exit-fast/Makefile
1170         tests/regression/ust/fork/Makefile
1171         tests/regression/ust/libc-wrapper/Makefile
1172         tests/regression/ust/baddr-statedump/Makefile
1173         tests/regression/ust/ust-dl/Makefile
1174         tests/regression/ust/java-jul/Makefile
1175         tests/regression/ust/java-log4j/Makefile
1176         tests/regression/ust/getcpu-override/Makefile
1177         tests/regression/ust/clock-override/Makefile
1178         tests/regression/ust/type-declarations/Makefile
1179         tests/regression/ust/rotation-destroy-flush/Makefile
1180         tests/regression/ust/blocking/Makefile
1181         tests/regression/ust/namespaces/Makefile
1182         tests/stress/Makefile
1183         tests/unit/Makefile
1184         tests/unit/ini_config/Makefile
1185         tests/perf/Makefile
1186         tests/utils/Makefile
1187         tests/utils/tap/Makefile
1188         tests/utils/testapp/Makefile
1189         tests/utils/testapp/gen-ns-events/Makefile
1190         tests/utils/testapp/gen-kernel-test-events/Makefile
1191         tests/utils/testapp/gen-py-events/Makefile
1192         tests/utils/testapp/gen-ust-events/Makefile
1193         tests/utils/testapp/gen-ust-events-ns/Makefile
1194         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1195         tests/utils/testapp/gen-ust-nevents/Makefile
1196         tests/utils/testapp/gen-ust-nevents-str/Makefile
1197         tests/utils/testapp/gen-syscall-events/Makefile
1198         tests/utils/testapp/gen-ust-tracef/Makefile
1199         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1200         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1201         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1202         tests/utils/xml-utils/Makefile
1203 ])
1204
1205 # Inject variable into python test script.
1206 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1207 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1208 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1209 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1210
1211 AC_OUTPUT
1212
1213 #
1214 # Mini-report on what will be built.
1215 #
1216
1217 PPRINT_INIT
1218 PPRINT_SET_INDENT(1)
1219 PPRINT_SET_TS(38)
1220
1221 AS_ECHO
1222 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1223 AS_ECHO
1224
1225 AS_IF([test -n "$report_fold"], [
1226         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1227 ], [
1228         AS_ECHO("$version_description")
1229 ])
1230
1231 AS_ECHO
1232 PPRINT_SUBTITLE([Features])
1233
1234 # Target architecture we're building for.
1235 target_arch=$host_cpu
1236 [
1237 for f in $CFLAGS; do
1238         if test $f = "-m32"; then
1239                         target_arch="32-bit"
1240         elif test $f = "-m64"; then
1241                         target_arch="64-bit"
1242         fi
1243 done
1244 ]
1245 PPRINT_PROP_STRING([Target architecture], $target_arch)
1246
1247 # kmod enabled/disabled
1248 test "x$with_kmod" != "xno" && value=1 || value=0
1249 PPRINT_PROP_BOOL([libkmod support], $value)
1250
1251 # LTTng-UST enabled/disabled
1252 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1253 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1254
1255 AS_ECHO
1256 PPRINT_SUBTITLE([Binaries])
1257
1258 # List binaries to be built
1259 test x$enable_bin_lttng != xno && value=1 || value=0
1260 PPRINT_PROP_BOOL([lttng], $value)
1261
1262 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1263 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1264
1265 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1266 PPRINT_PROP_BOOL([lttng-crash], $value)
1267
1268 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1269 PPRINT_PROP_BOOL([lttng-relayd], $value)
1270
1271 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1272 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1273
1274 # Extras
1275 test x$enable_extras != xno && value=1 || value=0
1276 AS_ECHO
1277 PPRINT_SET_INDENT(0)
1278 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1279 PPRINT_SET_INDENT(1)
1280
1281 AS_ECHO
1282 PPRINT_SUBTITLE([Tests])
1283
1284 # Print clear message that tests won't be built
1285 AS_IF([test "x$build_tests" = "xno"],[
1286         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1287 ])
1288
1289 # LTTng UST Java agent JUL tests enabled/disabled
1290 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1291 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1292
1293 # LTTng UST Java agent Log4j tests enabled/disabled
1294 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1295 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1296
1297 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1298 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1299
1300 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1301 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1302
1303 # LTTng UST Java agent Log4j tests enabled/disabled
1304 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1305 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1306
1307 #Python binding enabled/disabled
1308 test "x$enable_python_binding" = xyes && value=1 || value=0
1309 AS_ECHO
1310 PPRINT_SET_INDENT(0)
1311 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1312
1313 # man pages build enabled/disabled
1314 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1315
1316 AS_IF([test "x$man_pages_opt" != "xno"], [
1317         AS_IF([test "x$in_git_repo" = "xyes"], [
1318                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1319         ], [
1320                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1321                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1322                 ], [
1323                         PPRINT_PROP_STRING([build_man_pages_msg],
1324                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1325                                 $PPRINT_COLOR_SUBTITLE)
1326                 ])
1327         ])
1328 ], [
1329         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1330 ])
1331
1332 m4_popdef([build_man_pages_msg])
1333
1334 test "x$embedded_help" = xyes && value=1 || value=0
1335 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1336
1337 PPRINT_SET_INDENT(1)
1338
1339 report_bindir="`eval eval echo $bindir`"
1340 report_libdir="`eval eval echo $libdir`"
1341
1342 # Print the bindir and libdir this `make install' will install into.
1343 AS_ECHO
1344 PPRINT_SUBTITLE([Install directories])
1345 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1346 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1347
1348 AS_ECHO
1349 PPRINT_SUBTITLE([Search directories])
1350
1351 # If we build the sessiond, print the paths it will use
1352 AS_IF([test "$SESSIOND_BIN" = ""],[
1353         path="$report_bindir/lttng-sessiond"
1354 ],[
1355         path="$SESSIOND_BIN"
1356 ])
1357 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1358
1359 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1360         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1361 ],[
1362         path="$CONSUMERD32_BIN"
1363 ])
1364 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1365
1366 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1367         path="`eval eval echo $libdir`"
1368 ],[
1369         path="$CONSUMERD32_LIBDIR"
1370 ])
1371 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1372
1373 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1374         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1375 ],[
1376         path="$CONSUMERD64_BIN"
1377 ])
1378 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1379
1380 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1381         path="`eval eval echo $libdir`"
1382 ],[
1383         path="$CONSUMERD64_LIBDIR"
1384 ])
1385 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1386 PPRINT_SET_INDENT(0)
1387
1388 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1389         AS_ECHO
1390         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1391
1392 Note that the man pages are already built in this distribution tarball,
1393 therefore asciidoc and xmlto are only needed if you intend to modify
1394 their sources.
1395
1396 Also note that the installed man pages will contain the project's
1397 default command-line option and environment variable values.
1398
1399 Use --disable-man-pages to completely disable building and installing
1400 the man pages.])
1401 ])