| | 1 | dnl SPDX-License-Identifier: GPL-2.0-only |
| | 2 | AC_PREREQ([2.64]) |
| | 3 | AC_INIT([lttng-tools],[2.13.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| | 4 | |
| | 5 | AC_CONFIG_HEADERS([include/config.h]) |
| | 6 | AC_CONFIG_AUX_DIR([config]) |
| | 7 | AC_CONFIG_MACRO_DIR([m4]) |
| | 8 | |
| | 9 | AC_CANONICAL_TARGET |
| | 10 | AC_CANONICAL_HOST |
| | 11 | |
| | 12 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc]) |
| | 13 | AM_MAINTAINER_MODE([enable]) |
| | 14 | |
| | 15 | # Enable silent rules if available (Introduced in AM 1.11) |
| | 16 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| | 17 | |
| | 18 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| | 19 | |
| | 20 | # Checks for C compiler |
| | 21 | AC_USE_SYSTEM_EXTENSIONS |
| | 22 | AC_SYS_LARGEFILE |
| | 23 | AC_PROG_CC |
| | 24 | AC_PROG_CC_STDC |
| | 25 | AC_PROG_CXX |
| | 26 | RW_PROG_CXX_WORKS |
| | 27 | AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"]) |
| | 28 | |
| | 29 | # Detect warning flags supported by the compiler, append them to WARN_CFLAGS. |
| | 30 | # |
| | 31 | # Pass -Werror as an extra flag during the test: this is needed to make the |
| | 32 | # -Wunknown-warning-option diagnostic fatal with clang. |
| | 33 | AX_APPEND_COMPILE_FLAGS([ dnl |
| | 34 | -Wall dnl |
| | 35 | dnl We currently get this warning when building with Clang: |
| | 36 | dnl |
| | 37 | dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration] |
| | 38 | dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL; |
| | 39 | dnl ^ |
| | 40 | -Wno-incomplete-setjmp-declaration dnl |
| | 41 | -Wdiscarded-qualifiers dnl |
| | 42 | -Wmissing-declarations dnl |
| | 43 | -Wmissing-prototypes dnl |
| | 44 | -Wmissing-parameter-type dnl |
| | 45 | -Wold-style-definition dnl |
| | 46 | -Wstrict-prototypes dnl |
| | 47 | ], |
| | 48 | [WARN_CFLAGS], |
| | 49 | [-Werror]) |
| | 50 | |
| | 51 | # When given, add -Werror to WARN_CFLAGS. |
| | 52 | AC_ARG_ENABLE([Werror], |
| | 53 | [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])] |
| | 54 | ) |
| | 55 | AS_IF([test "x$enable_Werror" = "xyes"], |
| | 56 | [WARN_CFLAGS="${WARN_CFLAGS} -Werror"] |
| | 57 | ) |
| | 58 | |
| | 59 | # Checks for programs. |
| | 60 | AC_PROG_GREP |
| | 61 | AC_PROG_MAKE_SET |
| | 62 | AC_PROG_SED |
| | 63 | AC_PATH_PROG([report_fold], [fold]) |
| | 64 | LT_INIT |
| | 65 | |
| | 66 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| | 67 | AC_CHECK_TOOL([OBJCOPY], [objcopy], [no]) |
| | 68 | AS_IF([test "x$OBJCOPY" = "xno"], |
| | 69 | [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| | 70 | ) |
| | 71 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| | 72 | |
| | 73 | # check for pgrep |
| | 74 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| | 75 | AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"]) |
| | 76 | |
| | 77 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| | 78 | # is not distributed in tarballs |
| | 79 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| | 80 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| | 81 | |
| | 82 | # check for bison |
| | 83 | AC_PROG_YACC |
| | 84 | BISON=$YACC |
| | 85 | AX_PROG_BISON_VERSION([2.4], [have_bison=yes]) |
| | 86 | |
| | 87 | AS_IF([test "x$have_bison" != "xyes"], [ |
| | 88 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 89 | AC_MSG_FAILURE([ |
| | 90 | Bison >= 2.4 is required when building from the Git repository. You can |
| | 91 | set the YACC variable to override automatic detection. |
| | 92 | ]) |
| | 93 | ], [ |
| | 94 | AC_MSG_WARN([ |
| | 95 | Missing Bison >= 2.4. Note that the parser files are already built in |
| | 96 | this distribution tarball, so Bison is only needed if you intend to |
| | 97 | modify their sources. You can set the YACC variable to override automatic |
| | 98 | detection. |
| | 99 | ]) |
| | 100 | ]) |
| | 101 | ]) |
| | 102 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| | 103 | |
| | 104 | # check for flex |
| | 105 | AC_PROG_LEX |
| | 106 | FLEX=$LEX |
| | 107 | AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes]) |
| | 108 | |
| | 109 | AS_IF([test "x$have_flex" != "xyes"], [ |
| | 110 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 111 | AC_MSG_FAILURE([ |
| | 112 | Flex >= 2.5.35 is required when building from the Git repository. You can |
| | 113 | set the LEX variable to override automatic detection. |
| | 114 | ]) |
| | 115 | ], [ |
| | 116 | AC_MSG_WARN([ |
| | 117 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| | 118 | this distribution tarball, so Flex is only needed if you intend to |
| | 119 | modify their sources. You can set the LEX variable to override automatic |
| | 120 | detection. |
| | 121 | ]) |
| | 122 | ]) |
| | 123 | ]) |
| | 124 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| | 125 | |
| | 126 | |
| | 127 | # Checks for typedefs, structures, and compiler characteristics. |
| | 128 | AC_C_INLINE |
| | 129 | AC_TYPE_INT32_T |
| | 130 | AC_TYPE_INT64_T |
| | 131 | AC_TYPE_MODE_T |
| | 132 | AC_TYPE_OFF_T |
| | 133 | AC_TYPE_PID_T |
| | 134 | AC_TYPE_SIZE_T |
| | 135 | AC_TYPE_SSIZE_T |
| | 136 | AC_TYPE_UID_T |
| | 137 | AC_TYPE_UINT16_T |
| | 138 | AC_TYPE_UINT32_T |
| | 139 | AC_TYPE_UINT64_T |
| | 140 | AC_TYPE_UINT8_T |
| | 141 | |
| | 142 | AX_C___ATTRIBUTE__ |
| | 143 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| | 144 | [:], |
| | 145 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| | 146 | |
| | 147 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| | 148 | |
| | 149 | # Check if linker has the -no-pie option. |
| | 150 | AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes]) |
| | 151 | AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"]) |
| | 152 | |
| | 153 | AX_LIB_SOCKET_NSL |
| | 154 | |
| | 155 | LT_NO_UNDEFINED="" |
| | 156 | AS_CASE([$host_os], |
| | 157 | [cygwin*], |
| | 158 | [ |
| | 159 | LT_NO_UNDEFINED="-no-undefined" |
| | 160 | ], |
| | 161 | [cygwin*|darwin*|mingw*|solaris*], |
| | 162 | [ |
| | 163 | # On platforms where we only support the relayd, disable the other binaries by default |
| | 164 | AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no]) |
| | 165 | AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no]) |
| | 166 | AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no]) |
| | 167 | AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no]) |
| | 168 | AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no]) |
| | 169 | AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no]) |
| | 170 | ] |
| | 171 | ) |
| | 172 | |
| | 173 | AC_SUBST(LT_NO_UNDEFINED) |
| | 174 | |
| | 175 | # Compute minor/major/patchlevel version numbers |
| | 176 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| | 177 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| | 178 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| | 179 | |
| | 180 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| | 181 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| | 182 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| | 183 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| | 184 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| | 185 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| | 186 | |
| | 187 | version_name="N-Beer" |
| | 188 | version_description="An alcoholic drink made from yeast-fermented malt flavored with hops." |
| | 189 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| | 190 | |
| | 191 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| | 192 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| | 193 | |
| | 194 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| | 195 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| | 196 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| | 197 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| | 198 | libtool_fixup=$enableval, |
| | 199 | libtool_fixup=yes) |
| | 200 | |
| | 201 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| | 202 | [ |
| | 203 | libtool_m4="$srcdir/m4/libtool.m4" |
| | 204 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| | 205 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) |
| | 206 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| | 207 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| | 208 | [ |
| | 209 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| | 210 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| | 211 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| | 212 | ], |
| | 213 | [ |
| | 214 | AC_MSG_RESULT([none]) |
| | 215 | ]) |
| | 216 | ]) |
| | 217 | |
| | 218 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| | 219 | |
| | 220 | AC_CHECK_HEADERS([ \ |
| | 221 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| | 222 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| | 223 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| | 224 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| | 225 | sys/mount.h sys/param.h sys/time.h elf.h |
| | 226 | ]) |
| | 227 | |
| | 228 | AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes]) |
| | 229 | |
| | 230 | # Basic functions check |
| | 231 | AC_CHECK_FUNCS([ \ |
| | 232 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| | 233 | gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \ |
| | 234 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| | 235 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| | 236 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| | 237 | sched_getcpu sysconf sync_file_range |
| | 238 | ]) |
| | 239 | |
| | 240 | # Check for pthread_setname_np and pthread_getname_np |
| | 241 | LTTNG_PTHREAD_SETNAME_NP |
| | 242 | LTTNG_PTHREAD_GETNAME_NP |
| | 243 | |
| | 244 | # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so, |
| | 245 | # add -lrt to LIBS |
| | 246 | AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete]) |
| | 247 | |
| | 248 | # Checks for dl. |
| | 249 | AC_CHECK_LIB([dl], [dlopen], [ |
| | 250 | have_libdl=yes |
| | 251 | libdl_name=dl |
| | 252 | DL_LIBS="-ldl" |
| | 253 | ], [ |
| | 254 | # libdl not found, check for dlopen in libc. |
| | 255 | AC_CHECK_LIB([c], [dlopen], [ |
| | 256 | have_libc_dl=yes |
| | 257 | libdl_name=c |
| | 258 | DL_LIBS="-lc" |
| | 259 | ], [ |
| | 260 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| | 261 | ]) |
| | 262 | ]) |
| | 263 | AC_SUBST(DL_LIBS) |
| | 264 | |
| | 265 | # Check if libdl has dlmopen support. |
| | 266 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) |
| | 267 | AC_CHECK_LIB([$libdl_name], [dlmopen], [ |
| | 268 | AC_DEFINE([HAVE_DLMOPEN], [1]) |
| | 269 | HAVE_DLMOPEN=1 |
| | 270 | ], [ |
| | 271 | HAVE_DLMOPEN=0 |
| | 272 | ]) |
| | 273 | AC_SUBST(HAVE_DLMOPEN) |
| | 274 | |
| | 275 | # Babeltrace viewer check |
| | 276 | AC_ARG_WITH([babeltrace-bin], |
| | 277 | AS_HELP_STRING([--with-babeltrace-bin], |
| | 278 | [Location of the babeltrace viewer executable (including the filename)]), |
| | 279 | [BABELTRACE_BIN="$withval"], |
| | 280 | [BABELTRACE_BIN='']) |
| | 281 | AC_SUBST([BABELTRACE_BIN]) |
| | 282 | |
| | 283 | AC_ARG_WITH([babeltrace2-bin], |
| | 284 | AS_HELP_STRING([--with-babeltrace2-bin], |
| | 285 | [Location of the babeltrace2 viewer executable (including the filename)]), |
| | 286 | [BABELTRACE2_BIN="$withval"], |
| | 287 | [BABELTRACE2_BIN='']) |
| | 288 | AC_SUBST([BABELTRACE2_BIN]) |
| | 289 | |
| | 290 | AC_ARG_WITH([consumerd32-bin], |
| | 291 | AS_HELP_STRING([--with-consumerd32-bin], |
| | 292 | [Location of the 32-bit consumerd executable (including the filename)]), |
| | 293 | [CONSUMERD32_BIN="$withval"], |
| | 294 | [CONSUMERD32_BIN='']) |
| | 295 | AC_SUBST([CONSUMERD32_BIN]) |
| | 296 | |
| | 297 | AC_ARG_WITH([consumerd64-bin], |
| | 298 | AS_HELP_STRING([--with-consumerd64-bin], |
| | 299 | [Location of the 64-bit consumerd executable (including the filename)]), |
| | 300 | [CONSUMERD64_BIN="$withval"], |
| | 301 | [CONSUMERD64_BIN='']) |
| | 302 | AC_SUBST([CONSUMERD64_BIN]) |
| | 303 | |
| | 304 | AC_ARG_WITH([consumerd32-libdir], |
| | 305 | AS_HELP_STRING([--with-consumerd32-libdir], |
| | 306 | [Directory containing the 32-bit consumerd libraries]), |
| | 307 | [CONSUMERD32_LIBDIR="$withval"], |
| | 308 | [CONSUMERD32_LIBDIR='']) |
| | 309 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| | 310 | |
| | 311 | AC_ARG_WITH([consumerd64-libdir], |
| | 312 | AS_HELP_STRING([--with-consumerd64-libdir], |
| | 313 | [Directory containing the 64-bit consumerd libraries]), |
| | 314 | [CONSUMERD64_LIBDIR="$withval"], |
| | 315 | [CONSUMERD64_LIBDIR='']) |
| | 316 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| | 317 | |
| | 318 | AC_ARG_WITH([sessiond-bin], |
| | 319 | AS_HELP_STRING([--with-sessiond-bin], |
| | 320 | [Location of the sessiond executable (including the filename)]), |
| | 321 | [SESSIOND_BIN="$withval"], |
| | 322 | [SESSIOND_BIN='']) |
| | 323 | AC_SUBST([SESSIOND_BIN]) |
| | 324 | |
| | 325 | AC_ARG_WITH([lttng-system-rundir], |
| | 326 | AS_HELP_STRING([--with-lttng-system-rundir], |
| | 327 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| | 328 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| | 329 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| | 330 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| | 331 | |
| | 332 | AC_ARG_ENABLE([test-java-agent-jul], |
| | 333 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| | 334 | [test_java_agent_jul=$enableval], |
| | 335 | [test_java_agent_jul=no] |
| | 336 | ) |
| | 337 | |
| | 338 | AC_ARG_ENABLE([test-java-agent-log4j], |
| | 339 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| | 340 | [test_java_agent_log4j=$enableval], |
| | 341 | [test_java_agent_log4j=no] |
| | 342 | ) |
| | 343 | |
| | 344 | AC_ARG_ENABLE([test-java-agent-all], |
| | 345 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| | 346 | [test_java_agent_jul=$enableval |
| | 347 | test_java_agent_log4j=$enableval], |
| | 348 | [:] |
| | 349 | ) |
| | 350 | |
| | 351 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| | 352 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| | 353 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| | 354 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| | 355 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| | 356 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.]) |
| | 357 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| | 358 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| | 359 | |
| | 360 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| | 361 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| | 362 | $1="$2" |
| | 363 | AC_SUBST([$1]) |
| | 364 | ]) |
| | 365 | |
| | 366 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| | 367 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| | 368 | $1="$2" |
| | 369 | AC_SUBST([$1]) |
| | 370 | ]) |
| | 371 | |
| | 372 | # Default values |
| | 373 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384]) |
| | 374 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| | 375 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| | 376 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| | 377 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| | 378 | m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000]) |
| | 379 | m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 380 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345]) |
| | 381 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354]) |
| | 382 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| | 383 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 384 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| | 385 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| | 386 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 387 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| | 388 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 389 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576]) |
| | 390 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 391 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 392 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT]) |
| | 393 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| | 394 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| | 395 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| | 396 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| | 397 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| | 398 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 399 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| | 400 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| | 401 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| | 402 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 403 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| | 404 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 405 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 406 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| | 407 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 408 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 409 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| | 410 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| | 411 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0]) |
| | 412 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| | 413 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288]) |
| | 414 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| | 415 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER]) |
| | 416 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| | 417 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| | 418 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| | 419 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| | 420 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728]) |
| | 421 | _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000]) |
| | 422 | |
| | 423 | # Command short descriptions |
| | 424 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel]) |
| | 425 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session]) |
| | 426 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session]) |
| | 427 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions]) |
| | 428 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels]) |
| | 429 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules]) |
| | 430 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 431 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels]) |
| | 432 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules]) |
| | 433 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 434 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command]) |
| | 435 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events]) |
| | 436 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations]) |
| | 437 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration]) |
| | 438 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk]) |
| | 439 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations]) |
| | 440 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session]) |
| | 441 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session]) |
| | 442 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing]) |
| | 443 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session]) |
| | 444 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing]) |
| | 445 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule]) |
| | 446 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule]) |
| | 447 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources]) |
| | 448 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources]) |
| | 449 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information]) |
| | 450 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer]) |
| | 451 | |
| | 452 | if test "x$prefix" = "xNONE"; then |
| | 453 | prefix=$ac_default_prefix |
| | 454 | fi |
| | 455 | CONFDIR=`eval echo $sysconfdir` |
| | 456 | AC_SUBST(CONFDIR) |
| | 457 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| | 458 | |
| | 459 | AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.]) |
| | 460 | |
| | 461 | # Check libpopt |
| | 462 | PKG_CHECK_MODULES([POPT], [popt], |
| | 463 | [ |
| | 464 | dnl PKG_CHECK_MODULES defines POPT_LIBS |
| | 465 | ], |
| | 466 | [ |
| | 467 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| | 468 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| | 469 | AC_CHECK_LIB([popt], |
| | 470 | [poptGetContext], |
| | 471 | [POPT_LIBS="-lpopt"], |
| | 472 | [ |
| | 473 | AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| | 474 | ] |
| | 475 | ) |
| | 476 | ] |
| | 477 | ) |
| | 478 | AC_SUBST(POPT_LIBS) |
| | 479 | |
| | 480 | PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6]) |
| | 481 | |
| | 482 | AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])]) |
| | 483 | |
| | 484 | # URCU library version needed or newer |
| | 485 | PKG_CHECK_MODULES([URCU], [liburcu >= 0.9]) |
| | 486 | PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.9]) |
| | 487 | PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.9]) |
| | 488 | AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS" |
| | 489 | |
| | 490 | # Check for libkmod, it will be auto-neabled if found but won't fail if it's not, |
| | 491 | # it can be explicitly disabled with --without-kmod |
| | 492 | AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support]) |
| | 493 | AC_ARG_WITH([kmod], |
| | 494 | [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])], |
| | 495 | [], |
| | 496 | [with_kmod=check] |
| | 497 | ) |
| | 498 | |
| | 499 | AS_IF([test "x$with_kmod" != "xno"], |
| | 500 | [ |
| | 501 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| | 502 | [ |
| | 503 | AC_DEFINE([HAVE_KMOD], [1]) |
| | 504 | KMOD_LIBS="-lkmod" |
| | 505 | ], |
| | 506 | [ |
| | 507 | if test "x$with_kmod" != xcheck; then |
| | 508 | AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.]) |
| | 509 | else |
| | 510 | with_kmod=no |
| | 511 | fi |
| | 512 | ] |
| | 513 | ) |
| | 514 | ] |
| | 515 | ) |
| | 516 | AC_SUBST(KMOD_LIBS) |
| | 517 | |
| | 518 | # Check for liblttng-ust-ctl, fail if it's not found, |
| | 519 | # it can be explicitly disabled with --without-lttng-ust |
| | 520 | AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support]) |
| | 521 | AC_ARG_WITH([lttng-ust], |
| | 522 | [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])], |
| | 523 | [], |
| | 524 | [with_lttng_ust=yes] |
| | 525 | ) |
| | 526 | |
| | 527 | AS_IF([test "x$with_lttng_ust" = "xyes"], [ |
| | 528 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1]) |
| | 529 | |
| | 530 | # Check for liblttng-ust |
| | 531 | PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version]) |
| | 532 | |
| | 533 | # Check for liblttng-ust-ctl |
| | 534 | PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version]) |
| | 535 | |
| | 536 | AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS" |
| | 537 | ]) |
| | 538 | |
| | 539 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"]) |
| | 540 | |
| | 541 | |
| | 542 | # Check for fmemopen |
| | 543 | AC_CHECK_LIB([c], [fmemopen], |
| | 544 | [ |
| | 545 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| | 546 | ] |
| | 547 | ) |
| | 548 | |
| | 549 | # check for libpfm |
| | 550 | AC_CHECK_LIB([pfm], [pfm_initialize], |
| | 551 | [ |
| | 552 | have_libpfm=yes |
| | 553 | ]) |
| | 554 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"]) |
| | 555 | |
| | 556 | # For Python |
| | 557 | # SWIG version needed or newer: |
| | 558 | swig_version=2.0.0 |
| | 559 | |
| | 560 | AC_ARG_ENABLE([python-bindings], |
| | 561 | [AC_HELP_STRING([--enable-python-bindings], |
| | 562 | [compile Python bindings])], |
| | 563 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| | 564 | |
| | 565 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| | 566 | |
| | 567 | if test "x$enable_python_binding" = xyes; then |
| | 568 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| | 569 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| | 570 | AM_PATH_PYTHON([3.0]) |
| | 571 | |
| | 572 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| | 573 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| | 574 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| | 575 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| | 576 | AC_PATH_PROGS([PYTHON_CONFIG], |
| | 577 | [python$PYTHON_VERSION-config python-config], |
| | 578 | [no], |
| | 579 | [`dirname $PYTHON`]) |
| | 580 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| | 581 | ]) |
| | 582 | AC_MSG_CHECKING([python include flags]) |
| | 583 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| | 584 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| | 585 | ]) |
| | 586 | |
| | 587 | else |
| | 588 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| | 589 | [if you want Python bindings.]) |
| | 590 | |
| | 591 | fi |
| | 592 | |
| | 593 | # Epoll check. If not present, the build will fallback on poll() API |
| | 594 | AX_HAVE_EPOLL( |
| | 595 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| | 596 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| | 597 | ) |
| | 598 | AX_CONFIG_FEATURE( |
| | 599 | [epoll], [This platform supports epoll(7)], |
| | 600 | [HAVE_EPOLL], [This platform supports epoll(7).] |
| | 601 | ) |
| | 602 | |
| | 603 | AS_IF([test "x$ac_cv_func_dirfd" = "xyes"], |
| | 604 | [AX_CONFIG_FEATURE_ENABLE(dirfd)], |
| | 605 | [AX_CONFIG_FEATURE_DISABLE(dirfd)] |
| | 606 | ) |
| | 607 | AX_CONFIG_FEATURE( |
| | 608 | [dirfd], [Use directory file descriptors], |
| | 609 | [HAVE_DIRFD], [This platform supports directory file descriptors.] |
| | 610 | ) |
| | 611 | |
| | 612 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| | 613 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| | 614 | |
| | 615 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| | 616 | AX_JAVA_OPTIONS |
| | 617 | AX_PROG_JAVAC |
| | 618 | AX_PROG_JAVA |
| | 619 | AX_PROG_JAR |
| | 620 | |
| | 621 | AX_CHECK_CLASSPATH |
| | 622 | |
| | 623 | # Check for Java UST agent common class first |
| | 624 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| | 625 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| | 626 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| | 627 | fi |
| | 628 | |
| | 629 | if test "x$test_java_agent_jul" = "xyes"; then |
| | 630 | # Check for JUL agent class |
| | 631 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| | 632 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| | 633 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| | 634 | fi |
| | 635 | fi |
| | 636 | |
| | 637 | if test "x$test_java_agent_log4j" = "xyes"; then |
| | 638 | # Check for Log4j agent class |
| | 639 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| | 640 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| | 641 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| | 642 | fi |
| | 643 | |
| | 644 | # Check for Log4j class |
| | 645 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| | 646 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| | 647 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| | 648 | fi |
| | 649 | fi |
| | 650 | fi |
| | 651 | |
| | 652 | # enable building man pages (user's intention) |
| | 653 | AC_ARG_ENABLE( |
| | 654 | man-pages, |
| | 655 | AS_HELP_STRING( |
| | 656 | [--disable-man-pages], |
| | 657 | [Do not build and install man pages (already built in a distributed tarball)] |
| | 658 | ), |
| | 659 | [man_pages_opt=$enableval], |
| | 660 | [man_pages_opt=yes] |
| | 661 | ) |
| | 662 | |
| | 663 | # check for asciidoc and xmlto if we enabled building the man pages |
| | 664 | have_asciidoc_xmlto=no |
| | 665 | warn_prebuilt_man_pages=no |
| | 666 | |
| | 667 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| | 668 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| | 669 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| | 670 | |
| | 671 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| | 672 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 673 | # this is an error because we're in the Git repo, which |
| | 674 | # means the man pages are not already generated for us, |
| | 675 | # thus asciidoc/xmlto are required because we were asked |
| | 676 | # to build the man pages |
| | 677 | AC_MSG_ERROR([ |
| | 678 | You need asciidoc and xmlto to build the LTTng-tools man pages. Use |
| | 679 | --disable-man-pages to disable building the man pages, in which case |
| | 680 | they will not be installed. |
| | 681 | ]) |
| | 682 | ], [ |
| | 683 | # only warn here: since we're in the tarball, the man |
| | 684 | # pages should already be generated at this point, thus |
| | 685 | # asciidoc/xmlto are not strictly required |
| | 686 | warn_prebuilt_man_pages=yes |
| | 687 | ]) |
| | 688 | ], [ |
| | 689 | have_asciidoc_xmlto=yes |
| | 690 | ]) |
| | 691 | ]) |
| | 692 | |
| | 693 | # export man page build condition: build the man pages if the user |
| | 694 | # asked for it, and if the tools are available |
| | 695 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| | 696 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| | 697 | |
| | 698 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| | 699 | |
| | 700 | # embedded --help message |
| | 701 | AC_ARG_ENABLE( |
| | 702 | [embedded-help], |
| | 703 | AS_HELP_STRING( |
| | 704 | [--enable-embedded-help], |
| | 705 | [Embed the --help messages in the executable files] |
| | 706 | ), |
| | 707 | [embedded_help=$enableval], |
| | 708 | [embedded_help=no] |
| | 709 | ) |
| | 710 | AS_IF([test "x$embedded_help" = "xyes"], [ |
| | 711 | AS_IF([test "x$man_pages_opt" = "xno"], [ |
| | 712 | AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.]) |
| | 713 | ]) |
| | 714 | AC_PATH_PROG([man_prog_path], [man], [no]) |
| | 715 | AS_IF([test "x$man_prog_path" = "xno"], [ |
| | 716 | AC_MSG_ERROR([You need man with the --enable-embedded-help option.]) |
| | 717 | ]) |
| | 718 | AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.]) |
| | 719 | AC_SUBST([MANPROG], [$man_prog_path]) |
| | 720 | ]) |
| | 721 | AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"]) |
| | 722 | |
| | 723 | # Python agent test |
| | 724 | UST_PYTHON_AGENT="lttngust" |
| | 725 | |
| | 726 | AC_ARG_ENABLE(test-python2-agent, |
| | 727 | AS_HELP_STRING([--enable-test-python2-agent], |
| | 728 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| | 729 | ),[:],[test_python2_agent_autodetect=yes] |
| | 730 | ) |
| | 731 | |
| | 732 | AC_ARG_ENABLE(test-python3-agent, |
| | 733 | AS_HELP_STRING([--enable-test-python3-agent], |
| | 734 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| | 735 | ),[:],[test_python3_agent_autodetect=yes] |
| | 736 | ) |
| | 737 | |
| | 738 | AC_ARG_ENABLE(test-python-agent-all, |
| | 739 | AS_HELP_STRING([--enable-test-python-agent-all], |
| | 740 | [enable test for all python{2/3} agent.] |
| | 741 | ), |
| | 742 | ) |
| | 743 | |
| | 744 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| | 745 | unset test_python2_agent_autodetect |
| | 746 | unset test_python3_agent_autodetect |
| | 747 | ]) |
| | 748 | |
| | 749 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| | 750 | enable_test_python2_agent=yes |
| | 751 | enable_test_python3_agent=yes |
| | 752 | ]) |
| | 753 | |
| | 754 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| | 755 | enable_test_python2_agent=no |
| | 756 | enable_test_python3_agent=no |
| | 757 | ]) |
| | 758 | |
| | 759 | |
| | 760 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| | 761 | AS_IF([test -z "$PYTHON2"], [ |
| | 762 | PYTHON2=python2 |
| | 763 | ], [ |
| | 764 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| | 765 | ]) |
| | 766 | |
| | 767 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| | 768 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| | 769 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 770 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| | 771 | ]) |
| | 772 | ], [ |
| | 773 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| | 774 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 775 | PYTHON2_AGENT=$PYTHON2_BIN |
| | 776 | AC_MSG_RESULT([yes]) |
| | 777 | RUN_PYTHON_AGENT_TEST=yes |
| | 778 | ], [ |
| | 779 | AC_MSG_RESULT([no]) |
| | 780 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| | 781 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 782 | ]) |
| | 783 | ]) |
| | 784 | |
| | 785 | ]) |
| | 786 | |
| | 787 | ]) |
| | 788 | |
| | 789 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| | 790 | AS_IF([test -z "$PYTHON3"], [ |
| | 791 | PYTHON3=python3 |
| | 792 | ], [ |
| | 793 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| | 794 | ]) |
| | 795 | |
| | 796 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| | 797 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| | 798 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 799 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| | 800 | ]) |
| | 801 | ], [ |
| | 802 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| | 803 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| | 804 | PYTHON3_AGENT=$PYTHON3_BIN |
| | 805 | AC_MSG_RESULT([yes]) |
| | 806 | RUN_PYTHON_AGENT_TEST=yes |
| | 807 | ], [ |
| | 808 | AC_MSG_RESULT([no]) |
| | 809 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| | 810 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| | 811 | ]) |
| | 812 | ]) |
| | 813 | |
| | 814 | ]) |
| | 815 | ]) |
| | 816 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| | 817 | AC_SUBST([PYTHON2_AGENT]) |
| | 818 | AC_SUBST([PYTHON3_AGENT]) |
| | 819 | |
| | 820 | AC_ARG_ENABLE([test-sdt-uprobe], |
| | 821 | [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])], |
| | 822 | [test_sdt_uprobe="$enableval"], |
| | 823 | [test_sdt_uprobe=autodetect] |
| | 824 | ) |
| | 825 | |
| | 826 | AS_IF([test "$test_sdt_uprobe" != "no"], [ |
| | 827 | LTTNG_CHECK_SDT_WORKS |
| | 828 | AC_PATH_PROG([DTRACE], [dtrace]) |
| | 829 | ]) |
| | 830 | |
| | 831 | AS_IF([test "$test_sdt_uprobe" = "yes"], [ |
| | 832 | AS_IF([test "$lttng_cv_sdt_works" = "no"], [ |
| | 833 | AC_MSG_ERROR([Cannot find 'sys/sdt.h'.]) |
| | 834 | ]) |
| | 835 | AS_IF([test "x$DTRACE" = "x"], [ |
| | 836 | AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.]) |
| | 837 | ]) |
| | 838 | ]) |
| | 839 | |
| | 840 | AS_IF([test "$test_sdt_uprobe" = "autodetect"], [ |
| | 841 | AS_IF([test "$lttng_cv_sdt_works" = "yes"], [ |
| | 842 | AS_IF([test "x$DTRACE" != "x"], [ |
| | 843 | test_sdt_uprobe=yes |
| | 844 | ]) |
| | 845 | ]) |
| | 846 | ]) |
| | 847 | |
| | 848 | AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"]) |
| | 849 | |
| | 850 | # Arguments for binaries build exclusion |
| | 851 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| | 852 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| | 853 | [Disable the build of lttng-consumerd binaries])) |
| | 854 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| | 855 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| | 856 | [Disable the build of lttng-relayd binaries])) |
| | 857 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| | 858 | [Disable the build of lttng-sessiond binaries])) |
| | 859 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| | 860 | [Disable the build of the extra components])) |
| | 861 | |
| | 862 | |
| | 863 | # Always build libconfig since it a dependency of libcommon |
| | 864 | build_lib_config=yes |
| | 865 | |
| | 866 | build_lib_compat=no |
| | 867 | build_lib_consumer=no |
| | 868 | build_lib_hashtable=no |
| | 869 | build_lib_health=no |
| | 870 | build_lib_index=no |
| | 871 | build_lib_kernel_consumer=no |
| | 872 | build_lib_kernel_ctl=no |
| | 873 | build_lib_lttng_ctl=no |
| | 874 | build_lib_relayd=no |
| | 875 | build_lib_fd_tracker=no |
| | 876 | build_lib_sessiond_comm=no |
| | 877 | build_lib_testpoint=no |
| | 878 | build_lib_ust_consumer=no |
| | 879 | |
| | 880 | # There is an overlap for enabled dependencies, but this makes everything |
| | 881 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| | 882 | # here. |
| | 883 | |
| | 884 | # Enable binary dependencies. |
| | 885 | AS_IF([test x$enable_bin_lttng != xno], |
| | 886 | [ |
| | 887 | build_lib_lttng_ctl=yes |
| | 888 | ] |
| | 889 | ) |
| | 890 | |
| | 891 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| | 892 | [ |
| | 893 | build_lib_consumer=yes |
| | 894 | build_lib_sessiond_comm=yes |
| | 895 | build_lib_index=yes |
| | 896 | build_lib_health=yes |
| | 897 | build_lib_testpoint=yes |
| | 898 | ] |
| | 899 | ) |
| | 900 | |
| | 901 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| | 902 | # Do nothing since libconfig and libcommon are built by default. |
| | 903 | [] |
| | 904 | ) |
| | 905 | |
| | 906 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| | 907 | [ |
| | 908 | build_lib_lttng_ctl=yes |
| | 909 | build_lib_sessiond_comm=yes |
| | 910 | build_lib_hashtable=yes |
| | 911 | build_lib_compat=yes |
| | 912 | build_lib_index=yes |
| | 913 | build_lib_health=yes |
| | 914 | build_lib_testpoint=yes |
| | 915 | build_lib_fd_tracker=yes |
| | 916 | ] |
| | 917 | ) |
| | 918 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| | 919 | [ |
| | 920 | build_lib_lttng_ctl=yes |
| | 921 | build_lib_sessiond_comm=yes |
| | 922 | build_lib_kernel_ctl=yes |
| | 923 | build_lib_hashtable=yes |
| | 924 | build_lib_compat=yes |
| | 925 | build_lib_relayd=yes |
| | 926 | build_lib_testpoint=yes |
| | 927 | build_lib_health=yes |
| | 928 | ] |
| | 929 | ) |
| | 930 | |
| | 931 | # Libraries dependencies enabling |
| | 932 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| | 933 | [ |
| | 934 | build_lib_sessiond_comm=yes |
| | 935 | build_lib_hashtable=yes |
| | 936 | ] |
| | 937 | ) |
| | 938 | |
| | 939 | AS_IF([test x$build_lib_consumer = xyes], |
| | 940 | [ |
| | 941 | build_lib_sessiond_comm=yes |
| | 942 | build_lib_kernel_consumer=yes |
| | 943 | build_lib_hashtable=yes |
| | 944 | build_lib_compat=yes |
| | 945 | build_lib_relayd=yes |
| | 946 | AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes]) |
| | 947 | ] |
| | 948 | ) |
| | 949 | |
| | 950 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| | 951 | [ |
| | 952 | build_lib_kernel_ctl=yes |
| | 953 | build_lib_relayd=yes |
| | 954 | ] |
| | 955 | ) |
| | 956 | |
| | 957 | AS_IF([test x$build_lib_relayd = xyes], |
| | 958 | [ |
| | 959 | build_lib_sessiond_comm=yes |
| | 960 | ] |
| | 961 | ) |
| | 962 | |
| | 963 | # Find arch type |
| | 964 | AS_CASE([$host_cpu], |
| | 965 | [k1om], [ARCHTYPE="x86"], |
| | 966 | [i386], [ARCHTYPE="x86"], |
| | 967 | [i486], [ARCHTYPE="x86"], |
| | 968 | [i586], [ARCHTYPE="x86"], |
| | 969 | [i686], [ARCHTYPE="x86"], |
| | 970 | [amd64], [ARCHTYPE="x86"], |
| | 971 | [x86_64], [ARCHTYPE="x86"], |
| | 972 | [powerpc], [ARCHTYPE="ppc"], |
| | 973 | [ppc64], [ARCHTYPE="ppc"], |
| | 974 | [powerpc64], [ARCHTYPE="ppc"], |
| | 975 | [powerpc64le], [ARCHTYPE="ppc"], |
| | 976 | [ppc], [ARCHTYPE="ppc"], |
| | 977 | [s390], [ARCHTYPE="s390"], |
| | 978 | [s390x], [ARCHTYPE="s390"], |
| | 979 | [sparc], [ARCHTYPE="sparc64"], |
| | 980 | [sparc64], [ARCHTYPE="sparc64"], |
| | 981 | [alpha*], [ARCHTYPE="alpha"], |
| | 982 | [ia64], [ARCHTYPE="ia64"], |
| | 983 | [arm*], [ARCHTYPE="arm"], |
| | 984 | [aarch64*], [ARCHTYPE="aarch64"], |
| | 985 | [mips*], [ARCHTYPE="mips"], |
| | 986 | [nios2*], [ARCHTYPE="nios2"], |
| | 987 | [tile*], [ARCHTYPE="tile"], |
| | 988 | [hppa*], [ARCHTYPE="hppa"], |
| | 989 | [m68k], [ARCHTYPE="m68k"], |
| | 990 | [riscv*], [ARCHTYPE="riscv"], |
| | 991 | [ARCHTYPE="unknown"] |
| | 992 | ) |
| | 993 | |
| | 994 | AC_SUBST(ARCHTYPE) |
| | 995 | |
| | 996 | AS_CASE([$host_os], |
| | 997 | [linux*], [OSTYPE="linux"], |
| | 998 | [freebsd*], [OSTYPE="freebsd"], |
| | 999 | [solaris*], [OSTYPE="solaris"], |
| | 1000 | [cygwin*], [OSTYPE="cygwin"], |
| | 1001 | [mingw*], [OSTYPE="mingw"], |
| | 1002 | [OSTYPE="unknown"] |
| | 1003 | ) |
| | 1004 | AC_SUBST(OSTYPE) |
| | 1005 | AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"]) |
| | 1006 | |
| | 1007 | |
| | 1008 | |
| | 1009 | # Userspace callstack capture is only supported by the Linux kernel on x86. |
| | 1010 | AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support]) |
| | 1011 | AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[ |
| | 1012 | have_modules_userspace_callstack_context=yes |
| | 1013 | AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1]) |
| | 1014 | ]) |
| | 1015 | AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes]) |
| | 1016 | |
| | 1017 | # Export binaries build conditions. |
| | 1018 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| | 1019 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| | 1020 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| | 1021 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| | 1022 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| | 1023 | |
| | 1024 | # Export the tests and extras build conditions. |
| | 1025 | AS_IF([\ |
| | 1026 | test "x$enable_bin_lttng" != "xno" && \ |
| | 1027 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| | 1028 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| | 1029 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| | 1030 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| | 1031 | [build_tests=yes], |
| | 1032 | [build_tests=no] |
| | 1033 | ) |
| | 1034 | |
| | 1035 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| | 1036 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| | 1037 | |
| | 1038 | # Export libraries build conditions. |
| | 1039 | AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes]) |
| | 1040 | AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes]) |
| | 1041 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| | 1042 | AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes]) |
| | 1043 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| | 1044 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| | 1045 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| | 1046 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| | 1047 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| | 1048 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| | 1049 | AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes]) |
| | 1050 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| | 1051 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| | 1052 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| | 1053 | |
| | 1054 | AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS" |
| | 1055 | AC_SUBST(AM_CFLAGS) |
| | 1056 | |
| | 1057 | # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...". |
| | 1058 | AM_LDFLAGS="" |
| | 1059 | AC_SUBST(AM_LDFLAGS) |
| | 1060 | |
| | 1061 | # The order in which the include folders are searched is important. |
| | 1062 | # The top_builddir should always be searched first in the event that a build |
| | 1063 | # time generated file is included. An example of this is the "version.i" file. |
| | 1064 | # In a scenario where lttng-tools is built from a distribution tarball and in a |
| | 1065 | # out-of-tree manner, the generated "version.i" has priority on the one from |
| | 1066 | # the source (distribution tarball) and must be found first. |
| | 1067 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS" |
| | 1068 | AC_SUBST(AM_CPPFLAGS) |
| | 1069 | |
| | 1070 | lttngincludedir="${includedir}/lttng" |
| | 1071 | AC_SUBST(lttngincludedir) |
| | 1072 | |
| | 1073 | lttngactionincludedir="${includedir}/lttng/action" |
| | 1074 | AC_SUBST(lttngactionincludedir) |
| | 1075 | |
| | 1076 | lttngconditionincludedir="${includedir}/lttng/condition" |
| | 1077 | AC_SUBST(lttngconditionincludedir) |
| | 1078 | |
| | 1079 | lttngnotificationincludedir="${includedir}/lttng/notification" |
| | 1080 | AC_SUBST(lttngnotificationincludedir) |
| | 1081 | |
| | 1082 | lttngtriggerincludedir="${includedir}/lttng/trigger" |
| | 1083 | AC_SUBST(lttngtriggerincludedir) |
| | 1084 | |
| | 1085 | lttngeventruleincludedir="${includedir}/lttng/event-rule" |
| | 1086 | AC_SUBST(lttngeventruleincludedir) |
| | 1087 | |
| | 1088 | lttnglibexecdir="${libdir}/lttng/libexec" |
| | 1089 | AC_SUBST(lttnglibexecdir) |
| | 1090 | |
| | 1091 | AC_CONFIG_FILES([ |
| | 1092 | Makefile |
| | 1093 | doc/Makefile |
| | 1094 | doc/man/Makefile |
| | 1095 | doc/man/asciidoc-attrs.conf |
| | 1096 | include/Makefile |
| | 1097 | extras/Makefile |
| | 1098 | extras/bindings/Makefile |
| | 1099 | extras/bindings/swig/Makefile |
| | 1100 | extras/bindings/swig/python/Makefile |
| | 1101 | extras/core-handler/Makefile |
| | 1102 | src/Makefile |
| | 1103 | src/common/Makefile |
| | 1104 | src/common/kernel-ctl/Makefile |
| | 1105 | src/common/kernel-consumer/Makefile |
| | 1106 | src/common/consumer/Makefile |
| | 1107 | src/common/ust-consumer/Makefile |
| | 1108 | src/common/hashtable/Makefile |
| | 1109 | src/common/sessiond-comm/Makefile |
| | 1110 | src/common/compat/Makefile |
| | 1111 | src/common/relayd/Makefile |
| | 1112 | src/common/testpoint/Makefile |
| | 1113 | src/common/index/Makefile |
| | 1114 | src/common/health/Makefile |
| | 1115 | src/common/config/Makefile |
| | 1116 | src/common/string-utils/Makefile |
| | 1117 | src/common/fd-tracker/Makefile |
| | 1118 | src/common/filter/Makefile |
| | 1119 | src/lib/Makefile |
| | 1120 | src/lib/lttng-ctl/Makefile |
| | 1121 | src/lib/lttng-ctl/lttng-ctl.pc |
| | 1122 | src/bin/Makefile |
| | 1123 | src/bin/lttng-consumerd/Makefile |
| | 1124 | src/bin/lttng-sessiond/Makefile |
| | 1125 | src/bin/lttng-relayd/Makefile |
| | 1126 | src/bin/lttng/Makefile |
| | 1127 | src/bin/lttng-crash/Makefile |
| | 1128 | tests/Makefile |
| | 1129 | tests/destructive/Makefile |
| | 1130 | tests/regression/Makefile |
| | 1131 | tests/regression/kernel/Makefile |
| | 1132 | tests/regression/tools/Makefile |
| | 1133 | tests/regression/tools/streaming/Makefile |
| | 1134 | tests/regression/tools/filtering/Makefile |
| | 1135 | tests/regression/tools/health/Makefile |
| | 1136 | tests/regression/tools/tracefile-limits/Makefile |
| | 1137 | tests/regression/tools/snapshots/Makefile |
| | 1138 | tests/regression/tools/live/Makefile |
| | 1139 | tests/regression/tools/exclusion/Makefile |
| | 1140 | tests/regression/tools/save-load/Makefile |
| | 1141 | tests/regression/tools/save-load/configuration/Makefile |
| | 1142 | tests/regression/tools/mi/Makefile |
| | 1143 | tests/regression/tools/wildcard/Makefile |
| | 1144 | tests/regression/tools/crash/Makefile |
| | 1145 | tests/regression/tools/regen-metadata/Makefile |
| | 1146 | tests/regression/tools/regen-statedump/Makefile |
| | 1147 | tests/regression/tools/notification/Makefile |
| | 1148 | tests/regression/tools/rotation/Makefile |
| | 1149 | tests/regression/tools/base-path/Makefile |
| | 1150 | tests/regression/tools/metadata/Makefile |
| | 1151 | tests/regression/tools/tracker/Makefile |
| | 1152 | tests/regression/tools/working-directory/Makefile |
| | 1153 | tests/regression/tools/relayd-grouping/Makefile |
| | 1154 | tests/regression/tools/clear/Makefile |
| | 1155 | tests/regression/ust/Makefile |
| | 1156 | tests/regression/ust/nprocesses/Makefile |
| | 1157 | tests/regression/ust/high-throughput/Makefile |
| | 1158 | tests/regression/ust/low-throughput/Makefile |
| | 1159 | tests/regression/ust/before-after/Makefile |
| | 1160 | tests/regression/ust/buffers-pid/Makefile |
| | 1161 | tests/regression/ust/periodical-metadata-flush/Makefile |
| | 1162 | tests/regression/ust/multi-session/Makefile |
| | 1163 | tests/regression/ust/multi-lib/Makefile |
| | 1164 | tests/regression/ust/overlap/Makefile |
| | 1165 | tests/regression/ust/overlap/demo/Makefile |
| | 1166 | tests/regression/ust/linking/Makefile |
| | 1167 | tests/regression/ust/daemon/Makefile |
| | 1168 | tests/regression/ust/exit-fast/Makefile |
| | 1169 | tests/regression/ust/fork/Makefile |
| | 1170 | tests/regression/ust/libc-wrapper/Makefile |
| | 1171 | tests/regression/ust/baddr-statedump/Makefile |
| | 1172 | tests/regression/ust/ust-dl/Makefile |
| | 1173 | tests/regression/ust/java-jul/Makefile |
| | 1174 | tests/regression/ust/java-log4j/Makefile |
| | 1175 | tests/regression/ust/python-logging/Makefile |
| | 1176 | tests/regression/ust/getcpu-override/Makefile |
| | 1177 | tests/regression/ust/clock-override/Makefile |
| | 1178 | tests/regression/ust/type-declarations/Makefile |
| | 1179 | tests/regression/ust/rotation-destroy-flush/Makefile |
| | 1180 | tests/regression/ust/blocking/Makefile |
| | 1181 | tests/regression/ust/namespaces/Makefile |
| | 1182 | tests/stress/Makefile |
| | 1183 | tests/unit/Makefile |
| | 1184 | tests/unit/ini_config/Makefile |
| | 1185 | tests/perf/Makefile |
| | 1186 | tests/utils/Makefile |
| | 1187 | tests/utils/tap/Makefile |
| | 1188 | tests/utils/testapp/Makefile |
| | 1189 | tests/utils/testapp/gen-ns-events/Makefile |
| | 1190 | tests/utils/testapp/gen-kernel-test-events/Makefile |
| | 1191 | tests/utils/testapp/gen-ust-events/Makefile |
| | 1192 | tests/utils/testapp/gen-ust-events-ns/Makefile |
| | 1193 | tests/utils/testapp/gen-syscall-events-callstack/Makefile |
| | 1194 | tests/utils/testapp/gen-ust-nevents/Makefile |
| | 1195 | tests/utils/testapp/gen-ust-nevents-str/Makefile |
| | 1196 | tests/utils/testapp/gen-syscall-events/Makefile |
| | 1197 | tests/utils/testapp/gen-ust-tracef/Makefile |
| | 1198 | tests/utils/testapp/userspace-probe-elf-binary/Makefile |
| | 1199 | tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile |
| | 1200 | tests/utils/testapp/userspace-probe-sdt-binary/Makefile |
| | 1201 | ]) |
| | 1202 | |
| | 1203 | # Inject variable into python test script. |
| | 1204 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| | 1205 | # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script. |
| | 1206 | AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw]) |
| | 1207 | AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl]) |
| | 1208 | |
| | 1209 | AC_OUTPUT |
| | 1210 | |
| | 1211 | # |
| | 1212 | # Mini-report on what will be built. |
| | 1213 | # |
| | 1214 | |
| | 1215 | PPRINT_INIT |
| | 1216 | PPRINT_SET_INDENT(1) |
| | 1217 | PPRINT_SET_TS(38) |
| | 1218 | |
| | 1219 | AS_ECHO |
| | 1220 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| | 1221 | AS_ECHO |
| | 1222 | |
| | 1223 | AS_IF([test -n "$report_fold"], [ |
| | 1224 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| | 1225 | ], [ |
| | 1226 | AS_ECHO("$version_description") |
| | 1227 | ]) |
| | 1228 | |
| | 1229 | AS_ECHO |
| | 1230 | PPRINT_SUBTITLE([Features]) |
| | 1231 | |
| | 1232 | # Target architecture we're building for. |
| | 1233 | target_arch=$host_cpu |
| | 1234 | [ |
| | 1235 | for f in $CFLAGS; do |
| | 1236 | if test $f = "-m32"; then |
| | 1237 | target_arch="32-bit" |
| | 1238 | elif test $f = "-m64"; then |
| | 1239 | target_arch="64-bit" |
| | 1240 | fi |
| | 1241 | done |
| | 1242 | ] |
| | 1243 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| | 1244 | |
| | 1245 | # kmod enabled/disabled |
| | 1246 | test "x$with_kmod" != "xno" && value=1 || value=0 |
| | 1247 | PPRINT_PROP_BOOL([libkmod support], $value) |
| | 1248 | |
| | 1249 | # LTTng-UST enabled/disabled |
| | 1250 | test "x$with_lttng_ust" = "xyes" && value=1 || value=0 |
| | 1251 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| | 1252 | |
| | 1253 | AS_ECHO |
| | 1254 | PPRINT_SUBTITLE([Binaries]) |
| | 1255 | |
| | 1256 | # List binaries to be built |
| | 1257 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| | 1258 | PPRINT_PROP_BOOL([lttng], $value) |
| | 1259 | |
| | 1260 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| | 1261 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| | 1262 | |
| | 1263 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| | 1264 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| | 1265 | |
| | 1266 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| | 1267 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| | 1268 | |
| | 1269 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| | 1270 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| | 1271 | |
| | 1272 | # Extras |
| | 1273 | test x$enable_extras != xno && value=1 || value=0 |
| | 1274 | AS_ECHO |
| | 1275 | PPRINT_SET_INDENT(0) |
| | 1276 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1277 | PPRINT_SET_INDENT(1) |
| | 1278 | |
| | 1279 | AS_ECHO |
| | 1280 | PPRINT_SUBTITLE([Tests]) |
| | 1281 | |
| | 1282 | # Print clear message that tests won't be built |
| | 1283 | AS_IF([test "x$build_tests" = "xno"],[ |
| | 1284 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| | 1285 | ]) |
| | 1286 | |
| | 1287 | # LTTng UST Java agent JUL tests enabled/disabled |
| | 1288 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| | 1289 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| | 1290 | |
| | 1291 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1292 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| | 1293 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| | 1294 | |
| | 1295 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| | 1296 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| | 1297 | |
| | 1298 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| | 1299 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| | 1300 | |
| | 1301 | # LTTng UST Java agent Log4j tests enabled/disabled |
| | 1302 | test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0 |
| | 1303 | PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value) |
| | 1304 | |
| | 1305 | #Python binding enabled/disabled |
| | 1306 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| | 1307 | AS_ECHO |
| | 1308 | PPRINT_SET_INDENT(0) |
| | 1309 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1310 | |
| | 1311 | # man pages build enabled/disabled |
| | 1312 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| | 1313 | |
| | 1314 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| | 1315 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| | 1316 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1317 | ], [ |
| | 1318 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| | 1319 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| | 1320 | ], [ |
| | 1321 | PPRINT_PROP_STRING([build_man_pages_msg], |
| | 1322 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| | 1323 | $PPRINT_COLOR_SUBTITLE) |
| | 1324 | ]) |
| | 1325 | ]) |
| | 1326 | ], [ |
| | 1327 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| | 1328 | ]) |
| | 1329 | |
| | 1330 | m4_popdef([build_man_pages_msg]) |
| | 1331 | |
| | 1332 | test "x$embedded_help" = xyes && value=1 || value=0 |
| | 1333 | PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE) |
| | 1334 | |
| | 1335 | PPRINT_SET_INDENT(1) |
| | 1336 | |
| | 1337 | report_bindir="`eval eval echo $bindir`" |
| | 1338 | report_libdir="`eval eval echo $libdir`" |
| | 1339 | |
| | 1340 | # Print the bindir and libdir this `make install' will install into. |
| | 1341 | AS_ECHO |
| | 1342 | PPRINT_SUBTITLE([Install directories]) |
| | 1343 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| | 1344 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| | 1345 | |
| | 1346 | AS_ECHO |
| | 1347 | PPRINT_SUBTITLE([Search directories]) |
| | 1348 | |
| | 1349 | # If we build the sessiond, print the paths it will use |
| | 1350 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| | 1351 | path="$report_bindir/lttng-sessiond" |
| | 1352 | ],[ |
| | 1353 | path="$SESSIOND_BIN" |
| | 1354 | ]) |
| | 1355 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| | 1356 | |
| | 1357 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| | 1358 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1359 | ],[ |
| | 1360 | path="$CONSUMERD32_BIN" |
| | 1361 | ]) |
| | 1362 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| | 1363 | |
| | 1364 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| | 1365 | path="`eval eval echo $libdir`" |
| | 1366 | ],[ |
| | 1367 | path="$CONSUMERD32_LIBDIR" |
| | 1368 | ]) |
| | 1369 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| | 1370 | |
| | 1371 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| | 1372 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| | 1373 | ],[ |
| | 1374 | path="$CONSUMERD64_BIN" |
| | 1375 | ]) |
| | 1376 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| | 1377 | |
| | 1378 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| | 1379 | path="`eval eval echo $libdir`" |
| | 1380 | ],[ |
| | 1381 | path="$CONSUMERD64_LIBDIR" |
| | 1382 | ]) |
| | 1383 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |
| | 1384 | PPRINT_SET_INDENT(0) |
| | 1385 | |
| | 1386 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ |
| | 1387 | AS_ECHO |
| | 1388 | PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages. |
| | 1389 | |
| | 1390 | Note that the man pages are already built in this distribution tarball, |
| | 1391 | therefore asciidoc and xmlto are only needed if you intend to modify |
| | 1392 | their sources. |
| | 1393 | |
| | 1394 | Also note that the installed man pages will contain the project's |
| | 1395 | default command-line option and environment variable values. |
| | 1396 | |
| | 1397 | Use --disable-man-pages to completely disable building and installing |
| | 1398 | the man pages.]) |
| | 1399 | ]) |
projects / lttng-tools.git / blame_incremental