configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.6.7],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [1:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_CONFIG_SRCDIR([urcu.h])
  19
  20 AC_CONFIG_HEADERS([config.h urcu/config.h])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27
  28 # Checks for programs.
  29 AC_PROG_CC
  30 AC_PROG_MAKE_SET
  31 LT_INIT
  32
  33 # Checks for typedefs, structures, and compiler characteristics.
  34 AC_C_INLINE
  35 AC_TYPE_PID_T
  36 AC_TYPE_SIZE_T
  37
  38 # Checks for library functions.
  39 AC_FUNC_MALLOC
  40 AC_FUNC_MMAP
  41 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
  42
  43 # Find arch type
  44 AS_CASE([$host_cpu],
  45         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  46         [i486], [ARCHTYPE="x86"],
  47         [i586], [ARCHTYPE="x86"],
  48         [i686], [ARCHTYPE="x86"],
  49         [amd64], [ARCHTYPE="x86"],
  50         [x86_64], [ARCHTYPE="x86"],
  51         [powerpc], [ARCHTYPE="ppc"],
  52         [ppc64], [ARCHTYPE="ppc"],
  53         [powerpc64], [ARCHTYPE="ppc"],
  54         [ppc], [ARCHTYPE="ppc"],
  55         [s390], [ARCHTYPE="s390"],
  56         [s390x], [ARCHTYPE="s390"],
  57         [sparc64], [ARCHTYPE="sparc64"],
  58         [alpha*], [ARCHTYPE="alpha"],
  59         [ia64], [ARCHTYPE="gcc"],
  60         [arm*], [ARCHTYPE="arm"],
  61         [ARCHTYPE="unknown"]
  62 )
  63
  64 AC_SUBST(ARCHTYPE)
  65 AC_SUBST(SUBARCHTYPE)
  66
  67 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  68 ARCHSRC=urcu/arch/$ARCHTYPE.h
  69
  70 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  71         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
  72 ])
  73
  74 AS_IF([test "$host_cpu" = "armv7l"],[
  75         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
  76 ])
  77
  78 # ARM-specific checks
  79 AS_IF([test "x$ARCHTYPE" = "xarm"],[
  80         AC_MSG_CHECKING([for dmb instruction])
  81         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]], [[asm volatile("dmb":::"memory");]])],[
  82                 AC_MSG_RESULT([yes])
  83                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
  84         ],[
  85                 AC_MSG_RESULT([no])
  86         ])
  87 ])
  88
  89 # x86-specific checks
  90 AS_IF([test "x$ARCHTYPE" = "xx86"],[
  91         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
  92         #For now, using lock; addl compatibility mode even for i686, because the
  93         #Pentium III is seen as a i686, but lacks mfence instruction.
  94         #Only using fence for x86_64.
  95         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
  96                 AC_MSG_RESULT([yes])
  97                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
  98         ],[
  99                 AC_MSG_RESULT([no])
 100         ])
 101 ])
 102
 103 # Check if sys_futex() is available
 104 AC_MSG_CHECKING([for sys_futex()])
 105 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 106                 #include <sys/syscall.h>
 107                 #ifndef __NR_futex
 108                 #error "futexes not available"
 109                 #endif
 110         ])
 111 ],[
 112         AC_MSG_RESULT([yes])
 113         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 114         compat_futex_test=0
 115 ],[
 116         AC_MSG_RESULT([no])
 117         compat_futex_test=1
 118 ])
 119
 120 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 121 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 122
 123 # smp-support configure option
 124 AC_ARG_ENABLE([smp-support],
 125         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 126         [def_smp_support=$enableval],
 127         [def_smp_support="yes"])
 128 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 129
 130
 131 # From the sched_setaffinity(2)'s man page:
 132 # ~~~~
 133 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 134 # The library interfaces were introduced in glibc 2.3.  Initially, the
 135 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 136 # the cpuset size argument was removed, but this argument was
 137 # restored in glibc 2.3.4.
 138 # ~~~~
 139
 140 # In addition to that, some vendors ported the system call to 2.4
 141 # kernels.
 142
 143 # Furthermore, when the function first appeared, the MASK argument was
 144 # an unsigned long pointer, while later it was made into a cpu_set_t
 145 # pointer.  Systems that have the cpu_set_t version also should have
 146 # the CPU_ZERO, CPU_SET, etc. macros.
 147
 148 # All this mess means we have to cater for at least 3 different
 149 # sched_setaffinity prototypes:
 150
 151 # ~~~~
 152 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 153 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 154 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 155 # ~~~~
 156
 157 # Since we define _GNU_SOURCE in the sources, must do so too in the
 158 # autoconf tests, as defining _GNU_SOURCE or not exposes
 159 # sched_setaffinity bits differently.
 160 saved_CFLAGS=$CFLAGS
 161 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 162
 163 # First check if the function is available at all.
 164 AC_CHECK_FUNCS([sched_setaffinity],[
 165         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 166         # then we have the first version using unsigned long, and no
 167         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 168         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 169         # should also be present, but we confirm nonetheless.
 170
 171         AC_CHECK_TYPES([cpu_set_t],[
 172                 # We do have it.  Confirm that we have CPU_ZERO, and it actually works.
 173                 AC_MSG_CHECKING([whether CPU_ZERO works])
 174                 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 175                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 176                                 #define _GNU_SOURCE
 177                                 #include <sched.h>
 178                         ]],[[
 179                                 cpu_set_t foo; CPU_ZERO (&foo);
 180                         ]])
 181                 ],[
 182                         # Works!
 183                         AC_DEFINE(HAVE_CPU_ZERO, 1)
 184                         AC_MSG_RESULT([yes])
 185                 ],[
 186                         AC_MSG_RESULT([no])
 187                 ])
 188
 189                 # Check how many arguments does sched_setaffinity take.
 190                 # Should be 3 or 2.
 191                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 192                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 193                                 #include <sched.h>
 194                         ]],[[
 195                                 cpu_set_t foo;
 196                                 sched_setaffinity (0, sizeof (foo), &foo);
 197                         ]])
 198                 ],
 199                 [sched_set_affinity_args=3],
 200                 [sched_set_affinity_args=2])
 201                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
 202                         [Defined to sched_setaffinity's number of arguments.])
 203                 AC_MSG_RESULT([$sched_set_affinity_args])
 204         ],[
 205                 # No cpu_set_t, always 3 args.
 206                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 207         ],
 208         [#include <sched.h>])
 209 ])
 210
 211 CFLAGS=$saved_CFLAGS
 212
 213 AC_CONFIG_LINKS([
 214         urcu/arch.h:$ARCHSRC
 215         urcu/uatomic.h:$UATOMICSRC
 216 ])
 217 AC_CONFIG_FILES([
 218         Makefile
 219         tests/Makefile
 220         liburcu.pc
 221         liburcu-bp.pc
 222         liburcu-cds.pc
 223         liburcu-qsbr.pc
 224         liburcu-mb.pc
 225         liburcu-signal.pc
 226 ])
 227 AC_OUTPUT
 228
 229 # Report on selected configure options
 230 AS_IF([test "x$def_smp_support" = "xyes"],[
 231         AS_ECHO("SMP support enabled.")
 232 ],[
 233         AS_ECHO("SMP support disabled.")
 234 ])