configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
  29
  30 # Allow overriding storage used for TLS variables.
  31 AC_ARG_ENABLE([compiler-tls],
  32         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  33         [def_compiler_tls=$enableval],
  34         [def_compiler_tls="yes"])
  35
  36 # If not overridden, use ax_tls.m4 to check if TLS is available.
  37 AS_IF([test "x$def_compiler_tls" = "xyes"],
  38         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  39         [:])
  40
  41 AS_IF([test "x$def_tls_detect" = "x"],
  42         [:],
  43         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  44
  45 # Checks for C compiler
  46 AC_USE_SYSTEM_EXTENSIONS
  47 AC_PROG_CC
  48 AC_PROG_CC_STDC
  49
  50 # Checks for programs.
  51 AC_PROG_AWK
  52 AC_PROG_MAKE_SET
  53 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  54 LT_INIT
  55
  56 # Checks for typedefs, structures, and compiler characteristics.
  57 AC_C_INLINE
  58 AC_TYPE_PID_T
  59 AC_TYPE_SIZE_T
  60 AC_TYPE_SSIZE_T
  61 AC_TYPE_UINT16_T
  62 AC_TYPE_INT32_T
  63 AC_TYPE_UINT32_T
  64 AC_TYPE_UINT64_T
  65 AC_TYPE_UINT8_T
  66
  67 AX_C___ATTRIBUTE__
  68 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  69         [:],
  70         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  71
  72 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  73 LIBS="$PTHREAD_LIBS $LIBS"
  74 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  75 CC="$PTHREAD_CC"
  76
  77 # Checks for library functions.
  78 AC_FUNC_MALLOC
  79 AC_FUNC_MMAP
  80 AC_FUNC_FORK
  81 AC_CHECK_FUNCS([ \
  82         atexit \
  83         getcpuid \
  84         gettid \
  85         gettimeofday \
  86         memeset \
  87         memset \
  88         munmap \
  89         sched_getcpu \
  90         strerror \
  91         strtoul \
  92         sysconf \
  93 ])
  94
  95 # Check for headers
  96 AC_HEADER_STDBOOL
  97 AC_CHECK_HEADERS([ \
  98         limits.h \
  99         stddef.h \
 100         sys/param.h \
 101         sys/time.h \
 102 ])
 103
 104 # Find arch type
 105 AS_CASE([$host_cpu],
 106         [k1om], [ARCHTYPE="x86"],
 107         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 108         [i486], [ARCHTYPE="x86"],
 109         [i586], [ARCHTYPE="x86"],
 110         [i686], [ARCHTYPE="x86"],
 111         [amd64], [ARCHTYPE="x86"],
 112         [x86_64], [ARCHTYPE="x86"],
 113         [powerpc], [ARCHTYPE="ppc"],
 114         [ppc64], [ARCHTYPE="ppc"],
 115         [powerpc64], [ARCHTYPE="ppc"],
 116         [powerpc64le], [ARCHTYPE="ppc"],
 117         [ppc], [ARCHTYPE="ppc"],
 118         [s390], [ARCHTYPE="s390"],
 119         [s390x], [ARCHTYPE="s390"],
 120         [sparc], [ARCHTYPE="sparc64"],
 121         [sparc64], [ARCHTYPE="sparc64"],
 122         [alpha*], [ARCHTYPE="alpha"],
 123         [ia64], [ARCHTYPE="ia64"],
 124         [arm*], [ARCHTYPE="arm"],
 125         [aarch64*], [ARCHTYPE="aarch64"],
 126         [mips*], [ARCHTYPE="mips"],
 127         [nios2*], [ARCHTYPE="nios2"],
 128         [tile*], [ARCHTYPE="tile"],
 129         [hppa*], [ARCHTYPE="hppa"],
 130         [ARCHTYPE="unknown"]
 131 )
 132
 133 AS_CASE([$host],[*-*-linux-androideabi],
 134         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 135         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 136 )
 137
 138 AS_CASE([$host],[*-cygwin*],
 139         [AM_CONDITIONAL(USE_CYGWIN, true)],
 140         [AM_CONDITIONAL(USE_CYGWIN, false)]
 141 )
 142
 143 AC_SUBST(ARCHTYPE)
 144 AC_SUBST(SUBARCHTYPE)
 145
 146 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 147 ARCHSRC=urcu/arch/$ARCHTYPE.h
 148
 149 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 150         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 151 ])
 152
 153 AS_IF([test "$host_cpu" = "armv7l"],[
 154         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 155 ])
 156
 157 # ARM-specific checks
 158 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 159         AC_MSG_CHECKING([for dmb instruction])
 160         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 161                                 int main()
 162                                 {
 163                                         asm volatile("dmb":::"memory");
 164                                         return 0;
 165                                 }
 166                 ]])
 167         ],[
 168                 AC_MSG_RESULT([yes])
 169                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 170         ],[
 171                 AC_MSG_RESULT([no])
 172         ])
 173 ])
 174
 175 # Tile-specific checks
 176 AS_IF([echo "$host_cpu" | grep "^tile"],[
 177         AC_MSG_CHECKING([for Tile architecture type])
 178         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 179                                 #ifndef __tilegx__
 180                                 #error
 181                                 #endif
 182                 ]])
 183         ],[
 184                 AC_MSG_RESULT([ok])
 185         ],[
 186                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 187         ])
 188 ])
 189
 190 # x86-specific checks
 191 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 192         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 193         #For now, using lock; addl compatibility mode even for i686, because the
 194         #Pentium III is seen as a i686, but lacks mfence instruction.
 195         #Only using fence for x86_64.
 196         #
 197         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 198         #variant but lacks fence instructions.
 199         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 200                 AC_MSG_RESULT([yes])
 201                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 202         ],[
 203                 AC_MSG_RESULT([no])
 204         ])
 205 ])
 206
 207 # Check if sys_futex() is available
 208 AC_MSG_CHECKING([for sys_futex()])
 209 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 210                 #include <sys/syscall.h>
 211                 #ifndef __NR_futex
 212                 #error "futexes not available"
 213                 #endif
 214         ]])
 215 ],[
 216         AC_MSG_RESULT([yes])
 217         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 218         compat_futex_test=0
 219 ],[
 220         AC_MSG_RESULT([no])
 221         compat_futex_test=1
 222 ])
 223
 224 # Search for clock_gettime
 225 AC_SEARCH_LIBS([clock_gettime], [rt], [
 226         AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
 227 ], [])
 228
 229 # Check for pthread
 230 AC_CHECK_LIB([pthread], [pthread_create],
 231         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 232         [AC_CHECK_LIB([c], [pthread_create],
 233                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 234                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 235         )]
 236 )
 237
 238 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 239 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 240 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 241
 242 # smp-support configure option
 243 AC_ARG_ENABLE([smp-support],
 244         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 245         [def_smp_support=$enableval],
 246         [def_smp_support="yes"])
 247 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 248
 249
 250 # From the sched_setaffinity(2)'s man page:
 251 # ~~~~
 252 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 253 # The library interfaces were introduced in glibc 2.3.  Initially, the
 254 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 255 # the cpuset size argument was removed, but this argument was
 256 # restored in glibc 2.3.4.
 257 # ~~~~
 258
 259 # In addition to that, some vendors ported the system call to 2.4
 260 # kernels.
 261
 262 # Furthermore, when the function first appeared, the MASK argument was
 263 # an unsigned long pointer, while later it was made into a cpu_set_t
 264 # pointer.  Systems that have the cpu_set_t version also should have
 265 # the CPU_ZERO, CPU_SET, etc. macros.
 266
 267 # All this mess means we have to cater for at least 3 different
 268 # sched_setaffinity prototypes:
 269
 270 # ~~~~
 271 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 272 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 273 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 274 # ~~~~
 275
 276 # Since we define _GNU_SOURCE in the sources, must do so too in the
 277 # autoconf tests, as defining _GNU_SOURCE or not exposes
 278 # sched_setaffinity bits differently.
 279 saved_CFLAGS=$CFLAGS
 280 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 281
 282 AC_CHECK_TYPES([cpu_set_t],
 283         [have_cpu_set_t="yes"],
 284         [have_cpu_set_t="no"],
 285         [#include <sched.h>])
 286
 287 # Confirm that we have CPU_ZERO, and it actually works.
 288 AC_MSG_CHECKING([whether CPU_ZERO works])
 289 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 290 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 291                 #define _GNU_SOURCE
 292                 #include <sched.h>
 293                 int main()
 294                 {
 295                         cpu_set_t foo; CPU_ZERO(&foo);
 296                         return 0;
 297                 }
 298         ]])
 299 ],[
 300         AC_DEFINE(HAVE_CPU_ZERO, 1)
 301         AC_MSG_RESULT([yes])
 302 ],[
 303         AC_MSG_RESULT([no])
 304 ])
 305
 306 # Confirm that we have CPU_SET, and it actually works.
 307 AC_MSG_CHECKING([whether CPU_SET works])
 308 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 309 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 310                 #define _GNU_SOURCE
 311                 #include <sched.h>
 312                 int main()
 313                 {
 314                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 315                         return 0;
 316                 }
 317         ]])
 318 ],[
 319         AC_DEFINE(HAVE_CPU_SET, 1)
 320         AC_MSG_RESULT([yes])
 321 ],[
 322         AC_MSG_RESULT([no])
 323 ])
 324
 325 # First check if the function is available at all.
 326 AC_CHECK_FUNCS([sched_setaffinity],[
 327         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 328         # then we have the first version using unsigned long, and no
 329         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 330         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 331         # should also be present, but we confirm nonetheless.
 332
 333         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 334                 # We do have it.
 335                 # Check how many arguments does sched_setaffinity take.
 336                 # Should be 3 or 2.
 337                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 338                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 339                                 #include <sched.h>
 340                                 int main()
 341                                 {
 342                                         cpu_set_t foo;
 343                                         sched_setaffinity(0, sizeof (foo), &foo);
 344                                         return 0;
 345                                 }
 346                         ]])
 347                 ],
 348                 [sched_set_affinity_args=3],
 349                 [sched_set_affinity_args=2])
 350                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 351                         $sched_set_affinity_args,
 352                         [Defined to sched_setaffinity's number of arguments.])
 353                 AC_MSG_RESULT([$sched_set_affinity_args])
 354         ],[
 355                 # No cpu_set_t, always 3 args.
 356                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 357         ])
 358 ])
 359
 360 CFLAGS=$saved_CFLAGS
 361
 362 AC_CONFIG_LINKS([
 363         urcu/arch.h:$ARCHSRC
 364         urcu/uatomic.h:$UATOMICSRC
 365 ])
 366 AC_CONFIG_FILES([
 367         Makefile
 368         doc/Makefile
 369         doc/examples/Makefile
 370         tests/Makefile
 371         tests/common/Makefile
 372         tests/unit/Makefile
 373         tests/benchmark/Makefile
 374         tests/regression/Makefile
 375         tests/regression/regression_tests
 376         tests/utils/Makefile
 377         liburcu.pc
 378         liburcu-bp.pc
 379         liburcu-cds.pc
 380         liburcu-qsbr.pc
 381         liburcu-mb.pc
 382         liburcu-signal.pc
 383 ])
 384 AC_OUTPUT
 385
 386 # Report on selected configure options
 387 AS_IF([test "x$def_smp_support" = "xyes"],[
 388         AS_ECHO("SMP support enabled.")
 389 ],[
 390         AS_ECHO("SMP support disabled.")
 391 ])
 392
 393 AS_IF([test "x$def_tls_detect" = "x"],[
 394         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 395 ],[
 396         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 397 ])