scripts/lttng-modules/master.groovy

   1 /**
   2  * Copyright (C) 2016-2020 Michael Jeanson <mjeanson@efficios.com>
   3  *
   4  * This program is free software: you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation, either version 3 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16  */
  17
  18 import hudson.model.*
  19 import hudson.AbortException
  20 import hudson.console.HyperlinkNote
  21 import java.util.concurrent.CancellationException
  22 import org.eclipse.jgit.api.Git
  23 import org.eclipse.jgit.lib.Ref
  24
  25
  26 class InvalidKVersionException extends Exception {
  27   public InvalidKVersionException(String message) {
  28     super(message)
  29   }
  30 }
  31
  32 class EmptyKVersionException extends Exception {
  33   public EmptyKVersionException(String message) {
  34     super(message)
  35   }
  36 }
  37
  38 class VanillaKVersion implements Comparable<VanillaKVersion> {
  39
  40   Integer major = 0
  41   Integer majorB = 0
  42   Integer minor = 0
  43   Integer patch = 0
  44   Integer rc = Integer.MAX_VALUE
  45
  46   VanillaKVersion() {}
  47
  48   VanillaKVersion(version) {
  49     this.parse(version)
  50   }
  51
  52   static VanillaKVersion minKVersion() {
  53     return new VanillaKVersion("v0.0.0")
  54   }
  55
  56   static VanillaKVersion maxKVersion() {
  57     return new VanillaKVersion("v" + Integer.MAX_VALUE + ".0.0")
  58   }
  59
  60   static VanillaKVersion factory(version) {
  61     return new VanillaKVersion(version)
  62   }
  63
  64   def parse(version) {
  65     this.major = 0
  66     this.majorB = 0
  67     this.minor = 0
  68     this.patch = 0
  69     this.rc = Integer.MAX_VALUE
  70
  71     if (!version) {
  72       throw new EmptyKVersionException("Empty kernel version")
  73     }
  74
  75     def match = version =~ /^v(\d+)\.(\d+)(\.(\d+))?(\.(\d+))?(-rc(\d+))?$/
  76     if (!match) {
  77       throw new InvalidKVersionException("Invalid kernel version: ${version}")
  78     }
  79
  80     Integer offset = 0;
  81
  82     // Major
  83     this.major = Integer.parseInt(match.group(1))
  84     if (this.major <= 2) {
  85       offset = 2
  86       this.majorB = Integer.parseInt(match.group(2))
  87     }
  88
  89     // Minor
  90     if (match.group(2 + offset) != null) {
  91       this.minor = Integer.parseInt(match.group(2 + offset))
  92     }
  93
  94     // Patch level
  95     if (match.group(4 + offset) != null) {
  96       this.patch = Integer.parseInt(match.group(4 + offset))
  97     }
  98
  99     // RC
 100     if (match.group(8) != null) {
 101       this.rc = Integer.parseInt(match.group(8))
 102     }
 103   }
 104
 105   // Return true if this version is a release candidate
 106   Boolean isRC() {
 107     return this.rc != Integer.MAX_VALUE
 108   }
 109
 110   // Return true if both version are of the same stable branch
 111   Boolean isSameStable(VanillaKVersion o) {
 112     if (this.major != o.major) {
 113       return false
 114     }
 115     if (this.majorB != o.majorB) {
 116       return false
 117     }
 118     if (this.minor != o.minor) {
 119       return false
 120     }
 121
 122     return true
 123   }
 124
 125   @Override int compareTo(VanillaKVersion o) {
 126     if (this.major != o.major) {
 127       return Integer.compare(this.major, o.major)
 128     }
 129     if (this.majorB != o.majorB) {
 130       return Integer.compare(this.majorB, o.majorB)
 131     }
 132     if (this.minor != o.minor) {
 133       return Integer.compare(this.minor, o.minor)
 134     }
 135     if (this.patch != o.patch) {
 136       return Integer.compare(this.patch, o.patch)
 137     }
 138     if (this.rc != o.rc) {
 139       return Integer.compare(this.rc, o.rc)
 140     }
 141
 142     // Same version
 143     return 0;
 144   }
 145
 146   String toString() {
 147     String vString = "v${this.major}"
 148
 149     if (this.majorB > 0) {
 150       vString = vString.concat(".${this.majorB}")
 151     }
 152
 153     vString = vString.concat(".${this.minor}")
 154
 155     if (this.patch > 0) {
 156       vString = vString.concat(".${this.patch}")
 157     }
 158
 159     if (this.rc > 0 && this.rc < Integer.MAX_VALUE) {
 160       vString = vString.concat("-rc${this.rc}")
 161     }
 162     return vString
 163   }
 164 }
 165
 166 class UbuntuKVersion implements Comparable<UbuntuKVersion> {
 167
 168   Integer major = 0
 169   Integer minor = 0
 170   Integer patch = 0
 171   Integer umajor = 0
 172   Integer uminor = 0
 173   String suffix = ""
 174   String strLTS = ""
 175   Boolean isLTS = false
 176
 177   UbuntuKVersion() {}
 178
 179   UbuntuKVersion(version) {
 180     this.parse(version)
 181   }
 182
 183   static UbuntuKVersion minKVersion() {
 184     return new UbuntuKVersion("Ubuntu-lts-0.0.0-0.0")
 185   }
 186
 187   static UbuntuKVersion maxKVersion() {
 188     return new UbuntuKVersion("Ubuntu-" + Integer.MAX_VALUE + ".0.0-0.0")
 189   }
 190
 191   static UbuntuKVersion factory(version) {
 192     return new UbuntuKVersion(version)
 193   }
 194
 195   def parse(version) {
 196     this.major = 0
 197     this.minor = 0
 198     this.patch = 0
 199     this.umajor = 0
 200     this.uminor = 0
 201     this.suffix = "";
 202     this.isLTS = false
 203
 204     if (!version) {
 205       throw new EmptyKVersionException("Empty kernel version")
 206     }
 207
 208     //'Ubuntu-hwe-5.8-5.8.0-19.20_20.04.3',
 209     //'Ubuntu-lts-4.8.0-27.29_16.04.1',
 210     //'Ubuntu-4.4.0-70.91',
 211     def match = version =~ /^Ubuntu-(lts-|hwe-)??(?:\d+\.\d+-)??(\d+)\.(\d+)\.(\d+)-(\d+)\.(\d+)(.*)??$/
 212     if (!match) {
 213       throw new InvalidKVersionException("Invalid kernel version: ${version}")
 214     }
 215
 216     if (match.group(1) != null) {
 217         this.isLTS = true
 218         this.strLTS = match.group(1)
 219     }
 220
 221     // Major
 222     this.major = Integer.parseInt(match.group(2))
 223
 224     // Minor
 225     this.minor = Integer.parseInt(match.group(3))
 226
 227     // Patch level
 228     this.patch = Integer.parseInt(match.group(4))
 229
 230     // Ubuntu major
 231     this.umajor = Integer.parseInt(match.group(5))
 232
 233     // Ubuntu minor
 234     this.uminor = Integer.parseInt(match.group(6))
 235
 236     if (match.group(7) != null) {
 237       this.suffix = match.group(7)
 238     }
 239   }
 240
 241   // Return true if this version is a release candidate
 242   Boolean isRC() {
 243     return false
 244   }
 245
 246   // Return true if both version are of the same stable branch
 247   Boolean isSameStable(UbuntuKVersion o) {
 248     if (this.isLTS != o.isLTS) {
 249       return false
 250     }
 251     if (this.major != o.major) {
 252       return false
 253     }
 254     if (this.minor != o.minor) {
 255       return false
 256     }
 257     if (this.patch != o.patch) {
 258       return false
 259     }
 260
 261     return true
 262   }
 263
 264   @Override int compareTo(UbuntuKVersion o) {
 265     if (this.major != o.major) {
 266       return Integer.compare(this.major, o.major)
 267     }
 268     if (this.minor != o.minor) {
 269       return Integer.compare(this.minor, o.minor)
 270     }
 271     if (this.patch != o.patch) {
 272       return Integer.compare(this.patch, o.patch)
 273     }
 274     if (this.umajor != o.umajor) {
 275       return Integer.compare(this.umajor, o.umajor)
 276     }
 277     if (this.uminor != o.uminor) {
 278       return Integer.compare(this.uminor, o.uminor)
 279     }
 280     if (this.isLTS != o.isLTS) {
 281       if (o.isLTS) {
 282         return 1
 283       } else {
 284         return -1
 285       }
 286     }
 287
 288     // Same version
 289     return 0;
 290   }
 291
 292   String toString() {
 293     String vString = "Ubuntu-"
 294
 295     if (this.isLTS) {
 296       vString = vString.concat("${this.strLTS}")
 297     }
 298
 299     // The tag pattern changed for HWE kernels >= 5.0
 300     if (this.isLTS && this.major >= 5) {
 301       vString = vString.concat("${this.major}.${this.minor}-${this.major}.${this.minor}.${this.patch}-${this.umajor}.${this.uminor}${this.suffix}")
 302     } else {
 303       vString = vString.concat("${this.major}.${this.minor}.${this.patch}-${this.umajor}.${this.uminor}${this.suffix}")
 304     }
 305
 306     return vString
 307   }
 308 }
 309
 310
 311 // Retrieve parameters of the current build
 312 def mbranch = build.getEnvironment(listener).get('GIT_BRANCH').minus('origin/')
 313 def maxConcurrentBuild = build.buildVariableResolver.resolve('maxConcurrentBuild')
 314 def kgitrepo = build.buildVariableResolver.resolve('kgitrepo')
 315 def kverfloor_raw = build.buildVariableResolver.resolve('kverfloor')
 316 def kverceil_raw = build.buildVariableResolver.resolve('kverceil')
 317 def kverfilter = build.buildVariableResolver.resolve('kverfilter')
 318 def kverrc = build.buildVariableResolver.resolve('kverrc')
 319 def uversion = build.buildVariableResolver.resolve('uversion')
 320 def job = Hudson.instance.getJob(build.buildVariableResolver.resolve('kbuildjob'))
 321 def currentJobName = build.project.getFullDisplayName()
 322 def gitmodpath = build.getEnvironment(listener).get('WORKSPACE') + "/src/lttng-modules"
 323
 324 // Get the out variable
 325 def config = new HashMap()
 326 def bindings = getBinding()
 327 config.putAll(bindings.getVariables())
 328 def out = config['out']
 329
 330
 331 // Get the lttng-modules git url
 332 def gitmodrepo = Git.open(new File(gitmodpath))
 333 def mgitrepo = gitmodrepo.getRepository().getConfig().getString("remote", "origin", "url")
 334
 335 // Get tags from git repository
 336 def refs = Git.lsRemoteRepository().setTags(true).setRemote(kgitrepo).call()
 337
 338 // Get kernel versions to build
 339 def kversions = []
 340 def kversionsRC = []
 341 def matchStrs = []
 342 def blacklist = []
 343 def kversionFactory = ""
 344
 345 if (uversion != null) {
 346   kversionFactory = new UbuntuKVersion()
 347   switch (uversion) {
 348     case 'jammy':
 349       matchStrs = [
 350         ~/^refs\/tags\/(Ubuntu-5\.15\.0-\d{1,3}?\.[\d]+)$/,
 351       ]
 352       break
 353
 354     case 'focal':
 355       matchStrs = [
 356         ~/^refs\/tags\/(Ubuntu-5\.4\.0-\d{1,3}?\.[\d]+)$/,
 357         ~/^refs\/tags\/(Ubuntu-hwe-5\.13-5\.13\.0-.*_20\.04\.\d+)$/,
 358       ]
 359       break
 360
 361     case 'bionic':
 362       matchStrs = [
 363         ~/^refs\/tags\/(Ubuntu-4\.15\.0-\d{1,3}?\.[\d]+)$/,
 364         ~/^refs\/tags\/(Ubuntu-hwe-5\.4-5\.4\.0-.*_18\.04\.\d+)$/,
 365       ]
 366       break
 367
 368     case 'xenial':
 369       matchStrs = [
 370         ~/^refs\/tags\/(Ubuntu-4\.4\.0-\d{1,3}?\.[\d]+)$/,
 371         ~/^refs\/tags\/(Ubuntu-hwe-4\.15\.0-.*_16\.04\.\d+)$/,
 372       ]
 373       break
 374
 375     default:
 376       println "Unsupported Ubuntu version: ${uversion}"
 377       throw new InterruptedException()
 378       break
 379   }
 380 } else {
 381   // Vanilla
 382   kversionFactory = new VanillaKVersion()
 383   matchStrs = [
 384     ~/^refs\/tags\/(v[\d\.]+(-rc(\d+))?)$/,
 385   ]
 386   blacklist = [
 387     'v3.2.3',
 388   ]
 389 }
 390
 391 // Parse kernel versions
 392 def kverfloor = ""
 393 try {
 394     kverfloor = kversionFactory.factory(kverfloor_raw)
 395 } catch (EmptyKVersionException e) {
 396     kverfloor = kversionFactory.minKVersion()
 397 }
 398
 399 def kverceil = ""
 400 try {
 401     kverceil = kversionFactory.factory(kverceil_raw)
 402 } catch (EmptyKVersionException e) {
 403     kverceil = kversionFactory.maxKVersion()
 404 }
 405
 406 // Build a sorted list of versions to build
 407 for (ref in refs) {
 408   for (matchStr in matchStrs) {
 409     def match = ref.getName() =~ matchStr
 410     if (match && !blacklist.contains(match.group(1))) {
 411       def v = kversionFactory.factory(match.group(1))
 412
 413       if ((v >= kverfloor) && (v < kverceil)) {
 414         if (v.isRC()) {
 415           kversionsRC.add(v)
 416         } else {
 417           kversions.add(v)
 418         }
 419       }
 420     }
 421   }
 422 }
 423
 424 // The filtering step assumes the version lists are sorted
 425 kversions.sort()
 426 kversionsRC.sort()
 427
 428 switch (kverfilter) {
 429   case 'stable-head':
 430     // Keep only the head of each stable branch
 431     println('Filter kernel versions to keep only the latest point release of each stable branch.')
 432
 433     for (i = 0; i < kversions.size(); i++) {
 434       def curr = kversions[i]
 435       def next = i < kversions.size() - 1 ? kversions[i + 1] : null
 436
 437       if (next != null) {
 438         if (curr.isSameStable(next)) {
 439           kversions.remove(i)
 440           i--
 441         }
 442       }
 443     }
 444     break
 445
 446   case 'lts':
 447     // Keep only the head of each LTS branch and the latest non-RC tag
 448     println('Filter kernel versions to keep only the latest point release of each lts branch and the current stable.')
 449
 450     def lts_44 = kversionFactory.factory("v4.4")
 451     def lts_49 = kversionFactory.factory("v4.9")
 452     def lts_414 = kversionFactory.factory("v4.14")
 453     def lts_419 = kversionFactory.factory("v4.19")
 454     def lts_54 = kversionFactory.factory("v5.4")
 455
 456     // First filter the head of each branch
 457     for (i = 0; i < kversions.size(); i++) {
 458       def curr = kversions[i]
 459       def next = i < kversions.size() - 1 ? kversions[i + 1] : null
 460
 461       if (next != null) {
 462         if (curr.isSameStable(next)) {
 463           kversions.remove(i)
 464           i--
 465         }
 466       }
 467     }
 468
 469     for (i = 0; i < kversions.size(); i++) {
 470       def curr = kversions[i]
 471
 472       // Keep the newest tag
 473       if (i == kversions.size() - 1) {
 474         break
 475       }
 476
 477       // Prune non-LTS versions
 478       if (!(curr.isSameStable(lts_44) || curr.isSameStable(lts_49) || curr.isSameStable(lts_414) || curr.isSameStable(lts_419) || curr.isSameStable(lts_54))) {
 479         kversions.remove(i)
 480         i--
 481       }
 482     }
 483     break
 484
 485   default:
 486     // No filtering of kernel versions
 487     println('No kernel versions filtering selected.')
 488     break
 489 }
 490
 491 if (kverrc == "true") {
 492   // If the last RC version is newer than the last stable, add it to the build list
 493   if (kversionsRC.size() > 0 && kversionsRC.last() > kversions.last()) {
 494     kversions.add(kversionsRC.last())
 495   }
 496 }
 497
 498 println "Building the following kernel versions:"
 499 for (k in kversions) {
 500   println k
 501 }
 502
 503 // Debug: Stop build here
 504 //throw new InterruptedException()
 505
 506 def joburl = HyperlinkNote.encodeTo('/' + job.url, job.fullDisplayName)
 507
 508 def allBuilds = []
 509 def ongoingBuild = []
 510 def failedRuns = []
 511 def isFailed = false
 512 def similarJobQueued = 0;
 513
 514 // Loop while we have kernel versions remaining or jobs running
 515 while ( kversions.size() != 0 || ongoingBuild.size() != 0 ) {
 516
 517   if(ongoingBuild.size() < maxConcurrentBuild.toInteger() && kversions.size() != 0) {
 518     def kversion = kversions.pop()
 519     def job_params = [
 520       new StringParameterValue('mversion', mbranch),
 521       new StringParameterValue('mgitrepo', mgitrepo),
 522       new StringParameterValue('ktag', kversion.toString()),
 523       new StringParameterValue('kgitrepo', kgitrepo),
 524     ]
 525
 526     // Launch the parametrized build
 527     def param_build = job.scheduleBuild2(0, new Cause.UpstreamCause(build), new ParametersAction(job_params))
 528     println "triggering ${joburl} for the ${mbranch} branch on kernel ${kversion}"
 529
 530     // Add it to the ongoing build queue
 531     ongoingBuild.push(param_build)
 532
 533   } else {
 534
 535     println "Waiting... Queued: " + kversions.size() + " Running: " + ongoingBuild.size()
 536     try {
 537       Thread.sleep(10000)
 538     } catch(e) {
 539       if (e in InterruptedException) {
 540         build.setResult(hudson.model.Result.ABORTED)
 541         throw new InterruptedException()
 542       } else {
 543         throw(e)
 544       }
 545     }
 546
 547     // Abort job if a newer instance is queued
 548     if (!currentJobName.contains("gerrit")) {
 549       similarJobQueued = Hudson.instance.queue.items.count{it.task.getFullDisplayName() == currentJobName}
 550       if (similarJobQueued > 0) {
 551         println "Abort, a newer instance of the job was queued"
 552         build.setResult(hudson.model.Result.ABORTED)
 553         throw new InterruptedException()
 554       }
 555     }
 556
 557     def i = ongoingBuild.iterator()
 558     while ( i.hasNext() ) {
 559       currentBuild = i.next()
 560       if ( currentBuild.isCancelled() || currentBuild.isDone() ) {
 561         // Remove from queue
 562         i.remove()
 563
 564         // Print results
 565         def matrixParent = currentBuild.get()
 566         allBuilds.add(matrixParent)
 567         def kernelStr = matrixParent.buildVariableResolver.resolve("ktag")
 568         println "${matrixParent.fullDisplayName} (${kernelStr}) completed with status ${matrixParent.result}"
 569
 570         // Process child runs of matrixBuild
 571         def childRuns = matrixParent.getRuns()
 572         for ( childRun in childRuns ) {
 573           println "\t${childRun.fullDisplayName} (${kernelStr}) completed with status ${childRun.result}"
 574           if (childRun.result != Result.SUCCESS) {
 575             failedRuns.add(childRun)
 576             isFailed = true
 577           }
 578         }
 579       }
 580     }
 581   }
 582 }
 583
 584 // Get log of failed runs
 585 for (failedRun in failedRuns) {
 586   println "---START---"
 587   failedRun.writeWholeLogTo(out)
 588   println "---END---"
 589 }
 590
 591 println "---Build report---"
 592 for (b in allBuilds) {
 593   def kernelStr = b.buildVariableResolver.resolve("ktag")
 594   println "${b.fullDisplayName} (${kernelStr}) completed with status ${b.result}"
 595   // Cleanup builds
 596   try {
 597     b.delete()
 598   } catch (all) {}
 599 }
 600
 601 // Mark this build failed if any child build has failed
 602 if (isFailed) {
 603   build.setResult(hudson.model.Result.FAILURE)
 604 }
 605
 606 // EOF