Support older autotools
[urcu.git] / configure.ac
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
3
4
5 AC_INIT([userspace-rcu],[0.6.6],[mathieu dot desnoyers at efficios dot com])
6
7 # Following the numbering scheme proposed by libtool for the library version
8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
10
11 AC_CONFIG_AUX_DIR([config])
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
16
17 AC_CONFIG_SRCDIR([urcu.h])
18 AM_PROG_MKDIR_P
19
20 AC_CONFIG_HEADERS([config.h urcu/config.h])
21
22 # Keep at the end to do not pollute installed header.
23 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
24 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
25 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
26 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks
27 cmpxchg instruction.])
28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction is available for use on ARM.])
29
30 # Checks for programs.
31 AC_PROG_CC
32 AC_PROG_MAKE_SET
33 m4_ifdef([LT_INIT], [LT_INIT], [AC_PROG_LIBTOOL])
34
35 # Checks for typedefs, structures, and compiler characteristics.
36 AC_C_INLINE
37 AC_TYPE_PID_T
38 AC_TYPE_SIZE_T
39
40 # Checks for library functions.
41 AC_FUNC_MALLOC
42 AC_FUNC_MMAP
43 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
44
45 # Find arch type
46 case $host_cpu in
47 i386) ARCHTYPE="x86"; SUBARCHTYPE="x86compat" ;;
48 i486) ARCHTYPE="x86";;
49 i586) ARCHTYPE="x86";;
50 i686) ARCHTYPE="x86";;
51 amd64) ARCHTYPE="x86";;
52 x86_64) ARCHTYPE="x86";;
53 powerpc) ARCHTYPE="ppc" ;;
54 ppc64) ARCHTYPE="ppc" ;;
55 powerpc64) ARCHTYPE="ppc" ;;
56 ppc) ARCHTYPE="ppc" ;;
57 s390) ARCHTYPE="s390" ;;
58 s390x) ARCHTYPE="s390" ;;
59 sparc64) ARCHTYPE="sparc64" ;;
60 alpha*) ARCHTYPE="alpha" ;;
61 ia64) ARCHTYPE="gcc" ;;
62 arm*) ARCHTYPE="arm" ;;
63 *) ARCHTYPE="unknown";;
64 esac
65
66 if test "x$ARCHTYPE" = "xarm" ; then
67 AC_MSG_CHECKING([checking for dmb instruction])
68 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
69 ]], [[
70 asm volatile("dmb":::"memory");
71 ]])],[
72 AC_MSG_RESULT([yes])
73 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
74
75 ],[
76 AC_MSG_RESULT([no])
77
78 ])
79 fi
80
81 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
82 ARCHSRC=urcu/arch/$ARCHTYPE.h
83 if test "$ARCHTYPE" == "armv7l"; then
84 CFLAGS="-mcpu=cortex-a9 -mtune=cortex-a9 -O"
85 fi
86
87 AC_SUBST(ARCHTYPE)
88 AC_SUBST(SUBARCHTYPE)
89
90 [
91 #if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586"; then
92 #For now, using lock; addl compatibility mode even for i686, because the
93 #Pentium III is seen as a i686, but lacks mfence instruction.
94 #Only using fence for x86_64.
95 if test "x$ARCHTYPE" = "xx86" -a "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"; then
96 ]
97 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
98 [
99 fi
100 ]
101
102 AC_MSG_CHECKING([sys_futex()])
103 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
104 #include <sys/syscall.h>
105 ]], [[
106 #ifndef __NR_futex
107 #error "futexes not available"
108 #endif
109 ]])],[
110 AC_MSG_RESULT([yes])
111 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
112 compat_futex_test=0
113
114 ],[
115 AC_MSG_RESULT([no])
116 compat_futex_test=1
117
118 ])
119
120 AM_CONDITIONAL([COMPAT_FUTEX], [ test "x$compat_futex_test" = "x1" ])
121
122 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = xx86compat ])
123
124 [
125 if test "x$SUBARCHTYPE" = xx86compat; then
126 ]
127 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
128 [
129 fi
130 ]
131
132 AC_ARG_ENABLE([smp-support], [ --disable-smp-support Disable SMP support. Warning: only use this
133 on uniprocessor systems. [[default=enabled]]], [def_smp_support=$enableval], [def_smp_support="yes"])
134
135 [
136 if test "$def_smp_support" = "no"; then
137 echo "SMP support disabled."
138 else
139 ]
140 AC_DEFINE([CONFIG_RCU_SMP], [1])
141 [
142 echo "SMP support enabled."
143 fi
144 ]
145
146 # From the sched_setaffinity(2)'s man page:
147 # ~~~~
148 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
149 # The library interfaces were introduced in glibc 2.3. Initially, the
150 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
151 # the cpuset size argument was removed, but this argument was
152 # restored in glibc 2.3.4.
153 # ~~~~
154
155 # In addition to that, some vendors ported the system call to 2.4
156 # kernels.
157
158 # Furthermore, when the function first appeared, the MASK argument was
159 # an unsigned long pointer, while later it was made into a cpu_set_t
160 # pointer. Systems that have the cpu_set_t version also should have
161 # the CPU_ZERO, CPU_SET, etc. macros.
162
163 # All this mess means we have to cater for at least 3 different
164 # sched_setaffinity prototypes:
165
166 # ~~~~
167 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
168 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
169 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
170 # ~~~~
171
172 dnl Since we define _GNU_SOURCE in the sources, must do so too in the
173 dnl autoconf tests, as defining _GNU_SOURCE or not exposes
174 dnl sched_setaffinity bits differently.
175 saved_CFLAGS=$CFLAGS
176 CFLAGS="$CFLAGS -D_GNU_SOURCE"
177
178 # First check if the function is available at all.
179 AC_CHECK_FUNCS(
180 [sched_setaffinity],
181 [ # Okay, we have it. Check if also have cpu_set_t. If we don't,
182 # then we have the first version using unsigned long, and no
183 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
184 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
185 # should also be present, but we confirm nonetheless.
186
187 AC_CHECK_TYPES(
188 [cpu_set_t],
189 [ # We do have it. Confirm that we have CPU_ZERO, and it actually works.
190 AC_MSG_CHECKING([whether CPU_ZERO works])
191 AH_TEMPLATE([HAVE_CPU_ZERO],
192 [Define to 1 if we have CPU_ZERO and if it works])
193 AC_COMPILE_IFELSE(
194 [AC_LANG_PROGRAM(
195 [#define _GNU_SOURCE
196 #include <sched.h>],
197 [cpu_set_t foo; CPU_ZERO (&foo);])
198 ],
199 [ # Works!
200 AC_DEFINE(HAVE_CPU_ZERO, 1)
201 AC_MSG_RESULT([yes])
202 ],
203 [AC_MSG_RESULT([no])]
204 )
205
206 # Check how many arguments does sched_setaffinity take.
207 # Should be 3 or 2.
208 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
209 AC_COMPILE_IFELSE(
210 [AC_LANG_PROGRAM(
211 [#include <sched.h>],
212 [cpu_set_t foo; sched_setaffinity (0, sizeof (foo), &foo);])
213 ],
214 [sched_set_affinity_args=3],
215 [sched_set_affinity_args=2])
216 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
217 [Define to sched_setaffinity's number of arguments.])
218 AC_MSG_RESULT([$sched_set_affinity_args])
219 ],
220 [ # No cpu_set_t, always 3 args.
221 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) ],
222 [#include <sched.h>]
223 )
224 ]
225 )
226
227 CFLAGS=$saved_CFLAGS
228
229 AC_CONFIG_LINKS([
230 urcu/arch.h:$ARCHSRC
231 urcu/uatomic.h:$UATOMICSRC
232 ])
233 AC_CONFIG_FILES([
234 Makefile
235 tests/Makefile
236 liburcu-cds.pc
237 liburcu.pc
238 liburcu-bp.pc
239 liburcu-qsbr.pc
240 liburcu-mb.pc
241 liburcu-signal.pc
242 ])
243 AC_OUTPUT
This page took 0.041263 seconds and 5 git commands to generate.