configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.6.7],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_CONFIG_SRCDIR([urcu.h])
  19
  20 AC_CONFIG_HEADERS([config.h urcu/config.h])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27
  28 # Checks for programs.
  29 AC_PROG_CC
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32
  33 # Checks for typedefs, structures, and compiler characteristics.
  34 AC_C_INLINE
  35 AC_TYPE_PID_T
  36 AC_TYPE_SIZE_T
  37
  38 # Checks for library functions.
  39 AC_FUNC_MALLOC
  40 AC_FUNC_MMAP
  41 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  42
  43 # Find arch type
  44 AS_CASE([$host_cpu],
  45         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  46         [i486], [ARCHTYPE="x86"],
  47         [i586], [ARCHTYPE="x86"],
  48         [i686], [ARCHTYPE="x86"],
  49         [amd64], [ARCHTYPE="x86"],
  50         [x86_64], [ARCHTYPE="x86"],
  51         [powerpc], [ARCHTYPE="ppc"],
  52         [ppc64], [ARCHTYPE="ppc"],
  53         [powerpc64], [ARCHTYPE="ppc"],
  54         [ppc], [ARCHTYPE="ppc"],
  55         [s390], [ARCHTYPE="s390"],
  56         [s390x], [ARCHTYPE="s390"],
  57         [sparc64], [ARCHTYPE="sparc64"],
  58         [alpha*], [ARCHTYPE="alpha"],
  59         [ia64], [ARCHTYPE="gcc"],
  60         [arm*], [ARCHTYPE="arm"],
  61         [ARCHTYPE="unknown"]
  62 )
  63
  64 AC_SUBST(ARCHTYPE)
  65 AC_SUBST(SUBARCHTYPE)
  66
  67 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  68 ARCHSRC=urcu/arch/$ARCHTYPE.h
  69
  70 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  71         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  72 ])
  73
  74 AS_IF([test "$host_cpu" = "armv7l"],[
  75         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  76 ])
  77
  78 # ARM-specific checks
  79 AS_IF([test "x$ARCHTYPE" = "xarm"],[
  80         AC_MSG_CHECKING([for dmb instruction])
  81         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  82                                 int main()
  83                                 {
  84                                         asm volatile("dmb":::"memory");
  85                                         return 0;
  86                                 }
  87                 ]])
  88         ],[
  89                 AC_MSG_RESULT([yes])
  90                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
  91         ],[
  92                 AC_MSG_RESULT([no])
  93         ])
  94 ])
  95
  96 # x86-specific checks
  97 AS_IF([test "x$ARCHTYPE" = "xx86"],[
  98         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
  99         #For now, using lock; addl compatibility mode even for i686, because the
 100         #Pentium III is seen as a i686, but lacks mfence instruction.
 101         #Only using fence for x86_64.
 102         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
 103                 AC_MSG_RESULT([yes])
 104                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 105         ],[
 106                 AC_MSG_RESULT([no])
 107         ])
 108 ])
 109
 110 # Check if sys_futex() is available
 111 AC_MSG_CHECKING([for sys_futex()])
 112 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 113                 #include <sys/syscall.h>
 114                 #ifndef __NR_futex
 115                 #error "futexes not available"
 116                 #endif
 117         ]])
 118 ],[
 119         AC_MSG_RESULT([yes])
 120         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 121         compat_futex_test=0
 122 ],[
 123         AC_MSG_RESULT([no])
 124         compat_futex_test=1
 125 ])
 126
 127 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 128 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 129
 130 # smp-support configure option
 131 AC_ARG_ENABLE([smp-support],
 132         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 133         [def_smp_support=$enableval],
 134         [def_smp_support="yes"])
 135 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 136
 137
 138 # From the sched_setaffinity(2)'s man page:
 139 # ~~~~
 140 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 141 # The library interfaces were introduced in glibc 2.3.  Initially, the
 142 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 143 # the cpuset size argument was removed, but this argument was
 144 # restored in glibc 2.3.4.
 145 # ~~~~
 146
 147 # In addition to that, some vendors ported the system call to 2.4
 148 # kernels.
 149
 150 # Furthermore, when the function first appeared, the MASK argument was
 151 # an unsigned long pointer, while later it was made into a cpu_set_t
 152 # pointer.  Systems that have the cpu_set_t version also should have
 153 # the CPU_ZERO, CPU_SET, etc. macros.
 154
 155 # All this mess means we have to cater for at least 3 different
 156 # sched_setaffinity prototypes:
 157
 158 # ~~~~
 159 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 160 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 161 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 162 # ~~~~
 163
 164 # Since we define _GNU_SOURCE in the sources, must do so too in the
 165 # autoconf tests, as defining _GNU_SOURCE or not exposes
 166 # sched_setaffinity bits differently.
 167 saved_CFLAGS=$CFLAGS
 168 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 169
 170 # First check if the function is available at all.
 171 AC_CHECK_FUNCS([sched_setaffinity],[
 172         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 173         # then we have the first version using unsigned long, and no
 174         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 175         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 176         # should also be present, but we confirm nonetheless.
 177
 178         AC_CHECK_TYPES([cpu_set_t],[
 179                 # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 180                 AC_MSG_CHECKING([whether CPU_ZERO works])
 181                 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 182                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 183                                 #define _GNU_SOURCE
 184                                 #include <sched.h>
 185                                 int main()
 186                                 {
 187                                         cpu_set_t foo; CPU_ZERO (&foo);
 188                                         return 0;
 189                                 }
 190                         ]])
 191                 ],[
 192                         # Works!
 193                         AC_DEFINE(HAVE_CPU_ZERO, 1)
 194                         AC_MSG_RESULT([yes])
 195                 ],[
 196                         AC_MSG_RESULT([no])
 197                 ])
 198
 199                 # Check how many arguments does sched_setaffinity take.
 200                 # Should be 3 or 2.
 201                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 202                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 203                                 #include <sched.h>
 204                                 int main()
 205                                 {
 206                                         cpu_set_t foo;
 207                                         sched_setaffinity (0, sizeof (foo), &foo);
 208                                         return 0;
 209                                 }
 210                         ]])
 211                 ],
 212                 [sched_set_affinity_args=3],
 213                 [sched_set_affinity_args=2])
 214                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 215                         [Defined to sched_setaffinity's number of arguments.])
 216                 AC_MSG_RESULT([$sched_set_affinity_args])
 217         ],[
 218                 # No cpu_set_t, always 3 args.
 219                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 220         ],
 221         [#include <sched.h>])
 222 ])
 223
 224 CFLAGS=$saved_CFLAGS
 225
 226 AC_CONFIG_LINKS([
 227         urcu/arch.h:$ARCHSRC
 228         urcu/uatomic.h:$UATOMICSRC
 229 ])
 230 AC_CONFIG_FILES([
 231         Makefile
 232         tests/Makefile
 233         liburcu.pc
 234         liburcu-bp.pc
 235         liburcu-cds.pc
 236         liburcu-qsbr.pc
 237         liburcu-mb.pc
 238         liburcu-signal.pc
 239 ])
 240 AC_OUTPUT
 241
 242 # Report on selected configure options
 243 AS_IF([test "x$def_smp_support" = "xyes"],[
 244         AS_ECHO("SMP support enabled.")
 245 ],[
 246         AS_ECHO("SMP support disabled.")
 247 ])