configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.7.17],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [powerpc64le], [ARCHTYPE="gcc"],
  73         [ppc], [ARCHTYPE="ppc"],
  74         [s390], [ARCHTYPE="s390"],
  75         [s390x], [ARCHTYPE="s390"],
  76         [sparc], [ARCHTYPE="sparc64"],
  77         [sparc64], [ARCHTYPE="sparc64"],
  78         [alpha*], [ARCHTYPE="alpha"],
  79         [ia64], [ARCHTYPE="gcc"],
  80         [arm*], [ARCHTYPE="arm"],
  81         [aarch64], [ARCHTYPE="gcc"],
  82         [mips*], [ARCHTYPE="mips"],
  83         [ARCHTYPE="unknown"]
  84 )
  85
  86 AC_SUBST(ARCHTYPE)
  87 AC_SUBST(SUBARCHTYPE)
  88
  89 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  90 ARCHSRC=urcu/arch/$ARCHTYPE.h
  91
  92 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  93         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  94 ])
  95
  96 AS_IF([test "$host_cpu" = "armv7l"],[
  97         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  98 ])
  99
 100 # ARM-specific checks
 101 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 102         AC_MSG_CHECKING([for dmb instruction])
 103         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 104                                 int main()
 105                                 {
 106                                         asm volatile("dmb":::"memory");
 107                                         return 0;
 108                                 }
 109                 ]])
 110         ],[
 111                 AC_MSG_RESULT([yes])
 112                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 113         ],[
 114                 AC_MSG_RESULT([no])
 115         ])
 116 ])
 117
 118 # x86-specific checks
 119 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 120         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 121         #For now, using lock; addl compatibility mode even for i686, because the
 122         #Pentium III is seen as a i686, but lacks mfence instruction.
 123         #Only using fence for x86_64.
 124         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 125                 AC_MSG_RESULT([yes])
 126                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 127         ],[
 128                 AC_MSG_RESULT([no])
 129         ])
 130 ])
 131
 132 # Check if sys_futex() is available
 133 AC_MSG_CHECKING([for sys_futex()])
 134 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 135                 #include <sys/syscall.h>
 136                 #ifndef __NR_futex
 137                 #error "futexes not available"
 138                 #endif
 139         ]])
 140 ],[
 141         AC_MSG_RESULT([yes])
 142         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 143         compat_futex_test=0
 144 ],[
 145         AC_MSG_RESULT([no])
 146         compat_futex_test=1
 147 ])
 148
 149 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 150 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 151
 152 # smp-support configure option
 153 AC_ARG_ENABLE([smp-support],
 154         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 155         [def_smp_support=$enableval],
 156         [def_smp_support="yes"])
 157 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 158
 159
 160 # From the sched_setaffinity(2)'s man page:
 161 # ~~~~
 162 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 163 # The library interfaces were introduced in glibc 2.3.  Initially, the
 164 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 165 # the cpuset size argument was removed, but this argument was
 166 # restored in glibc 2.3.4.
 167 # ~~~~
 168
 169 # In addition to that, some vendors ported the system call to 2.4
 170 # kernels.
 171
 172 # Furthermore, when the function first appeared, the MASK argument was
 173 # an unsigned long pointer, while later it was made into a cpu_set_t
 174 # pointer.  Systems that have the cpu_set_t version also should have
 175 # the CPU_ZERO, CPU_SET, etc. macros.
 176
 177 # All this mess means we have to cater for at least 3 different
 178 # sched_setaffinity prototypes:
 179
 180 # ~~~~
 181 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 182 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 183 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 184 # ~~~~
 185
 186 # Since we define _GNU_SOURCE in the sources, must do so too in the
 187 # autoconf tests, as defining _GNU_SOURCE or not exposes
 188 # sched_setaffinity bits differently.
 189 saved_CFLAGS=$CFLAGS
 190 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 191
 192 AC_CHECK_TYPES([cpu_set_t],
 193         [have_cpu_set_t="yes"],
 194         [have_cpu_set_t="no"],
 195         [#include <sched.h>])
 196
 197 # Confirm that we have CPU_ZERO, and it actually works.
 198 AC_MSG_CHECKING([whether CPU_ZERO works])
 199 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 200 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 201                 #define _GNU_SOURCE
 202                 #include <sched.h>
 203                 int main()
 204                 {
 205                         cpu_set_t foo; CPU_ZERO(&foo);
 206                         return 0;
 207                 }
 208         ]])
 209 ],[
 210         AC_DEFINE(HAVE_CPU_ZERO, 1)
 211         AC_MSG_RESULT([yes])
 212 ],[
 213         AC_MSG_RESULT([no])
 214 ])
 215
 216 # Confirm that we have CPU_SET, and it actually works.
 217 AC_MSG_CHECKING([whether CPU_SET works])
 218 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 219 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 220                 #define _GNU_SOURCE
 221                 #include <sched.h>
 222                 int main()
 223                 {
 224                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 225                         return 0;
 226                 }
 227         ]])
 228 ],[
 229         AC_DEFINE(HAVE_CPU_SET, 1)
 230         AC_MSG_RESULT([yes])
 231 ],[
 232         AC_MSG_RESULT([no])
 233 ])
 234
 235 # First check if the function is available at all.
 236 AC_CHECK_FUNCS([sched_setaffinity],[
 237         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 238         # then we have the first version using unsigned long, and no
 239         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 240         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 241         # should also be present, but we confirm nonetheless.
 242
 243         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 244                 # We do have it.
 245                 # Check how many arguments does sched_setaffinity take.
 246                 # Should be 3 or 2.
 247                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 248                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 249                                 #include <sched.h>
 250                                 int main()
 251                                 {
 252                                         cpu_set_t foo;
 253                                         sched_setaffinity(0, sizeof (foo), &foo);
 254                                         return 0;
 255                                 }
 256                         ]])
 257                 ],
 258                 [sched_set_affinity_args=3],
 259                 [sched_set_affinity_args=2])
 260                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 261                         $sched_set_affinity_args,
 262                         [Defined to sched_setaffinity's number of arguments.])
 263                 AC_MSG_RESULT([$sched_set_affinity_args])
 264         ],[
 265                 # No cpu_set_t, always 3 args.
 266                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 267         ])
 268 ])
 269
 270 CFLAGS=$saved_CFLAGS
 271
 272 AC_CONFIG_LINKS([
 273         urcu/arch.h:$ARCHSRC
 274         urcu/uatomic.h:$UATOMICSRC
 275 ])
 276 AC_CONFIG_FILES([
 277         Makefile
 278         doc/Makefile
 279         tests/Makefile
 280         liburcu.pc
 281         liburcu-bp.pc
 282         liburcu-cds.pc
 283         liburcu-qsbr.pc
 284         liburcu-mb.pc
 285         liburcu-signal.pc
 286 ])
 287 AC_OUTPUT
 288
 289 # Report on selected configure options
 290 AS_IF([test "x$def_smp_support" = "xyes"],[
 291         AS_ECHO("SMP support enabled.")
 292 ],[
 293         AS_ECHO("SMP support disabled.")
 294 ])
 295
 296 AS_IF([test "x$def_tls_detect" = "x"],[
 297         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 298 ],[
 299         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 300 ])