Use initial-exec tls model
[urcu.git] / configure.ac
1 AC_PREREQ(2.59)
2 AC_INIT([userspace-rcu],[0.11.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
3
4 # Following the numbering scheme proposed by libtool for the library version
5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
6 AC_SUBST([URCU_LIBRARY_VERSION], [6:0:0])
7
8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
9 AC_CONFIG_AUX_DIR([config])
10 AC_CONFIG_MACRO_DIR([m4])
11
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14
15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
16 AM_MAINTAINER_MODE([enable])
17
18 # Enable silent rules if available (Introduced in AM 1.11)
19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
20
21 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
22 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
23 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
24 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
25 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
26 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
27 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
28 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
29 AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.])
30
31 # Allow requiring the operating system to support the membarrier system
32 # call. Applies to default and bulletproof flavors.
33 AC_ARG_ENABLE([sys-membarrier-fallback],
34 AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
35 [def_sys_membarrier_fallback=$enableval],
36 [def_sys_membarrier_fallback="yes"])
37 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
38
39 # Allow overriding storage used for TLS variables.
40 AC_ARG_ENABLE([compiler-tls],
41 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
42 [def_compiler_tls=$enableval],
43 [def_compiler_tls="yes"])
44
45 # If not overridden, use ax_tls.m4 to check if TLS is available.
46 AS_IF([test "x$def_compiler_tls" = "xyes"],
47 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
48 [:])
49
50 AS_IF([test "x$def_tls_detect" = "x"],
51 [:],
52 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
53
54 # Checks for C compiler
55 AC_USE_SYSTEM_EXTENSIONS
56 AC_PROG_CC
57 AC_PROG_CC_STDC
58
59 # Checks for programs.
60 AC_PROG_AWK
61 AC_PROG_MAKE_SET
62 AC_CHECK_PROGS(NPROC, [nproc gnproc])
63 AC_CHECK_PROGS(GETCONF, [getconf])
64 AS_IF([test "x$NPROC" != "x"],
65 [NPROC_CMD=$NPROC],
66 [AS_IF([test "x$GETCONF" != "x"],
67 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
68 [NPROC_CMD="echo 1"]
69 )]
70 )
71 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
72
73 LT_INIT
74
75 # Checks for typedefs, structures, and compiler characteristics.
76 AC_C_INLINE
77 AC_TYPE_PID_T
78 AC_TYPE_SIZE_T
79 AC_TYPE_SSIZE_T
80 AC_TYPE_UINT16_T
81 AC_TYPE_INT32_T
82 AC_TYPE_UINT32_T
83 AC_TYPE_UINT64_T
84 AC_TYPE_UINT8_T
85
86 AX_C___ATTRIBUTE__
87 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
88 [:],
89 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
90
91 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
92
93 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
94
95 # Checks for library functions.
96 AC_FUNC_MMAP
97 AC_FUNC_FORK
98 AC_CHECK_FUNCS([ \
99 atexit \
100 getcpuid \
101 gettid \
102 gettimeofday \
103 memeset \
104 memset \
105 munmap \
106 rand_r \
107 sched_getcpu \
108 strerror \
109 strtoul \
110 sysconf \
111 ])
112
113 # AC_FUNC_MALLOC causes problems when cross-compiling.
114 #AC_FUNC_MALLOC
115
116 # Check for headers
117 AC_HEADER_STDBOOL
118 AC_CHECK_HEADERS([ \
119 limits.h \
120 stddef.h \
121 sys/param.h \
122 sys/time.h \
123 ])
124
125 # Find arch type
126 AS_CASE([$host_cpu],
127 [k1om], [ARCHTYPE="x86"],
128 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
129 [i486], [ARCHTYPE="x86"],
130 [i586], [ARCHTYPE="x86"],
131 [i686], [ARCHTYPE="x86"],
132 [amd64], [ARCHTYPE="x86"],
133 [x86_64], [ARCHTYPE="x86"],
134 [powerpc], [ARCHTYPE="ppc"],
135 [ppc64], [ARCHTYPE="ppc"],
136 [powerpc64], [ARCHTYPE="ppc"],
137 [powerpc64le], [ARCHTYPE="ppc"],
138 [ppc], [ARCHTYPE="ppc"],
139 [s390], [ARCHTYPE="s390"],
140 [s390x], [ARCHTYPE="s390"],
141 [sparc], [ARCHTYPE="sparc64"],
142 [sparc64], [ARCHTYPE="sparc64"],
143 [alpha*], [ARCHTYPE="alpha"],
144 [ia64], [ARCHTYPE="ia64"],
145 [arm*], [ARCHTYPE="arm"],
146 [aarch64*], [ARCHTYPE="aarch64"],
147 [mips*], [ARCHTYPE="mips"],
148 [nios2*], [ARCHTYPE="nios2"],
149 [tile*], [ARCHTYPE="tile"],
150 [hppa*], [ARCHTYPE="hppa"],
151 [m68k], [ARCHTYPE="m68k"],
152 [ARCHTYPE="unknown"]
153 )
154
155 AS_CASE([$host],[*-cygwin*],
156 [AM_CONDITIONAL(USE_CYGWIN, true)],
157 [AM_CONDITIONAL(USE_CYGWIN, false)]
158 )
159
160 AC_SUBST(ARCHTYPE)
161 AC_SUBST(SUBARCHTYPE)
162
163 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
164 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
165
166 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
167 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
168 ])
169
170 AS_IF([test "$host_cpu" = "armv7l"],[
171 AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
172 ])
173
174 # ARM-specific checks
175 AS_IF([test "x$ARCHTYPE" = "xarm"],[
176 AC_MSG_CHECKING([for dmb instruction])
177 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
178 int main()
179 {
180 asm volatile("dmb":::"memory");
181 return 0;
182 }
183 ]])
184 ],[
185 AC_MSG_RESULT([yes])
186 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
187 ],[
188 AC_MSG_RESULT([no])
189 ])
190 ])
191
192 # Tile-specific checks
193 AS_IF([echo "$host_cpu" | grep "^tile"],[
194 AC_MSG_CHECKING([for Tile architecture type])
195 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
196 #ifndef __tilegx__
197 #error
198 #endif
199 ]])
200 ],[
201 AC_MSG_RESULT([ok])
202 ],[
203 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
204 ])
205 ])
206
207 # x86-specific checks
208 AS_IF([test "x$ARCHTYPE" = "xx86"],[
209 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
210 #For now, using lock; addl compatibility mode even for i686, because the
211 #Pentium III is seen as a i686, but lacks mfence instruction.
212 #Only using fence for x86_64.
213 #
214 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
215 #variant but lacks fence instructions.
216 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
217 AC_MSG_RESULT([yes])
218 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
219 config_rcu_have_fence=yes
220 ],[
221 AC_MSG_RESULT([no])
222 config_rcu_have_fence=no
223 ])
224 ])
225
226 # Check if sys_futex() is available
227 AC_MSG_CHECKING([for sys_futex()])
228 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
229 #include <sys/syscall.h>
230 #ifndef __NR_futex
231 #error "futexes not available"
232 #endif
233 ]])
234 ],[
235 AC_MSG_RESULT([yes])
236 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
237 compat_futex_test=0
238 ],[
239 AC_MSG_RESULT([no])
240 compat_futex_test=1
241 ])
242
243 # Search for clock_gettime
244 AC_SEARCH_LIBS([clock_gettime], [rt], [
245 AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
246 config_rcu_have_clock_gettime=yes
247 ], [])
248
249 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
250 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
251 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
252
253 # smp-support configure option
254 AC_ARG_ENABLE([smp-support],
255 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
256 [def_smp_support=$enableval],
257 [def_smp_support="yes"])
258 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
259
260 # RCU debugging option
261 AC_ARG_ENABLE([rcu-debug],
262 AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
263 self-checks. Introduce performance penalty.]))
264 AS_IF([test "x$enable_rcu_debug" = "xyes"], [
265 AC_DEFINE([CONFIG_RCU_DEBUG], [1])
266 ])
267
268 # From the sched_setaffinity(2)'s man page:
269 # ~~~~
270 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
271 # The library interfaces were introduced in glibc 2.3. Initially, the
272 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
273 # the cpuset size argument was removed, but this argument was
274 # restored in glibc 2.3.4.
275 # ~~~~
276
277 # In addition to that, some vendors ported the system call to 2.4
278 # kernels.
279
280 # Furthermore, when the function first appeared, the MASK argument was
281 # an unsigned long pointer, while later it was made into a cpu_set_t
282 # pointer. Systems that have the cpu_set_t version also should have
283 # the CPU_ZERO, CPU_SET, etc. macros.
284
285 # All this mess means we have to cater for at least 3 different
286 # sched_setaffinity prototypes:
287
288 # ~~~~
289 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
290 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
291 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
292 # ~~~~
293
294 AC_CHECK_TYPES([cpu_set_t],
295 [have_cpu_set_t="yes"],
296 [have_cpu_set_t="no"],
297 [#include <sched.h>])
298
299 # Confirm that we have CPU_ZERO, and it actually works.
300 AC_MSG_CHECKING([whether CPU_ZERO works])
301 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
302 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
303 #include <sched.h>
304 int main()
305 {
306 cpu_set_t foo; CPU_ZERO(&foo);
307 return 0;
308 }
309 ]])
310 ],[
311 AC_DEFINE(HAVE_CPU_ZERO, 1)
312 AC_MSG_RESULT([yes])
313 ],[
314 AC_MSG_RESULT([no])
315 ])
316
317 # Confirm that we have CPU_SET, and it actually works.
318 AC_MSG_CHECKING([whether CPU_SET works])
319 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
320 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
321 #include <sched.h>
322 int main()
323 {
324 cpu_set_t foo, mask; CPU_SET(0, &foo);
325 return 0;
326 }
327 ]])
328 ],[
329 AC_DEFINE(HAVE_CPU_SET, 1)
330 AC_MSG_RESULT([yes])
331 ],[
332 AC_MSG_RESULT([no])
333 ])
334
335 # First check if the function is available at all.
336 AC_CHECK_FUNCS([sched_setaffinity],[
337 # Okay, we have it. Check if also have cpu_set_t. If we don't,
338 # then we have the first version using unsigned long, and no
339 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
340 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
341 # should also be present, but we confirm nonetheless.
342
343 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
344 # We do have it.
345 # Check how many arguments does sched_setaffinity take.
346 # Should be 3 or 2.
347 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
348 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
349 #include <sched.h>
350 int main()
351 {
352 cpu_set_t foo;
353 sched_setaffinity(0, sizeof (foo), &foo);
354 return 0;
355 }
356 ]])
357 ],
358 [sched_set_affinity_args=3],
359 [sched_set_affinity_args=2])
360 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
361 $sched_set_affinity_args,
362 [Defined to sched_setaffinity's number of arguments.])
363 AC_MSG_RESULT([$sched_set_affinity_args])
364 ],[
365 # No cpu_set_t, always 3 args.
366 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
367 ])
368 ])
369
370 AM_CPPFLAGS="-include config.h"
371 AC_SUBST(AM_CPPFLAGS)
372
373 AM_CFLAGS="-Wall $AM_CFLAGS"
374 AC_SUBST(AM_CFLAGS)
375
376 AC_CONFIG_LINKS([
377 include/urcu/arch.h:$ARCHSRC
378 include/urcu/uatomic.h:$UATOMICSRC
379 ])
380 AC_CONFIG_FILES([
381 Makefile
382 doc/Makefile
383 doc/examples/Makefile
384 include/Makefile
385 src/Makefile
386 tests/Makefile
387 tests/common/Makefile
388 tests/unit/Makefile
389 tests/benchmark/Makefile
390 tests/regression/Makefile
391 tests/regression/regression_tests
392 tests/utils/Makefile
393 src/liburcu.pc
394 src/liburcu-bp.pc
395 src/liburcu-cds.pc
396 src/liburcu-qsbr.pc
397 src/liburcu-mb.pc
398 src/liburcu-signal.pc
399 ])
400 AC_OUTPUT
401
402 #
403 # Mini-report on what will be built.
404 #
405
406 PPRINT_INIT
407 PPRINT_SET_INDENT(1)
408 PPRINT_SET_TS(38)
409
410 AS_ECHO
411 AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
412 AS_ECHO
413
414 PPRINT_SUBTITLE([Features])
415
416 PPRINT_PROP_STRING([Target architecture], $host_cpu)
417
418 # SMP support enabled/disabled
419 test "x$def_smp_support" = "xyes" && value=1 || value=0
420 PPRINT_PROP_BOOL([SMP support], $value)
421
422 # Memory fence support available
423 test "x$config_rcu_have_fence" = "xyes" && value=1 || value=0
424 PPRINT_PROP_BOOL([Memory fence instructions], $value)
425
426 # Futex support available
427 test "x$compat_futex_test" = "x0" && value=1 || value=0
428 PPRINT_PROP_BOOL([Futex support], $value)
429
430 # TLS
431 test "x$def_tls_detect" = "x" && value="pthread_getspecific()" || value="$def_tls_detect"
432 PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
433
434 # clock_gettime() available
435 test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
436 PPRINT_PROP_BOOL([clock_gettime()], $value)
437
438 # Require membarrier
439 test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
440 PPRINT_PROP_BOOL([Require membarrier], $value)
441
442 # RCU debug enabled/disabled
443 test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
444 PPRINT_PROP_BOOL([Internal debugging], $value)
445
446 report_bindir="`eval eval echo $bindir`"
447 report_libdir="`eval eval echo $libdir`"
448
449 # Print the bindir and libdir this `make install' will install into.
450 AS_ECHO
451 PPRINT_SUBTITLE([Install directories])
452 PPRINT_PROP_STRING([Binaries], [$report_bindir])
453 PPRINT_PROP_STRING([Libraries], [$report_libdir])
454
This page took 0.049826 seconds and 4 git commands to generate.